Disassembler: rename 'print arg' routines

[ddt180.git] / ddt180.z80

; Disassembled ddtz.com, version "DDT/Z    [8101]"\r
; with modified relocater.\r
;\r
; Build steps:\r
;   - Assemble to a .REL file with M80 or a compatible assembler.\r
;   - Use Digital Research Link-80 to generate a .PRL file (op switch).\r
;   - Cut the .PRL header (first 256 byte) end rename the result to DDTZ.COM.\r
\r
;-------------------------------------------------------------------------------\r
; Relocation loader\r
;\r
TPA	equ	0100h\r
	cseg\r
	.phase	TPA\r
\r
	jp	start\r
	ds	3\r
\r
ldr_end:\r
ldr_size	equ	$ - TPA\r
current_phase	defl	$\r
\r
	.dephase\r
current_cseg	defl	$\r
\r
;-------------------------------------------------------------------------------\r
; DDT/Z core\r
;\r
\r
; Some greneral definitions\r
\r
BS		equ	08h\r
TAB		equ	09h\r
CR		equ	0dh\r
LF		equ	0ah\r
DEL		equ	7fh\r
CNTRX		equ	'X'-'@'\r
\r
; CP/M memory layout\r
\r
BDOS		equ	5\r
TPA		equ	0100h\r
\r
; BDOS function calls\r
\r
BDOS_PSTR	equ	9       ;Print String\r
\r
; ddtz specific definitions\r
\r
STACK_SIZE	equ	80	;ddtz internal stack\r
CONBUF_SIZE	equ	80	;Size of console input buffer\r
EXPR_BUF_SIZE	equ	128	;expressen buffer for conditional breakpoints\r
BP_CNT		equ	12	;Number of breakpoints\r
BP_SIZE		equ	4	;Size of a breakpoint record\r
\r
;-------------------------------------------------------------------------------\r
\r
ddtz_base:\r
	jp ddtz_bdos\r
l0003h:\r
	rst 30h\r
di_or_ei:\r
	nop\r
	ret\r
ddtz_bdos:\r
	jp	0\r
\r
current_cseg	defl	$ - current_cseg\r
	.phase	current_phase + current_cseg\r
signon:\r
	db	'DDTZ/180'\r
	db	' - Version '\r
	maclib	version.inc\r
	defvers\r
	db	CR,LF,'$'\r
msgz80:\r
	db	'Z80 or better required!',cr,lf,'$'\r
\r
current_phase	defl	$\r
	.dephase\r
current_cseg	defl	$\r
	ds	STACK_SIZE - (current_phase - signon)\r
\r
\r
stack:\r
reg.l2:	db	000h\r
reg.h2:	db	000h\r
reg.e2:	db	000h\r
reg.d2:	db	000h\r
reg.c2:	db	000h\r
reg.b2:	db	000h\r
reg.f2:	db	000h\r
reg.a2:	db	000h\r
	db	000h\r
reg.i:	db	000h\r
reg.iy:	dw	0000h\r
reg.ix:	dw	0000h\r
reg.f:	db	000h\r
reg.a:	db	000h\r
reg.c:	db	000h\r
reg.b:	db	000h\r
reg.e:	db	000h\r
reg.d:	db	000h\r
reg.l:	db	000h\r
reg.h:	db	000h\r
reg_sp:	dw	TPA\r
reg.iff:\r
	db	0f3h\r
	db	0c3h\r
reg.pc:	dw	TPA\r
\r
cmd_rpt:dw	mainloop\r
\r
;-------------------------------------------------------------------------------\r
\r
conbuf:\r
	db	CONBUF_SIZE\r
\r
	ld sp,stack\r
	exx\r
	ld de,ddtz_base\r
	call cp_hl_de\r
	jr c,l0079h\r
	ex de,hl\r
l0079h:\r
	ld de,TPA\r
l007ch:\r
	dec hl\r
	ld (hl),000h\r
	ld a,h\r
	sub d\r
	ld b,a\r
	ld a,l\r
	sub e\r
	or b\r
	jr nz,l007ch\r
	ld a,i\r
	ld (reg.i),a\r
	ld a,0f3h\r
	jp po,l0093h\r
	ld a,0fbh\r
l0093h:\r
	ld (reg.iff),a\r
	call di_or_ei\r
	ld hl,ddtz_base\r
	ld l,000h\r
	ld (reg_sp),hl\r
\r
	ld hl,(1)		;wboot addr\r
	ld de,?const\r
	ld b,6\r
vini_l:\r
	inc	hl\r
	inc	hl\r
	inc	hl\r
	ex	de,hl\r
	inc	hl\r
	ld	(hl),e\r
	inc	hl\r
	ld	(hl),d\r
	inc	hl\r
	ex	de,hl\r
	djnz	vini_l\r
\r
	jr mainloop\r
\r
	ds	CONBUF_SIZE + 3 - ($ - conbuf)\r
\r
;-------------------------------------------------------------------------------\r
\r
?const:	jp	0		; return console input status\r
?conin:	jp	0		; return console input character\r
?cono:	jp	0		; send console output character\r
?list:	jp	0		; send list output character\r
?auxo:	jp      0		; send auxiliary output character\r
?auxi:	jp      0		; return auxiliary input character\r
\r
CMDTAB:\r
	dw	ERROR ;cmd_@	;examine/substitute the displacement register @\r
	dw	ERROR ;cmd_A	;Assemble\r
	dw	cmd_B		;Breakpoints display/set/clear\r
	dw	ERROR ;cmd_C	;trace over Calls\r
	dw	cmd_D		;Display memory in hex and ascii\r
	dw	ERROR		;\r
	dw	ERROR ;cmd_F	;specify Filename and command line\r
	dw	cmd_G		;Go\r
	dw	cmd_H		;compute Hex and other expressions\r
	dw	cmd_I		;Input a byte from port\r
	dw	ERROR		;\r
	dw	ERROR		;\r
	dw	cmd_L		;List disassembled code\r
	dw	cmd_M		;Move memory [and verify]\r
	dw	ERROR		;\r
	dw	cmd_O		;Output a byte to port\r
	dw	ERROR		;\r
	dw	cmd_Q		;Qery memory for byte string\r
	dw	cmd_R		;Read binary or hex file\r
	dw	cmd_S		;Substitute memory\r
	dw	cmd_T		;Trace\r
	dw	ERROR		;\r
	dw	cmd_V		;Verify (compare) two memory areas\r
	dw	ERROR ;cmd_W	;Write a file to disk\r
	dw	cmd_X		;eXamine [and substitute] registers\r
	dw	ERROR ;cmd_Y	;examine [and substitute] Y variables\r
	dw	cmd_Z		;Zap (fill) memory with a byte string\r
\r
ERROR:\r
	call	pstr_inl\r
	dc	'?',CR,LF\r
	;fall thru\r
mainloop:\r
	ld sp,stack\r
	ld hl,(reg.pc)\r
	call bp_clr_temporary\r
	ld hl,(cmd_rpt)\r
	ld de,mainloop\r
	push de\r
	call cp_hl_de\r
	ld a,'>'\r
	call outchar\r
	call nz,outchar\r
	call z,outbl\r
	call get_line\r
	call skipbl\r
	jr z,exe_hl\r
	pop hl\r
	push hl\r
	ld (cmd_rpt),hl\r
	inc de\r
	sub '@'\r
	jr c,ERROR\r
	cp 'Z'+1-'@'\r
	jr nc,ERROR\r
	ld hl,CMDTAB\r
	call add_hl_a2\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
exe_hl:\r
CALL_HL:\r
	jp (hl)\r
\r
;-------------------------------------------------------------------------------\r
\r
crlf:\r
	call	pstr_inl\r
	dc	CR,LF\r
	xor a\r
	ld (con_col),a\r
	call inchar\r
	jr c,mainloop\r
	ret\r
\r
sub_01d9h:\r
	call	pstr_inl\r
	dc	'-'\r
	dec hl\r
	jp cpl.hl\r
\r
out_hl_dec_neg:\r
	push hl\r
	call sub_01d9h\r
	defb 03eh		;ld a,..  swallow push hl\r
out.hl.dec:\r
	push hl\r
	ld b,006h\r
	call sub_01f9h\r
	pop hl\r
	call	pstr_inl\r
	dc	'.'\r
l01f3h:\r
	call outbl\r
	djnz l01f3h\r
	ret\r
\r
sub_01f9h:\r
	dec b\r
	push de\r
	ld de,10\r
	call div_hl_de\r
	ld a,h\r
	or l\r
	call nz,sub_01f9h\r
	ld a,e\r
	pop de\r
	jr out_dgt\r
\r
out_hl_neg:\r
	push hl\r
	call sub_01d9h\r
	call out_hl\r
	pop hl\r
	ret\r
\r
out_hl:\r
	ld a,h\r
	call out_hex\r
	ld a,l\r
\r
out_hex:\r
	push af\r
	rra\r
	rra\r
	rra\r
	rra\r
	call out_dgt\r
	pop af\r
\r
out_dgt:\r
	or	0f0h\r
	daa\r
	add	a,0a0h\r
	adc	a,040h\r
	jr outchar\r
\r
out.bin.w:\r
	ld a,h\r
	call out.bin.b\r
	ld a,l\r
out.bin.b:\r
	ld b,8\r
l01c9h:\r
	rlca\r
	push	af\r
	ld	a,'0'/2\r
	adc	a,a\r
	call	outchar\r
	pop af\r
	djnz l01c9h\r
	ld a,'"'\r
	jr outchar\r
