* cpm/BIOS.MAC

[avrcpm.git] / cpm / utils / ACT.MAC

; This is a utility program to control the timer of the AVR CP/M emulator.\r
; This file is stolen from the SIMH AltairZ80 Simulator.\r
;\r
; changed to assemble with z80asm\r
; \r
	.z80				; mnemonics only\r
\r
TIMERCTL	equ 040h\r
DEBUGPORT	equ 04FH\r
\r
printStringCmd	equ	09h\r
bdos		equ	5\r
cr		equ	13\r
lf		equ	10\r
cmdLine		equ	80h\r
starttimercmd	equ	1\r
quitTimerCmd	equ	2\r
printTimerCmd	equ	15\r
uptimeCmd	equ	16\r
\r
StopTraceCmd	equ	00h\r
StartTraceCmd	equ	01h\r
PrintStackCmd	equ	02h\r
\r
	aseg\r
	org	100h\r
\r
	jp	start\r
\r
usage:	db	'Usage: ACT S|P|B|Q|U|T|N',cr,lf\r
	db	'  S = (Re)Start the timer',cr,lf\r
	db	'  P = Print elapsed time since last S or Q command',cr,lf\r
	db	'  B = Print elapsed time for simple benchmark loop. wait < 60s',cr,lf\r
	db	'         ATmega88 with 20MHz D0 = 035,999s',cr,lf\r
	db	'  Q = Print the timer, then restart it',cr,lf\r
	db	'  U = Print uptime',cr,lf\r
	db	'  T = Trace enable',cr,lf\r
	db	'  N = Trace disable',cr,lf\r
	db	'  K = Print stack usage',cr,lf\r
	db	'$',1AH\r
\r
start:	ld	a,(cmdLine)		; get number of characters on command line\r
	or	a\r
	jp	z,pusage		; print usage, if command line empty\r
	ld	a,(cmdLine+2)		; get first character\r
	cp	'B'\r
	jp	z,bench\r
	ld	b,a\r
	ld	hl,table		; <HL> points to (letter, port, command)\r
again:	ld	a,(hl)			; compare command line letter with table entry\r
	inc	hl			; point to command\r
	cp	b\r
	jp	z,found			; if found\r
	inc	hl			; otherwise proceed to next entry\r
	inc	hl\r
	cp	'$'			; end of table?\r
	jp	nz,again		; try next character\r
\r
pusage:	ld	de,usage		; address of usage text\r
	ld	c,printStringCmd	; CP/M command for print\r
	jp	bdos			; print it, get ret from bdos\r
\r
found:	ld	a,(hl)			; get timer command\r
	inc	hl\r
	ld	(port),a\r
	ld	a,(hl)\r
	db	0D3H			;"out (port),a"\r
port:	db	0\r
	ret\r
\r
bench:\r
	ld	a,startTimerCmd\r
	out	(TIMERCTL),a		; start timer\r
; loop starts here\r
	ld	c,10\r
l1:	ld	b,0\r
l2:	ld	a,0\r
l3:	dec	a\r
	jp	nz,l3			; 256 x\r
	dec	b\r
	jp	nz,l2			; 256 x\r
	dec	c\r
	jp	nz,l1			; 10 x\r
; loop ends here\r
	ld	a,printTimerCmd\r
	out	(TIMERCTL),a		; print elapsed time\r
	ret				; and done\r
\r
table:\r
	db	'N',DEBUGPORT,StopTraceCmd\r
	db	'T',DEBUGPORT,StartTraceCmd\r
	db	'K',DEBUGPORT,PrintStackCmd\r
	db	'S',TIMERCTL,starttimercmd\r
	db	'P',TIMERCTL,printTimerCmd\r
	db	'Q',TIMERCTL,quitTimerCmd\r
	db	'U',TIMERCTL,uptimeCmd\r
	db	'$'			; Stop mark\r
\r
timend	equ	$\r
	ds	((timend+127) and 0ff80h)-timend	; fill remainder with zeroes\r
\r
	end\r
; vim:set ts=8 noet nowrap\r
\r