New relocator

[ddt180.git] / ddt180.z80

; Disassembled ddtz.com, version "DDT/Z    [8101]"\r
; with modified relocater.\r
;\r
; Build steps:\r
;   - Assemble to a .REL file with M80 or a compatible assembler.\r
;   - Use Digital Research Link-80 to generate a .PRL file (op switch).\r
;   - Cut the .PRL header (first 256 byte) end rename the result to DDTZ.COM.\r
\r
\r
	maclib	config.inc\r
\r
; Some greneral definitions\r
\r
BS		equ	08h\r
TAB		equ	09h\r
CR		equ	0dh\r
LF		equ	0ah\r
DEL		equ	7fh\r
CNTRX		equ	'X'-'@'\r
\r
; CP/M memory layout\r
\r
BDOS		equ	5\r
TPA		equ	0100h\r
\r
; ddtz specific definitions\r
\r
STACK_SIZE	equ	80	;ddtz internal stack\r
CONBUF_SIZE	equ	80	;Size of console input buffer\r
BP_CNT		equ	12	;Number of breakpoints\r
BP_SIZE		equ	4	;Size of a breakpoint record\r
\r
bitmap_size	equ	(prog_size+7)/8\r
\r
;-------------------------------------------------------------------------------\r
\r
	cseg\r
start:\r
ddtz_base:\r
	jr reloc\r
	nop\r
l0003h:\r
	rst 30h			;rst used by ddtz\r
di_or_ei:			;ints enabled/disabled while ddtz is running\r
	nop\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
signon:\r
	db	'DDTZ/180'\r
	db	' - Version '\r
	maclib	version.inc\r
	defvers\r
	dc	'  ('\r
\r
;-------------------------------------------------------------------------------\r
\r
reloc_getbit	macro\r
	local	nextbit\r
	exx\r
	djnz	nextbit\r
	ld	b,8			;reload bit counter\r
	ld	e,(hl)			;get next 8 relocation bits\r
	inc	hl\r
nextbit:\r
	sla	e\r
	exx\r
	endm\r
\r
;-------------------------------------------------------------------------------\r
; Clear old position\r
\r
cmde_clr:\r
	ld	(hl),0\r
	inc	hl\r
	dec	bc\r
	ld	a,b\r
	or	c\r
	jr	nz,cmde_clr\r
\r
; Determine current position\r
\r
reloc:\r
	ld	bc,(028h-2)\r
	ld	de,(028h)\r
	ld	a,i			;get iff2\r
	ex	af,af'\r
	di\r
	ld	sp,028h			;rst instr needs a minimal stack\r
	ld	hl,0e9e1h		;opcpdes pop hl/jp (hl)\r
	ld	(028h),hl\r
	rst	028h\r
wearehere:\r
	ld	(028h-2),bc\r
	ld	(028h),de\r
	ld	de,-(wearehere-ddtz_base)\r
	add	hl,de			; hl:\r
\r
	ld	de,ddtz_base		; de:\r
	or	a\r
	sbc	hl,de\r
	ex	de,hl			; de: reloc offset\r
	ld	hl,stack\r
	add	hl,de\r
	ld	sp,hl\r
	ex	af,af'\r
	push	af\r
	pop	bc\r
	bit	2,c\r
	jr	z,$+3\r
	ei\r
	ld	hl,ddtz_end		;start of reloc bitmap\r
	add	hl,de\r
	push	hl\r
	exx\r
	pop	hl\r
	ld	b,1			;init bit counter b\r
	exx\r
\r
	LD	HL,ddtz_base\r
	add	hl,de			;--> ddtz_base\r
\r
reloc_lp:\r
	push	de\r
	push	hl\r
\r
	ld	de,4\r
	ld	a,2\r
	ld	hl,0\r
reloc_l:\r
	reloc_getbit\r
	jr	nc,reloc_got\r
	cp	16\r
	jr	z,reloc_done\r
	add	hl,de\r
	ld	b,a\r
	ex	de,hl\r
reloc_l1:\r
	add	hl,hl\r
	djnz	reloc_l1\r
	ex	de,hl\r
	add	a,a\r
	jr	reloc_l\r
reloc_got:\r
	ex	de,hl\r
	ld	hl,0\r
	ld	b,a\r
reloc_bitloop:\r
	reloc_getbit\r
	adc	hl,hl\r
	djnz	reloc_bitloop\r
	add	hl,de\r
	pop	de\r
	add	hl,de\r
	pop	de\r
\r
	LD	A,(HL)\r
	ADD	A,E\r
	LD	(HL),A\r
	INC	HL\r
	LD	A,(HL)\r
	ADC	A,D\r
	LD	(HL),A\r
	inc	hl\r
	jr	reloc_lp\r
reloc_done:\r
	exx\r
	ld	(bitmap_end),hl\r
;-------------------------------------------------------------------------------\r
\r
\r
init:\r
	LD	SP,stack\r
\r
    if CPM\r
\r
	ld 	hl,(1)		;wboot addr\r
	ld 	de,convec\r
	ex	de,hl\r
	ld 	b,3\r
vini_l:\r
	inc	de\r
	inc	de\r
	inc	de\r
	inc	hl\r
	ld	(hl),e\r
	inc	hl\r
	ld	(hl),d\r
	inc	hl\r
	djnz	vini_l\r
    else\r
	xor	a\r
	dec	a\r
	daa			; Z80: 099H, x180+: 0F9H\r
	cp	99h		; Result on 180 type cpus is F9 here. Thanks Hitachi\r
	jr	z,ini_z80\r
\r
	xor	a\r
	call	cinit\r
	ld	a,1\r
	call	cinit\r
	jr	ini_sign\r
ini_z80:\r
;      if ...\r
;	.printx Error: Not yet implemented!\r
;	db "Stop\r
;      endif\r
    endif	; CPM\r
\r
ini_sign:\r
	ld	hl,signon\r
	call	pstr\r
	ld	hl,ddtz_base\r
	call	out_hl\r
	call	pstr_inl\r
	dc	' - '\r
	ld	hl,(bitmap_end)\r
	dec	hl\r
	call	out_hl\r
	call	pstr_inl\r
	dc	')',CR,LF\r
\r
	ld 	a,i\r
	ld 	(reg.i),a\r
	ld 	a,0f3h\r
	jp 	po,l0093h\r
	ld 	a,0fbh\r
l0093h:\r
	ld 	(reg.iff),a\r
	call 	di_or_ei\r
	ld 	hl,ddtz_base\r
	ld 	l,000h\r
	ld 	(reg_sp),hl\r
\r
	jp 	mainloop\r
\r
;-------------------------------------------------------------------------------\r
\r
    if CPM\r
\r
convec:\r
const:	jp	0		; return console input status\r
conin:	jp	0		; return console input character\r
conout:	jp	0		; send console output character\r
\r
    else\r
\r
	include	z180reg.inc\r
\r
iobyte	equ	3\r
\r
max_device	equ 3\r
\r
;-------------------------------------------------------------------------------\r
\r
; init device\r
cinit:				; a = device\r
	call	vector_io_0\r
	dw	as0init\r
	dw	rret\r
	dw	rret\r
	dw	rret\r
\r
; character input status\r
const:				; return a != 0 if character waiting\r
	call	vector_io\r
	dw	as0ista\r
	dw	null$status\r
	dw	csio_ista\r
	dw	null$status\r
\r
; character input\r
conin:				; return a = input char\r
	call	vector_io\r
	dw	as0inp\r
	dw	null$input\r
	dw	csio_inp\r
	dw	null$input\r
\r
; character output\r
conout:				; c = output char\r
	call	vector_io\r
	dw	as0out\r
	dw	rret\r
	dw	csio_out\r
	dw	rret\r
\r
;-------------------------------------------------------------------------------\r
\r
vector_io:\r
	ld	a,(iobyte)\r
vector_io_0:\r
	pop	hl\r
	cp	max_device\r
	jr	c,exist\r
	ld	a,max_device	; use null device if a >= max$device\r
exist:\r
	call	add_hl_a2\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a\r
	jp	(hl)\r
\r
;-------------------------------------------------------------------------------\r
\r
null$input:\r
	ld	a,1Ah\r
rret:\r
	ret\r
ret$true:\r
	or	0FFh\r
	ret\r
\r
null$status:\r
	xor	a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
;\r
; TC = (f PHI /(2*baudrate*Clock_mode)) - 2\r
;\r
; TC = (f PHI / (32 * baudrate)) - 2\r
;\r
; Init Serial I/O for console input and output (ASCI1)\r
;\r
\r
\r
\r
as0init:\r
	ld	hl,initab0\r
	jp	ioiniml\r
\r
as1init:\r
	ld	hl,initab1\r
	jp	ioiniml\r
\r
\r
	ld	a,M_MPBT\r
	out0	(cntlb1),a\r
	ld	a,M_RE + M_TE + M_MOD2	;Rx/Tx enable\r
	out0	(cntla1),a\r
	ld	a,M_RIE\r
	out0	(stat1),a	;Enable rx interrupts\r
\r
	ret			;\r
\r
\r
initab0:\r
	db	1,stat0,0		;Disable rx/tx interrupts\r
					;Enable baud rate generator\r
	db	1,asext0,M_BRGMOD+M_DCD0DIS+M_CTS0DIS\r
	db	2,astc0l,low 28, high 28\r
	db	1,cntlb0,M_MPBT		;No MP Mode, X16\r
	db	1,cntla0,M_RE+M_TE+M_MOD2 ;Rx/Tx enable, 8N1\r
	db	0\r
\r
initab1:\r
	db	1,stat1,0		;Disable rx/tx ints, disable CTS1\r
	db	1,asext1,M_BRGMOD	;Enable baud rate generator\r
	db	2,astc1l,low 3, high 3\r
	db	1,cntlb1,M_MPBT		;No MP Mode, X16\r
	db	1,cntla1,M_RE+M_TE+M_MOD2 ;Rx/Tx enable, 8N1\r
	db	0\r
\r
;-------------------------------------------------------------------------------\r
\r
ioiniml:\r
	push	bc\r
	xor	a\r
ioml_lp:\r
	ld	b,(hl)\r
	inc	hl\r
	cp	b\r
	jr	z,ioml_e\r
\r
	ld	c,(hl)\r
	inc	hl\r
	otimr\r
	jr	ioml_lp\r
ioml_e:\r
	pop	bc\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
as0ista:\r
	in0	a,(stat0)\r
	rlca\r
	sbc	a,a\r
	ret\r
\r
as1ista:\r
	in0	a,(stat1)\r
	rlca\r
	sbc	a,a\r
	ret\r
\r
as0inp:\r
	in0	a,(stat0)\r
	rlca\r
	jr	nc,as0inp\r
	in0	a,rdr0\r
	ret\r
\r
as1inp:\r
	in0	a,(stat1)\r
	rlca\r
	jr	nc,as1inp\r
	in0	a,rdr1\r
	ret\r
\r
as0out:\r
	in0	a,(stat0)\r
	and	M_TDRE\r
	jr	z,as0out\r
	out0	(tdr0),c\r
	ld	a,c\r
	ret\r
\r
as1out:\r
	in0	a,(stat1)\r
	and	M_TDRE\r
	jr	z,as1out\r
	out0	(tdr1),c\r
	ld	a,c\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
\r
csio_rx_tmp:	db	0ffh\r
\r
csio_ista:\r
	ld	hl,csio_rx_tmp\r
	ld	a,(hl)\r
	cp	0ffh\r
	jr	nz,csist_1\r
	ld	a,01\r
	call	csio_wr\r
	call	csio_rd\r
	call	csio_rd\r
	ld	(hl),a\r
	sub	a,0ffh\r
	ret	z\r
csist_1:\r
	or	0ffh\r
	ret\r
\r
csio_inp:\r
	ld	hl,csio_rx_tmp\r
	ld	a,(hl)\r
	ld	(hl),0ffh\r
	cp	0ffh\r
	ret	nz\r
csin_1:\r
	ld	a,01\r
	call	csio_wr\r
	call	csio_rd\r
	call	csio_rd\r
	cp	0ffh\r
	jr	z,csin_1\r
	ret\r
\r
csio_rd:\r
	ld	a,M_CSIO_RE\r
	call	csio_cmd_wait\r
	in0	a,(trdr)\r
	ret\r
\r
csio_out:\r
	ld	a,02\r
	call	csio_wr\r
	call	csio_rd\r
	call	csio_rd\r
	or	a\r
	jr	z,csio_out\r
\r
	ld	a,c\r
	inc	a		;ff..02 --> 00..03\r
	cp	04h\r
	jr	nc,csout_1\r
	ld	a,00h\r
	call	csio_wr\r
csout_1:\r
	ld	a,c\r
csio_wr:\r
	out0	(trdr),a\r
	ld	a,M_CSIO_TE\r
csio_cmd_wait:\r
	out0	(cntr),a\r