\r
out.ascii:\r
	push bc\r
	ld c,a\r
	res 7,a\r
	cp ' '\r
	push af\r
	call nc,outbl\r
	call	pstr_inl\r
	dc	''''\r
	pop af\r
	jr nc,l0242h\r
	sub 0c0h\r
	ld b,a\r
	call	pstr_inl\r
	dc	'^'\r
	ld a,b\r
l0242h:\r
	call outchar\r
	cp ''''\r
	call z,outchar\r
	call	pstr_inl\r
	dc	''''\r
	sla c\r
	pop bc\r
	ret nc\r
	ld a,'.'\r
	jr outchar\r
\r
outbl6:\r
	call outbl2\r
outbl4:\r
	call outbl2\r
outbl2:\r
	call outbl\r
outbl:\r
	ld a,' '\r
outchar:\r
	push ix\r
	push iy\r
	push hl\r
	push de\r
	push bc\r
	push af\r
	and 07fh\r
	ld	c,a\r
	call	?cono\r
	ld hl,con_col\r
	inc (hl)\r
	pop af\r
	pop bc\r
	pop de\r
	pop hl\r
	pop iy\r
	pop ix\r
	ret\r
\r
pstr_sel:\r
	inc b\r
	jr pstr_sel2\r
pstr_sel1:\r
	call sub_0345h\r
pstr_sel2:\r
	djnz pstr_sel1\r
	;fall thru\r
pstr:\r
	ld a,(hl)\r
	inc hl\r
	and a\r
	ret z\r
	call outchar\r
	ret m\r
	jr pstr\r
\r
pstr_inl:\r
	ex	(sp),hl\r
	call	pstr\r
	ex	(sp),hl\r
	ret\r
\r
p_goto_col:\r
	ld	a,(con_col)\r
	cp	c\r
	ret	nc\r
	ret	z\r
	call	outbl\r
	jr	p_goto_col\r
\r
;-------------------------------------------------------------------------------\r
\r
incharw:\r
	call inchar\r
	jr nc,incharw\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
inchar:\r
	push ix\r
	push hl\r
	push de\r
	push bc\r
	call	?const\r
	and a\r
	jr	z,inch1\r
	call	?conin\r
	scf\r
inch1:\r
	pop bc\r
	pop de\r
	pop hl\r
	pop ix\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
DELC:\r
	ld	a,b\r
	or	a\r
	ret	z\r
	call	DELC1\r
	dec	hl\r
	dec	b\r
	inc	c\r
	ld	a,(hl)\r
	cp	' '\r
	ret	nc\r
DELC1:\r
	call	pstr_inl\r
	dc	BS,' ',BS\r
	ret\r
\r
DELL:\r
	ld a,b			;\r
	or a			;\r
	ret z			;\r
	call DELC		;\r
	jr DELL			;\r
\r
;-------------------------------------------------------------------------------\r
\r
get_line:\r
	push hl			;\r
	ld hl,conbuf		;\r
	ld c,(hl)		;\r
	inc hl			;\r
	ld b,000h		;\r
	inc hl			;\r
inlnxtch:\r
	ld a,c			;\r
	or a			;\r
	jr z,inl_e		;\r
	call incharw		;\r
	cp CR			;\r
	jr z,inl_e		;Accept line\r
	cp LF			;\r
	jr z,inl_e		;Accept line\r
\r
	cp BS			;\r
	jr z,gl_1		;\r
	cp DEL			;\r
	jr nz,gl_2		;\r
gl_1:\r
	call DELC		;Delete Char\r
	jr inlnxtch		;\r
gl_2:\r
	cp CNTRX		;\r
	jr nz,gl_3		;\r
	call DELL		;Delete Line\r
	jr inlnxtch		;\r
gl_3:\r
	cp TAB			;\r
	jr nz,gl_4		;\r
	ld a,' '		;\r
gl_4:\r
	ld (hl),a		;\r
	cp ' '			;\r
	jr nc,gl_5		;\r
	ld a,'^'		;Controll characters\r
	call outchar		;\r
	ld a,(hl)		;\r
	add a,'@'		;\r
gl_5:\r
	call outchar		;\r
	inc hl			;\r
	inc b			;\r
	dec c			;\r
	jr inlnxtch		;\r
\r
inl_e:\r
	ld (hl),0\r
	ld hl,conbuf+1		;\r
	ld (hl),b		;\r
	call CRLF		;\r
	inc	hl\r
	ex	de,hl\r
	pop hl			;\r
	ret			;\r
\r
;-------------------------------------------------------------------------------\r
\r
get_char_upper:\r
	ld a,(de)\r
toupper:\r
	cp 'a'\r
	ret c\r
	cp 'z'+1\r
	ccf\r
	ret c\r
	and 05fh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
skipbl0:\r
	inc de\r
skipbl:\r
	call get_char_upper\r
	cp ' '\r
	jr z,skipbl0\r
	or a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
next_arg:\r
	call skipbl\r
	cp ','\r
	ret nz\r
	call skipbl0\r
	cp a\r
	ret\r
\r
assert_eol:\r
	call skipbl\r
	ret z\r
to_error:\r
	jp ERROR\r
\r
;-------------------------------------------------------------------------------\r
\r
chk_stack:\r
	push hl\r
	push de\r
	ld hl,0\r
	add hl,sp\r
	ld de,stack-(STACK_SIZE-28)\r
	call cp_hl_de\r
	pop de\r
	pop hl\r
	jr c,to_error\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
add_hl_a2:\r
	add a,a\r
add_hl_a:\r
	add a,l\r
	ld l,a\r
	ret nc\r
	inc h\r
	ret\r
\r
cp_hl_de:\r
	and a\r
	sbc hl,de\r
	add hl,de\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
lookupch:\r
	ld b,0\r
l02f5h:\r
	ld a,(hl)\r
	and a\r
	ret z\r
	call get_char_upper\r
	cp (hl)\r
	jr z,l0300h\r
	inc hl\r
	inc b\r
	jr l02f5h\r
l0300h:\r
	scf\r
	inc de\r
	ret\r
\r
sub_0303h:\r
	ld hl,t_reg_names\r
	ld b,07fh\r
l030ch:\r
	inc b\r
	ld a,(hl)\r
	and a\r
	ret z\r
	call sub_031ch\r
	jr nc,l030ch\r
	res 7,b\r
	ret\r
\r
sub_031ch:\r
	push bc\r
	push de\r
l031eh:\r
	call get_char_upper\r
	xor (hl)\r
	and 07fh\r
	jr nz,l0336h\r
	bit 7,(hl)\r
	inc hl\r
	inc de\r
	jr z,l031eh\r
	scf\r
	bit 7,b\r
	call z,sub_060ch\r
	jr nc,l0339h\r
	pop af\r
	scf\r
	pop bc\r
	ret\r
l0336h:\r
	call sub_0345h\r
l0339h:\r
	pop de\r
	and a\r
	pop bc\r
	ret\r
\r
sub_0345h:\r
	ld a,(hl)\r
	and a\r
	ret z\r
l0348h:\r
	ld a,(hl)\r
	inc hl\r
	and a\r
	ret m\r
	jr l0348h\r
\r
sub_034eh:\r
	call get_arg_range\r
	push hl\r
	push bc\r
	call next_arg\r
	call sub_0363h\r
	ex de,hl\r
	pop bc\r
	pop hl\r
	ret\r
\r
sub_035dh:\r
	call expr\r
	jr c,error0\r
	ret\r
\r
sub_0363h:\r
	call sub_035dh\r
l0366h:\r
	jp assert_eol\r
\r
get_lastarg_def:\r
	call get_arg_def\r
	jr l0366h\r
\r
get_arg_def:\r
	push hl\r
	call expr\r
	jr c,l0375h\r
	ex (sp),hl\r
l0375h:\r
	pop hl\r
	ret\r
\r
sub_0377h:\r
	call b_037c_start\r
	jr l0366h\r
\r
b_037c_start:\r
	defb 0e6h		;and a,..  clear carry\r
get_arg_range:\r
	scf\r
	ex af,af'\r
	push bc\r
	push hl\r
	call expr\r
	jr nc,l038ch\r
	ex af,af'\r
	jr c,error0\r
	ex af,af'\r
	pop hl\r
	defb 03eh		;ld a,..  swallow pop af\r
l038ch:\r
	pop af\r
	call get_range\r
	jr nc,l0398h\r
	ex af,af'\r
	pop bc\r
	ret nc\r
error0:\r
	jp ERROR\r
l0398h:\r
	pop af\r
	ret\r
\r
get_range:\r
	call next_arg\r
	cp 'S'\r
	jr nz,l03a2h\r
	inc de\r
l03a2h:\r
	push hl\r
	push af			;'S' flag\r
	call expr\r
	jr c,l03b8h\r
	ld b,h\r
	ld c,l\r
	pop af\r
	pop hl\r
	jr z,l03b6h		;'S'?\r
	ld a,c\r
	sub l\r
	ld c,a\r
	ld a,b\r
	sbc a,h\r
	ld b,a\r
	inc bc\r
l03b6h:\r
	and a\r
	ret\r
l03b8h:\r
	pop af\r
	pop hl\r
	jr z,error0		;'S', but no expression following\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
expr:\r
	call skipbl\r
expr1:\r
	call do_factor\r
	ret c\r
l0433h:\r
	call do_binary_op\r
	push hl\r
	push bc\r
	call do_factor\r
	pop bc\r
	ex de,hl\r
	ex (sp),hl\r
	jr nc,l0447h\r
	pop de\r
	ld a,b\r
	or c\r
	ret z\r
	jp ERROR\r
\r
l0447h:\r
	ld a,b\r
	or c\r
	push bc\r
	ret nz\r
	pop bc\r
\r
doop_add:\r
	add hl,de\r
l044dh:\r
	pop de\r
	jr l0433h\r
\r
doop_sub:\r
	and a\r
	sbc hl,de\r
	jr l044dh\r
\r
doop_mlt:\r
	push bc\r
	ld b,h\r
	ld c,l\r
	ld hl,0\r
	ld a,010h\r
l045dh:\r
	add hl,hl\r
	ex de,hl\r
	add hl,hl\r
	ex de,hl\r
	jr nc,l0464h\r
	add hl,bc\r
l0464h:\r
	dec a\r
	jr nz,l045dh\r
	pop bc\r
	jr l044dh\r
\r
doop_div:\r
	call div_hl_de\r
	jr l044dh\r
\r
doop_mod:\r
	call div_hl_de\r
	ex de,hl\r
	jr l044dh\r
\r
; divide x/y\r
;     hl: x\r
;     de: y\r
;   return:\r
;     hl: q  (x/y)\r
;     de: r  (x%y)\r
\r
div_hl_de:\r
	push	bc\r
	ex	de,hl		;de: x\r
	ld	b,h		;bc: y\r
	ld	c,l\r
	ld	hl,0		;hl: r\r
	ld	a,16\r
\r
;  de: x   (x shifted out, q shifted in)\r
;  bc: y\r
;  hl: r   (initially 0)\r
\r
div_lp:\r
	ex	de,hl\r
	add	hl,hl		;x <<= 1\r
	ex	de,hl\r
	adc	hl,hl		;r <<= 1\r
	inc	de\r
	or	a\r
	sbc	hl,bc\r
	jr 	nc,div_norestore\r
	dec	de\r
	add	hl,bc\r
div_norestore:\r
	dec	a\r
	jr	nz,div_lp\r
	ex	de,hl\r
	pop	bc\r
	ret\r
\r
doop_and:\r
	ld a,h\r
	and d\r
	ld h,a\r
	ld a,l\r
	and e\r
	ld l,a\r
	jr l044dh\r
\r
doop_or:\r
	ld a,h\r
	or d\r
	ld h,a\r
	ld a,l\r
	or e\r
	ld l,a\r
	jr l044dh\r
\r
doop_xor:\r
	ld a,h\r
	xor d\r
	ld h,a\r
	ld a,l\r
	xor e\r
	ld l,a\r
	jr l044dh\r
\r
do_binary_op:\r
	push hl\r
	ld hl,tab_op_a\r
	call lookupch\r
	ld a,b\r
	ld hl,tblf_opa\r
	call add_hl_a2\r
	ld c,(hl)\r
	inc hl\r
	ld b,(hl)\r
	pop hl\r
	ret\r
\r
tab_op_a:\r
	DB	'+-*/%&!#',0\r
\r
tblf_opa:\r
	dw	doop_add\r
	dw	doop_sub\r
	dw	doop_mlt\r
	dw	doop_div\r
	dw	doop_mod\r
	dw	doop_and\r
	dw	doop_or\r
	dw	doop_xor\r
	dw	0\r
\r
;-------------------------------------------------------------------------------\r
\r
fact_factor:\r
	call do_factor\r
	ret nc\r
	jp ERROR\r
\r
do_factor:\r
	call chk_stack\r
	call get.number\r
	ret nc\r
	inc de\r
	ld hl,ddtz_base-1\r
	cp 'T'\r
	ret z\r
	ld hl,(high_load)\r
	cp 'H'\r
	ret z\r
	ld hl,(max_load)\r
	cp 'M'\r
	ret z\r
	ld hl,TPA\r
	cp 'L'\r
	ret z\r
	cp '-'\r
	jr z,fact_factneg\r
	cp '~'\r
	jr z,fact_factinv\r
	cp '+'\r
	jr z,fact_factor\r
	cp '^'\r
	jr z,fact_reg.CPU\r
	cp '('\r
	jr z,fact_mem\r
	cp '['\r
	jr z,expr_brckt\r
	cp ''''\r
	jr z,fact_factstring\r
	dec de\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
fact_factstring:\r
	ld hl,0\r
l054bh:\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0557h\r
	and a\r
	ret z\r
l0552h:\r
	ld h,l\r
	ld l,a\r
	inc de\r
	jr l054bh\r
l0557h:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0552h\r
	sub '.'\r
	or a\r
	ret nz\r
	inc de\r
	set 7,l\r
	ret\r
\r
fact_reg.CPU:\r
	call sub_0caeh\r
	jr nc,error1\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	and a\r
	bit 0,c\r
	ret nz\r
	ld h,000h\r
	ret\r
\r
fact_factneg:\r
	call fact_factor\r
	dec hl\r
cpl.hl:\r
	ld a,h\r
	cpl\r
	ld h,a\r
	ld a,l\r
	cpl\r
	ld l,a\r
	ret\r
