* cpm/utils/timer.mac

[avrcpm.git] / cpm / AVRCPM.LIB

; Macro Definitions for CP/M 2.2  BIOS Data Structures.\r
;\r
;	 dtbl	<dph0,dph1,...>		- drive table\r
;\r
;	 dpb	label			- disk parameter block\r
;		sectors_per_track,\r
;		block_size,\r
;		disk_size,\r
;		number_dir_entries,\r
;		checked_dir_entries,\r
;		track_offset,\r
;\r
;	 dph	disk_parameter_block	- disk parameter header\r
;\r
;	 endef				- generate the ram data areas\r
;	\r
;\r
; These macros do not support sector skew, \r
; and assume that the first sector is allways 0.\r
;\r
;\r
; Example, where only drive A: and E: are defined, both with \r
; the avrcpm disk definition (standard ss/sd floppy but without skew):\r
;\r
;	dphtab:	dtbl	<dpha, 0, 0, 0, dphe>\r
;		dpb	dpb243, 26, 1024, 243, 64, 64, 2\r
;	dpha:	dph	dpb243\r
;	dphe:	dph	dpb243\r
;		endef\r
;\r
\r
;	Drive Table.  Contains 16 one word entries.\r
\r
dtbl	macro	?list\r
	local	?n,?i\r
?n	set	0\r
	irp	?drv,<?list>\r
	ifnb	<?drv>\r
	 dw	?drv\r
	else\r
	 dw	0\r
	endif\r
?n	set	?n+1\r
	endm\r
\r
	if ?n gt 16\r
.' Too many drives.  Max 16 allowed'\r
	 exitm\r
	endif\r
\r
	if ?n lt 16\r
	 rept (16-?n)\r
	 dw	0\r
	 endm\r
	endif\r
?dn	set	0\r
	endm\r
\r
ddb	macro	data,messag\r
;;	define a db statement\r
	db	data		messag\r
	endm\r
ddw	macro	data,messag\r
;;	define a dw statement\r
	dw	data		messag\r
	endm\r
\r
dpb	macro	pbn,nsec,bls,dks,dir,cks,ofs\r
;;	 generate the set statements for later tables\r
als&pbn set	(dks)/8 	;;size of allocation vector\r
	 if	((dks) mod 8) ne 0\r
als&pbn  set	als&pbn+1\r
	 endif\r
css&pbn set	(cks+3)/4 	;;number of checksum elements\r
;;	 generate the block shift value\r
blkval	 set	bls/128 ;;number of sectors/block\r
blkshf	 set	0	;;counts right 0's in blkval\r
blkmsk	 set	0	;;fills with 1's from right\r
	 rept	16	;;once for each bit position\r
	  if	blkval eq 1\r
	   exitm\r
	  endif\r
;;	  otherwise, high order 1 not found yet\r
blkshf	  set	blkshf+1\r
blkmsk	  set	(blkmsk shl 1) or 1\r
blkval	  set	blkval/2\r
	 endm\r
;;	 generate the extent mask byte\r
blkval	 set	bls/1024	;;number of kilobytes/block\r
extmsk	 set	0	;;fill from right with 1's\r
	 rept	16\r
	  if	blkval eq 1\r
	    exitm\r
	  endif\r
;;	  otherwise more to shift\r
extmsk	  set	(extmsk shl 1) or 1\r
blkval	  set	blkval/2\r
	 endm\r
;;	 may be double byte allocation\r
	 if	(dks) gt 256\r
extmsk	  set	(extmsk shr 1)\r
	 endif\r
;;	 now generate directory reservation bit vector\r
dirrem	 set	dir	;;# remaining to process\r
dirbks	 set	bls/32	;;number of entries per block\r
dirblk	 set	0	;;fill with 1's on each loop\r
	 rept	16\r
	  if	dirrem eq 0\r
	   exitm\r
	  endif\r
;;	  not complete, iterate once again\r
;;	  shift right and add 1 high order bit\r
dirblk	  set	(dirblk shr 1) or 8000h\r
	  if	dirrem gt dirbks\r
dirrem	   set	dirrem-dirbks\r
	  else\r
dirrem	   set	0\r
	  endif\r
	 endm\r
pbn:	ddw	%nsec,<;sec per track>\r
	ddb	%blkshf,<;block shift>\r
	ddb	%blkmsk,<;block mask>\r
	ddb	%extmsk,<;extnt mask>\r
	ddw	%(dks)-1,<;disk size-1>\r
	ddw	%(dir)-1,<;directory max>\r
	ddb	%dirblk shr 8,<;alloc0>\r
	ddb	%dirblk and 0ffh,<;alloc1>\r
	ddw	%(cks+3)/4,<;check size>\r
	ddw	%ofs,<;offset>\r
	endm\r
\r
\r
lset	macro	lb,dn,val\r
lb&dn	set	val\r
	endm\r
ldw	macro	lb,dn\r
	dw	lb&dn\r
	endm\r
\r
dph	macro	pbn\r
	dw	0000h,0000h	;no translate table\r
	dw	0000h,0000h	;scratch area\r
	dw	dirbuf,pbn	;dir buff,parm block\r
;	dw	csv&?dn,alv&?dn	;check, alloc vectors\r
	ldw	csv,%?dn\r
	ldw	alv,%?dn\r
	lset	css,%?dn,css&pbn\r
	lset	als,%?dn,als&pbn\r
?dn	set	?dn+1\r
	endm\r
\r
\r
lds	macro	lb,dn,val\r
lb&dn:	ds	val&dn\r
	endm\r
\r
\r
endef	macro\r
begdat	equ	$\r
\r
dirbuf: ds	128	;directory access buffer\r
?n	set	0\r
	rept	?dn\r
	lds	alv,%?n,als\r
	lds	csv,%?n,css\r
?n	set	?n+1\r
	endm\r
enddat	equ	$\r
datsiz	equ	$-begdat\r
	endm\r
\r