cswr_wait:\r
	in0	a,(cntr)\r
	and	M_CSIO_TE+M_CSIO_RE\r
	jr	nz,cswr_wait\r
	ret\r
\r
    endif ; CPM\r
\r
;-------------------------------------------------------------------------------\r
\r
CMDTAB:\r
;	dw	ERROR ;cmd_@	;examine/substitute the displacement register @\r
;	dw	ERROR ;cmd_A	;Assemble\r
	dw	cmd_B		;Breakpoints display/set/clear\r
	dw	ERROR ;cmd_C	;trace over Calls\r
	dw	cmd_D		;Display memory in hex and ascii\r
	dw	cmd_E		;rElocate debugger\r
	dw	ERROR ;cmd_F	;specify Filename and command line\r
	dw	cmd_G		;Go\r
	dw	cmd_H		;compute Hex and other expressions\r
	dw	cmd_I		;Input a byte from port\r
	dw	ERROR		;\r
	dw	ERROR		;\r
	dw	cmd_L		;List disassembled code\r
	dw	cmd_M		;Move memory [and verify]\r
	dw	ERROR		;\r
	dw	cmd_O		;Output a byte to port\r
	dw	ERROR		;\r
	dw	cmd_Q		;Qery memory for byte string\r
	dw	cmd_R		;Read binary or hex file\r
	dw	cmd_S		;Substitute memory\r
	dw	cmd_T		;Trace\r
	dw	ERROR		;\r
	dw	cmd_V		;Verify (compare) two memory areas\r
	dw	ERROR ;cmd_W	;Write a file to disk\r
	dw	cmd_X		;eXamine [and substitute] registers\r
	dw	ERROR ;cmd_Y	;examine [and substitute] Y variables\r
	dw	cmd_Z		;Zap (fill) memory with a byte string\r
\r
ERROR:\r
	call	pstr_inl\r
	dc	'?',CR,LF\r
	;fall thru\r
mainloop:\r
	ld sp,stack\r
	ld hl,(reg.pc)\r
	call bp_clr_temporary\r
	ld hl,(cmd_rpt)\r
	ld de,mainloop\r
	push de\r
	call cp_hl_de\r
	ld a,'>'\r
	call outchar\r
	call nz,outchar\r
	call z,outbl\r
	call get_line\r
	call skipbl\r
	jr z,exe_hl\r
	pop hl\r
	push hl\r
	ld (cmd_rpt),hl\r
	inc de\r
	sub 'B'\r
	jr c,ERROR\r
	cp 'Z'+1-'@'\r
	jr nc,ERROR\r
	ld hl,CMDTAB\r
	call add_hl_a2\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
exe_hl:\r
CALL_HL:\r
	jp (hl)\r
\r
;-------------------------------------------------------------------------------\r
\r
crlf:\r
	call	pstr_inl\r
	dc	CR,LF\r
	xor a\r
	ld (con_col),a\r
	call inchar\r
	jr c,mainloop\r
	ret\r
\r
sub_01d9h:\r
	call	pstr_inl\r
	dc	'-'\r
	jp neg.hl\r
\r
out_hl_dec_neg:\r
	push hl\r
	call sub_01d9h\r
	defb 03eh		;ld a,..  swallow push hl\r
out.hl.dec:\r
	push hl\r
	ld b,006h\r
	call sub_01f9h\r
	pop hl\r
	call	pstr_inl\r
	dc	'.'\r
l01f3h:\r
	call outbl\r
	djnz l01f3h\r
	ret\r
\r
sub_01f9h:\r
	dec b\r
	push de\r
	ld de,10\r
	call div_hl_de\r
	ld a,h\r
	or l\r
	call nz,sub_01f9h\r
	ld a,e\r
	pop de\r
	jr out_dgt\r
\r
out_hl_neg:\r
	push hl\r
	call sub_01d9h\r
	call out_hl\r
	pop hl\r
	ret\r
\r
out_hl:\r
	ld a,h\r
	call out_hex\r
	ld a,l\r
\r
out_hex:\r
	push af\r
	rra\r
	rra\r
	rra\r
	rra\r
	call out_dgt\r
	pop af\r
\r
out_dgt:\r
	or	0f0h\r
	daa\r
	add	a,0a0h\r
	adc	a,040h\r
	jr outchar\r
\r
out.bin.w:\r
	ld a,h\r
	call out.bin.b\r
	ld a,l\r
out.bin.b:\r
	ld b,8\r
l01c9h:\r
	rlca\r
	push	af\r
	and	1\r
	call	out_dgt\r
	pop af\r
	djnz l01c9h\r
	ld a,'"'\r
	jr outchar\r
\r
out.ascii:\r
	push bc\r
	ld c,a\r
	res 7,a\r
	cp ' '\r
	push af\r
	call nc,outbl\r
	call	pstr_inl\r
	dc	''''\r
	pop af\r
	jr nc,l0242h\r
	sub 0c0h\r
	ld b,a\r
	call	pstr_inl\r
	dc	'^'\r
	ld a,b\r
l0242h:\r
	call outchar\r
	cp ''''\r
	call z,outchar\r
	call	pstr_inl\r
	dc	''''\r
	sla c\r
	pop bc\r
	ret nc\r
	ld a,'.'\r
	jr outchar\r
\r
outbl6:\r
	call outbl2\r
outbl4:\r
	call outbl2\r
outbl2:\r
	call outbl\r
outbl:\r
	ld a,' '\r
outchar:\r
	push ix\r
	push iy\r
	push hl\r
	push de\r
	push bc\r
	push af\r
	and 07fh\r
	ld	c,a\r
	call	conout\r
	ld hl,con_col\r
	inc (hl)\r
	pop af\r
	pop bc\r
	pop de\r
	pop hl\r
	pop iy\r
	pop ix\r
	ret\r
\r
p_goto_col:\r
	ld	a,(con_col)\r
	cp	c\r
	ret	nc\r
	ret	z\r
	call	outbl\r
	jr	p_goto_col\r
\r
;-------------------------------------------------------------------------------\r
\r
incharw:\r
	call inchar\r
	jr nc,incharw\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
inchar:\r
	push ix\r
	push hl\r
	push de\r
	push bc\r
	call	const\r
	and a\r
	jr	z,inch1\r
	call	conin\r
	scf\r
inch1:\r
	pop bc\r
	pop de\r
	pop hl\r
	pop ix\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
DELC:\r
	ld	a,b\r
	or	a\r
	ret	z\r
	call	DELC1\r
	dec	hl\r
	dec	b\r
	ld	a,(hl)\r
	cp	' '\r
	ret	nc\r
DELC1:\r
	call	pstr_inl\r
	dc	BS,' ',BS\r
	ret\r
\r
DELL:\r
	ld a,b			;\r
	or a			;\r
	ret z			;\r
	call DELC		;\r
	jr DELL			;\r
\r
;-------------------------------------------------------------------------------\r
\r
get_line:\r
	push hl			;\r
	ld hl,conbuf		;\r
	ld b,0			;\r
inlnxtch:\r
	ld a,b			;\r
	cp CONBUF_SIZE		;\r
	jr z,inl_e		;\r
	call incharw		;\r
	cp CR			;\r
	jr z,inl_e		;Accept line\r
	cp LF			;\r
	jr z,inl_e		;Accept line\r
\r
	cp BS			;\r
	jr z,gl_1		;\r
	cp DEL			;\r
	jr nz,gl_2		;\r
gl_1:\r
	call DELC		;Delete Char\r
	jr inlnxtch		;\r
gl_2:\r
	cp CNTRX		;\r
	jr nz,gl_3		;\r
	call DELL		;Delete Line\r
	jr inlnxtch		;\r
gl_3:\r
	cp TAB			;\r
	jr nz,gl_4		;\r
	ld a,' '		;\r
gl_4:\r
	ld (hl),a		;\r
	cp ' '			;\r
	jr nc,gl_5		;\r
	ld a,'^'		;Controll characters\r
	call outchar		;\r
	ld a,(hl)		;\r
	add a,'@'		;\r
gl_5:\r
	call outchar		;\r
	inc hl			;\r
	inc b			;\r
	jr inlnxtch		;\r
\r
inl_e:\r
	ld (hl),0\r
	call CRLF		;\r
	ld de,conbuf		;\r
	pop hl			;\r
	ret			;\r
\r
;-------------------------------------------------------------------------------\r
\r
get_char_upper:\r
	ld a,(de)\r
toupper:\r
	cp 'a'\r
	ret c\r
	cp 'z'+1\r
	ccf\r
	ret c\r
	and 05fh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
skipbl0:\r
	inc de\r
skipbl:\r
	call get_char_upper\r
	cp ' '\r
	jr z,skipbl0\r
	or a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
next_arg:\r
	call skipbl\r
	cp ','\r
	ret nz\r
	call skipbl0\r
	cp a\r
	ret\r
\r
assert_eol:\r
	call skipbl\r
	ret z\r
to_error:\r
	jp ERROR\r
\r
;-------------------------------------------------------------------------------\r
\r
chk_stack:\r
	push hl\r
	push de\r
	ld hl,0\r
	add hl,sp\r
	ld de,stack-(STACK_SIZE-28)\r
	call cp_hl_de\r
	pop de\r
	pop hl\r
	jr c,to_error\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
add_hl_a2:\r
	add a,a\r
add_hl_a:\r
	add a,l\r
	ld l,a\r
	ret nc\r
	inc h\r
	ret\r
\r
cp_hl_de:\r
	and a\r
	sbc hl,de\r
	add hl,de\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
lookupch:\r
	ld b,0\r
l02f5h:\r
	ld a,(hl)\r
	and a\r
	ret z\r
	call get_char_upper\r
	cp (hl)\r
	jr z,l0300h\r
	inc hl\r
	inc b\r
	jr l02f5h\r
l0300h:\r
	scf\r
	inc de\r
	ret\r
\r
sub_0303h:\r
	ld hl,t_reg_names\r
	ld b,07fh\r
l030ch:\r
	inc b\r
	ld a,(hl)\r
	and a\r
	ret z\r
	call sub_031ch\r
	jr nc,l030ch\r
	res 7,b\r
	ret\r
\r
sub_031ch:\r
	push bc\r
	push de\r
l031eh:\r
	call get_char_upper\r
	xor (hl)\r
	and 07fh\r
	jr nz,l0336h\r
	bit 7,(hl)\r
	inc hl\r
	inc de\r
	jr z,l031eh\r
	scf\r
	bit 7,b\r
	call z,sub_060ch\r
	jr nc,l0339h\r
	pop af\r
	scf\r
	pop bc\r
	ret\r
l0336h:\r
	call str_sel_next\r
l0339h:\r
	pop de\r
	and a\r
	pop bc\r
	ret\r
\r
str_sel:\r
	inc b\r
	jr str_sel2\r
str_sel1:\r
	call str_sel_next\r
str_sel2:\r
	djnz str_sel1\r
	ret\r
\r
str_sel_next:\r
	ld a,(hl)\r
	and a\r
	ret z\r
l0348h:\r
	ld a,(hl)\r
	inc hl\r
	and a\r
	ret m\r
	jr l0348h\r
\r
get_arg_range_target:\r
	call get_arg_range\r
	push hl\r
	push bc\r
	call next_arg\r
	call get_arg_final\r
	ex de,hl\r
	pop bc\r
	pop hl\r
	ret\r
\r
sub_035dh:\r
	call expr\r
	jr c,error0\r
	ret\r
\r
get_arg_final:\r
	call sub_035dh\r
l0366h:\r
	jp assert_eol\r
\r
get_lastarg_def:\r
	call get_arg_def\r
	jr l0366h\r
\r
get_arg_def:\r
	push hl\r
	call expr\r
	jr c,l0375h\r
	ex (sp),hl\r
l0375h:\r
	pop hl\r
	ret\r
\r
sub_0377h:\r
	call b_037c_start\r
	jr l0366h\r
\r
b_037c_start:\r
	defb 0e6h		;and a,..  clear carry\r
get_arg_range:\r
	scf\r
	ex af,af'\r
	push bc\r
	push hl\r
	call expr\r
	jr nc,l038ch\r
	ex af,af'\r
	jr c,error0\r
	ex af,af'\r
	pop hl\r
	defb 03eh		;ld a,..  swallow pop af\r
l038ch:\r
	pop af\r
	call get_range\r
	jr nc,l0398h\r
	ex af,af'\r
	pop bc\r
	ret nc\r
error0:\r
	jp ERROR\r
l0398h:\r
	pop af\r
	ret\r
\r
get_range:\r
	call next_arg\r
	cp 'S'\r
	jr nz,l03a2h\r
	inc de\r
l03a2h:\r
	push hl\r
	push af			;'S' flag\r
	call expr\r
	jr c,l03b8h\r
	ld b,h\r
	ld c,l\r
	pop af\r
	pop hl\r
	jr z,l03b6h		;'S'?\r
	ld a,c\r
	sub l\r
	ld c,a\r
	ld a,b\r
	sbc a,h\r
	ld b,a\r
	inc bc\r
l03b6h:\r
	and a\r
	ret\r
l03b8h:\r
	pop af\r
	pop hl\r
	jr z,error0		;'S', but no expression following\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
expr:\r
	call skipbl\r
expr1:\r
	call do_factor\r
	ret c\r
l0433h:\r
	call do_binary_op\r
	push hl\r
	push bc\r
	call do_factor\r
	pop bc\r
	ex de,hl\r
	ex (sp),hl\r
	jr nc,l0447h\r
	pop de\r
	ld a,b\r
	or c\r
	ret z\r
	jp ERROR\r
\r
l0447h:\r
	ld a,b\r
	or c\r
	push bc\r
	ret nz\r
	pop bc\r
\r
doop_add:\r
	add hl,de\r
l044dh:\r
	pop de\r
	jr l0433h\r
\r
doop_sub:\r
	and a\r
	sbc hl,de\r
	jr l044dh\r
\r
doop_mlt:\r
	push bc\r
	ld b,h\r
	ld c,l\r
	ld hl,0\r
	ld a,010h\r
l045dh:\r
	add hl,hl\r
	ex de,hl\r
	add hl,hl\r
	ex de,hl\r
	jr nc,l0464h\r
	add hl,bc\r
l0464h:\r
	dec a\r
	jr nz,l045dh\r
	pop bc\r
	jr l044dh\r
\r
doop_div:\r
	call div_hl_de\r
	jr l044dh\r
\r
doop_mod:\r
	call div_hl_de\r
	ex de,hl\r
	jr l044dh\r
\r
; divide x/y\r
;     hl: x\r
;     de: y\r
;   return:\r
;     hl: q  (x/y)\r
;     de: r  (x%y)\r
\r
div_hl_de:\r
	push	bc\r
	ex	de,hl		;de: x\r
	ld	b,h		;bc: y\r
	ld	c,l\r
	ld	hl,0		;hl: r\r
	ld	a,16\r
\r
;  de: x   (x shifted out, q shifted in)\r
;  bc: y\r
;  hl: r   (initially 0)\r
\r
div_lp:\r
	ex	de,hl\r
	add	hl,hl		;x <<= 1\r
	ex	de,hl\r
	adc	hl,hl		;r <<= 1\r
	inc	de\r
	or	a\r
	sbc	hl,bc\r
	jr 	nc,div_norestore\r
	dec	de\r
	add	hl,bc\r
div_norestore:\r
	dec	a\r
	jr	nz,div_lp\r
	ex	de,hl\r
	pop	bc\r
	ret\r
\r
doop_and:\r
	ld a,h\r
	and d\r
	ld h,a\r
	ld a,l\r
	and e\r
	ld l,a\r
	jr l044dh\r
\r
doop_or:\r
	ld a,h\r
	or d\r
	ld h,a\r
	ld a,l\r
	or e\r
	ld l,a\r
	jr l044dh\r
\r
doop_xor:\r
	ld a,h\r
	xor d\r
	ld h,a\r
	ld a,l\r
	xor e\r
	ld l,a\r
	jr l044dh\r
\r
do_binary_op:\r
	push hl\r
	ld hl,tab_op_a\r
	call lookupch\r
	ld a,b\r
	ld hl,tblf_opa\r
	call add_hl_a2\r
	ld c,(hl)\r
	inc hl\r
	ld b,(hl)\r
	pop hl\r
	ret\r
\r
tab_op_a:\r
	DB	'+-*/%&!#',0\r
\r
tblf_opa:\r
	dw	doop_add\r
	dw	doop_sub\r
	dw	doop_mlt\r
	dw	doop_div\r
	dw	doop_mod\r
	dw	doop_and\r
	dw	doop_or\r
	dw	doop_xor\r
	dw	0\r
\r
;-------------------------------------------------------------------------------\r
\r
fact_factor:\r
	call do_factor\r
	ret nc\r
	jp ERROR\r
\r
do_factor:\r
	call chk_stack\r
	call get.number\r
	ret nc\r
	inc de\r
	ld hl,ddtz_base-1\r
	cp 'T'\r
	ret z\r
	ld hl,(high_load)\r
	cp 'H'\r
	ret z\r
	ld hl,(max_load)\r
	cp 'M'\r
	ret z\r
	ld hl,TPA\r
	cp 'L'\r
	ret z\r
	ld hl,(reg.pc)\r
	cp '$'\r
	ret z\r
	cp '-'\r
	jr z,fact_factneg\r
	cp '~'\r
	jr z,fact_factinv\r
	cp '+'\r
	jr z,fact_factor\r
	cp '^'\r
	jr z,fact_reg.CPU\r
	cp '('\r
	jr z,fact_mem\r
	cp '['\r
	jr z,expr_brckt\r
	cp ''''\r
	jr z,fact_factstring\r
	dec de\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
