SVN --> GIT

[avrcpm.git] / cpm / cpmdsk / ELIZA.BAS

5 PRINT TAB(16);"**************************"\r
10 PRINT TAB(26);"ELIZA"\r
20 PRINT TAB(20);"CREATIVE COMPUTING"\r
30 PRINT TAB(18);"MORRISTOWN, NEW JERSEY":PRINT\r
40 PRINT TAB(19);"ADAPTED FOR IBM PC BY"\r
50 PRINT TAB(20);"PATRICIA DANIELSON AND PAUL HASHFIELD"\r
52 PRINT TAB(21);"BE SURE THAT THE CAPS LOCK IS ON"\r
53 PRINT:PRINT TAB(16);"PLEASE DON'T USE COMMAS OR PERIODS IN YOUR INPUTS":PRINT\r
55 PRINT TAB(16);"*************************"\r
60 PRINT :PRINT :PRINT\r
80 REM*****INITIALIZATION**********\r
100 DIM S(36),R(36),N(36)\r
105 DIM KEYWORD$(36),WORDIN$(7),WORDOUT$(7),REPLIES$(112)\r
110 N1=36:N2=14:N3=112\r
112 FOR X = 1 TO N1: READ KEYWORD$(X): NEXT X\r
114 FOR X = 1 TO N2/2: READ WORDIN$(X):READ WORDOUT$(X): NEXT X\r
116 FOR X = 1 TO N3: READ REPLIES$(X): NEXT X\r
130 FOR X=1 TO N1\r
140 READ S(X),L:R(X)=S(X):N(X)=S(X)+L-1\r
150 NEXT X\r
160 PRINT "HI! I'M ELIZA. WHAT'S YOUR PROBLEM?"\r
170 REM ***********************************\r
180 REM *******USER INPUT SECTION**********\r
190 REM ***********************************\r
200 INPUT I$\r
201 I$="  "+I$+"  "\r
210 REM GET RID OF APOSTROPHES\r
220 FOR L=1 TO LEN(I$)\r
230 REM IF MID$(I$,L,1)="'" THEN I$=LEFT$(I$,L-1)+RIGHT$(I$,LEN(I$)-L):GOTO 230\r
240 IF L+4>LEN(I$) THEN 250\r
241 IF MID$(I$,L,4) <> "SHUT" THEN 250\r
242 PRINT "O.K. IF YOU FEEL THAT WAY I'LL SHUT UP...."\r
243 END\r
250 NEXT L\r
255 IF I$=P$ THEN PRINT "PLEASE DON'T REPEAT YOURSELF!":GOTO 170\r
260 REM ***********************************\r
270 REM ********FIND KEYWORD IN I$*********\r
280 REM ***********************************\r
300 FOR K=1 TO N1\r
320 FOR L=1 TO LEN(I$)-LEN(KEYWORD$(K))+1\r
340 IF MID$(I$,L,LEN(KEYWORD$(K)))<>KEYWORD$(K) THEN 350\r
341 IF K <> 13 THEN 349\r
342 IF MID$(I$,L,LEN(KEYWORD$(29)))=KEYWORD$(29) THEN K = 29\r
349 F$ = KEYWORD$(K): GOTO 390\r
350 NEXT L\r
360 NEXT K\r
370 K=36: GOTO 570:REM WE DIDN'T FIND ANY KEYWORDS\r
380 REM ******************************************\r
390 REM **TAKE PART OF STRING AND CONJUGATE IT****\r
400 REM **USING THE LIST OF STRINGS TO BE SWAPPED*\r
410 REM ******************************************\r
430 C$=" "+RIGHT$(I$,LEN(I$)-LEN(F$)-L+1)+" "\r
440 FOR X=1 TO N2/2\r
460 FOR L=1 TO LEN(C$)\r
470 IF L+LEN(WORDIN$(X))>LEN(C$) THEN 510\r
480 IF MID$(C$,L,LEN(WORDIN$(X)))<>WORDIN$(X) THEN 510\r
490 C$=LEFT$(C$,L-1)+WORDOUT$(X)+RIGHT$(C$,LEN(C$)-L-LEN(WORDIN$(X))+1)\r
495 L = L+LEN(WORDOUT$(X))\r
500 GOTO 540\r
510 IF L+LEN(WORDOUT$(X))>LEN(C$)THEN 540\r
520 IF MID$(C$,L,LEN(WORDOUT$(X)))<>WORDOUT$(X) THEN 540\r
530 C$=LEFT$(C$,L-1)+WORDIN$(X)+RIGHT$(C$,LEN(C$)-L-LEN(WORDOUT$(X))+1)\r
535 L=L+LEN(WORDIN$(X))\r
540 NEXT L\r
550 NEXT X\r
555 IF MID$(C$,2,1)=" "THEN C$=RIGHT$(C$,LEN(C$)-1):REM ONLY 1 SPACE\r
556 FOR L=1 TO LEN(C$)\r
557 IF MID$(C$,L,1)="!" THEN C$=LEFT$(C$,L-1)+RIGHT$(C$,LEN(C$)-L):GOTO 557\r
558 NEXT L\r
560 REM **********************************************\r
570 REM **NOW USING THE KEYWORD NUMBER (K) GET REPLY**\r
580 REM **********************************************\r
600 F$ = REPLIES$(R(K))\r
610 R(K)=R(K)+1:IF R(K)>N(K) THEN R(K)=S(K)\r
620 IF RIGHT$(F$,1)<>"*" THEN PRINT F$:P$=I$:GOTO 170\r
625 IF C$<>"   " THEN 630\r
626 PRINT "YOU WILL HAVE TO ELABORATE MORE FOR ME TO HELP YOU"\r
627 GOTO 170\r
630 PRINT LEFT$(F$,LEN(F$)-1);C$\r
640 P$=I$:GOTO 170\r
1000 REM *******************************\r
1010 REM *****PROGRAM DATA FOLLOWS******\r
1020 REM *******************************\r
1030 REM *********KEYWORDS**************\r
1049 REM *******************************\r
1050 DATA "CAN YOU ","CAN I ","YOU ARE ","YOU'RE ","I DON'T ","I FEEL "\r
1060 DATA "WHY DON'T YOU ","WHY CAN'T I ","ARE YOU ","I CAN'T ","I AM ","I'M "\r
1070 DATA "YOU ","I WANT ","WHAT ","HOW ","WHO ","WHERE ","WHEN ","WHY "\r
1080 DATA "NAME ","CAUSE ","SORRY ","DREAM ","HELLO ","HI ","MAYBE "\r
1090 DATA "NO","YOUR ","ALWAYS ","THINK ","ALIKE ","YES ","FRIEND "\r
1100 DATA "COMPUTER", "NOKEYFOUND"\r
1200 REM *********************************\r
1210 REM ***STRING DATA FOR CONJUGATIONS**\r
1220 REM *********************************\r
1230 DATA " ARE "," AM "," WERE "," WAS "," YOU "," I "," YOUR"," MY "\r
1235 DATA " I'VE "," YOU'VE "," I'M "," YOU'RE "\r
1240 DATA " ME "," YOU "\r
1300 REM ******************************\r
1310 REM *********REPLIES**************\r
1320 REM ******************************\r
1330 DATA "DON'T YOU BELIEVE THAT I CAN*"\r
1340 DATA "PERHAPS YOU WOULD LIKE TO BE LIKE ME*"\r
1350 DATA "YOU WANT ME TO BE ABLE TO*"\r
1360 DATA "PERHAPS YOU DON'T WANT TO*"\r
1365 DATA "DO YOU WANT TO BE ABLE TO*"\r
1370 DATA "WHAT MAKES YOU THINK I AM*"\r
1380 DATA "DOES IT PLEASE YOU TO BELIEVE I AM*"\r
1390 DATA "PERHAPS YOU WOULD LIKE TO BE*"\r
1400 DATA "DO YOU SOMETIMES WISH YOU WERE*"\r
1410 DATA "DON'T YOU REALLY*"\r
1420 DATA "WHY DON'T YOU*"\r
1430 DATA "DO YOU WISH TO BE ABLE TO*"\r
1440 DATA "DOES THAT TROUBLE YOU*"\r
1450 DATA "DO YOU OFTEN FEEL*"\r
1460 DATA "DO YOU OFTEN FEEL*"\r
1470 DATA "DO YOU ENJOY FEELING*"\r
1480 DATA "DO YOU REALLY BELIEVE I DON'T*"\r
1490 DATA "PERHAPS IN GOOD TIME I WILL*"\r
1500 DATA "DO YOU WANT ME TO*"\r
1510 DATA "DO YOU THINK YOU SHOULD BE ABLE TO*"\r
1520 DATA "WHY CAN'T YOU*"\r
1530 DATA "WHY ARE YOU INTERESTED IN WHETHER OR NOT I AM*"\r
1540 DATA "WOULD YOU PREFER IF I WERE NOT*"\r
1550 DATA "PERHAPS IN YOUR FANTASIES I AM*"\r
1560 DATA "HOW DO YOU KNOW YOU CAN'T*"\r
1570 DATA "HAVE YOU TRIED?"\r
1580 DATA "PERHAPS YOU CAN NOW*"\r
1590 DATA "DID YOU COME TO ME BECAUSE YOU ARE*"\r
1600 DATA "HOW LONG HAVE YOU BEEN*"\r
1610 DATA "DO YOU BELIEVE IT IS NORMAL TO BE*"\r
1620 DATA "DO YOU ENJOY BEING*"\r
1630 DATA "WE WERE DISCUSSING YOU--NOT ME."\r
1640 DATA "OH, I*"\r
1650 DATA "YOU'RE NOT REALLY TALKING ABOUT ME, ARE YOU?"\r
1660 DATA "WHAT WOULD IT MEAN TO YOU IF YOU GOT*"\r
1670 DATA "WHY DO YOU WANT*"\r
1680 DATA "SUPPOSE YOU SOON GOT*"\r
1690 DATA "WHAT IF YOU NEVER GOT*"\r
1700 DATA "I SOMETIMES ALSO WANT*"\r
1710 DATA "WHY DO YOU ASK?"\r
1720 DATA "DOES THAT QUESTION INTEREST YOU?"\r
1730 DATA "WHAT ANSWER WOULD PLEASE YOU THE MOST?"\r
1740 DATA "WHAT DO YOU THINK?"\r
1750 DATA "ARE SUCH QUESTIONS ON YOUR MIND OFTEN?"\r
1760 DATA "WHAT IS IT THAT YOU REALLY WANT TO KNOW?"\r
1770 DATA "HAVE YOU ASKED ANYONE ELSE?"\r
1780 DATA "HAVE YOU ASKED SUCH QUESTIONS BEFORE?"\r
1790 DATA "WHAT ELSE COMES TO MIND WHEN YOU ASK THAT?"\r
1800 DATA "NAMES DON'T INTEREST ME."\r
1810 DATA "I DON'T CARE ABOUT NAMES --PLEASE GO ON."\r
1820 DATA "IS THAT THE REAL REASON?"\r
1830 DATA "DON'T ANY OTHER REASONS COME TO MIND?"\r
1840 DATA "DOES THAT REASON EXPLAIN ANYTHING ELSE?"\r
1850 DATA "WHAT OTHER REASONS MIGHT THERE BE?"\r
1860 DATA "PLEASE DON'T APOLOGIZE!"\r
1870 DATA "APOLOGIES ARE NOT NECESSARY."\r
1880 DATA "WHAT FEELINGS DO YOU HAVE WHEN YOU APOLOGIZE?"\r
1890 DATA "DON'T BE SO DEFENSIVE!"\r
1900 DATA "WHAT DOES THAT DREAM SUGGEST TO YOU?"\r
1910 DATA "DO YOU DREAM OFTEN?"\r
1920 DATA "WHAT PERSONS APPEAR IN YOUR DREAMS?"\r
1930 DATA "ARE YOU DISTURBED BY YOUR DREAMS?"\r
1940 DATA "HOW DO YOU DO ...PLEASE STATE YOUR PROBLEM."\r
1950 DATA "YOU DON'T SEEM QUITE CERTAIN."\r
1960 DATA "WHY THE UNCERTAIN TONE?"\r
1970 DATA "CAN'T YOU BE MORE POSITIVE?"\r
1980 DATA "YOU AREN'T SURE?"\r
1990 DATA "DON'T YOU KNOW?"\r
2000 DATA "ARE YOU SAYING NO JUST TO BE NEGATIVE?"\r
2010 DATA "YOU ARE BEING A BIT NEGATIVE."\r
2020 DATA "WHY NOT?"\r
2030 DATA "ARE YOU SURE?"\r
2040 DATA "WHY NO?"\r
2050 DATA "WHY ARE YOU CONCERNED ABOUT MY*"\r
2060 DATA "WHAT ABOUT YOUR OWN*"\r
2070 DATA "CAN YOU THINK OF A SPECIFIC EXAMPLE?"\r
2080 DATA "WHEN?"\r
2090 DATA "WHAT ARE YOU THINKING OF?"\r
2100 DATA "REALLY, ALWAYS?"\r
2110 DATA "DO YOU REALLY THINK SO?"\r
2120 DATA "BUT YOU ARE NOT SURE YOU*"\r
2130 DATA "DO YOU DOUBT YOU*"\r
2140 DATA "IN WHAT WAY?"\r
2150 DATA "WHAT RESEMBLANCE DO YOU SEE?"\r
2160 DATA "WHAT DOES THE SIMILARITY SUGGEST TO YOU?"\r
2170 DATA "WHAT OTHER CONNECTIONS DO YOU SEE?"\r
2180 DATA "COULD THERE REALLY BE SOME CONNECTION?"\r
2190 DATA "HOW?"\r
2200 DATA "YOU SEEM QUITE POSITIVE."\r
2210 DATA "ARE YOU SURE?"\r
2220 DATA "I SEE."\r
2230 DATA "I UNDERSTAND."\r
2240 DATA "WHY DO YOU BRING UP THE TOPIC OF FRIENDS?"\r
2250 DATA "DO YOUR FRIENDS WORRY YOU?"\r
2260 DATA "DO YOUR FRIENDS PICK ON YOU?"\r
2270 DATA "ARE YOU SURE YOU HAVE ANY FRIENDS?"\r
2280 DATA "DO YOU IMPOSE ON YOUR FRIENDS?"\r
2290 DATA "PERHAPS YOUR LOVE FOR FRIENDS WORRIES YOU."\r
2300 DATA "DO COMPUTERS WORRY YOU?"\r
2310 DATA "ARE YOU TALKING ABOUT ME IN PARTICULAR?"\r
2320 DATA "ARE YOU FRIGHTENED BY MACHINES?"\r
2330 DATA "WHY DO YOU MENTION COMPUTERS?"\r
2340 DATA "WHAT DO YOU THINK MACHINES HAVE TO DO WITH YOUR PROBLEM?"\r
2350 DATA "DON'T YOU THINK COMPUTERS CAN HELP PEOPLE?"\r
2360 DATA "WHAT IS IT ABOUT MACHINES THAT WORRIES YOU?"\r
2370 DATA "SAY, DO YOU HAVE ANY PSYCHOLOGICAL PROBLEMS?"\r
2380 DATA "WHAT DOES THAT SUGGEST TO YOU?"\r
2390 DATA "I SEE."\r
2400 DATA "I'M NOT SURE I UNDERSTAND YOU FULLY."\r
2410 DATA "COME COME ELUCIDATE YOUR THOUGHTS."\r
2420 DATA "CAN YOU ELABORATE ON THAT?"\r
2430 DATA "THAT IS QUITE INTERESTING."\r
2500 REM *************************\r
2510 REM *****DATA FOR FINDING RIGHT REPLIES\r
2520 REM *************************\r
2530 DATA 1,3,4,2,6,4,6,4,10,4,14,3,17,3,20,2,22,3,25,3\r
2540 DATA 28,4,28,4,32,3,35,5,40,9,40,9,40,9,40,9,40,9,40,9\r
2550 DATA 49,2,51,4,55,4,59,4,63,1,63,1,64,5,69,5,74,2,76,4\r
2560 DATA 80,3,83,7,90,3,93,6,99,7,106,6\r
\1a\1a\1a\1a\1a\1a\1a