\r
fact_factinv:\r
	call fact_factor\r
	jr cpl.hl\r
\r
fact_mem:\r
	call expr1\r
	jr c,error1\r
	ld a,(de)\r
	cp ')'\r
	jr nz,error1\r
	inc de\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	ld a,(de)\r
	inc de\r
	cp '.'\r
	ret z\r
	dec de\r
	xor a\r
	ld h,a\r
	ret\r
\r
expr_brckt:\r
	call expr1\r
	jr c,error1\r
	ld a,(de)\r
	cp ']'\r
	inc de\r
	ret z\r
error1:\r
	jp ERROR\r
\r
;-------------------------------------------------------------------------------\r
\r
get.number:\r
	call get.hexdigit\r
	ret c\r
	push de\r
test_number:\r
	inc de\r
	call get.hexdigit\r
	jr nc,test_number\r
	pop de\r
	cp '.'\r
	jr z,get_dec_number\r
	cp '"'\r
	jr z,get_bin_number\r
	ld hl,0\r
next_hexdigit:\r
	call get.hexdigit\r
	jr c,hexnum_done\r
	add hl,hl\r
	add hl,hl\r
	add hl,hl\r
	add hl,hl\r
	call add_hl_a\r
	inc de\r
	jr next_hexdigit\r
\r
hexnum_done:\r
	xor 'H'\r
	ret nz\r
	inc de\r
	ret\r
\r
get_bin_number:\r
	ld hl,0\r
next_bindigit:\r
	call get.bindigit\r
l05dbh:\r
	inc de\r
	jr c,l05e4h\r
	add hl,hl\r
	call add_hl_a\r
	jr next_bindigit\r
l05e4h:\r
	cp '"'\r
	jr nz,error11\r
	call get.bindigit\r
	jr nc,l05dbh\r
	or a\r
	ret\r
\r
get_dec_number:\r
	ld hl,0\r
next_decdigit:\r
	call get.decdigit\r
	inc de\r
	jr c,decnum_done\r
	push bc\r
	add hl,hl\r
	ld b,h\r
	ld c,l\r
	add hl,hl\r
	add hl,hl\r
	add hl,bc\r
	pop bc\r
	call add_hl_a\r
	jr next_decdigit\r
decnum_done:\r
	cp '.'\r
	ret z\r
error11:\r
	jp ERROR\r
\r
sub_060ch:\r
	call get_char_upper\r
	cp 'Z'+1\r
	jr l0614h\r
\r
get.hexdigit:\r
	ld a,(de)\r
hex_digit:\r
	call toupper\r
	cp 'F'+1\r
l0614h:\r
	ccf\r
	ret c\r
	cp 'A'\r
	jr c,l061eh\r
	sub 'A'-10\r
	ret\r
\r
get.decdigit:\r
	call get_char_upper\r
l061eh:\r
	cp '9'+1\r
	jr l0625h\r
\r
get.bindigit:\r
	call get_char_upper\r
	cp '1'+1\r
l0625h:\r
	ccf\r
	ret c\r
	cp '0'\r
	ret c\r
	sub '0'\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_cpustat0:\r
	call assert_eol\r
p_cpustat:\r
	call p_f\r
	call outbl2\r
	ld hl,b_06e9_start\r
	ld de,b_0709_start\r
	ld b,6\r
l063eh:\r
	call p_regs\r
	djnz l063eh\r
	call outbl6\r
	push hl\r
	push de\r
	ld iy,(reg.pc)\r
	call p_disas_instr\r
	pop de\r
	pop hl\r
	call crlf\r
	call p_f2\r
	call outbl2\r
	ld b,7\r
l065bh:\r
	call p_regs\r
	djnz l065bh\r
	jp crlf\r
\r
p_f:\r
	ld a,(reg.f)\r
	call p_flags\r
	ld a,(reg.iff)\r
	cp 0f3h\r
	jr z,outbl_1\r
	ld a,'E'\r
	jp outchar\r
p_f2:\r
	ld a,(reg.f2)\r
	call p_flags\r
	jr outbl_1\r
\r
p_flags:\r
	push	hl\r
	ld	hl,t_flag_names+7\r
	ld	c,a\r
	ld	b,8\r
fl_loop:\r
	ld	a,' '\r
	cp	(hl)\r
	ld	a,c\r
	rlca\r
	ld	c,a\r
	jr	z,fl_skip\r
	ld	a,(hl)\r
	call	c,outchar\r
	call	nc,outbl\r
fl_skip:\r
	dec	hl\r
	djnz	fl_loop\r
	pop	hl\r
	ret\r
\r
p_regs:\r
	push de\r
	call pstr\r
	call	pstr_inl\r
	dc	'='\r
	ex (sp),hl\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	inc hl\r
	ld a,(hl)\r
	inc hl\r
	push hl\r
	and a\r
	jr z,l06deh\r
	ex de,hl\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	ex de,hl\r
	call out_hl\r
	jr l06e2h\r
l06deh:\r
	ld a,(de)\r
	call out_hex\r
l06e2h:\r
	pop de\r
	pop hl\r
outbl_1:\r
	jp outbl\r
\r
b_06e9_start:\r
	DC	'A '\r
	DC	'BC '\r
	DC	'DE '\r
	DC	'HL '\r
	DC	'SP'\r
	DC	'PC'\r
	DC	'a'''\r
	DC	'bc'''\r
	DC	'de'''\r
	DC	'hl'''\r
	DC	'IX'\r
	DC	'IY'\r
	DC	'I'\r
	DB	0\r
\r
b_0709_start:\r
	dw	reg.a\r
	db	000h\r
	dw	reg.c\r
	db	001h\r
	dw	reg.e\r
	db	001h\r
	dw	reg.l\r
	db	001h\r
	dw	reg_sp\r
	db	001h\r
	dw	reg.pc\r
	db	002h\r
	dw	reg.a2\r
	db	000h\r
	dw	reg.c2\r
	db	001h\r
	dw	reg.e2\r
	db	001h\r
	dw	reg.l2\r
	db	001h\r
	dw	reg.ix\r
	db	001h\r
	dw	reg.iy\r
	db	001h\r
	dw	reg.i\r
	db	000h\r
	db	000h\r
\r
;-------------------------------------------------------------------------------\r
; > G [startaddr] [;breakp..]\r
;      Go [to start] [with temporary breakpoints]\r
\r
cmd_G:\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call expr\r
	jr c,l0740h\r
	ld (reg.pc),hl\r
l0740h:\r
	call skipbl\r
	jr z,user_go0\r
	cp ';'\r
	jp nz,ERROR\r
	inc de\r
	ld a,002h\r
	call bp_enter\r
user_go0:\r
	jp user_go\r
\r
;-------------------------------------------------------------------------------\r
\r
bpl_init:\r
	ld	b,BP_CNT\r
	ld	ix,bp_tab\r
	ex	(sp),hl\r
	ld	(pbl_loop_adr),hl\r
	ex	(sp),hl\r
	ret\r
\r
bpl_next:\r
	ld	de,BP_SIZE\r
	push	af\r
	add	ix,de\r
	pop	af\r
	dec	b\r
	ret	z\r
\r
	ex	(sp),hl\r
	ld	hl,(pbl_loop_adr)\r
	ex	(sp),hl\r
	ret\r
\r
bp_clr_temporary:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 0f1h\r
	ld (ix+000h),a\r
\r
	call bpl_next\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > B\r
;      display all breakpoints\r
; > B breakp [breakp..]\r
;      set breakpoints\r
; > BX\r
;      clear all breakpoints\r
; > BX breakp [breakp..]\r
;      clear breakpoints\r
;\r
; breakp can be any valid expression\r
\r
cmd_B:\r
	call skipbl\r
	jr z,bp_print\r
	inc de\r
	cp 'X'\r
	jr z,bp_clr0\r
	dec de\r
	ld a,001h\r
	jp bp_enter\r
\r
bp_clr0:\r
	call skipbl\r
	jr z,bp_clr_all\r
bp_clr_next:\r
	call expr\r
	jp c,assert_eol\r
	push de\r
	call bp_clr\r
	pop de\r
	call next_arg\r
	jr bp_clr_next\r
\r
bp_clr_all:\r
	scf\r
bp_clr:\r
	call	bpl_init\r
\r
	push af\r
	jr c,l07a7h\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	call cp_hl_de\r
	jr nz,l07aeh\r
l07a7h:\r
	ld (ix+000h),000h\r
l07aeh:\r
	pop af\r
	call bpl_next\r
	ret\r
\r
bp_print:\r
	ld	c,0\r
	call	bpl_init\r
\r
	bit 0,(ix+000h)\r
	jr z,bp_pr_cont\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	call out_hl\r
	call outbl2\r
	inc	c\r
bp_pr_cont:\r
	call bpl_next\r
	ld	a,c\r
	or	a\r
	call 	nz,crlf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; Add break points to list\r
;   A = 1	 Permanent (B command)\r
;   A = 2	 Temporary (G command)\r
\r
bp_enter:\r
	ld b,a\r
	call skipbl\r
	ret z\r
\r
	push bc\r
	call expr\r
	jr c,error12\r
	pop bc\r
	bit 0,b\r
	push bc\r
	push de\r
	push hl\r
	call nz,bp_clr\r
	pop hl\r
	call bp_get_freeslot\r
	pop de\r
	ld (ix+002h),l\r
	ld (ix+003h),h\r
	call next_arg\r
	pop af\r
	ld (ix+000h),a\r
	and 00fh\r
	jr bp_enter\r
\r
bp_get_freeslot:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 00fh\r
	ret z\r
\r
	call	bpl_next\r
error12\r
	jp ERROR\r
\r
\r
;-------------------------------------------------------------------------------\r
; Breakpoint handling routine.\r
\r
bpddtz:\r
	ld (reg.l),hl\r
	pop hl\r
	dec hl\r
	ld (reg.pc),hl\r
	ld (reg_sp),sp\r
	ld sp,reg.l\r
	push de\r
	push bc\r
	push af\r
	push ix\r
	push iy\r
	ld a,i\r
	call di_or_ei\r
	ld h,a\r
	ld l,000h\r
	push hl\r
	ld a,0f3h		; EI\r
	jp po,l08dfh\r
	ld a,0fbh		; DI\r
l08dfh:\r
	ld (reg.iff),a\r
	ex af,af'\r
	push af\r
	exx\r
	push bc\r
	push de\r
	push hl\r
	call bp_restore_mem\r
	ld a,(b_21e2_start)\r
	dec a\r
	jr z,l090bh\r
	call inchar		;Keyboard hit?\r
	jr c,do_break		;yes\r
	call sub_0913h\r
	and a\r
	jp z,user_go\r
	and 083h\r
	jp z,l2151h\r
do_break:\r
	call bp_clr_temporary\r
	call p_cpustat\r
	jp mainloop\r
\r
l090bh:\r
	ld (b_21e2_start),a\r
	ld c,007h\r
	jp l0a41h\r
\r
sub_0913h:\r
	ld a,080h\r
	ex af,af'\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 007h\r
	jr z,l0938h\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	ld hl,(reg.pc)\r
	call cp_hl_de\r
	jr nz,l0938h\r
	ex af,af'\r
	res 7,a\r
	or (ix+000h)\r
	ex af,af'\r
l0938h:\r
	call	bpl_next\r
	ex af,af'\r
	ret\r
\r
bp_restore_mem:\r
	call	bpl_init\r
\r
	bit 5,(ix+000h)\r
	res 5,(ix+000h)\r
	jr z,l099ah\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	ld a,(l0003h)\r
	cp (hl)\r
	jr nz,l099ah\r
	ld a,(ix+001h)\r
	ld (hl),a\r
l099ah:\r
	res 3,(ix+000h)\r
\r
	call	bpl_next\r
	ret\r
\r
bp_tst_@pc:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 003h\r
	jr z,bp_tst_e\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	ld hl,(reg.pc)\r
	call cp_hl_de\r
	ret z\r