fact_factstring:\r
	ld hl,0\r
l054bh:\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0557h\r
	and a\r
	ret z\r
l0552h:\r
	ld h,l\r
	ld l,a\r
	inc de\r
	jr l054bh\r
l0557h:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0552h\r
	sub '.'\r
	or a\r
	ret nz\r
	inc de\r
	set 7,l\r
	ret\r
\r
fact_reg.CPU:\r
	call sub_0caeh\r
	jr nc,error1\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	and a\r
	bit 0,c\r
	ret nz\r
	ld h,000h\r
	ret\r
\r
fact_factinv:\r
	call fact_factor\r
	jr cpl.hl\r
\r
fact_factneg:\r
	call fact_factor\r
neg.hl:\r
	dec hl\r
cpl.hl:\r
	ld a,h\r
	cpl\r
	ld h,a\r
	ld a,l\r
	cpl\r
	ld l,a\r
	ret\r
\r
fact_mem:\r
	call expr1\r
	jr c,error1\r
	ld a,(de)\r
	cp ')'\r
	jr nz,error1\r
	inc de\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	ld a,(de)\r
	inc de\r
	cp '.'\r
	ret z\r
	dec de\r
	xor a\r
	ld h,a\r
	ret\r
\r
expr_brckt:\r
	call expr1\r
	jr c,error1\r
	ld a,(de)\r
	cp ']'\r
	inc de\r
	ret z\r
error1:\r
	jp ERROR\r
\r
;-------------------------------------------------------------------------------\r
\r
get.number:\r
	call get.hexdigit\r
	ret c\r
	push de\r
test_number:\r
	inc de\r
	call get.hexdigit\r
	jr nc,test_number\r
	pop de\r
	cp '.'\r
	jr z,get_dec_number\r
	cp '"'\r
	jr z,get_bin_number\r
	ld hl,0\r
next_hexdigit:\r
	call get.hexdigit\r
	jr c,hexnum_done\r
	add hl,hl\r
	add hl,hl\r
	add hl,hl\r
	add hl,hl\r
	call add_hl_a\r
	inc de\r
	jr next_hexdigit\r
\r
hexnum_done:\r
	xor 'H'\r
	ret nz\r
	inc de\r
	ret\r
\r
get_bin_number:\r
	ld hl,0\r
next_bindigit:\r
	call get.bindigit\r
l05dbh:\r
	inc de\r
	jr c,l05e4h\r
	add hl,hl\r
	call add_hl_a\r
	jr next_bindigit\r
l05e4h:\r
	cp '"'\r
	jr nz,error11\r
	call get.bindigit\r
	jr nc,l05dbh\r
	or a\r
	ret\r
\r
get_dec_number:\r
	ld hl,0\r
next_decdigit:\r
	call get.decdigit\r
	inc de\r
	jr c,decnum_done\r
	push bc\r
	add hl,hl\r
	ld b,h\r
	ld c,l\r
	add hl,hl\r
	add hl,hl\r
	add hl,bc\r
	pop bc\r
	call add_hl_a\r
	jr next_decdigit\r
decnum_done:\r
	cp '.'\r
	ret z\r
error11:\r
	jp ERROR\r
\r
sub_060ch:\r
	call get_char_upper\r
	cp 'Z'+1\r
	jr l0614h\r
\r
get.hexdigit:\r
	ld a,(de)\r
hex_digit:\r
	call toupper\r
	cp 'F'+1\r
l0614h:\r
	ccf\r
	ret c\r
	cp 'A'\r
	jr c,l061eh\r
	sub 'A'-10\r
	ret\r
\r
get.decdigit:\r
	call get_char_upper\r
l061eh:\r
	cp '9'+1\r
	jr l0625h\r
\r
get.bindigit:\r
	call get_char_upper\r
	cp '1'+1\r
l0625h:\r
	ccf\r
	ret c\r
	cp '0'\r
	ret c\r
	sub '0'\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_cpustat0:\r
	call assert_eol\r
p_cpustat:\r
	call p_f\r
	call outbl2\r
	ld hl,b_06e9_start\r
	ld de,b_0709_start\r
	ld b,6\r
l063eh:\r
	call p_regs\r
	djnz l063eh\r
	call outbl6\r
	push hl\r
	push de\r
	ld iy,(reg.pc)\r
	call p_disas_instr\r
	pop de\r
	pop hl\r
	call crlf\r
	call p_f2\r
	call outbl2\r
	ld b,7\r
l065bh:\r
	call p_regs\r
	djnz l065bh\r
	jp crlf\r
\r
p_f:\r
	ld a,(reg.f)\r
	call p_flags\r
	ld a,(reg.iff)\r
	cp 0f3h\r
	jr z,outbl_1\r
	ld a,'E'\r
	jp outchar\r
p_f2:\r
	ld a,(reg.f2)\r
	call p_flags\r
	jr outbl_1\r
\r
p_flags:\r
	push	hl\r
	ld	hl,t_flag_names+7\r
	ld	c,a\r
	ld	b,8\r
fl_loop:\r
	ld	a,' '\r
	cp	(hl)\r
	ld	a,c\r
	rlca\r
	ld	c,a\r
	jr	z,fl_skip\r
	ld	a,(hl)\r
	call	c,outchar\r
	call	nc,outbl\r
fl_skip:\r
	dec	hl\r
	djnz	fl_loop\r
	pop	hl\r
	ret\r
\r
p_regs:\r
	push de\r
	call pstr\r
	call	pstr_inl\r
	dc	'='\r
	ex (sp),hl\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	inc hl\r
	ld a,(hl)\r
	inc hl\r
	push hl\r
	and a\r
	jr z,l06deh\r
	ex de,hl\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	ex de,hl\r
	call out_hl\r
	jr l06e2h\r
l06deh:\r
	ld a,(de)\r
	call out_hex\r
l06e2h:\r
	pop de\r
	pop hl\r
outbl_1:\r
	jp outbl\r
\r
b_06e9_start:\r
	DC	'A '\r
	DC	'BC '\r
	DC	'DE '\r
	DC	'HL '\r
	DC	'SP'\r
	DC	'PC'\r
	DC	'a'''\r
	DC	'bc'''\r
	DC	'de'''\r
	DC	'hl'''\r
	DC	'IX'\r
	DC	'IY'\r
	DC	'I'\r
	DB	0\r
\r
b_0709_start:\r
	dw	reg.a\r
	db	000h\r
	dw	reg.c\r
	db	001h\r
	dw	reg.e\r
	db	001h\r
	dw	reg.l\r
	db	001h\r
	dw	reg_sp\r
	db	001h\r
	dw	reg.pc\r
	db	002h\r
	dw	reg.a2\r
	db	000h\r
	dw	reg.c2\r
	db	001h\r
	dw	reg.e2\r
	db	001h\r
	dw	reg.l2\r
	db	001h\r
	dw	reg.ix\r
	db	001h\r
	dw	reg.iy\r
	db	001h\r
	dw	reg.i\r
	db	000h\r
	db	000h\r
\r
;-------------------------------------------------------------------------------\r
; > E addr\r
;      relocate debugger to addr\r
; > ER addr\r
;      relocate just below addr\r
;\r
; Move debugger to given address and restart.\r
; New location must not overlap with current location.\r
\r
\r
cmd_E:\r
	call	skipbl\r
	sub	'R'\r
	jr	nz,$+3\r
	 inc	de\r
	push	af\r
	call	get_arg_final\r
\r
	ex	de,hl\r
	ld	hl,(bitmap_end)\r
	ld	bc,ddtz_base\r
	or	a\r
	sbc	hl,bc\r
	ld	b,h\r
	ld	c,l\r
	ex	de,hl\r
	pop	af\r
	jr	nz,cmde_bottom\r
	sbc	hl,bc\r
cmde_bottom:\r
	ld	ix,cmde_clr-ddtz_base\r
	ex	de,hl			;de = dst\r
	add	ix,de\r
	ld	hl,ddtz_base		;hl = src\r
\r
	push	hl\r
	or	a\r
	sbc	hl,de\r
	call	c,neg.hl		;abs(distance)\r
	or	a\r
	sbc	hl,bc\r
	jp	c,error\r
	pop	hl\r
	push	hl\r
	push	bc\r
	ldir\r
	pop	bc\r
	pop	hl\r
	jp	(ix)\r
\r
;-------------------------------------------------------------------------------\r
; > G [startaddr] [;breakp..]\r
;      Go [to start] [with temporary breakpoints]\r
\r
cmd_G:\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call expr\r
	jr c,l0740h\r
	ld (reg.pc),hl\r
l0740h:\r
	call skipbl\r
	jr z,user_go0\r
	cp ';'\r
	jp nz,ERROR\r
	inc de\r
	ld a,002h\r
	call bp_enter\r
user_go0:\r
	jp user_go\r
\r
;-------------------------------------------------------------------------------\r
\r
bpl_init:\r
	ld	b,BP_CNT\r
	ld	ix,bp_tab\r
	ex	(sp),hl\r
	ld	(pbl_loop_adr),hl\r
	ex	(sp),hl\r
	ret\r
\r
bpl_next:\r
	ld	de,BP_SIZE\r
	push	af\r
	add	ix,de\r
	pop	af\r
	dec	b\r
	ret	z\r
\r
	ex	(sp),hl\r
	ld	hl,(pbl_loop_adr)\r
	ex	(sp),hl\r
	ret\r
\r
bp_clr_temporary:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 0f1h\r
	ld (ix+000h),a\r
\r
	call bpl_next\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > B\r
;      display all breakpoints\r
; > B breakp [breakp..]\r
;      set breakpoints\r
; > BX\r
;      clear all breakpoints\r
; > BX breakp [breakp..]\r
;      clear breakpoints\r
;\r
; breakp can be any valid expression\r
\r
cmd_B:\r
	call skipbl\r
	jr z,bp_print\r
	inc de\r
	cp 'X'\r
	jr z,bp_clr0\r
	dec de\r
	ld a,001h\r
	jp bp_enter\r
\r
bp_clr0:\r
	call skipbl\r
	jr z,bp_clr_all\r
bp_clr_next:\r
	call expr\r
	jp c,assert_eol\r
	push de\r
	call bp_clr\r
	pop de\r
	call next_arg\r
	jr bp_clr_next\r
\r
bp_clr_all:\r
	scf\r
bp_clr:\r
	call	bpl_init\r
\r
	push af\r
	jr c,l07a7h\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	call cp_hl_de\r
	jr nz,l07aeh\r
l07a7h:\r
	ld (ix+000h),000h\r
l07aeh:\r
	pop af\r
	call bpl_next\r
	ret\r
\r
bp_print:\r
	ld	c,0\r
	call	bpl_init\r
\r
	bit 0,(ix+000h)\r
	jr z,bp_pr_cont\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	call out_hl\r
	call outbl2\r
	inc	c\r
bp_pr_cont:\r
	call bpl_next\r
	ld	a,c\r
	or	a\r
	call 	nz,crlf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; Add break points to list\r
;   A = 1	 Permanent (B command)\r
;   A = 2	 Temporary (G command)\r
\r
bp_enter:\r
	ld b,a\r
	call skipbl\r
	ret z\r
\r
	push bc\r
	call expr\r
	jr c,error12\r
	pop bc\r
	bit 0,b\r
	push bc\r
	push de\r
	push hl\r
	call nz,bp_clr\r
	pop hl\r
	call bp_get_freeslot\r
	pop de\r
	ld (ix+002h),l\r
	ld (ix+003h),h\r
	call next_arg\r
	pop af\r
	ld (ix+000h),a\r
	and 00fh\r
	jr bp_enter\r
\r
bp_get_freeslot:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 00fh\r
	ret z\r
\r
	call	bpl_next\r
error12\r
	jp ERROR\r
\r
\r
;-------------------------------------------------------------------------------\r
; Breakpoint handling routine.\r
\r
bpddtz:\r
	ld (reg.l),hl\r
	pop hl\r
	dec hl\r
	ld (reg.pc),hl\r
	ld (reg_sp),sp\r
	ld sp,reg.l\r
	push de\r
	push bc\r
	push af\r
	push ix\r
	push iy\r
	ld a,i\r
	call di_or_ei\r
	ld h,a\r
	ld l,000h\r
	push hl\r
	ld a,0f3h		; EI\r
	jp po,l08dfh\r
	ld a,0fbh		; DI\r
l08dfh:\r
	ld (reg.iff),a\r
	ex af,af'\r
	push af\r
	exx\r
	push bc\r
	push de\r
	push hl\r
	call bp_restore_mem\r
	ld a,(b_21e2_start)\r
	dec a\r
	jr z,l090bh\r
	call inchar		;Keyboard hit?\r
	jr c,do_break		;yes\r
	call sub_0913h\r
	and a\r
	jp z,user_go\r
	and 083h\r
	jp z,l2151h\r
do_break:\r
	call bp_clr_temporary\r
	call p_cpustat\r
	jp mainloop\r
\r
l090bh:\r
	ld (b_21e2_start),a\r
	ld c,007h\r
	jp l0a41h\r
\r
sub_0913h:\r
	ld a,080h\r
	ex af,af'\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 007h\r
	jr z,l0938h\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	ld hl,(reg.pc)\r
	call cp_hl_de\r
	jr nz,l0938h\r
	ex af,af'\r
	res 7,a\r
	or (ix+000h)\r
	ex af,af'\r
l0938h:\r
	call	bpl_next\r
	ex af,af'\r
	ret\r
\r
bp_restore_mem:\r
	call	bpl_init\r
\r
	bit 5,(ix+000h)\r
	res 5,(ix+000h)\r
	jr z,l099ah\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	ld a,(l0003h)\r
	cp (hl)\r
	jr nz,l099ah\r
	ld a,(ix+001h)\r
	ld (hl),a\r
l099ah:\r
	res 3,(ix+000h)\r
\r
	call	bpl_next\r
	ret\r
\r
bp_tst_@pc:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and 003h\r
	jr z,bp_tst_e\r
	ld e,(ix+002h)\r
	ld d,(ix+003h)\r
	ld hl,(reg.pc)\r
	call cp_hl_de\r
	ret z\r
bp_tst_e:\r
	call	bpl_next\r
	sub a\r
	inc a\r
	ret\r
\r
bp_trace_enter:\r
	call bp_get_freeslot\r
	ld (ix+002h),l\r
	ld (ix+003h),h\r
	ld a,(b_21e2_start)\r
	and a\r
	ld a,008h\r
	jr nz,bp_t_e\r
	rra\r
bp_t_e:\r
	ld (ix+000h),a\r
	ret\r
\r
bp_set_to_mem:\r
	call	bpl_init\r
\r
	ld a,(ix+000h)\r
	and c\r
	jr z,l0a1dh\r
	set 5,(ix+000h)\r
	ld l,(ix+002h)\r
	ld h,(ix+003h)\r
	ld a,(hl)\r
	ld (ix+001h),a\r
	ld a,(l0003h)\r
	ld (hl),a\r
	and 038h\r
	ld h,000h\r
	ld l,a\r
	ld (hl),0c3h\r
	inc hl\r
	ld de,bpddtz\r
	ld (hl),e\r
	inc hl\r
	ld (hl),d\r
l0a1dh:\r
\r
	call	bpl_next\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
user_go:\r
	sub a\r
	ld (b_21e2_start),a\r
	ld a,(bp_p_cpu_flag)\r
	and a\r
	call nz,p_cpustat\r
	call bp_tst_@pc\r
	ld c,007h\r
	jr nz,l0a41h\r
	ld a,001h\r
	ld (b_21e2_start),a\r
	call tc_set_bp\r
	ld c,008h\r
l0a41h:\r
	call bp_set_to_mem\r
	ld sp,reg.l2\r
	pop hl\r
	pop de\r
	pop bc\r
	pop af\r
	exx\r
	ex af,af'\r
	pop af\r
	ld i,a\r
	pop iy\r
	pop ix\r
	pop af\r
	pop bc\r
	pop de\r
	pop hl\r
	ld sp,(reg_sp)\r
	jp reg.iff\r
\r
;-------------------------------------------------------------------------------\r
; > Y\r
;      examine all Y variables\r
; > Y[0..9]\r
;      examine (and substitute) an Y variable\r
\r
\r
;-------------------------------------------------------------------------------\r
; > X\r
;      eXamine (display) all cpu registers and\r
;      the instruction at the current program counter\r
; > X register\r
;      eXamine (and substitute) a register\r
\r
\r
cmd_X:\r
	call skipbl\r
	call sub_0caeh\r
	jp nc,p_cpustat0\r
	call assert_eol\r
	ld a,b\r
	cp 25\r
	jr z,l0c5fh\r
	cp 26\r
	jr z,l0c4fh\r
	ex de,hl\r
	ld hl,t_reg_names\r
	call pstr_sel\r
	call l0c33h\r
\r
	call outbl\r
	push de\r
	push bc\r
	call get_line\r
	call skipbl\r
	jr z,l0c30h\r
	call get_arg_final\r
	ex de,hl\r
	pop bc\r
	pop hl\r
	ld (hl),e\r
	bit 0,c\r
	ret z\r
	inc hl\r
	ld (hl),d\r
	ret\r
l0c30h:\r
	pop af\r
	pop hl\r
	ret\r
\r
l0c33h:\r
	call	pstr_inl\r
	dc	'='\r
	ld a,(de)\r
	bit 0,c\r
	jp z,out_hex\r
	ld l,a\r
	inc de\r
	ld a,(de)\r
	dec de\r
	ld h,a\r
	jp out_hl\r
\r
l0c4fh:\r
	call p_f\r
	ld a,0f3h\r
	ld (reg.iff),a\r
	scf\r
	call sub_0c6ah\r
	ld (reg.f),a\r
	ret\r
l0c5fh:\r
	call p_f2\r
	and a\r
	call sub_0c6ah\r
	ld (reg.f2),a\r
	ret\r
\r
sub_0c6ah:\r
	push af\r
	call outbl\r
	call assert_eol\r
	call get_line\r
	pop af\r
	ex af,af'\r
	ld b,0\r
l0c76h:\r
	call skipbl\r
	ld a,b\r
	ret z\r
	push bc\r
	ld hl,t_flag_names\r
	call lookupch\r
	jp nc,ERROR\r
	inc	b\r
	xor	a\r
	scf\r
nxt_f:\r
	rla\r
	djnz	nxt_f\r
	pop	bc\r
	jr	c,l0c97h\r
	or	b\r
	ld	b,a\r
	jr l0c76h\r
\r
l0c97h:\r
	ex af,af'\r
	jp nc,ERROR\r
	ex af,af'\r
	ld a,0fbh\r
	ld (reg.iff),a\r
	jr l0c76h\r
\r
t_flag_names:\r
	db	'CNV H ZSE',0\r
\r
sub_0caeh:\r
	call sub_0303h\r
	ret nc\r
	ld a,b\r
	add a,b\r
	add a,b\r
	ld hl,b_0cfa_start\r
	call add_hl_a\r
	ld c,(hl)\r
	inc hl\r
	ld a,(hl)\r
	inc hl\r
	ld h,(hl)\r
	ld l,a\r
	scf\r
	ret\r
\r
t_reg_names:\r
	DC	'BC'''		;0\r
	DC	'DE'''		;1\r
	DC	'HL'''		;2\r
	DC	'BC'		;3\r
	DC	'DE'		;4\r
	DC	'HL'		;5\r
	DC	'A'''		;6\r
	DC	'B'''		;7\r
	DC	'C'''		;8\r
	DC	'D'''		;9\r
	DC	'E'''		;10\r
	DC	'H'''		;11\r
	DC	'L'''		;12\r
	DC	'A'		;13\r
	DC	'B'		;14\r
	DC	'C'		;15\r
	DC	'D'		;16\r
	DC	'E'		;17\r
	DC	'H'		;18\r
	DC	'L'		;19\r
	DC	'IX'		;20\r
	DC	'IY'		;21\r
	DC	'SP'		;22\r
	DC	'PC'		;23\r
	DC	'I'		;24\r
	DC	'F'''		;25\r
	DC	'F'		;26\r
	DB	0\r
\r
b_0cfa_start:\r
	db	003h\r
	dw	reg.c2\r
	db	003h\r
	dw	reg.e2\r
	db	003h\r
	dw	reg.l2\r
	db	003h\r
	dw	reg.c\r
	db	003h\r
	dw	reg.e\r
	db	003h\r
	dw	reg.l\r
	db	000h\r
	dw	reg.a2\r
	db	000h\r
	dw	reg.b2\r
	db	000h\r
	dw	reg.c2\r
	db	000h\r
	dw	reg.d2\r
	db	000h\r
	dw	reg.e2\r
	db	000h\r
	dw	reg.h2\r
	db	000h\r
	dw	reg.l2\r
	db	000h\r
	dw	reg.a\r
	db	000h\r
	dw	reg.b\r
	db	000h\r
	dw	reg.c\r
	db	000h\r
	dw	reg.d\r
	db	000h\r
	dw	reg.e\r
	db	000h\r
	dw	reg.h\r
	db	000h\r
	dw	reg.l\r
	db	003h\r
	dw	reg.ix\r
	db	003h\r
	dw	reg.iy\r
	db	003h\r
	dw	reg_sp\r
	db	003h\r
	dw	reg.pc\r
	db	000h\r
	dw	reg.i\r
	db	000h\r
	dw	reg.f2\r
	db	000h\r
	dw	reg.f\r