bp_tst_e:\r
	call	bpl_next\r
	sub a\r
	inc a\r
	ret\r
\r
bp_trace_enter:\r
	call bp_get_freeslot\r
	ld (ix+002h),l\r
	ld (ix+003h),h\r
	ld a,(b_21e2_start)\r
	and a\r
	ld a,008h\r
	jr nz,bp_t_e\r
	rra\r
bp_t_e:\r
	ld (ix+000h),a\r
	ret\r
\r
bp_set_to_mem:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and c\r
	jr z,l0a1dh\r
	set 5,(ix+000h)\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	ld a,(hl)\r
	ld (ix+001h),a\r
	ld a,(l0003h)\r
	ld (hl),a\r
	and 038h\r
	ld h,000h\r
	ld l,a\r
	ld (hl),0c3h\r
	inc hl\r
	ld de,bpddtz\r
	ld (hl),e\r
	inc hl\r
	ld (hl),d\r
l0a1dh:\r
\r
	call	bpl_next\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
user_go:\r
	sub a\r
	ld (b_21e2_start),a\r
	ld a,(bp_p_cpu_flag)\r
	and a\r
	call nz,p_cpustat\r
	call bp_tst_@pc\r
	ld c,007h\r
	jr nz,l0a41h\r
	ld a,001h\r
	ld (b_21e2_start),a\r
	call tc_set_bp\r
	ld c,008h\r
l0a41h:\r
	call bp_set_to_mem\r
	ld sp,reg.l2\r
	pop hl\r
	pop de\r
	pop bc\r
	pop af\r
	exx\r
	ex af,af'\r
	pop af\r
	ld i,a\r
	pop iy\r
	pop ix\r
	pop af\r
	pop bc\r
	pop de\r
	pop hl\r
	ld sp,(reg_sp)\r
	jp reg.iff\r
\r
;-------------------------------------------------------------------------------\r
; > Y\r
;      examine all Y variables\r
; > Y[0..9]\r
;      examine (and substitute) an Y variable\r
\r
\r
;-------------------------------------------------------------------------------\r
; > X\r
;      eXamine (display) all cpu registers and\r
;      the instruction at the current program counter\r
; > X register\r
;      eXamine (and substitute) a register\r
\r
\r
cmd_X:\r
	call skipbl\r
	call sub_0caeh\r
	jp nc,p_cpustat0\r
	call assert_eol\r
	ld a,b\r
	cp 25\r
	jr z,l0c5fh\r
	cp 26\r
	jr z,l0c4fh\r
	ex de,hl\r
	ld hl,t_reg_names\r
	call pstr_sel\r
	call l0c33h\r
\r
	call outbl\r
	push de\r
	push bc\r
	call get_line\r
	call skipbl\r
	jr z,l0c30h\r
	call sub_0363h\r
	ex de,hl\r
	pop bc\r
	pop hl\r
	ld (hl),e\r
	bit 0,c\r
	ret z\r
	inc hl\r
	ld (hl),d\r
	ret\r
l0c30h:\r
	pop af\r
	pop hl\r
	ret\r
\r
l0c33h:\r
	call	pstr_inl\r
	dc	'='\r
	ld a,(de)\r
	bit 0,c\r
	jp z,out_hex\r
	ld l,a\r
	inc de\r
	ld a,(de)\r
	dec de\r
	ld h,a\r
	jp out_hl\r
\r
l0c4fh:\r
	call p_f\r
	ld a,0f3h\r
	ld (reg.iff),a\r
	scf\r
	call sub_0c6ah\r
	ld (reg.f),a\r
	ret\r
l0c5fh:\r
	call p_f2\r
	and a\r
	call sub_0c6ah\r
	ld (reg.f2),a\r
	ret\r
\r
sub_0c6ah:\r
	push af\r
	call outbl\r
	call assert_eol\r
	call get_line\r
	pop af\r
	ex af,af'\r
	ld b,0\r
l0c76h:\r
	call skipbl\r
	ld a,b\r
	ret z\r
	push bc\r
	ld hl,t_flag_names\r
	call lookupch\r
	jp nc,ERROR\r
	inc	b\r
	xor	a\r
	scf\r
nxt_f:\r
	rla\r
	djnz	nxt_f\r
	pop	bc\r
	jr	c,l0c97h\r
	or	b\r
	ld	b,a\r
	jr l0c76h\r
\r
l0c97h:\r
	ex af,af'\r
	jp nc,ERROR\r
	ex af,af'\r
	ld a,0fbh\r
	ld (reg.iff),a\r
	jr l0c76h\r
\r
t_flag_names:\r
	db	'CNV H ZSE',0\r
\r
sub_0caeh:\r
	call sub_0303h\r
	ret nc\r
	ld a,b\r
	add a,b\r
	add a,b\r
	ld hl,b_0cfa_start\r
	call add_hl_a\r
	ld c,(hl)\r
	inc hl\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	scf\r
	ret\r
\r
t_reg_names:\r
	DC	'BC'''		;0\r
	DC	'DE'''		;1\r
	DC	'HL'''		;2\r
	DC	'BC'		;3\r
	DC	'DE'		;4\r
	DC	'HL'		;5\r
	DC	'A'''		;6\r
	DC	'B'''		;7\r
	DC	'C'''		;8\r
	DC	'D'''		;9\r
	DC	'E'''		;10\r
	DC	'H'''		;11\r
	DC	'L'''		;12\r
	DC	'A'		;13\r
	DC	'B'		;14\r
	DC	'C'		;15\r
	DC	'D'		;16\r
	DC	'E'		;17\r
	DC	'H'		;18\r
	DC	'L'		;19\r
	DC	'IX'		;20\r
	DC	'IY'		;21\r
	DC	'SP'		;22\r
	DC	'PC'		;23\r
	DC	'I'		;24\r
	DC	'F'''		;25\r
	DC	'F'		;26\r
	DB	0\r
\r
b_0cfa_start:\r
	db	003h\r
	dw	reg.c2\r
	db	003h\r
	dw	reg.e2\r
	db	003h\r
	dw	reg.l2\r
	db	003h\r
	dw	reg.c\r
	db	003h\r
	dw	reg.e\r
	db	003h\r
	dw	reg.l\r
	db	000h\r
	dw	reg.a2\r
	db	000h\r
	dw	reg.b2\r
	db	000h\r
	dw	reg.c2\r
	db	000h\r
	dw	reg.d2\r
	db	000h\r
	dw	reg.e2\r
	db	000h\r
	dw	reg.h2\r
	db	000h\r
	dw	reg.l2\r
	db	000h\r
	dw	reg.a\r
	db	000h\r
	dw	reg.b\r
	db	000h\r
	dw	reg.c\r
	db	000h\r
	dw	reg.d\r
	db	000h\r
	dw	reg.e\r
	db	000h\r
	dw	reg.h\r
	db	000h\r
	dw	reg.l\r
	db	003h\r
	dw	reg.ix\r
	db	003h\r
	dw	reg.iy\r
	db	003h\r
	dw	reg_sp\r
	db	003h\r
	dw	reg.pc\r
	db	000h\r
	dw	reg.i\r
	db	000h\r
	dw	reg.f2\r
	db	000h\r
	dw	reg.f\r
\r
;-------------------------------------------------------------------------------\r
; > S [startaddr]\r
;      Substitute memory\r
\r
cmd_S:\r
	ld hl,(last_S)\r
	call get_lastarg_def\r
l0d60h:\r
	ld (last_S),hl\r
	call out_hl\r
	call outbl\r
	ld a,(hl)\r
	call out_hex\r
	call outbl2\r
	call get_line\r
	call skipbl\r
	inc hl\r
	jr z,l0d60h\r
	dec hl\r
	inc de\r
	cp '.'\r
	jr	nz,cmds_dash\r
	call get_char_upper\r
	or	a\r
	jr	nz,l0d8ah\r
	ret\r
cmds_dash:\r
	jp z,assert_eol\r
	cp '-'\r
	jr nz,l0d8ah\r
	call get_char_upper\r
	or a\r
	dec hl\r
	jr z,l0d60h\r
	inc hl\r
l0d8ah:\r
	dec de\r
	call sub_0ef8h\r
	jr l0d60h\r
\r
;-------------------------------------------------------------------------------\r
; > @\r
;      examine (substitute) displacement register @\r
\r
;cmd_@:\r
\r
;-------------------------------------------------------------------------------\r
; >>I [port]\r
;      Input a byte from port\r
\r
cmd_I:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_I)\r
	call get_lastarg_def\r
	ld (last_I),hl\r
	ld b,h\r
	ld c,l\r
	in a,(c)\r
	push af\r
	call out_hex\r
	call outbl4\r
	pop af\r
	call out.bin.b\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; >>O [byte] [port]\r
;      Output a byte to a port\r
\r
cmd_O:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_O_val)\r
	call get_arg_def\r
	ld a,l\r
	ld (last_O_val),a\r
	push af\r
	call next_arg\r
	ld hl,(last_O_addr)\r
	call get_lastarg_def\r
	ld (last_O_addr),hl\r
	ld b,h\r
	ld c,l\r
	pop af\r
	out (c),a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > Vstartaddr endaddr targetaddr\r
;      Verify (compare) two memory areas\r
\r
cmd_V:\r
	call sub_034eh\r
l0dedh:\r
	push bc\r
	ld a,(de)\r
	ld b,(hl)\r
	cp b\r
	jr z,l0e10h\r
	ld c,a\r
	call out_hl\r
	call outbl\r
	ld a,b\r
	call out_hex\r
	call outbl2\r
	ld a,c\r
	call out_hex\r
	call outbl\r
	ex de,hl\r
	call out_hl\r
	ex de,hl\r
	call crlf\r
l0e10h:\r
	pop bc\r
	inc de\r
	cpi\r
	jp pe,l0dedh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > M startaddr endaddr destaddr\r
;      Move memory\r
\r
cmd_M:\r
	call sub_034eh\r
	call cp_hl_de\r
	jr nc,cmdm_up\r
	add hl,bc\r
	ex de,hl\r
	add hl,bc\r
	ex de,hl\r
	dec hl\r
	dec de\r
	lddr\r
	db 01h		;swallow ldir instruction (ld bc,...)\r
cmdm_up:\r
	ldir\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > H\r
;      display Highest load address of last filed loaded, Maximum "High"\r
;      off all loaded files, and Top address of available memory\r
; > H expression\r
;      evaluate expression and display result in hex, decimal and other formats\r
\r
cmd_H:\r
	call expr\r
	jp c,p_max_high0\r
	call assert_eol\r
	call out_hl\r
	call outbl2\r
	call out_hl_neg\r
	call outbl4\r
	call out.hl.dec\r
	call outbl2\r
	call out_hl_dec_neg\r
	call outbl4\r
	call out.bin.w\r
	call outbl2\r
	ld a,l\r
	call out.ascii\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; > Q[J] startaddr endaddr bytes\r
;      Query memory for a byte string [Justified]\r
\r
cmd_Q:\r
	call get_arg_range\r
	push bc\r
	push hl\r
	call sub_0ee6h\r
	pop hl\r
l0e96h:\r
	push	hl\r
	push	de\r
	push bc\r
l0edah:\r
	ld a,(de)\r
	cp (hl)\r
	jr nz,l0ee2h\r
	inc de\r
	inc hl\r
	djnz l0edah\r
l0ee2h:\r
	pop bc\r
	pop de\r
	pop hl\r
	jr nz,l0eb0h\r
	push bc\r
	ld bc,16\r
	and a			;clear carry\r
	call sub_0f58h\r
	pop bc\r
l0eb0h:\r
	inc hl\r
	ex (sp),hl\r
	dec hl\r
	ld a,h\r
	or l\r
	ex (sp),hl\r
	jr nz,l0e96h\r
	pop bc\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > Z startaddr endaddr bytes\r