\r
;-------------------------------------------------------------------------------\r
; > S [startaddr]\r
;      Substitute memory\r
\r
cmd_S:\r
	ld hl,(last_S)\r
	call get_lastarg_def\r
l0d60h:\r
	ld (last_S),hl\r
	call out_hl\r
	call outbl\r
	ld a,(hl)\r
	call out_hex\r
	call outbl2\r
	call get_line\r
	call skipbl\r
	inc hl\r
	jr z,l0d60h\r
	dec hl\r
	inc de\r
	cp '.'\r
	jr	nz,cmds_dash\r
	call get_char_upper\r
	or	a\r
	jr	nz,l0d8ah\r
	ret\r
cmds_dash:\r
	jp z,assert_eol\r
	cp '-'\r
	jr nz,l0d8ah\r
	call get_char_upper\r
	or a\r
	dec hl\r
	jr z,l0d60h\r
	inc hl\r
l0d8ah:\r
	dec de\r
	call sub_0ef8h\r
	jr l0d60h\r
\r
;-------------------------------------------------------------------------------\r
; > @\r
;      examine (substitute) displacement register @\r
\r
;cmd_@:\r
\r
;-------------------------------------------------------------------------------\r
; >>I [port]\r
;      Input a byte from port\r
\r
cmd_I:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_I)\r
	call get_lastarg_def\r
	ld (last_I),hl\r
	ld b,h\r
	ld c,l\r
	in a,(c)\r
	push af\r
	call out_hex\r
	call outbl4\r
	pop af\r
	call out.bin.b\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; >>O [byte] [port]\r
;      Output a byte to a port\r
\r
cmd_O:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_O_val)\r
	call get_arg_def\r
	ld a,l\r
	ld (last_O_val),a\r
	push af\r
	call next_arg\r
	ld hl,(last_O_addr)\r
	call get_lastarg_def\r
	ld (last_O_addr),hl\r
	ld b,h\r
	ld c,l\r
	pop af\r
	out (c),a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > V startaddr endaddr targetaddr\r
;      Verify (compare) two memory areas\r
\r
cmd_V:\r
	call get_arg_range_target\r
l0dedh:\r
	push bc\r
	ld a,(de)\r
	ld b,(hl)\r
	cp b\r
	jr z,l0e10h\r
	ld c,a\r
	call out_hl\r
	call outbl\r
	ld a,b\r
	call out_hex\r
	call outbl2\r
	ld a,c\r
	call out_hex\r
	call outbl\r
	ex de,hl\r
	call out_hl\r
	ex de,hl\r
	call crlf\r
l0e10h:\r
	pop bc\r
	inc de\r
	cpi\r
	jp pe,l0dedh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > M startaddr endaddr destaddr\r
;      Move memory\r
\r
cmd_M:\r
	call get_arg_range_target\r
	call cp_hl_de\r
	jr nc,cmdm_up\r
	add hl,bc\r
	ex de,hl\r
	add hl,bc\r
	ex de,hl\r
	dec hl\r
	dec de\r
	lddr\r
	ret\r
cmdm_up:\r
	ldir\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > H\r
;      display Highest load address of last filed loaded, Maximum "High"\r
;      off all loaded files, and Top address of available memory\r
; > H expression\r
;      evaluate expression and display result in hex, decimal and other formats\r
\r
cmd_H:\r
	call expr\r
	jp c,p_max_high0\r
	call assert_eol\r
	call out_hl\r
	call outbl2\r
	call out_hl_neg\r
	call outbl4\r
	call out.hl.dec\r
	call outbl2\r
	call out_hl_dec_neg\r
	call outbl4\r
	call out.bin.w\r
	call outbl2\r
	ld a,l\r
	call out.ascii\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; > Q[J] startaddr endaddr bytes\r
;      Query memory for a byte string [Justified]\r
\r
cmd_Q:\r
	call get_arg_range\r
	push bc\r
	push hl\r
	call sub_0ee6h\r
	pop hl\r
l0e96h:\r
	push	hl\r
	push	de\r
	push bc\r
l0edah:\r
	ld a,(de)\r
	cp (hl)\r
	jr nz,l0ee2h\r
	inc de\r
	inc hl\r
	djnz l0edah\r
l0ee2h:\r
	pop bc\r
	pop de\r
	pop hl\r
	jr nz,l0eb0h\r
	push bc\r
	ld bc,16\r
	and a			;clear carry\r
	call sub_0f58h\r
	pop bc\r
l0eb0h:\r
	inc hl\r
	ex (sp),hl\r
	dec hl\r
	ld a,h\r
	or l\r
	ex (sp),hl\r
	jr nz,l0e96h\r
	pop bc\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > Z startaddr endaddr bytes\r
;      Zap (fill) memory with a byte string\r
\r
cmd_Z:\r
	call get_arg_range\r
	push bc\r
	push hl\r
	call sub_0ee6h\r
	ld a,b\r
	pop hl\r
	pop bc\r
	push hl\r
	ex de,hl\r
l0ec7h:\r
	ldi\r
	jp po,l0ed3h\r
	dec a\r
	jr nz,l0ec7h\r
	pop hl\r
	ldir\r
	ret\r
l0ed3h:\r
	pop hl\r
	ret\r
\r
sub_0ee6h:\r
	ld hl,conbuf\r
	call sub_0ef7h\r
	ld de,conbuf\r
	and a\r
	sbc hl,de\r
	ld b,l\r
	ret nz\r
	jp ERROR\r
\r
sub_0ef7h:			;from cmd_Q, cmd_Z\r
	db	0e6h		;and 037h (clear carry)\r
sub_0ef8h:			;from cmd_S\r
	scf\r
l0ef9h:\r
	push af\r
	call next_arg\r
	cp ''''\r
	jr z,l0f1eh\r
	push hl\r
	call expr\r
	ld a,l\r
	pop hl\r
	jr c,l0f42h\r
	ld (hl),a\r
	inc hl\r
	jr l0f3ah\r
l0f1eh:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0f2bh\r
	or a\r
	jr z,l0f42h\r
l0f27h:\r
	ld (hl),a\r
	inc hl\r
	jr l0f1eh\r
l0f2bh:\r
	inc de\r
	ld a,(de)\r
	cp ''''\r
	jr z,l0f27h\r
	cp '.'\r
	jr nz,l0f3ah\r
	inc de\r
	dec hl\r
	set 7,(hl)\r
	inc hl\r
l0f3ah:\r
	pop af\r
	jr nc,l0ef9h\r
	ld (last_S),hl\r
	jr l0ef9h\r
l0f42h:\r
	pop af\r
	ret nc\r
	ld (last_S),hl\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; >>D [startaddr] [endaddr]\r
;      Display memory in hex and ASCII\r
\r
cmd_D:\r
	ld (cmd_rpt),hl\r
	ld hl,(last_D)\r
	ld bc,128\r
	call sub_0377h\r
	scf\r
sub_0f58h:\r
	push bc\r
	push de\r
	push hl\r
	push af\r
l0f5ch:\r
	call out_hl\r
	call outbl2\r
	ld de,0\r
l0f68h:\r
	ld a,(hl)\r
	inc hl\r
	call out_hex\r
	call outbl\r
	dec bc\r
	inc e\r
	ld a,e\r
	cp 010h\r
	jr z,l0f80h\r
	and 003h\r
	call z,outbl\r
	ld a,b\r
	or c\r
	jr nz,l0f68h\r
l0f80h:\r
	call outbl\r
	and a\r
	sbc hl,de\r
l0f86h:\r
	ld a,(hl)\r
	call sub_0fa3h\r
	call outchar\r
	inc hl\r
	dec e\r
	jr nz,l0f86h\r
	pop af\r
	push af\r
	jr nc,l0f97h\r
	ld (last_D),hl\r
l0f97h:\r
	call crlf\r
	ld a,b\r
	or c\r
	jr nz,l0f5ch\r
	pop af\r
	pop hl\r
	pop de\r
	pop bc\r
	ret\r
\r
sub_0fa3h:\r
	and 07fh\r
	cp 07fh\r
	jr z,l0fach\r
	cp ' '\r
	ret nc\r
l0fach:\r
	ld a,'.'\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; > Fcommandline\r
;      specifiy filenames and command line\r
\r
;cmd_F:\r
\r
;-------------------------------------------------------------------------------\r
; > R [displacement]\r
;	Read Intel Hex File from console [add displacement]\r
\r
cmd_R:\r
	ld hl,0\r
	call get_lastarg_def	;get offset from command line\r
	push hl\r
	ld hl,0\r
	ld (high_load),hl\r
w_recstart:\r
	call i.getchar\r
	jr z,rdhex_done\r
	cp ':'\r
	jr nz,w_recstart\r
	ld c,0			;init checksum\r
	call i.gethexbyte	;record len\r
	ld b,a\r
	call i.gethexbyte	;address high\r
	ld h,a\r
	call i.gethexbyte	;address low\r
	ld l,a\r
	call i.gethexbyte	;record type (ignored)\r
	ld a,b\r
	and a			;record len == 0?\r
	jr z,rdhex_done\r
l16c6h:\r
	call i.gethexbyte\r
	pop de			;offset\r
	push de\r
	push hl\r
	add hl,de\r
	call i.storebyte\r
	pop hl\r
	inc hl\r
	djnz l16c6h		;repeat for record len\r
	call i.gethexbyte	;checksum\r
	ld a,c\r
	and a\r
	jr nz,error2		;exit if checksum error\r
	jr w_recstart		;next record\r
\r
rdhex_done:\r
	pop hl\r
	call i.gethexbyte\r
	jp p_max_high\r
\r
i.gethexbyte:\r
	call sub_16f6h\r
	rlca\r
	rlca\r
	rlca\r
	rlca\r
	ld d,a\r
	call sub_16f6h\r
	add a,d\r
	ld d,a\r
	add a,c\r
	ld c,a\r
	ld a,d\r
	ret\r
\r
sub_16f6h:\r
	call i.getchar\r
	jr z,error2\r
	call hex_digit\r
	ret nc\r
error2:\r
	jp ERROR\r
\r
i.getchar:\r
	call incharw\r
	cp 01ah\r
	ret\r
\r
i.storebyte:\r
	push af\r
	push de\r
	ld de,ddtz_base		;don't load over ddtz\r
	call cp_hl_de\r
	jr nc,ist_1\r
\r
	ld de,(bitmap_end)\r
	call cp_hl_de\r
	jr nc,error2\r
ist_1:\r
	ld de,(high_load)\r
	call cp_hl_de\r
	jr c,l1157h\r
	ld (high_load),hl\r
l1157h:\r
	ld de,(max_load)\r
	call cp_hl_de\r
	jr c,l1163h\r
	ld (max_load),hl\r
l1163h:\r
	pop de\r
	pop af\r
	ld (hl),a		;store byte\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_max_high0:\r
	call assert_eol\r
p_max_high:\r
	call pstr_inl\r
	DC	'High = '\r
	ld hl,(high_load)\r
	call out_hl\r
	call pstr_inl\r
	DC	'  Max = '\r
	ld hl,(max_load)\r
	call out_hl\r
	call pstr_inl\r
	DC	'  Top = '\r
	ld hl,ddtz_base-1\r
	call out_hl\r
	jp crlf\r
\r
;-------------------------------------------------------------------------------\r
; > Wstartaddr endaddr\r
;      Write a file to disk\r
\r
;cmd_W:\r
\r
;-------------------------------------------------------------------------------\r
; > A [startaddr]\r
;      Assemble Zilog Z180 mnemonics\r
\r
;cmd_A:\r
\r
;-------------------------------------------------------------------------------\r
; >>L [startaddr] [endaddr]\r
;      List disassembled code\r
\r
cmd_L:\r
	ld (cmd_rpt),hl\r
	call expr\r
	jr nc,l18dbh\r
	ld hl,(last_L)\r
l18dbh:\r
	call next_arg\r
	call get_range\r
	jr nc,l1905h\r
	call assert_eol\r
	ld b,16\r
l18ebh:\r
	push bc\r
	call	cmdl_p_line\r
	pop bc\r
	djnz l18ebh\r
	ret\r
\r
l1905h:\r
	call assert_eol\r
	ld	d,h\r
	ld	e,l\r
	add	hl,bc\r
	ex	de,hl\r
l190fh:\r
	push	de\r
	call	cmdl_p_line\r
	pop 	de\r
	call	cp_hl_de\r
	jr	c,l190fh\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
cmdl_p_line:\r
	push	hl\r
	call out_hl\r
	call outbl2\r
	sub a\r
	ld (con_col),a\r
	push	hl\r
	pop	iy\r
	call p_disas_instr\r
	call	crlf\r
	pop	hl\r
	ld	c,b\r
	ld	b,0\r
	add	hl,bc\r
	ld	(last_L),hl\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
p_disas_instr:\r
	call disas_get_instrlen\r
	jr nc,l197fh\r
	push	bc\r
	ld	a,(con_col)\r
	add	a,5\r
	ld	c,a\r
	call	pstr					;print mnemonic\r
	call	p_goto_col\r
	call	pr_instr_args				;print arguments\r
	pop bc\r
	scf\r
	ret\r
\r
l197fh:\r
	call pstr_inl\r
	DC	'???'\r
	ld b,1\r
	sub a\r
	ret\r
\r
disas_get_instrlen:\r
	sub a\r
	ld (isprefix_ixiy),a\r
	ld a,(iy+000h)\r
	cp 0edh\r
	jr z,disas_pfx.ED\r
	cp 0ddh\r
	jr z,l19abh\r
	cp 0fdh\r
	jr z,l19afh\r
sub_19a0h:\r
	ld a,(iy+000h)\r
	cp 0cbh\r
	jr z,disas_pfx.CB\r
	jr disas_nopfx\r
l19abh:\r
	ld a,1\r
	jr l19b1h\r
l19afh:\r
	ld a,2\r
l19b1h:\r
	ld (isprefix_ixiy),a\r
	call disas_pfx.DDFD\r
	ret nc\r
	push bc\r
	call sub_19a0h\r
	pop af\r
	add a,b\r
	ld b,a\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_nopfx:\r
	ld hl,b_1b54_start		;2 byte opcodes\r
	call lookup_op_arg\r
	ld b,2\r
	ret c\r
	ld hl,b_1ab6_start		;1 byte opcodes (no parameters)\r
	call lookup_op\r
	ld b,1\r
	ret c\r
	ld hl,b_1ad1_start		;1 byte opcodes\r
	call lookup_op_arg\r
	ld b,1\r
	ret c\r
	ld hl,b_1b9b_start		;3 byte opcodes\r
	call lookup_op_arg\r
	ld b,3\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.ED:\r
	inc iy\r
	ld hl,l228bh\r
	call lookup_op_arg\r
	ld b,3\r
	ret c\r
	ld hl,b_1c40_start\r
	call lookup_op_arg\r
	ld b,4\r
	ret c\r
\r
	ld hl,b_1bc9_start		;1 byte opcode, no arguments\r
	call lookup_op\r
	jr c,da_ed1\r
\r
	ld hl,b_1bf4_start\r
	call lookup_op_arg\r
	ret nc\r
\r
	ld a,e\r
	cp a_noarg\r
	jr nz,da_ed0\r
	ld c,(iy+0)\r
	ld a,c\r
	rra\r
	and 0ch\r
	ld b,a\r
	ld a,c\r
	and 03h\r
	call str_sel_ab\r
\r
da_ed0:\r
	scf\r
da_ed1:\r
	ld b,2\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.CB:\r
	push iy\r
	inc iy\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr z,l1a42h\r
	inc iy\r
l1a42h:\r
	ld hl,b_1c55_start\r
	call lookup_op_arg\r
	pop iy\r
	ld b,2\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
disas_pfx.DDFD:\r
	inc iy\r
	ld hl,b_19ef_start\r
	call test_DDFD\r
	ld b,002h\r
	ret c\r
	ld hl,l1a0ah\r
	call test_DDFD\r
	ld b,001h\r
	ret c\r
	ld a,(iy+000h)\r
	cp 0cbh\r
	jr nz,l19edh\r
	ld a,(iy+002h)\r
	cp 036h\r
	ret z\r
	and 007h\r
	cp 006h\r
	jr nz,l19edh\r
	ld b,002h\r
	scf\r
	ret\r
l19edh:\r
	and a\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; DD/FD 3 byte (ix+d)/(iy+d)\r
b_19ef_start:\r
	db	034h\r
	db	035h\r
	db	036h\r
	db	046h\r
	db	04eh\r
	db	056h\r
	db	05eh\r
	db	066h\r
	db	06eh\r
	db	070h\r
	db	071h\r
	db	072h\r
	db	073h\r
	db	074h\r
	db	075h\r
	db	077h\r
	db	07eh\r
	db	086h\r
	db	08eh\r
	db	096h\r
	db	09eh\r
	db	0a6h\r
	db	0aeh\r
	db	0b6h\r
	db	0beh\r
	db	0\r
\r
; DD/FD 2 byte\r
l1a0ah:\r
	db	009h\r
	db	019h\r
	db	021h\r
	db	022h\r
	db	023h\r
	db	029h\r
	db	02ah\r
	db	02bh\r
	db	039h\r
	db	0e1h\r
	db	0e3h\r
	db	0e5h\r
	db	0e9h\r
	db	0f9h\r
	db	0\r
\r
;-------------------------------------------------------------------------------\r
\r
test_DDFD:\r
	ld a,(hl)\r
	and a\r
	ret z\r
	inc hl\r
	cp (iy+000h)\r
	jr nz,test_DDFD\r
	scf\r
	ret\r
\r
lookup_op:\r
	ld a,(hl)\r
	inc hl\r
	cp 0ffh\r
	ret z\r
	cp (iy+000h)\r
	jr z,l1a7fh\r
	inc hl\r
	jr lookup_op\r
l1a7fh:\r
	ld b,(hl)\r
	ld e,a_noarg\r
	jr get_mnemonic\r
\r
lookup_op_arg:\r
	call lookup_branch_op\r
	ret nc\r
	ld a,e\r
	ld e,d\r
	cp a,0ffh\r
	ret z			;carry clear\r
	ld b,a\r
\r
get_mnemonic:\r
	ld hl,t_MNEMONICS\r
	bit 7,b\r
	jr z,get_m1\r
	res 7,b\r
	ld a,(iy+000h)\r
	rra\r
	rra\r
	rra\r
	and 07h\r
str_sel_ab:\r
	add b\r
	ld b,a\r
get_m1:\r
	call str_sel\r
	scf\r
	ret\r
\r
lookup_branch_op		;TODO\r
	ld a,(hl)\r
	and a\r
	ret z\r
	inc hl\r
	and (iy+000h)\r
	cp (hl)\r
	inc hl\r
	jr z,l1aa8_br\r
	inc hl\r
	inc hl\r
	jr lookup_branch_op\r
\r
l1aa8_br:\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; 1 byte opcodes (no parameters)\r
; Format: db opcode, t_MNEMONICS-index\r
b_1ab6_start:\r
	db 076h,i_HALT		;halt\r
	db 0d9h,i_EXX		;exx\r
	db 0f3h,i_DI		;di\r
	db 0fbh,i_EI		;ei\r
	db 000h,i_NOP		;nop\r
;	db 007h,i_RLCA		;rlca\r
;	db 00fh,i_RRCA		;rrca\r
;	db 017h,i_RLA		;rla\r
;	db 01fh,i_RRA		;rra\r
;	db 027h,i_DAA		;daa\r
;	db 02fh,i_CPL		;cpl\r
;	db 037h,i_SCF		;scf\r
;	db 03fh,i_CCF		;ccf\r
	db 0c9h,i_RET		;ret\r
	db 0ffh\r
\r
\r
; 1 byte opcodes\r
; Format: db mask, match, t_MNEMONICS-index\r
;	  dw argument formating function\r
b_1ad1_start:\r
	db 0c0h,040h,i_LD	;ld r[y],r[z]\r
	db a_rr\r
\r
	db 0c0h,080h,i_ADD+080h	;add a,r[z]\r
	db a_r\r
\r
;	db 0f8h,080h,i_ADD	;add a,r[z]\r
;	db a_ar\r
;	db 0f8h,088h,i_ADC	;adc a,r[z]\r
;	db a_ar\r
;	db 0f8h,090h,i_SUB	;sub r[z]\r
;	db a_r\r
;	db 0f8h,098h,i_SBC	;sbc a,r[z]\r
;	db a_ar\r
;	db 0f8h,0a0h,i_AND	;and r[z]\r
;	db a_r\r
;	db 0f8h,0a8h,i_XOR	;xor r[z]\r
;	db a_r\r
;	db 0f8h,0b0h,i_OR	;or r[z]\r
;	db a_r\r
;	db 0f8h,0b8h,i_CP	;cp r[z]\r
;	db a_r\r
\r
	db 0c7h,0c0h,i_RET	;ret cc\r
	db a_cc\r
	db 0c7h,0c7h,i_RST	;rst\r
	db a_rst\r
	db 0cfh,0c1h,i_POP	;pop rp2\r
	db a_p2\r
	db 0cfh,0c5h,i_PUSH	;push rp2\r
	db a_p2\r
	db 0ffh,0e3h,i_EX	;ex (sp),hl\r
	db a_esphl\r
	db 0ffh,0e9h,i_JP	;jp (hl)\r
	db a_hl\r
	db 0ffh,0ebh,i_EX	;ex de,hl\r
	db a_dehl\r
	db 0ffh,0f9h,i_LD	;ld sp,hl\r
	db a_lsphl\r
	db 0cfh,003h,i_INC	;inc rp\r
	db a_p\r
	db 0cfh,00bh,i_DEC	;dec rp\r
	db a_p\r
	db 0c7h,004h,i_INC	;inc r[y]\r
	db a_ry\r
	db 0c7h,005h,i_DEC	;dec r[y]\r
	db a_ry\r
	db 0ffh,008h,i_EX	;ex af,af'\r
	db a_eaf\r
	db 0cfh,009h,i_ADD	;add hl,rp\r
	db a_hlp\r
	db 0efh,002h,i_LD	;ld (rp),a ;rp=bc,de\r
	db a_pa\r
	db 0efh,00ah,i_LD	;ld a,(rp) ;rp=bc,de\r
	db a_ap\r
\r
	db 0c7h,007h,i_RLCA+080h;rlca\r
	db a_noarg\r
\r
	db 0\r
\r
; 2 byte opcodes\r
b_1b54_start:\r
	db 0c7h,006h,i_LD	;ld r[y],nn\r
	db a_rn\r
\r
	db 0c7h,0c6h,i_ADD+080h	;add a,r[z]\r
	db a_n\r
\r
;	db 0ffh,0c6h,i_ADD	;add a,nn\r
;	db a_an\r
;	db 0ffh,0ceh,i_ADC	;adc a,nn\r
;	db a_an\r
;	db 0ffh,0d6h,i_SUB	;sub nn\r
;	db a_n\r
;	db 0ffh,0deh,i_SBC	;sbc a,nn\r
;	db a_an\r
;	db 0ffh,0e6h,i_AND	;and nn\r
;	db a_n\r
;	db 0ffh,0eeh,i_XOR	;xor nn\r
;	db a_n\r
;	db 0ffh,0f6h,i_OR	;or nn\r
;	db a_n\r
;	db 0ffh,0feh,i_CP	;cp nn\r
;	db a_n\r
\r
	db 0ffh,010h,i_DJNZ	;djnz\r
	db a_j\r
	db 0ffh,018h,i_JR	;jr\r
	db a_j\r
	db 0e7h,020h,i_JR	;jr cc,\r
	db a_ccj\r
	db 0ffh,0d3h,i_OUT	;out (nn),a\r
	db a_ma\r
	db 0ffh,0dbh,i_IN	;in a,(nn)\r
	db a_am\r
	db 0\r
\r
; 3 byte opcodes\r
b_1b9b_start:\r
	db 0c7h,0c2h,i_JP	;jp cc,mn\r
	db a_ccnn\r
	db 0c7h,0c4h,i_CALL	;call cc,mn\r
	db a_ccnn\r
	db 0cfh,001h,i_LD	;ld ww,mn\r
	db a_rnn\r
	db 0ffh,0c3h,i_JP	;jp mn\r
	db a_nn\r
	db 0ffh,0cdh,i_CALL	;call mn\r
	db a_nn\r
	db 0ffh,022h,i_LD	;ld (mn),hl\r
	db a_mmhl\r
	db 0ffh,02ah,i_LD	;ld hl,(mn)\r
	db a_hlmm\r
	db 0ffh,032h,i_LD	;ld (mn),a\r
	db a_mma\r
	db 0ffh,03ah,i_LD	;ld a,(mn)\r
	db a_amm\r
	db 0\r
\r
; Prefix ED + 1 byte opcode, no arguments\r
; Format: opcode, t_MNEMONICS index\r
b_1bc9_start:\r
	db 044h,i_NEG		;neg\r
	db 045h,i_RETN		;retn\r
	db 04dh,i_RETI		;reti\r
	db 067h,i_RRD		;rrd\r
	db 06fh,i_RLD		;rld\r