;      Zap (fill) memory with a byte string\r
\r
cmd_Z:\r
	call get_arg_range\r
	push bc\r
	push hl\r
	call sub_0ee6h\r
	ld a,b\r
	pop hl\r
	pop bc\r
	push hl\r
	ex de,hl\r
l0ec7h:\r
	ldi\r
	jp po,l0ed3h\r
	dec a\r
	jr nz,l0ec7h\r
	pop hl\r
	ldir\r
	ret\r
l0ed3h:\r
	pop hl\r
	ret\r
\r
sub_0ee6h:\r
	ld hl,conbuf+1\r
	call sub_0ef7h\r
	ld de,conbuf+1\r
	and a\r
	sbc hl,de\r
	ld b,l\r
	ret nz\r
	jp ERROR\r
\r
sub_0ef7h:			;from cmd_Q, cmd_Z\r
	db	0e6h		;and 037h (clear carry)\r
sub_0ef8h:			;from cmd_S\r
	scf\r
l0ef9h:\r
	push af\r
	call next_arg\r
	cp ''''\r
	jr z,l0f1eh\r
	push hl\r
	call expr\r
	ld a,l\r
	pop hl\r
	jr c,l0f42h\r
	ld (hl),a\r
	inc hl\r
	jr l0f3ah\r
l0f1eh:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0f2bh\r
	or a\r
	jr z,l0f42h\r
l0f27h:\r
	ld (hl),a\r
	inc hl\r
	jr l0f1eh\r
l0f2bh:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0f27h\r
	cp '.'\r
	jr nz,l0f3ah\r
	inc de\r
	dec hl\r
	set 7,(hl)\r
	inc hl\r
l0f3ah:\r
	pop af\r
	jr nc,l0ef9h\r
	ld (last_S),hl\r
	jr l0ef9h\r
l0f42h:\r
	pop af\r
	ret nc\r
	ld (last_S),hl\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; >>D [startaddr] [endaddr]\r
;      Display memory in hex and ASCII\r
\r
cmd_D:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_D)\r
	ld bc,128\r
	call sub_0377h\r
	scf\r
sub_0f58h:\r
	push bc\r
	push de\r
	push hl\r
	push af\r
l0f5ch:\r
	call out_hl\r
	call outbl2\r
	ld de,0\r
l0f68h:\r
	ld a,(hl)\r
	inc hl\r
	call out_hex\r
	call outbl\r
	dec bc\r
	inc e\r
	ld a,e\r
	cp 010h\r
	jr z,l0f80h\r
	and 003h\r
	call z,outbl\r
	ld a,b\r
	or c\r
	jr nz,l0f68h\r
l0f80h:\r
	call outbl\r
	and a\r
	sbc hl,de\r
l0f86h:\r
	ld a,(hl)\r
	call sub_0fa3h\r
	call outchar\r
	inc hl\r
	dec e\r
	jr nz,l0f86h\r
	pop af\r
	push af\r
	jr nc,l0f97h\r
	ld (last_D),hl\r
l0f97h:\r
	call crlf\r
	ld a,b\r
	or c\r
	jr nz,l0f5ch\r
	pop af\r
	pop hl\r
	pop de\r
	pop bc\r
	ret\r
\r
sub_0fa3h:\r
	and 07fh\r
	cp 07fh\r
	jr z,l0fach\r
	cp ' '\r
	ret nc\r
l0fach:\r
	ld a,'.'\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > Fcommandline\r
;      specifiy filenames and command line\r
\r
;cmd_F:\r
\r
;-------------------------------------------------------------------------------\r
; > R [displacement]\r
;	Read Intel Hex File from console [add displacement]\r
\r
cmd_R:\r
	ld hl,0\r
	call get_lastarg_def	;get offset from command line\r
	push hl\r
	ld hl,0\r
	ld (high_load),hl\r
w_recstart:\r
	call i.getchar\r
	jr z,rdhex_done\r
	cp ':'\r
	jr nz,w_recstart\r
	ld c,0			;init checksum\r
	call i.gethexbyte	;record len\r
	ld b,a\r
	call i.gethexbyte	;address high\r
	ld h,a\r
	call i.gethexbyte	;address low\r
	ld l,a\r
	call i.gethexbyte	;record type (ignored)\r
	ld a,b\r
	and a			;record len == 0?\r
	jr z,rdhex_done\r
l16c6h:\r
	call i.gethexbyte\r
	pop de			;offset\r
	push de\r
	push hl\r
	add hl,de\r
	call i.storebyte\r
	pop hl\r
	inc hl\r
	djnz l16c6h		;repeat for record len\r
	call i.gethexbyte	;checksum\r
	ld a,c\r
	and a\r
	jr nz,error2		;exit if checksum error\r
	jr w_recstart		;next record\r
\r
rdhex_done:\r
	pop hl\r
	call i.gethexbyte\r
	jp p_max_high\r
\r
i.gethexbyte:\r
	call sub_16f6h\r
	rlca\r
	rlca\r
	rlca\r
	rlca\r
	ld d,a\r
	call sub_16f6h\r
	add a,d\r
	ld d,a\r
	add a,c\r
	ld c,a\r
	ld a,d\r
	ret\r
\r
sub_16f6h:\r
	call i.getchar\r
	jr z,error2\r
	call hex_digit\r
	ret nc\r
error2:\r
	jp ERROR\r
\r
i.getchar:\r
	call incharw\r
	cp 01ah\r
	ret\r
\r
i.storebyte:\r
	push af\r
	push de\r
	ld de,TPA		;lowest allowed load address\r
	call cp_hl_de\r
	jr c,error2\r
	ld de,(BDOS+1)		;highest allowed load address\r
	call cp_hl_de\r
	jr nc,error2\r
	ld de,(high_load)\r
	call cp_hl_de\r
	jr c,l1157h\r
	ld (high_load),hl\r
l1157h:\r
	ld de,(max_load)\r
	call cp_hl_de\r
	jr c,l1163h\r
	ld (max_load),hl\r
l1163h:\r
	pop de\r
	pop af\r
	ld (hl),a		;store byte\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_max_high0:\r
	call assert_eol\r
p_max_high:\r
	call pstr_inl\r
	DC	'High = '\r
	ld hl,(high_load)\r
	call out_hl\r
	call pstr_inl\r
	DC	'  Max = '\r
	ld hl,(max_load)\r
	call out_hl\r
	call pstr_inl\r
	DC	'  Top = '\r
	ld hl,ddtz_base-1\r
	call out_hl\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; > Wstartaddr endaddr\r
;      Write a file to disk\r
\r
;cmd_W:\r
\r
;-------------------------------------------------------------------------------\r
; > A [startaddr]\r
;      Assemble Zilog Z180 mnemonics\r
\r
;cmd_A:\r
\r
;-------------------------------------------------------------------------------\r
; >>L [startaddr] [endaddr]\r
;      List disassembled code\r
\r
cmd_L:\r
	ld (cmd_rpt),hl\r
	call expr\r
	jr nc,l18dbh\r
	ld hl,(last_L)\r
l18dbh:\r
	call next_arg\r
	call get_range\r
	jr nc,l1905h\r
	call assert_eol\r
	ld b,16\r
l18ebh:\r
	push bc\r
	call	cmdl_p_line\r
	pop bc\r
	djnz l18ebh\r
	ret\r
\r
l1905h:\r
	call assert_eol\r
	ld	d,h\r
	ld	e,l\r
	add	hl,bc\r
	ex	de,hl\r
l190fh:\r
	push	de\r
	call	cmdl_p_line\r
	pop 	de\r
	call	cp_hl_de\r
	jr	c,l190fh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
cmdl_p_line:\r
	push	hl\r
	call out_hl\r
	call outbl2\r
	sub a\r
	ld (con_col),a\r
	push	hl\r
	pop	iy\r
	call p_disas_instr\r
	call	crlf\r
	pop	hl\r
	ld	c,b\r
	ld	b,0\r
	add	hl,bc\r
	ld	(last_L),hl\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_disas_instr:\r
	call disas_get_instrlen\r
	jr nc,l197fh\r
	push	bc\r
	ld	a,(con_col)\r
	add	a,5\r
	ld	c,a\r
	call	pstr					;print mnemonic\r
	call	p_goto_col\r
	ex de,hl\r
	call CALL_HL					;print arguments\r
	pop bc\r
	scf\r
	ret\r
\r
l197fh:\r
	call pstr_inl\r
	DC	'???'\r
	ld b,1\r
	sub a\r
	ret\r
\r
disas_get_instrlen:\r
	sub a\r
	ld (isprefix_ixiy),a\r
	ld a,(iy+000h)\r
	cp 0edh\r
	jr z,disas_pfx.ED\r
	cp 0ddh\r
	jr z,l19abh\r
	cp 0fdh\r
	jr z,l19afh\r
sub_19a0h:\r
	ld a,(iy+000h)\r
	cp 0cbh\r
	jr z,disas_pfx.CB\r
	jr disas_nopfx\r
l19abh:\r
	ld a,1\r
	jr l19b1h\r
l19afh:\r
	ld a,2\r
l19b1h:\r
	ld (isprefix_ixiy),a\r
	call disas_pfx.DDFD\r
	ret nc\r
	push bc\r
	call sub_19a0h\r
	pop af\r
	add a,b\r
	ld b,a\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_nopfx:\r
	ld hl,b_1b54_start		;2 byte opcodes\r
	call lookup_op_arg\r
	ld b,2\r
	ret c\r
	ld hl,b_1ab6_start		;1 byte opcodes (no parameters)\r
	call lookup_op\r
	ld b,1\r
	ret c\r
	ld hl,b_1ad1_start		;1 byte opcodes\r
	call lookup_op_arg\r
	ld b,1\r
	ret c\r
	ld hl,b_1b9b_start		;3 byte opcodes\r
	call lookup_op_arg\r
	ld b,3\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.ED:\r
	inc iy\r
	ld hl,b_1bc9_start		;1 byte opcode, no arguments\r
	call lookup_op\r
	ld b,2\r
	ret c\r
	ld hl,b_1bf4_start\r
	call lookup_op_arg\r
	ld b,2\r
	ret c\r
\r
	ld hl,l228bh\r
	call lookup_op_arg\r
	ld b,3\r
	ret c\r
	ld hl,b_1c40_start\r
	call lookup_op_arg\r
	ld b,4\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.CB:\r
	push iy\r
	inc iy\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr z,l1a42h\r
	inc iy\r
l1a42h:\r
	ld hl,b_1c55_start\r
	call lookup_op_arg\r
	pop iy\r
	ld b,2\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.DDFD:\r
	inc iy\r
	ld hl,b_19ef_start\r
	call test_DDFD\r
	ld b,002h\r
	ret c\r
	ld hl,l1a0ah\r
	call test_DDFD\r
	ld b,001h\r
	ret c\r
	ld a,(iy+000h)\r
	cp 0cbh\r
	jr nz,l19edh\r
	ld a,(iy+002h)\r
	cp 036h\r
	ret z\r
	and 007h\r
	cp 006h\r
	jr nz,l19edh\r
	ld b,002h\r
	scf\r
	ret\r
l19edh:\r
	and a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; DD/FD 3 byte (ix+d)/(iy+d)\r
b_19ef_start:\r
	db	034h\r
	db	035h\r
	db	036h\r
	db	046h\r
	db	04eh\r
	db	056h\r
	db	05eh\r
	db	066h\r
	db	06eh\r
	db	070h\r
	db	071h\r
	db	072h\r
	db	073h\r
	db	074h\r
	db	075h\r
	db	077h\r
	db	07eh\r
	db	086h\r
	db	08eh\r
	db	096h\r
	db	09eh\r
	db	0a6h\r
	db	0aeh\r
	db	0b6h\r
	db	0beh\r
	db	0\r
\r
; DD/FD 2 byte\r
l1a0ah:\r
	db	009h\r
	db	019h\r
	db	021h\r
	db	022h\r
	db	023h\r
	db	029h\r
	db	02ah\r
	db	02bh\r
	db	039h\r
	db	0e1h\r
	db	0e3h\r
	db	0e5h\r
	db	0e9h\r
	db	0f9h\r
	db	0\r
\r
;-------------------------------------------------------------------------------\r
\r
lookup_op:\r
	ld a,(hl)\r
	cp 0ffh\r
	ret z\r
	cp (iy+000h)\r
	jr z,l1a7fh\r
	inc hl\r
	inc hl\r
	jr lookup_op\r
l1a7fh:\r
	ld de,p_arg_none\r
	inc hl\r
	ld c,(hl)\r
	jr get_mnemonic\r
\r
\r
test_DDFD:\r
	ld a,(hl)\r
	and a\r
	ret z\r
	inc hl\r
	cp (iy+000h)\r
	jr nz,test_DDFD\r
	scf\r
	ret\r
\r
lookup_op_arg:\r
	ld a,(iy+000h)\r
	and (hl)\r
	inc hl\r
	cp (hl)\r
	jr z,l1aa8h\r
	inc hl\r
	inc hl\r
	inc hl\r
	inc hl\r
	ld a,(hl)\r
	and a\r
	jr nz,lookup_op_arg\r
	ret\r
\r
l1aa8h:\r
	inc hl\r
	ld c,(hl)\r
	inc c\r
	ret z\r
	dec c\r
	inc hl\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
get_mnemonic:\r
	ld hl,t_MNEMONICS\r
	ld b,0\r
	add hl,bc\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; 1 byte opcodes (no parameters)\r
; Format: db opcode, t_MNEMONICS-index\r
b_1ab6_start:\r
	db 076h,o_HALT		;halt\r
	db 0d9h,o_EXX		;exx\r
	db 0f3h,o_DI		;di\r
	db 0fbh,o_EI		;ei\r
	db 000h,o_NOP		;nop\r
	db 007h,o_RLCA		;rlca\r
	db 00fh,o_RRCA		;rrca\r
	db 017h,o_RLA		;rla\r
	db 01fh,o_RRA		;rra\r
	db 027h,o_DAA		;daa\r
	db 02fh,o_CPL		;cpl\r
	db 037h,o_SCF		;scf\r
	db 03fh,o_CCF		;ccf\r
	db 0c9h,o_RET		;ret\r
	db 0ffh\r
\r
\r
; 1 byte opcodes\r
; Format: db mask, match, t_MNEMONICS-index\r
;	  dw argument formating function\r
b_1ad1_start:\r
	db 0c0h,040h,o_LD	;ld r[y],r[z]\r
	dw p_arg_ry_rz\r
	db 0f8h,080h,o_ADD	;add a,r[z]\r
	dw p_arg_a_r\r
	db 0f8h,088h,o_ADC	;adc a,r[z]\r
	dw p_arg_a_r\r
	db 0f8h,090h,o_SUB	;sub r[z]\r
	dw p_rz\r
	db 0f8h,098h,o_SBC	;sbc a,r[z]\r
	dw p_arg_a_r\r
	db 0f8h,0a0h,o_AND	;and r[z]\r
	dw p_rz\r
	db 0f8h,0a8h,o_XOR	;xor r[z]\r
	dw p_rz\r
	db 0f8h,0b0h,o_OR	;or r[z]\r
	dw p_rz\r
	db 0f8h,0b8h,o_CP	;cp r[z]\r
	dw p_rz\r
	db 0c7h,0c0h,o_RET	;ret cc\r
	dw p_cc\r
	db 0c7h,0c7h,o_RST	;rst\r
	dw p_arg_rst\r
	db 0cfh,0c1h,o_POP	;pop rr\r
	dw p_rp2\r
	db 0cfh,0c5h,o_PUSH	;push rr\r
	dw p_rp2\r
	db 0ffh,0e3h,o_EX	;ex (sp),hl\r
	dw l1ca0h\r
	db 0ffh,0e9h,o_JP	;jp (hl)\r
	dw l1caeh\r
	db 0ffh,0ebh,o_EX	;ex de,hl\r
	dw p_arg_ex_dehl\r
	db 0ffh,0f9h,o_LD	;ld sp,hl\r
	dw l1cc1h\r
	db 0cfh,003h,o_INC	;inc rr\r
	dw p_rp\r
	db 0cfh,00bh,o_DEC	;dec rr\r
	dw p_rp\r
	db 0c7h,004h,o_INC	;inc r\r
	dw p_ry\r
	db 0c7h,005h,o_DEC	;dec r\r
	dw p_ry\r
	db 0ffh,008h,o_EX	;ex af,af'\r
	dw p_arg_ex_afaf\r
	db 0cfh,009h,o_ADD	;add hl,rr\r
	dw l1cd3h\r
	db 0efh,002h,o_LD	;ld (rr),a ;rr=bc,de\r
	dw l1cdch\r
	db 0efh,00ah,o_LD	;ld a,(rr) ;rr=bc,de\r
	dw l1ce5h\r
	db 0\r
\r
; 2 byte opdodes\r
b_1b54_start:\r
	db 0c7h,006h,o_LD	;ld r,nn\r
	dw l1cfah\r
	db 0ffh,0c6h,o_ADD	;add a,nn\r
	dw l1cf5h\r
	db 0ffh,0ceh,o_ADC	;adc a,nn\r
	dw l1cf5h\r
	db 0ffh,0d6h,o_SUB	;sub nn\r
	dw l1d09h\r
	db 0ffh,0deh,o_SBC	;sbc a,nn\r
	dw l1cf5h\r
	db 0ffh,0e6h,o_AND	;and nn\r
	dw l1d09h\r
	db 0ffh,0eeh,o_XOR	;xor nn\r
	dw l1d09h\r
	db 0ffh,0f6h,o_OR	;or nn\r
	dw l1d09h\r
	db 0ffh,0feh,o_CP	;cp nn\r
	dw l1d09h\r
	db 0ffh,010h,o_DJNZ	;djnz\r
	dw p_arg_jrel\r
	db 0ffh,018h,o_JR	;jr\r
	dw p_arg_jrel\r
	db 0e7h,020h,o_JR	;jr cc,\r
	dw p_arg_cc_jrel\r
	db 0ffh,0d3h,o_OUT	;out (nn),a\r
	dw l1d37h\r
	db 0ffh,0dbh,o_IN	;in a,(nn)\r
	dw l1d29h\r
	db 0\r
\r
; 3 byte opcodes\r
b_1b9b_start:\r
	db 0c7h,0c2h,o_JP	;jp cc,mn\r
	dw p_arg_cc_mn\r
	db 0c7h,0c4h,o_CALL	;call cc,mn\r
	dw p_arg_cc_mn\r
	db 0cfh,001h,o_LD	;ld ww,mn\r
	dw p_arg_ww_mn\r
	db 0ffh,0c3h,o_JP	;jp mn\r
	dw p_arg_mn\r
	db 0ffh,0cdh,o_CALL	;call mn\r
	dw p_arg_mn\r
	db 0ffh,022h,o_LD	;ld (mn),hl\r
	dw p_arg_addr_hl\r
	db 0ffh,02ah,o_LD	;ld hl,(mn)\r
	dw p_arg_hl_addr\r
	db 0ffh,032h,o_LD	;ld (mn),a\r
	dw p_arg_addr_a\r
	db 0ffh,03ah,o_LD	;ld a,(mn)\r
	dw p_arg_a_addr\r
	db 0\r
\r
; Prefix ED + 1 byte opcode, no arguments\r
; Format: opcode, t_MNEMONICS index\r
b_1bc9_start:\r
	db 044h,o_NEG		;neg\r
	db 045h,o_RETN		;retn\r
	db 04dh,o_RETI		;reti\r
	db 067h,o_RRD		;rrd\r
	db 06fh,o_RLD		;rld\r
	db 0a0h,o_LDI		;ldi\r
	db 0a1h,o_CPI		;cpi\r
	db 0a2h,o_INI		;ini\r
	db 0a3h,o_OUTI		;outi\r
	db 0a8h,o_LDD		;ldd\r
	db 0a9h,o_CPD		;cpd\r
	db 0aah,o_IND		;ind\r
	db 0abh,o_OUTD		;outd\r
	db 0b0h,o_LDIR		;ldir\r
	db 0b1h,o_CPIR		;cpir\r
	db 0b2h,o_INIR		;inir\r
	db 0b3h,o_OTIR		;otir\r
	db 0b8h,o_LDDR		;lddr\r
	db 0b9h,o_CPDR		;cpdr\r
	db 0bah,o_INDR		;indr\r
	db 0bbh,o_OTDR		;otdr\r
	db 08bh,o_OTDM		;otdm\r
	db 09bh,o_OTDMR		;otdmr\r
	db 083h,o_OTIM		;otim\r
	db 093h,o_OTIMR		;otimr\r
	db 076h,o_SLP		;slp\r
	db 0ffh			;<end mark>\r
\r
b_1bf4_start:\r
	db 0ffh,070h,0ffh	;in (c)    ;\r
	dw p_arg_in_c	   	;\r
	db 0c7h,040h,o_IN	;in r,(c)  ;r=b,c,d,e,h,l,a\r
	dw p_arg_in_c	   	;\r
	db 0ffh,071h,0ffh	;out (c),0 ;\r
	dw p_arg_out_c	   	;\r
	db 0c7h,041h,o_OUT	;out (c),r ;r=b,c,d,e,h,l,a\r
	dw p_arg_out_c	   	;\r
	db 0cfh,042h,o_SBC	;sbc hl,rr\r
	dw l1dcah	   	;\r
	db 0cfh,04ah,o_ADC	;adc hl,rr\r
	dw l1dcah	   	;\r
	db 0ffh,046h,o_IM	;im 0\r
	dw l1d85h	   	;\r
	db 0ffh,056h,o_IM	;im 1\r
	dw l1d89h	   	;\r
	db 0ffh,05eh,o_IM	;im 2\r
	dw l1d8dh	   	;\r
	db 0e7h,047h,o_LD	;ld i,a ... ld a,r\r
	dw p_arg_IR	   	;\r
	db 0cfh,04ch,o_MLT	;mlt rr\r
	dw p_rp\r
	db 0c7h,004h,o_TST	;tst r\r
	dw p_ry\r
	db 0\r
\r
l228bh:\r
	db 0ffh,030h,0ffh	;in0 (m)\r
	dw p_arg_r_m\r
	db 0c7h,000h,o_IN0	;in0 r,(m) ;r=b,c,d,e,h,l,a\r
	dw p_arg_r_m\r
	db 0ffh,031h,0ffh	;out0 (m),0\r
	dw p_arg_m_r\r
	db 0c7h,001h,o_OUT0	;out0 (m),r ;r=b,c,d,e\r
	dw p_arg_m_r\r
	db 0ffh,064h,o_TST	;tst m\r
	dw l1d09h\r
	db 0ffh,074h,o_TSTIO	;tstio m\r
	dw l1d09h\r
	db 0\r
\r
; Prefix ED + 1 byte opcode + 2 byte address\r
; Format: db mask, match, t_MNEMONICS-index\r
;	  dw argument formating function\r
b_1c40_start:\r
	db 0cfh,043h,o_LD	;ld (mn),ww	;ww=bc,de,hl,sp\r
	dw p_arg_addr_ww\r
	db 0cfh,04bh,o_LD	;ld ww,(mn)	;ww=bc,de,hl,sp\r
	dw p_arg_ww_addr\r
	db 0\r
\r
; CB\r
b_1c55_start:\r
	db 0f8h,000h,o_RLC	;rlc g\r
	dw p_rz_cb\r
	db 0f8h,008h,o_RRC	;rrc g\r
	dw p_rz_cb\r
	db 0f8h,010h,o_RL	;rl g\r
	dw p_rz_cb\r
	db 0f8h,018h,o_RR	;rr g\r
	dw p_rz_cb\r
	db 0f8h,020h,o_SLA	;sla g\r
	dw p_rz_cb\r
	db 0f8h,028h,o_SRA	;sra g\r
	dw p_rz_cb\r
	db 0f8h,038h,o_SRL	;srl g\r
	dw p_rz_cb\r
	db 0c0h,040h,o_BIT	;bit b,g\r
	dw p_arg_bitop\r
	db 0c0h,080h,o_RES	;res b,g\r
	dw p_arg_bitop\r
	db 0c0h,0c0h,o_SET	;set b,g\r
	dw p_arg_bitop\r
	db 0\r
\r
;-------------------------------------------------------------------------------\r
\r
p_arg_ry_rz:\r
	call p_ry\r
	call p_char_comma\r
	jp p_rz\r
p_arg_a_r:\r
	call p_A_comma\r
	jp p_rz\r
\r
p_arg_r_m:\r
	call p_ry\r
	call p_char_comma\r
	jp sub_1d2ch\r
\r
p_arg_m_r:\r
	call sub_1d2ch\r
	call p_char_comma\r
	jp p_ry\r
\r
p_arg_rst:\r
	ld a,(iy+000h)\r
	and 038h\r
	jp out_hex\r
\r
l1ca0h:\r
	call pstr_inl\r
	DC	'(SP),'\r
	jp p_arg_hlixiy\r
\r
l1caeh:\r
	call p_char_lparen\r
	call p_arg_hlixiy\r
	jr out_rparen\r
\r
p_arg_ex_dehl:\r
	call pstr_inl\r
	DC	'DE,HL'\r
p_arg_none:\r
	ret\r
\r
l1cc1h:\r
	call pstr_inl\r
	DC	'SP,'\r
	jp p_arg_hlixiy\r
\r
p_arg_ex_afaf:\r
	call pstr_inl\r
	DC	'AF,AF'''\r
	ret\r
\r
l1cd3h:\r
	call p_arg_hlixiy\r
	call p_char_comma\r
	jp p_rp\r
l1cdch:\r
	call sub_1ce8h\r
	call p_char_comma\r
	jp p_char_A\r
\r
l1ce5h:\r
	call p_A_comma\r
sub_1ce8h:\r
	call p_char_lparen\r
	call p_rp\r
	jr out_rparen\r
\r
l1cf5h:\r
	call p_A_comma\r
	jr l1d09h\r
l1cfah:\r
	call p_ry\r
	call p_char_comma\r
	ld a,(isprefix_ixiy)\r
	and a\r
	ld a,(iy+002h)\r
	jr nz,l1d0ch\r
l1d09h:\r
	ld a,(iy+001h)\r
l1d0ch:\r
	jp out_hex\r
\r
p_arg_cc_jrel:\r
	ld a,(iy+000h)\r
	and 018h\r
	call p_arg_cc0\r
	call p_char_comma\r
p_arg_jrel:\r
	ld c,(iy+001h)\r
	ld a,c\r
	rla\r
	sbc a,a\r
	ld b,a\r
	push iy\r
	pop hl\r
	add hl,bc\r
	inc hl\r
	inc hl\r
	jr l1d4eh\r
\r
l1d29h:\r
	call p_A_comma\r