;	db 0a0h,i_LDI		;ldi\r
;	db 0a1h,i_CPI		;cpi\r
;	db 0a2h,i_INI		;ini\r
;	db 0a3h,i_OUTI		;outi\r
;	db 0a8h,i_LDD		;ldd\r
;	db 0a9h,i_CPD		;cpd\r
;	db 0aah,i_IND		;ind\r
;	db 0abh,i_OUTD		;outd\r
;	db 0b0h,i_LDIR		;ldir\r
;	db 0b1h,i_CPIR		;cpir\r
;	db 0b2h,i_INIR		;inir\r
;	db 0b3h,i_OTIR		;otir\r
;	db 0b8h,i_LDDR		;lddr\r
;	db 0b9h,i_CPDR		;cpdr\r
;	db 0bah,i_INDR		;indr\r
;	db 0bbh,i_OTDR		;otdr\r
	db 08bh,i_OTDM		;otdm\r
	db 09bh,i_OTDMR		;otdmr\r
	db 083h,i_OTIM		;otim\r
	db 093h,i_OTIMR		;otimr\r
	db 076h,i_SLP		;slp\r
	db 0ffh			;<end mark>\r
\r
b_1bf4_start:\r
	db 0e4h,0a0h,i_LDI\r
	db a_noarg\r
	db 0ffh,070h,i_IN	;in (c)    ;\r
	db a_c\r
	db 0c7h,040h,i_IN	;in r,(c)  ;r=b,c,d,e,h,l,a\r
	db a_rc\r
	db 0ffh,071h,0ffh	;out (c),0 ;\r
	db a_cr\r
	db 0c7h,041h,i_OUT	;out (c),r ;r=b,c,d,e,h,l,a\r
	db a_cr\r
	db 0cfh,042h,i_SBC	;sbc hl,rp\r
	db a_hlp\r
	db 0cfh,04ah,i_ADC	;adc hl,rp\r
	db a_hlp\r
	db 0ffh,046h,i_IM	;im 0\r
	db a_im0\r
	db 0ffh,056h,i_IM	;im 1\r
	db a_im1\r
	db 0ffh,05eh,i_IM	;im 2\r
	db a_im2\r
	db 0e7h,047h,i_LD	;ld i,a ... ld a,r\r
	db a_ai\r
	db 0cfh,04ch,i_MLT	;mlt rr\r
	db a_p\r
	db 0c7h,004h,i_TST	;tst r\r
	db a_ry\r
	db 0\r
\r
l228bh:\r
	db 0ffh,030h,i_IN0	;in0 (m)\r
	db a_m\r
	db 0c7h,000h,i_IN0	;in0 r,(m) ;r=b,c,d,e,h,l,a\r
	db a_rm\r
	db 0ffh,031h,0ffh	;out0 (m),0\r
	db a_mr\r
	db 0c7h,001h,i_OUT0	;out0 (m),r ;r=b,c,d,e\r
	db a_mr\r
	db 0ffh,064h,i_TST	;tst m\r
	db a_n\r
	db 0ffh,074h,i_TSTIO	;tstio m\r
	db a_n\r
	db 0\r
\r
; Prefix ED + 1 byte opcode + 2 byte address\r
; Format: db mask, match, t_MNEMONICS-index\r
;	  dw argument formating function\r
b_1c40_start:\r
	db 0cfh,043h,i_LD	;ld (mn),ww	;ww=bc,de,hl,sp\r
	db a_mmp\r
	db 0cfh,04bh,i_LD	;ld ww,(mn)	;ww=bc,de,hl,sp\r
	db a_pmm\r
	db 0\r
\r
; CB\r
b_1c55_start:\r
	db 0c0h,000h,i_RLC+080h	;rlc g\r
	db a_cbr\r
\r
;	db 0f8h,000h,i_RLC	;rlc g\r
;	db a_cbr\r
;	db 0f8h,008h,i_RRC	;rrc g\r
;	db a_cbr\r
;	db 0f8h,010h,i_RL	;rl g\r
;	db a_cbr\r
;	db 0f8h,018h,i_RR	;rr g\r
;	db a_cbr\r
;	db 0f8h,020h,i_SLA	;sla g\r
;	db a_cbr\r
;	db 0f8h,028h,i_SRA	;sra g\r
;	db a_cbr\r
;	db 0f8h,038h,i_SRL	;srl g\r
;	db a_cbr\r
	db 0c0h,040h,i_BIT	;bit b,g\r
	db a_bcbr\r
	db 0c0h,080h,i_RES	;res b,g\r
	db a_bcbr\r
	db 0c0h,0c0h,i_SET	;set b,g\r
	db a_bcbr\r
	db 0\r
\r
;-------------------------------------------------------------------------------\r
;-------------------------------------------------------------------------------\r
\r
\r
pr_instr_args:\r
	ld	hl,t_argf\r
	ld	d,0\r
	add	hl,de\r
pria_l:\r
	ld	a,(hl)		;get next token\r
	inc	hl\r
	or	a\r
	ret	z		;\r
	jp	m,pria_1\r
	call	outchar		;print as normal character\r
	jr	pria_l\r
\r
pria_1:				;\r
	push	hl\r
	ld	hl,do_arg_n\r
	and	07fh\r
	call	add_hl_a2\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a\r
	ld 	a,(iy+000h)\r
	call	CALL_HL\r
	pop	hl\r
	jr	pria_l\r
\r
;\r
;	http://www.z80.info/decoding.htm\r
;\r
;	| 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |\r
;	|   x   |     y     |     z     |\r
;	        |   p   | q |\r
;\r
\r
t_argf:\r
;  1 byte opcodes\r
a_rr	equ	$-t_argf\r
	db	fi_ry,','		;ld r[y],r[z]\r
a_r	equ	$-t_argf\r
	db	fi_rz,0			;op r[z]\r
;a_ar	equ	$-t_argf\r
;	db	'A,',fi_rz,0		;op A,r[z]\r
a_cc	equ	$-t_argf\r
	db	fi_ccy,0		;op cc[y]\r
a_rst	equ	$-t_argf\r
	db	fi_rst,0		;rst y*8\r
a_p2	equ	$-t_argf\r
	db	fi_rp2,0		;rp2[p]\r
a_esphl	equ	$-t_argf\r
	db	'(SP),',fi_hlixiy,0	;ex (sp),hl\r
a_hl	equ	$-t_argf\r
	db	'(',fi_hlixiy,')',0	;jp (hl)\r
a_dehl	equ	$-t_argf\r
	db	'DE,HL',0\r
a_lsphl	equ	$-t_argf\r
	db	'SP,',fi_hlixiy,0	;ld SP,HL\r
a_eaf	equ	$-t_argf\r
	db	'AF,AF''',0		;ex af,af'\r
a_hlp	equ	$-t_argf\r
	db	fi_hlixiy,','		;add hl,rp\r
a_p	equ	$-t_argf\r
	db	fi_rp,0			;rp[p]\r
a_pa	equ	$-t_argf\r
	db	'(',fi_rp,'),A',0	;ld (rp),a ;rp=bc,de\r
a_ap	equ	$-t_argf\r
	db	'A,(',fi_rp,')',0	;ld a,(rp) ;rp=bc,de\r
\r
;  2 byte opcodes\r
a_rn	equ	$-t_argf\r
	db	fi_ry,',',fi_n,0	;ld r[y],n\r
;a_an	equ	$-t_argf\r
;	db	'A,'			;op a,n\r
a_n	equ	$-t_argf\r
	db	fi_n,0			;op n\r
a_ccj	equ	$-t_argf\r
	db	fi_ccy2,','		;jr cc,j	;cc = nz,z,nc,c\r
a_j	equ	$-t_argf\r
	db	fi_j,0			;jr j\r
a_ma	equ	$-t_argf\r
	db	'(',fi_n,'),A',0	;out (n),a\r
a_am	equ	$-t_argf\r
	db	'A,(',fi_n,')',0	;in a,(n)\r
\r
;  3 byte opcodes\r
a_ccnn	equ	$-t_argf\r
	db	fi_ccy,',',fi_nn,0	;op cc[y],nn\r
a_rnn	equ	$-t_argf\r
	db	fi_rp,','		;ld rp[p],nn\r
a_nn	equ	$-t_argf\r
	db	fi_nn,0			;jp nn\r
a_mmhl	equ	$-t_argf\r
	db	'(',fi_nn,'),',fi_hlixiy,0 ;ld (nn),hl\r
a_hlmm	equ	$-t_argf\r
	db	fi_hlixiy,',(',fi_nn,')',0 ;ld hl,(nn)\r
a_mma	equ	$-t_argf\r
	db	'(',fi_nn,'),A',0	;ld (nn),a\r
a_amm	equ	$-t_argf\r
	db	'A,(',fi_nn,')',0	;ld a,(nn)\r
\r
;  Prefix ED + 1 byte opcode\r
a_rc	equ	$-t_argf\r
	db	fi_ry,','		;in r[y],(c)\r
a_c	equ	$-t_argf\r
	db	'(C)',0			;in (c)\r
a_cr	equ	$-t_argf\r
	db	'(C),'			;out (c),r[y]\r
a_ry	equ	$-t_argf\r
	db	fi_ry,0			;inc r[y]\r
a_im0	equ	$-t_argf\r
	db	'0',0			;im 0\r
a_im1	equ	$-t_argf\r
	db	'1',0			;im 1\r
a_im2	equ	$-t_argf\r
	db	'2',0			;im 2\r
a_ai	equ	$-t_argf\r
	db	fi_ir,0			;ld a,i ... r,a\r
\r
;  Prefix ED + 2 byte (opcode + immediate)\r
a_rm	equ	$-t_argf\r
	db	fi_ry,','		;in0 r[y],(n)\r
a_m	equ	$-t_argf\r
	db	'(',fi_n,')',0		;in0 (n)\r
a_mr	equ	$-t_argf\r
	db	'(',fi_n,'),',fi_ry,0	;out0 (n),r[y]\r
\r
;  Prefix ED + 3 byte (opcode + address)\r
a_mmp	equ	$-t_argf\r
	db	'(',fi_nn,'),',fi_rp,0	;ld (nn),rp\r
a_pmm	equ	$-t_argf\r
	db	fi_rp,',(',fi_nn,')',0	;ld rp,(nn)\r
\r
;  Prefix CB + 1 byte opcode\r
a_bcbr	equ	$-t_argf\r
	db	fi_y,','		;op y,r[z]\r
a_cbr	equ	$-t_argf\r
	db	fi_rz_cb,0		;op r[z]\r
a_noarg	equ	$-t_argf\r
	db	0\r
\r
\r
;-------------------------------------------------------------------------------\r
\r
argpf_index	defl	0\r
\r
argpf	macro	x\r
fi_&x	equ	80h+argpf_index\r
	dw	p_&x\r
argpf_index	defl	argpf_index+1\r
	endm\r
\r
do_arg_n:\r
	argpf	ry\r
	argpf	rz\r
	argpf	ccy\r
	argpf	ccy2\r
	argpf	rst\r
	argpf	rp\r
	argpf	rp2\r
	argpf	hlixiy\r
	argpf	n\r
	argpf	j\r
	argpf	nn\r
	argpf	ir\r
	argpf	rz_cb\r
	argpf	y\r
\r
\r
p_n:\r
	ld a,(isprefix_ixiy)\r
	and a\r
	ld a,(iy+001h)\r
	jr z,out_hex_0\r
	ld a,(iy+002h)\r
	jr out_hex_0\r
\r
p_rst:\r
	and 038h\r
out_hex_0:\r
	jp out_hex\r
\r
\r
p_j:\r
	ld c,(iy+001h)\r
	ld a,c\r
	rla\r
	sbc a,a\r
	ld b,a\r
	push iy\r
	pop hl\r
	add hl,bc\r
	inc hl\r
	inc hl\r
	jr out_hl_0\r
\r
p_nn:\r
	ld l,(iy+001h)\r
	ld h,(iy+002h)\r
out_hl_0:\r
	jp out_hl\r
\r
p_ir:\r
	rra\r
	rra\r
	rra\r
	and 03\r
	ld hl,t_arg_IR\r
	jr p_arg\r
\r
\r
get_cb_opc:\r
	ld a,(isprefix_ixiy)\r
	and a\r
	ld a,(iy+001h)\r
	ret z\r
	ld a,(iy+002h)\r
	ret\r
\r
p_y:\r
	call get_cb_opc\r
	rra\r
	rra\r
	rra\r
	and 007h\r
	jp out_dgt\r
\r
p_rz_cb:\r
	call get_cb_opc\r
	jr p_rz\r
\r
p_ry:\r
	rra\r
	rra\r
	rra\r
p_rz:\r
	and 007h\r
	cp 006h\r
	ld b,a\r
	ld hl,t_arg_r\r
	jr nz,p_arg0\r
	ld a,(isprefix_ixiy)\r
	and a\r
	jr z,p_arg0\r
	ld hl,t_lp_IXIY\r
	dec a\r
	call p_arg\r
	ld a,(iy+001h)\r
	push af\r
	rlca\r
	ld a,'+'\r
	jr nc,l1e61h\r
	pop af\r
	neg\r
	push af\r
	ld a,'-'\r