sub_1d2ch:\r
	call p_char_lparen\r
	ld a,(iy+001h)\r
p_arg_nn_rp:\r
	call out_hex\r
out_rparen:\r
	jr p_char_rparen\r
\r
l1d37h:\r
	call sub_1d2ch\r
	jr p_char_comma_A\r
\r
p_arg_cc_mn:\r
	call p_arg_cc\r
	call p_char_comma\r
p_arg_mn:\r
	ld l,(iy+001h)\r
	ld h,(iy+002h)\r
l1d4eh:\r
	jp out_hl\r
\r
p_arg_ww_mn:\r
	call p_rp\r
	call p_char_comma\r
	jr p_arg_mn\r
\r
p_arg_addr_hl:\r
	call p_arg_addr\r
	call p_char_comma\r
	jp p_arg_hlixiy\r
\r
p_arg_hl_addr:\r
	call p_arg_hlixiy\r
	call p_char_comma\r
	jp p_arg_addr\r
\r
p_arg_addr_a:\r
	call p_arg_addr\r
p_char_comma_A:\r
	call p_char_comma\r
	jr p_char_A\r
\r
p_A_comma:\r
	call p_char_A\r
p_char_comma:\r
	ld a,','\r
	db 021h\r
p_char_A:\r
	ld a,'A'\r
	db 021h\r
l1d85h:\r
	ld a,'0'\r
	db 021h\r
l1d89h:\r
	ld a,'1'\r
	db 021h\r
l1d8dh:\r
	ld a,'2'\r
	db 021h\r
p_char_rparen:\r
	ld a,')'\r
	db 021h\r
p_char_lparen:\r
	ld a,'('\r
	jp outchar\r
\r
p_arg_IR:\r
	ld a,(iy+000h)\r
	rra\r
	rra\r
	rra\r
	and 03\r
	ld hl,t_arg_IR\r
	jp p_arg\r
\r
t_arg_IR:\r
	DC	'I,A'\r
	DC	'R,A'\r
	DC	'A,I'\r
	DC	'A,R'\r
	db	0\r
\r
p_arg_in_c:\r
	call p_ry\r
	call p_char_comma\r
	ld hl,t__C_\r
	jp pstr\r
\r
p_arg_out_c:\r
	ld hl,t__C_\r
	call pstr\r
	call p_char_comma\r
	jr p_ry\r
\r
l1dcah:\r
	call p_arg_hlixiy\r
	call p_char_comma\r
	jp p_rp\r
\r
p_arg_addr_ww:\r
	call p_arg_addr\r
	call p_char_comma\r
	jp p_rp\r
\r
p_arg_ww_addr:\r
	call p_rp\r
	call p_char_comma\r
	jr p_arg_addr\r
\r
p_arg_a_addr:\r
	call p_A_comma\r
p_arg_addr:\r
	call p_char_lparen\r
	ld l,(iy+001h)\r
	ld h,(iy+002h)\r
	jr p_char_rparen\r
\r
p_arg_bitop:\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr nz,l1defh\r
	ld a,(iy+001h)\r
	jr l1df2h\r
l1defh:\r
	ld a,(iy+002h)\r
l1df2h:\r
	push af\r
	rra\r
	rra\r
	rra\r
	and 007h\r
	add a,'0'\r
	call outchar\r
	call p_char_comma\r
	pop af\r
	jr p_r0\r
\r
p_rz_cb:\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr nz,l1e0eh\r
	ld a,(iy+001h)\r
	jr l1e11h\r
l1e0eh:\r
	ld a,(iy+002h)\r
l1e11h:\r
	jr p_r0\r
\r
p_ry:\r
	ld a,(iy+000h)\r
	rra\r
	rra\r
	rra\r
	jr p_r0\r
p_rz:\r
	ld a,(iy+000h)\r
p_r0:\r
	and 007h\r
	cp 006h\r
	ld b,a\r
	ld hl,t_arg_r\r
	jr nz,p_arg0\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr z,p_arg0\r
	ld hl,t_lp_IXIY\r
	dec a\r
	call p_arg\r
	ld a,(iy+001h)\r
	push af\r
	rlca\r
	ld a,'+'\r
	jr nc,l1e61h\r
	pop af\r
	neg\r
	push af\r
	ld a,'-'\r
l1e61h:\r
	call outchar\r
	pop af\r
	jp p_arg_nn_rp\r
\r
t_lp_IXIY:\r
	DC	'(IX'\r
	DC	'(IY'\r
\r
p_arg_hlixiy:\r
	ld a,(isprefix_ixiy)\r
	ld hl,t_HL.IX.IY\r
	jr p_arg\r
\r
p_rp2:\r
p_arg_zz:\r
	ld hl,t_arg_rp2\r
	jr l1e8eh\r
p_rp:\r
p_arg_ww:\r
	ld hl,t_arg_rp\r
l1e8eh:\r
	ld a,(iy+000h)\r
	rra\r
	rra\r
	rra\r
	rra\r
	and 003h\r
	cp 002h\r
	jr z,p_arg_hlixiy\r
	jr p_arg\r
\r
p_cc:\r
p_arg_cc:\r
	ld a,(iy+000h)\r
p_arg_cc0:\r
	rra\r
	rra\r
	rra\r
	and 007h\r
	ld hl,t_arg_cc\r
p_arg:\r
	ld b,a\r
p_arg0:\r
	jp pstr_sel\r
\r
;-------------------------------------------------------------------------------\r
\r
if 0\r
p_bli:\r
	ld a,(iy+000h)\r
	rra\r
	and 00ch\r
	ld b,a\r
	ld a,(iy+000h)\r
	and 003h\r
	or b\r
	ld hl,t_mn_bli\r
	jr p_arg\r
endif\r
\r
;-------------------------------------------------------------------------------\r
\r
opc	macro	x\r
\r
i_&x	equ	opc_index\r
o_&x	equ	$-opc_tabstart\r
	dc	'&x'\r
opc_index	defl	opc_index+1\r
	endm\r
\r
opc1	macro	x,y\r
\r
i_&x&y	equ	opc_index\r
o_&x&y	equ	$-opc_tabstart\r
	db	'&x'\r
i_&y	equ	opc_index+1\r
o_&y	equ	$-opc_tabstart\r
	dc	'&y'\r
opc_index	defl	opc_index+2\r
	endm\r
\r
\r
t_MNEMONICS:\r
opc_tabstart	defl	$\r
opc_index	defl	0\r
; 1-byte other\r
	opc NOP\r
	opc1 R,LD\r
	opc INC\r
	opc DEC\r
	opc DJNZ\r
	opc JR\r
	opc HALT\r
\r
	opc RLCA\r
	opc RRCA\r
	opc RLA\r
	opc RRA\r
	opc DAA\r
	opc CPL\r
	opc SCF\r
	opc CCF\r
\r
; 1-byte "alu"\r
	opc ADD\r
	opc ADC\r
	opc SUB\r
	opc SBC\r
	opc AND\r
;	opc XOR\r
	opc1 X,OR\r
	opc CP\r
\r
	opc RET\r
	opc POP\r
	opc JP\r
	opc CALL\r
	opc PUSH\r
	opc RST\r
	opc OUT\r
	opc EXX\r
	opc IN\r
	opc EX\r
	opc1 L,DI\r
	opc EI\r
; CB\r
	opc RLC\r
	opc RRC\r
	opc1 S,RL\r
	opc RR\r
	opc SLA\r
	opc SRA\r
;	    SLL\r
;	opc SRL\r
	opc BIT\r
	opc RES\r
	opc SET\r
\r
; ED\r
	opc NEG\r
	opc RETN\r
	opc RETI\r
	opc1 OT,IM\r
	opc RRD\r
;	opc RLD\r
\r
;Block instructions\r
t_mn_bli:\r
;	opc LDI\r
	opc CPI\r
	opc INI\r
	opc OUTI\r
	opc LDD\r
	opc CPD\r
	opc IND\r
	opc OUTD\r
	opc LDIR\r
	opc CPIR\r
	opc INIR\r
	opc OTIR\r
	opc LDDR\r
	opc CPDR\r
	opc INDR\r
	opc OTDR\r
\r
;Z180\r
	opc IN0\r
	opc OUT0\r
	opc TST\r
	opc MLT\r
	opc TSTIO\r
	opc SLP\r
;	opc OTIM\r
	opc OTDM\r
	opc OTIMR\r
	opc OTDMR\r
\r
	DB	0\r
\r
t_arg_r:\r
	DC	'B'\r
	DC	'C'\r
	DC	'D'\r
	DC	'E'\r
	DC	'H'\r
	DC	'L'\r
	DC	'(HL)'\r
	DC	'A'\r
	DB	0\r
t_arg_rp:\r
	DC	'BC'\r
	DC	'DE'\r
	DC	'HL'\r
	DC	'SP'\r
	DB	0\r
t_arg_rp2:\r
	DC	'BC'\r
	DC	'DE'\r
	DC	'HL'\r
	DC	'AF'\r
	DB	0\r