l1e61h:\r
	call outchar\r
	pop af\r
	call out_hex\r
	ld a,')'\r
	jp outchar\r
\r
p_rp2:\r
	ld hl,t_arg_rp2\r
	db 0ddh			;swallow t_arg_rp in ix\r
p_rp:\r
	ld hl,t_arg_rp\r
	rra\r
	rra\r
	rra\r
	rra\r
	and 003h\r
	cp 002h\r
	jr nz,p_arg\r
p_hlixiy:\r
	ld a,(isprefix_ixiy)\r
	ld hl,t_HL.IX.IY\r
	jr p_arg\r
\r
p_ccy2:\r
	and 018h\r
p_ccy:\r
	rra\r
	rra\r
	rra\r
	and 007h\r
	ld hl,t_arg_cc\r
p_arg:\r
	ld b,a\r
p_arg0:\r
	;fall thru\r
\r
pstr_sel:\r
	call str_sel\r
	;fall thru\r
pstr:\r
	ld a,(hl)\r
	inc hl\r
	and a\r
	ret z\r
	call outchar\r
	ret m\r
	jr pstr\r
\r
pstr_inl:\r
	ex	(sp),hl\r
	call	pstr\r
	ex	(sp),hl\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
opc	macro	x\r
\r
i_&x	equ	opc_index\r
;o_&x	equ	$-opc_tabstart\r
	dc	'&x'\r
opc_index	defl	opc_index+1\r
	endm\r
\r
t_MNEMONICS:\r
;opc_tabstart	defl	$\r
opc_index	defl	0\r
; 1-byte other\r
	opc NOP\r
	opc LD\r
	opc INC\r
	opc DEC\r
	opc DJNZ\r
	opc JR\r
	opc HALT\r
\r
	opc RLCA\r
	opc RRCA\r
	opc RLA\r
	opc RRA\r
	opc DAA\r
	opc CPL\r
	opc SCF\r
	opc CCF\r
\r
; 1-byte "alu"\r
	opc ADD\r
	opc ADC\r
	opc SUB\r
	opc SBC\r
	opc AND\r
	opc XOR\r
	opc OR\r
	opc CP\r
\r
	opc RET\r
	opc POP\r
	opc JP\r
	opc CALL\r
	opc PUSH\r
	opc RST\r
	opc OUT\r
	opc EXX\r
	opc IN\r
	opc EX\r
	opc DI\r
	opc EI\r
; CB\r
	opc RLC\r
	opc RRC\r
	opc RL\r
	opc RR\r
	opc SLA\r
	opc SRA\r
	opc SLL\r
	opc SRL\r
	opc BIT\r
	opc RES\r
	opc SET\r
\r
; ED\r
	opc NEG\r
	opc RETN\r
	opc RETI\r
	opc IM\r
	opc RRD\r
	opc RLD\r
\r
; Block instructions\r
	opc LDI\r
	opc CPI\r
	opc INI\r
	opc OUTI\r
	opc LDD\r
	opc CPD\r
	opc IND\r
	opc OUTD\r
	opc LDIR\r
	opc CPIR\r
	opc INIR\r
	opc OTIR\r
	opc LDDR\r
	opc CPDR\r
	opc INDR\r
	opc OTDR\r
\r
; Z180\r
	opc IN0\r
	opc OUT0\r
	opc TST\r
	opc MLT\r
	opc TSTIO\r
	opc SLP\r
	opc OTIM\r
	opc OTDM\r
	opc OTIMR\r
	opc OTDMR\r
\r
	DB	0\r
\r
t_arg_r:\r
	DC	'B'\r
	DC	'C'\r
	DC	'D'\r
	DC	'E'\r
	DC	'H'\r
	DC	'L'\r
	DC	'(HL)'\r
	DC	'A'\r
	DB	0\r
t_arg_rp:\r
	DC	'BC'\r
	DC	'DE'\r
	DC	'HL'\r
	DC	'SP'\r
	DB	0\r
t_arg_rp2:\r
	DC	'BC'\r
	DC	'DE'\r
	DC	'HL'\r
	DC	'AF'\r
	DB	0\r
t_HL.IX.IY:\r
	DC	'HL'\r
	DC	'IX'\r
	DC	'IY'\r
	DB	0\r
t_arg_cc:\r
	DC	'NZ'\r
	DC	'Z'\r
	DC	'NC'\r
	DC	'C'\r
	DC	'PO'\r
	DC	'PE'\r
	DC	'P'\r
	DC	'M'\r
	DB	0\r
\r
t_lp_IXIY:\r
	DC	'(IX'\r
	DC	'(IY'\r
\r
t_arg_IR:\r
	DC	'I,A'\r
	DC	'R,A'\r
	DC	'A,I'\r
	DC	'A,R'\r
	db	0\r
\r
\r
;-------------------------------------------------------------------------------\r
\r
tc_set_bp:\r
	ld hl,(reg.pc)\r
	ld a,h\r
	or l\r
	jr z,l2037h\r
	ld de,BDOS\r
	and a\r
	sbc hl,de\r
	ld hl,l20edh		;set break after BDOS call\r
	jr z,l2031h\r
	ld iy,(reg.pc)\r
	call disas_get_instrlen\r
	jp nc,ERROR\r
	ld c,b\r
	ld b,0\r
	ld hl,(reg.pc)\r
	add hl,bc\r
	call bp_trace_enter\r
	ld iy,(reg.pc)\r
	ld hl,t_op_branch\r
	call lookup_branch_op\r
	ccf\r
	ret c\r
	ex de,hl\r
l2031h:\r
	call CALL_HL\r
	call c,bp_trace_enter\r
l2037h:\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
t_op_branch:\r
	db 0ffh,0ddh		;Prefix DD\r
	dw l20a7h\r
	db 0ffh,0fdh		;Prefix FD\r
	dw l20ach\r
	db 0ffh,0edh		;Prefix ED\r
	dw l20b8h\r
\r
	db 0ffh,0cdh		;call mn\r
	dw l2080h\r
	db 0ffh,0c3h		;jp mn\r
	dw l208bh\r
	db 0ffh,0e9h		;jp ()\r
	dw l20a2h\r
	db 0ffh,0c9h		;ret\r
	dw l20dch\r
	db 0ffh,0cfh		;rst 8\r
	dw l2115h\r
	db 0c7h,0c7h		;rst n\r
	dw l20f9h\r
	db 0c7h,0c4h		;call cc,mn\r
	dw l2080h\r
	db 0f7h,010h		;djnz d; jr d\r
	dw l2093h\r
	db 0e7h,020h		;jr cc,d\r
	dw l2093h\r
	db 0c7h,0c2h		;jp cc,mn\r
	dw l208bh\r
	db 0c7h,0c0h		;ret cc\r
	dw l20c5h\r
	db 0\r
\r
;-------------------------------------------------------------------------------\r
; call mn	call cc,mn\r
l2080h:\r
\r
; jp mn		jp cc,mn\r
l208bh:\r
	ld l,(iy+001h)\r
	ld h,(iy+002h)\r
	scf\r
	ret\r
\r
l2093h:\r
	ld c,(iy+001h)\r
	ld a,c\r
	rla\r
	sbc a,a\r
	ld b,a\r
	ld hl,(reg.pc)\r
	add hl,bc\r
	inc hl\r
	inc hl\r
	scf\r
	ret\r
\r
; jp (hl)\r
l20a2h:\r
	ld hl,(reg.l)\r
	scf\r
	ret\r
\r
; Prefix DD\r
l20a7h:\r
	ld hl,(reg.ix)\r
	jr l20afh\r
; Prefix FD\r
l20ach:\r
	ld hl,(reg.iy)\r
l20afh:\r
	ld a,(iy+001h)\r
	cp 0e9h			; jp (ix); jp (iy)\r
	scf\r
	ret z\r
	and a\r
	ret\r
\r
; Prefix ED\r
l20b8h:\r
	ld a,(iy+001h)\r
	cp 04dh			; reti\r
	jr z,l20dch\r
	cp 045h			; retn\r
	jr z,l20dch\r
	and a\r
	ret\r
l20c5h:\r
	ld a,(iy+000h)\r
	ld (l20d7h),a\r
	ld hl,(reg.f)\r
	push hl\r
	pop af\r
	call l20d7h\r
	scf\r
	jr c,l20dch\r
	ret\r
l20d7h:\r
	nop\r
	and a\r
	pop hl\r
	inc hl\r
	jp (hl)\r
\r
l20dch:\r
l20edh:\r
	ld hl,(reg_sp)		;break on return address\r
	ld e,(hl)\r
	inc hl\r
	ld d,(hl)\r
	ex de,hl\r
	call bp_trace_enter\r
l2115h:\r
	and a\r
	ret\r
\r
l20f9h:\r
	ld a,(l0003h)\r
	cp (iy+000h)\r
	ret z\r
	ld a,(iy+000h)\r
	and 038h\r
	ld l,a\r
	ld h,000h\r
	ld a,(b_21e2_start)\r
	and a\r
	ret z\r
	scf\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
; >>C[N][J] [steps]\r
; >>C[N][J] W expression\r
; >>C[N][J] U expression\r
;     trace over Calls [No list] [Jumps only] /.While./.Until.\r
\r
\r
;-------------------------------------------------------------------------------\r
; >>T[N][J] [steps]\r
; >>T[N][J] W expression\r
; >>T[N][J] U expression\r
;      Trace [no List] [Jumps only] / .While. / .Until.\r
\r
cmd_T:\r
	ld (cmd_rpt),hl\r
	ld hl,1				;default: 1 step\r
	call get_lastarg_def\r
	ld (trace_cnt_or_ptr),hl\r
	sub a\r
	ld (bp_p_cpu_flag),a\r
	call tc_set_bp\r
	jr user_go1\r
\r
l2151h:\r
	call bp_clr_temporary\r
	ld hl,(trace_cnt_or_ptr)\r
	dec hl\r
	ld (trace_cnt_or_ptr),hl\r
	ld a,h\r
	or l\r
	jp z,do_break\r
\r
	call tc_set_bp\r
	jp nc,do_break\r
	sbc a,a\r
	ld (bp_p_cpu_flag),a\r
user_go1:\r
	jp user_go\r
\r
;-------------------------------------------------------------------------------\r
\r
con_col:\r
	db	0\r
\r
;-------------------------------------------------------------------------------\r
\r
b_21e2_start:\r
	db	0\r
trace_cnt_or_ptr:\r
	dw	0\r
\r
bp_p_cpu_flag:\r
	db	0\r
\r
bp_tab:\r
	rept BP_CNT\r
	 rept BP_SIZE\r
	  db	0\r
	 endm\r
	endm\r
\r
;-------------------------------------------------------------------------------\r
\r
last_S:\r
	dw	TPA\r
\r
last_I:\r
	dw	0\r
\r
last_O_addr:\r
	dw	0\r
last_O_val:\r
	db	0\r
\r
last_D:\r
	dw	TPA\r
\r
high_load:\r
	dw	TPA\r
max_load:\r
	dw	TPA\r
\r
isprefix_ixiy:\r
	db	0\r
last_L:\r
	dw	TPA\r
\r
pbl_loop_adr:\r
	dw	0addeh\r
\r
bitmap_end:\r
	dw	0\r
\r
;-------------------------------------------------------------------------------\r
\r
conbuf:\r
	ds	CONBUF_SIZE+1\r
\r
;-------------------------------------------------------------------------------\r
\r
	rept	(STACK_SIZE+3)/4\r
	db	0deh,0adh,0beh,0efh\r
	endm\r
stack:\r
reg.l2:	db	000h\r
reg.h2:	db	000h\r
reg.e2:	db	000h\r
reg.d2:	db	000h\r
reg.c2:	db	000h\r
reg.b2:	db	000h\r
reg.f2:	db	000h\r
reg.a2:	db	000h\r
	db	000h\r
reg.i:	db	000h\r
reg.iy:	dw	0000h\r
reg.ix:	dw	0000h\r
reg.f:	db	000h\r
reg.a:	db	000h\r
reg.c:	db	000h\r
reg.b:	db	000h\r
reg.e:	db	000h\r
reg.d:	db	000h\r
reg.l:	db	000h\r
reg.h:	db	000h\r
reg_sp:	dw	TPA\r
reg.iff:\r
	db	0f3h\r
	db	0c3h\r
reg.pc:	dw	TPA\r
\r
cmd_rpt:dw	mainloop\r
	db	0ffh,0ffh,0ffh\r
;-------------------------------------------------------------------------------\r
\r
ddtz_size	equ	$-ddtz_base\r
prog_size	equ	$-start\r
ddtz_end:\r
\r
;-------------------------------------------------------------------------------\r
\r
	end\r