t_HL.IX.IY:\r
	DC	'HL'\r
	DC	'IX'\r
	DC	'IY'\r
	DB	0\r
t_arg_cc:\r
	DC	'NZ'\r
	DC	'Z'\r
	DC	'NC'\r
	DC	'C'\r
	DC	'PO'\r
	DC	'PE'\r
	DC	'P'\r
	DC	'M'\r
	DB	0\r
t__C_:\r
	DC	'(C)'\r
	DB	0\r
\r
;-------------------------------------------------------------------------------\r
;-------------------------------------------------------------------------------\r
if 0\r
\r
lookup_argstr:\r
	;todo\r
	ret\r
\r
\r
pr_instr_args:\r
	ld	hl,t_argf\r
	call	lookup_argstr\r
\r
	ret	z\r
\r
pria_l:\r
	ld	a,(hl)		;get next token\r
	inc	hl\r
	or	a\r
	ret	z		;\r
	jp	m,pria_1\r
	call	outchar		;print as normal character\r
	jr	pria_l\r
\r
pria_1:				;\r
	push	hl\r
	ld	hl,do_arg_n\r
	and	07fh\r
	call	add_hl_a2\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a\r
	call	CALL_HL\r
	pop	hl\r
	jr	pria_l\r
\r
;\r
;	http://www.z80.info/decoding.htm\r
;\r
;	| 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |\r
;	|   x   |     y     |     z     |\r
;	        |   p   | q |\r
;\r
\r
t_argf:\r
	db	fi_ry,',',fi_rz,0	;ld r[y],r[z]\r
	db	'A,',fi_rz,0		;op A,r[z]\r
	db	fi_ry,',(',fi_m8,')',0	;in a,(m8)\r
	db	'(',fi_m8,'),',fi_ry,0	;out (m8),a\r
	db	fi_rst,0\r
	db	'(SP),',fi_hlixiy,0	;\r
	db	'DE,HL',0\r
	db	'AF,AF''',0\r
	db	fi_hlixiy,0\r
	db	fi_rp			;rp[p]\r
	db	fi_rp2			;rp2[p]\r
\r
;-------------------------------------------------------------------------------\r
\r
argpf_index	defl	0\r
\r
argpf	macro	x\r
fi_&x	equ	80h+argpf_index\r
	dw	p_&x\r
argpf_index	defl	argpf_index+1\r
	endm\r
\r
do_arg_n:\r
	argpf	ry\r
	argpf	rz\r
	argpf	m8\r
	argpf	rst\r
	argpf	hlixiy\r
	argpf	rp\r
	argpf	rp2\r
\r
p_ry:\r
p_rz:\r
p_m8:\r
p_rst:\r
p_hlixiy:\r
p_rp:\r
p_rp2:\r
\r
\r
endif\r
;-------------------------------------------------------------------------------\r
;-------------------------------------------------------------------------------\r
\r
tc_set_bp:\r
	ld hl,(reg.pc)\r
	ld a,h\r
	or l\r
	jr z,l2037h\r
	ld de,BDOS\r
	and a\r
	sbc hl,de\r
	ld hl,l20edh		;set break after BDOS call\r
	jr z,l2031h\r
	ld iy,(reg.pc)\r
	call disas_get_instrlen\r
	jp nc,ERROR\r
	ld c,b\r
	ld b,0\r
	ld hl,(reg.pc)\r
	add hl,bc\r
	call bp_trace_enter\r
	ld iy,(reg.pc)\r
	ld hl,t_op_branch\r
	call lookup_op_arg\r
	ccf\r
	ret c\r
	ex de,hl\r
l2031h:\r
	call CALL_HL\r
	call c,bp_trace_enter\r
l2037h:\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
t_op_branch:\r
	db 0ffh,0ddh,0		;Prefix DD\r
	dw l20a7h\r
	db 0ffh,0fdh,0		;Prefix FD\r
	dw l20ach\r
	db 0ffh,0edh,0		;Prefix ED\r
	dw l20b8h\r
t_op_branch0:\r
	db 0ffh,0cdh,0		;call mn\r
	dw l2080h\r
	db 0ffh,0c3h,0		;jp mn\r
	dw l208bh\r
	db 0ffh,0e9h,0		;jp ()\r
	dw l20a2h\r
	db 0ffh,0c9h,0		;ret\r
	dw l20dch\r
	db 0ffh,0cfh,0		;rst 8\r
	dw l2115h\r
	db 0c7h,0c7h,0		;rst n\r
	dw l20f9h\r
	db 0c7h,0c4h,0		;call cc,mn\r
	dw l2080h\r
	db 0f7h,010h,0		;djnz d; jr d\r
	dw l2093h\r
	db 0e7h,020h,0		;jr cc,d\r
	dw l2093h\r
	db 0c7h,0c2h,0		;jp cc,mn\r
	dw l208bh\r
	db 0c7h,0c0h,0		;ret cc\r
	dw l20c5h\r
	db 0\r
\r
;-------------------------------------------------------------------------------\r
; call mn	call cc,mn\r
l2080h:\r
\r
; jp mn		jp cc,mn\r
l208bh:\r
	ld l,(iy+001h)\r
	ld h,(iy+002h)\r
	scf\r
	ret\r
\r
l2093h:\r
	ld c,(iy+001h)\r
	ld a,c\r
	rla\r
	sbc a,a\r
	ld b,a\r
	ld hl,(reg.pc)\r
	add hl,bc\r
	inc hl\r
	inc hl\r
	scf\r
	ret\r
\r
; jp (hl)\r
l20a2h:\r
	ld hl,(reg.l)\r
	scf\r
	ret\r
\r
; Prefix DD\r
l20a7h:\r
	ld hl,(reg.ix)\r
	jr l20afh\r
; Prefix FD\r
l20ach:\r
	ld hl,(reg.iy)\r
l20afh:\r
	ld a,(iy+001h)\r
	cp 0e9h			; jp (ix); jp (iy)\r
	scf\r
	ret z\r
	and a\r
	ret\r
\r
; Prefix ED\r
l20b8h:\r
	ld a,(iy+001h)\r
	cp 04dh			; reti\r
	jr z,l20dch\r
	cp 045h			; retn\r
	jr z,l20dch\r
	and a\r
	ret\r
l20c5h:\r
	ld a,(iy+000h)\r
	ld (l20d7h),a\r
	ld hl,(reg.f)\r
	push hl\r
	pop af\r
	call l20d7h\r
	scf\r
	jr c,l20dch\r
	ret\r
l20d7h:\r
	nop\r
	and a\r
	pop hl\r
	inc hl\r
	jp (hl)\r
\r
l20dch:\r
l20edh:\r
	ld hl,(reg_sp)		;break on return address\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	ex de,hl\r
	call bp_trace_enter\r
l2115h:\r
	and a\r
	ret\r
\r
l20f9h:\r
	ld a,(l0003h)\r
	cp (iy+000h)\r
	ret z\r
	ld a,(iy+000h)\r
	and 038h\r
	ld l,a\r
	ld h,000h\r
	ld a,(b_21e2_start)\r
	and a\r
	ret z\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; >>C[N][J] [steps]\r
; >>C[N][J] W expression\r
; >>C[N][J] U expression\r
;     trace over Calls [No list] [Jumps only] /.While./.Until.\r
\r
\r
;-------------------------------------------------------------------------------\r
; >>T[N][J] [steps]\r
; >>T[N][J] W expression\r
; >>T[N][J] U expression\r
;      Trace [no List] [Jumps only] / .While. / .Until.\r
\r
cmd_T:\r
	ld (cmd_rpt),hl\r
	ld hl,1				;default: 1 step\r
	call get_lastarg_def\r
	ld (trace_cnt_or_ptr),hl\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call tc_set_bp\r
	jr user_go1\r
\r
l2151h:\r
	call bp_clr_temporary\r
	ld hl,(trace_cnt_or_ptr)\r
	dec hl\r
	ld (trace_cnt_or_ptr),hl\r
	ld a,h\r
	or l\r
	jp z,do_break\r
\r
	call tc_set_bp\r
	jp nc,do_break\r
	sbc a,a\r
	ld (bp_p_cpu_flag),a\r
user_go1:\r
	jp user_go\r
\r
;-------------------------------------------------------------------------------\r
\r
con_col:\r
	db	0\r
\r
;-------------------------------------------------------------------------------\r
\r
b_21e2_start:\r
	db	0\r
trace_cnt_or_ptr:\r
	dw	0\r
\r
bp_p_cpu_flag:\r
	db	0\r
\r
bp_tab:\r
	rept BP_CNT\r
	 rept BP_SIZE\r
	  db	0\r
	 endm\r
	endm\r
\r
expr_buf:\r
current_cseg	defl	$ - current_cseg\r
	.phase	current_phase + current_cseg\r
\r
start:\r
	LD	SP,ldr_end+(stack-ddtz_base)\r
	LD	DE,signon		;ldr_end+(expr_buf-ddtz_base)\r
	LD	C,BDOS_PSTR\r
	CALL	BDOS\r
\r
	xor	a\r
	dec	a\r
	jp	po,reloc\r
	ld	de,msgz80\r
	LD	C,BDOS_PSTR\r
	CALL	BDOS\r
	jp	0\r
\r
reloc:\r
	LD	HL,ldr_end+ddtz_size	;start of reloc bitmap\r
	ld	bc,0108h		;init bit counter\r
\r
	EXX\r
	LD	HL,(BDOS+1)\r
	LD	(ldr_end+(ddtz_bdos+1-ddtz_base)),HL\r
	LD	BC,ddtz_size-1\r
	LD	D,B\r
	LD	E,0FFH\r
	INC	DE			;size rounded up to next page boundary\r
	INC	BC			;ddtz_size\r
	OR	A\r
	SBC	HL,DE			;BDOS - size\r
	LD	(BDOS+1),HL		;-> new BDOS entry\r
\r
	push	hl\r
	PUSH	BC\r
	ld	de,ldr_end\r
	sbc	hl,de\r
	EX	DE,HL			;-> DE\r
	LD	HL,ldr_size\r
	add	hl,bc\r
	ld	b,h\r
	ld	c,l\r
	LD	HL,TPA\r
reloc_lp:\r
	EXX\r
	djnz	reloc_nl\r
	ld	b,c			;reload bit counter\r
	LD	e,(HL)			;get next 8 relocation bits\r
	INC	HL\r
reloc_nl:\r
	sla	e\r
	EXX\r
	JR	NC,reloc_next\r
	DEC	HL\r
	LD	A,(HL)\r
	ADD	A,E\r
	LD	(HL),A\r
	INC	HL\r
	LD	A,(HL)\r
	ADC	A,D\r
	LD	(HL),A\r
reloc_next:\r
	cpi\r
	jp	pe,reloc_lp\r
	dec	hl\r
\r
	POP	BC\r
	pop	de\r
	EX	DE,HL\r
	ADD	HL,BC\r
	EX	DE,HL\r
	DEC	DE\r
	LDDR\r
	LD	HL,conbuf+2-ddtz_base\r
	ADD	HL,DE\r
	JP	(HL)\r
\r
current_phase	defl	$\r
	.dephase\r
current_cseg	defl	$\r
\r
	ds	EXPR_BUF_SIZE - ($ - expr_buf)\r
expr_bufe:\r
\r
;-------------------------------------------------------------------------------\r
\r
last_S:\r
	dw	TPA\r
\r
last_I:\r
	dw	0\r
\r
last_O_addr:\r
	dw	0\r
last_O_val:\r
	db	0\r
\r
last_D:\r
	dw	TPA\r
\r
high_load:\r
	dw	TPA\r
max_load:\r
	dw	TPA\r
\r
isprefix_ixiy:\r
	db	0\r
last_L:\r
	dw	TPA\r
\r
pbl_loop_adr:\r
	dw	0\r
\r
ddtz_size	equ	$-ddtz_base\r
ddtz_end:\r
\r
;-------------------------------------------------------------------------------\r
\r
	end\r