Improved Makefile

[kermit-80.git] / cpxac.asm

IF NOT lasm\r
.printx * CPXAC.ASM *\r
ENDIF	;NOT lasm\r
;	KERMIT - (Celtic for "FREE")\r
;\r
;	This is the CP/M-80 implementation of the Columbia University\r
;	KERMIT file transfer protocol.\r
;\r
;	Version 4.0\r
;\r
;	Copyright June 1981,1982,1983,1984,1985\r
;	Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;\r
;\r
\r
;\r
; Keep module name, edit number, and last revision date in memory.\r
;\r
family:	db	'CPXCP.ASM  (1)	3-DEC-2015$'	; First entry for V4.11\r
\r
;\r
; Assembly time message to let me know I'm building the right version.\r
;\r
\r
.printx * Assembling Kermit-80 for AVR-CP/M *\r
\r
\r
\r
SC16IS740_ADDR	equ	90H	;SC16IS740 I2C address. (8bit, A0=VDD, A1=VDD)\r
OUTSIZE		equ	64\r
\r
; Virtual I2C Interface\r
\r
VI2C_STAT	equ	05h\r
VI2C_CTRL	equ	05h\r
VI2C_BLEN	equ	06h\r
VI2C_ADR	equ	07h\r
VI2C_BSIZ	equ	66		;largest message size including address byte (SLA)\r
\r
;----------------------------- ISC16IS740 UART -------------------------------\r
I2C_UART_PORT	equ	50H\r
\r
I2C_UART_RHR	equ	I2C_UART_PORT+00H	;R	Receive Holding\r
I2C_UART_THR	equ	I2C_UART_PORT+00H	;W	Transmit Holding\r
I2C_UART_IER	equ	I2C_UART_PORT+01H	;R/W	Interrupt Enable\r
I2C_UART_FCR	equ	I2C_UART_PORT+02H	;W	FIFO Control\r
 TX_FIFO_RES	equ	04H			; TX FIFO reset\r
 RX_FIFO_RES	equ	02H			; RX FIFO reset\r
 FIFO_ENABLE	equ	01H			; FIFO enable\r
\r
I2C_UART_IIR	equ	I2C_UART_PORT+02H	;R	Interrupt Identification\r
I2C_UART_LCR	equ	I2C_UART_PORT+03H	;R/W	Line Control\r
	DLAB	equ	80H			; Devisor latch enable\r
	WLS0	equ	01H			; Word Length Select Bit 0\r
	WLS1	equ	02H			; Word Length Select Bit 1 for 8 bit word\r
	STB	equ	04H			; Stop bit count - 2 stop bits\r
\r
I2C_UART_MCR	equ	I2C_UART_PORT+04H	;R/W	Modem Control\r
	RTS	equ	02H			;RTS pin, 1 = active (low)\r
	DTR	equ	01H			;DTR pin (not on '740)\r
I2C_UART_LSR	equ	I2C_UART_PORT+05H	;R	Line Status\r
	TXE	equ	40H			; THR and TSR empty\r
	TXRDY	equ	20H			; THR empty\r
	RX_FE	equ	08H			; Framig error\r
	RX_PE	equ	04H			; Parity error\r
	RX_OE	equ	02H			; Overrun error\r
	RXRDY	equ	01H			; Receved byte available\r
I2C_UART_MSR	equ	I2C_UART_PORT+06H	;R	Modem Status\r
I2C_UART_SPR	equ	I2C_UART_PORT+07H	;R/W	Scratchpad\r
I2C_UART_TCR	equ	I2C_UART_PORT+06H	;R/W	Transmission Control\r
I2C_UART_TLR	equ	I2C_UART_PORT+07H	;R/W	Trigger Level\r
I2C_UART_TXLVL	equ	I2C_UART_PORT+08H	;R	Transmit FIFO Level\r
I2C_UART_RXLVL	equ	I2C_UART_PORT+09H	;R	Receive FIFO Level\r
I2C_UART_EFCR	equ	I2C_UART_PORT+0FH	;R/W	Extra Features\r
I2C_UART_DLL	equ	I2C_UART_PORT+00H	;R/W	divisor latch LSB\r
I2C_UART_DLH	equ	I2C_UART_PORT+01H	;R/W	divisor latch MSB\r
I2C_UART_EFR	equ	I2C_UART_PORT+02H	;R/W	Enhanced Feature\r
I2C_UART_XON1	equ	I2C_UART_PORT+04H	;R/W	Xon1 word\r
I2C_UART_XON2	equ	I2C_UART_PORT+05H	;R/W	Xon2 word\r
I2C_UART_XOFF1	equ	I2C_UART_PORT+06H	;R/W	Xoff1 word\r
I2C_UART_XOFF2	equ	I2C_UART_PORT+07H	;R/W	Xoff2 word\r
\r
\r
\r
z80	set	TRUE	;This one emulates an Z80.\r
\r
\r
	.z80\r
\r
sysxin:		; continuation of system initialisation from sysinit\r
\r
	call	speedtest\r
	call	prspeedmsg\r
\r
	ld	hl,6			;set default baud rate\r
	ld	(speed),hl\r
	ex	de,hl\r
	call	sysspd\r
\r
	ld	a,RTS+DTR\r
	out	(I2C_UART_MCR),a\r
	ret\r
\r
;	ld	a,07H			;Enable and clear fifos\r
;	out	(I2C_UART_FCR),a	;\r
;	ld	a,03H			;8N1\r
;	out	(I2C_UART_LCR),a	;\r
\r
prspeedmsg:\r
	push	af\r
	ld	de,freqmsg\r
	call	prtstr\r
	pop	af\r
	cp	13+1\r
	jr	c,$+3\r
	 xor	a\r
	ld	e,a\r
	ld	d,0\r
	ld	hl,fm_tab\r
	add	hl,de\r
	add	hl,de\r
	ld	e,(hl)\r
	inc	hl\r
	ld	d,(hl)\r
	call	prtstr\r
	ld	de,fdimmsg\r
	call	prtstr\r
	ret\r
\r
mkftab	macro	x\r
	irp	y,<x>\r
fm&y:\r
	db	'&y','$'\r
	endm\r
fm_tab:\r
	irp	y,<x>\r
	dw	fm&y\r
	endm\r
	endm\r
\r
\r
freqmsg:\r
	db	'UART crystal frequency: ','$'\r
	mkftab	<?,1.8432,3.6864,5.5296,7.3728,9.216,11.0592,12.9024,14.7456,16.5888,18.432,20.2752,22.1184,23.9616>\r
fdimmsg:\r
	db	' MHz.',cr,lf,'$'\r
\r
\r
;\r
;	system-dependent KERMIT termination processing\r
;	If we've changed anything, this is our last chance to put it back.\r
;\r
sysexit:\r
	ret\r
\r
;\r
;	system-dependent processing for start of CONNECT command\r
;\r
syscon:\r
	ret\r
\r
conmsg:		; Messages printed when entering transparent (CONNECT) mode:\r
\r
	db	'$'\r
\r
;\r
;	syscls - system-dependent close routine\r
;	called when exiting transparent session.\r
;\r
syscls:\r
	ret\r
\r
	.8080\r
\r
;\r
;	sysinh - help for system-dependent special functions.\r
;	called in response to <escape>?, after listing all the\r
;	system-independent escape sequences.\r
;\r
sysinh:\r
	lxi	d, inhlps\r
	call	prtstr\r
	ret\r
\r
; Additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
inhlps:\r
	db	cr,lf,'B  Transmit a BREAK (0.3s)'\r
	db	cr,lf,'L  Transmit a LONG BREAK (1.8s)'\r
	db	'$'			; string terminator\r
\r
	.z80\r
;\r
;	sysint - system dependent special functions\r
;	called when transparent escape character has been typed;\r
;	the second character of the sequence is in A (and in B).\r
;	returns:\r
;	non-skip: sequence has been processed\r
;	skip:	seqence was not recognized\r
;\r
sysint:\r
	and	5FH		; convert lower case to upper, for testing...\r
	cp	'B'		; send break ?\r
	jr	z,sendbr	; then jump to send break routine\r
	cp	'L'		; long break ?\r
	jr	z,longbr	; then jump to long break routine\r
	jp	rskp		; take skip return - command not recognised\r
\r
;\r
; Break routines\r
;\r
longbr:\r
	ld	e,180		; time for long break is 1800 ms\r
	jr	setbit\r
\r
sendbr:\r
	ld	e,25		; time for break is 300 ms\r
\r
setbit:\r
	in	a,(I2C_UART_LCR)\r
	set	6,a		; Break contol bit\r
	out	(I2C_UART_LCR),a\r
;\r
;	Now, delay for duration of hangup or break\r
	ld	a,e		; delay count\r
	call	delay\r
;\r
;	Time's up. Put transmitter back in normal state and return.\r
\r
	in	a,(I2C_UART_LCR)\r
	res	6,a		; Break contol bit\r
	out	(I2C_UART_LCR),a\r
	ret			; done.\r
\r
	.8080\r
;\r
;	sysflt - system-dependent filter\r
;	called with character in E.\r
;	if this character should not be printed, return with A = zero.\r
;	preserves bc, de, hl.\r
;	note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
;\r
sysflt:\r
	mov	a,e		; get character for testing\r
	ret\r
\r
;\r
;	mdmflt - modem filter\r
;	called with character to be sent to printer in E\r
;	with parity set as appropriate.\r
;	return with accumulator = 0 do do nothing,\r
;				<> 0 to send char in E.\r
mdmflt:\r
	mov	a,e		; get character to test\r
	ret\r
\r
;\r
;	prtflt - printer filter\r
;	called with character to be sent to printer in E\r
;	returns with a = 0 to do nothing\r
;		     a <> 0 to print it.\r
;\r
;	this routine for those printer that automatically insert\r
;	a lf on cr, or cr for lf.  Should this be shifted to\r
;	the system indep. stuff, in say 4.06?\r
;\r
prtflt:\r
	mov	a,e		; get character to test\r
\r
IF FALSE			; strip out lf from printer stream\r
	ani	7fh		; make sure it is parity less\r
	cpi	lf		; is it a line feed?\r
	rnz			; no, print it\r
;	xra	a		; yes, don't.\r
\r
ENDIF\r
\r
	ret\r
\r
;\r
; system-dependent processing for BYE command.\r
;\r
sysbye:\r
	ret\r
\r
;\r
;	This is the system-dependent command to change the baud rate.\r
;	DE contains the two-byte value from the baud rate table; both\r
;	bytes of this value are also stored in 'speed'.\r
;\r
	.z80\r
sysspd:\r
	ld	hl,0\r
	ld	a,(clk_div)\r
	ld	b,a\r
sysspd_1:\r
	add	hl,de\r
	djnz	sysspd_1\r
	ld	a,l\r
	ld	(sysspd_dll),a\r
	ld	a,h\r
	ld	(sysspd_dlh),a\r
\r
	ld	hl,sysspd_tab\r
	call	ioinil\r
\r
	in	a,(I2C_UART_MSR)	;Clear Modem Status Register\r
	in	a,(I2C_UART_LSR)	;Clear Line Status Register\r
	in	a,(I2C_UART_RHR)	;Clear Receiver Buffers\r
	in	a,(I2C_UART_RHR)\r
	ret\r
\r
sysspd_tab:\r
	db	(sysspd_tab_end - ($+1))/2\r
	db	I2C_UART_LCR, DLAB+03H	;Set devisor latch access bit\r
	db	I2C_UART_DLL\r
sysspd_dll:\r
	ds	1			;1200 bit/s at 1.832 MHz\r
	db	I2C_UART_DLH\r
sysspd_dlh:\r
	ds	1			;Out to the MSB divisor port\r
	db	I2C_UART_LCR, 03H	;Disable Divisor Access Latch\r
	db	I2C_UART_FCR, 07H	;Clear and enable fifos\r
	db	I2C_UART_MCR, 00H	;Enable loopback\r
	db	I2C_UART_IER, 0		;Set no interrupts\r
sysspd_tab_end:\r
\r
\r
\r
;\r
;	Speed tables\r
; (Note that speed tables MUST be in alphabetical order for later\r
; lookup procedures, and must begin with a value showing the total\r
; number of entries.  The speed help tables are just for us poor\r
; humans.\r
;\r
;	db	string length, string, divisor (2 bytes or 1 word, ab)\r
;		the data byte a is return in A and E, and b in D\r
;		only byte 'a' is the key for the table\r
\r
spdtbl: db	15			; Number of entries\r
	db	3,'110$'\r
	dw		1047\r
	db	6,'115200$'\r
	dw		   1\r
	db	4,'1200$'\r
	dw		  96\r
	db	3,'150$'\r
	dw		 768\r
	db	5,'19200$'\r
	dw		   6\r
	db	4,'2400$'\r
	dw		  48\r
	db	5,'28800$'\r
	dw		   5\r
	db	3,'300$'\r
	dw		 384\r
	db	5,'38400$'\r
	dw		   3\r
	db	3,'450$'\r
	dw		 288\r
	db	4,'4800$'\r
	dw		  24\r
	db	5,'57600$'\r
	dw		   2\r
	db	3,'600$'\r
	dw		 192\r
	db	2,'75$'\r
	dw		1536\r
	db	4,'9600$'\r
	dw		  12\r
IF 0\r
sphtbl: db	cr,lf,'  75    110    150    300    450    600   1200   2400'\r
	db	cr,lf,'4800   9600  19200  28800  38400  57600 115200$'\r
ENDIF\r
\r
sphtbl: db	cr,lf,'           110    300    600   2400   9600  28800  57600'\r
	db	cr,lf,'     75    150    450   1200   4800  19200  38400 115200$'\r
\r
\r
speedtest:\r
	ld	hl,spt_tab\r
	call	ioinil\r
\r
	in	a,(I2C_UART_MSR)	;Clear Modem Status Register\r
	in	a,(I2C_UART_LSR)	;Clear Line Status Register\r
	in	a,(I2C_UART_RHR)	;Clear Receiver Buffers\r
	in	a,(I2C_UART_RHR)\r
\r
	ld	a,2			;start write transaction\r
	out	(VI2C_CTRL),a\r
\r
	; get time stamp\r
	in	a,(41H)			;lsb ms\r
	ld	e,a\r
	in	a,(42H)			;msb ms\r
	ld	d,a\r
	in	a,(43H)			;lsb seconds\r
	ld	c,a\r
\r
spt_1:\r
	in	a,(I2C_UART_RXLVL)\r
	cp	60\r
	jr	nz,spt_1\r
\r
	; get 2nd time stamp\r
	in	a,(41H)			;lsb ms\r
	ld	l,a\r
	in	a,(42H)			;msb ms\r
	ld	h,a\r
	in	a,(43H)			;lsb seconds\r
	sub	c\r
	jr	z,spt_3\r
	ld	bc,1000\r
spt_2:\r
	add	hl,bc\r
	dec	a\r
	jr	nz,spt_2\r
spt_3:\r
	sbc	hl,de\r
	ld	d,h\r
	ld	e,l\r
	inc	hl\r
	srl	h\r
	rr	l\r
	ld	bc,500\r
	add	hl,bc\r
\r
	xor	a			;clear carry\r
spt_4:\r
	inc	a\r
	sbc	hl,de\r
	jr	nc,spt_4\r
	dec	a\r
	ld	(clk_div),a\r
	ret\r
\r
spt_tab:\r
	db	(spt_tab_end - ($+1))/2\r
	db	I2C_UART_LCR, DLAB+03H	;Set devisor latch access bit\r
	db	I2C_UART_DLL, low 96	;1200 bit/s at 1.832 MHz\r
	db	I2C_UART_DLH, high 96	;Out to the MSB divisor port\r
	db	I2C_UART_LCR, 03H	;Disable Divisor Access Latch\r
	db	I2C_UART_FCR, 07H	;Clear and enable fifos\r
	db	I2C_UART_MCR, 10H	;Enable loopback\r
	db	I2C_UART_IER, 0		;Set no interrupts\r
	db	VI2C_ADR+0, low outbuf\r
	db	VI2C_ADR+1, high outbuf\r
	db	VI2C_BLEN, 60+2\r
spt_tab_end:\r
\r
;----------------------------------------------------------------------\r
; output bytes to ports\r
;\r
;     hl: tables of port,value pairs:\r
;         db n  ;number of pairs\r
;	  db port1,val1, port2,val2,... portn,valn\r
;         ...\r
;         db 0 ; Terminate table\r
\r
ioinil:\r
	push	bc\r
	ld	b,(hl)		;count\r
	inc	hl\r
io1_lp:\r
	ld	c,(hl)		;port address\r
	inc	hl\r
	outi\r
	jr	nz,io1_lp\r
	pop	bc\r
	ret\r
\r
;\r
;	This is the system-dependent SET PORT command.\r
;	HL contains the argument from the command table.\r
;\r
sysprt:\r
	ret\r
\r
prttbl EQU	0		; SET PORT is not supported\r
prhtbl EQU	0\r
\r
;\r
;	selmdm - select modem port\r
;	selcon - select console port\r
;	selmdm is called before using inpmdm or outmdm;\r
;	selcon is called before using inpcon or outcon.\r
;	For iobyt systems, diddle the I/O byte to select console or comm port;\r
;	For the rest, does nothing.\r
;	preserves bc, de, hl.\r
;\r
selmdm:\r
	ret\r
\r
selcon:\r
IF 1\r
	jr	omflush\r
ELSE\r
	ret\r
ENDIF\r
\r
;\r
;	Get character from console, or return zero.\r
;	result is returned in A.  destroys bc, de, hl.\r
;\r
inpcon:\r
	ld	c,dconio	;Direct console I/O BDOS call.\r
	ld	e,0FFH		;Input.\r
	call	BDOS\r
\r
	ret\r
\r
;\r
;	Output character in E to the console.\r
;	destroys bc, de, hl\r
;\r
outcon:\r
	ld	c,dconio	;Console output bdos call.\r
	call	bdos		;Output the char to the console.\r
\r
	ret\r
\r
;\r
;	outmdm - output a char from E to the modem.\r
;		the parity bit has been set as necessary.\r
;	returns nonskip; bc, de, hl preserved.\r
;\r
outmdm:\r
IF 0\r
	in	a,(I2C_UART_LSR) ;Get the output done flag.\r
	and	TXRDY		;Is it set?\r
	jr	z,outmdm	;If not, loop until it is.\r
	ld	a,e\r
	out	(I2C_UART_THR),a ;Output it.\r
ENDIF\r
IF 1\r
\r
	push	hl\r
	ld	hl,(outptr)\r
	ld	(hl),e			;return buffered char\r
	inc	hl\r
	ld	(outptr),hl\r
	ld	a,(outcnt)\r
	inc	a\r
	ld	(outcnt),a\r
	cp	OUTSIZE\r
	jr	nc,omflush_1		;buffer full\r
	pop	hl\r
	ret\r
\r
omflush:\r
	ld	a,(outcnt)\r
	or	a\r
	ret	z\r
\r
	scf\r
	push	hl\r
omflush_1:\r
	push	bc\r
	ld	c,a			;outcnt\r
	ld	b,a\r
	jr	c,$+4\r
	 ld	b,1\r
	ld	hl,outbuf\r
	ld	a,h\r
	out	(VI2C_ADR+1),a\r
	ld	a,l\r
	out	(VI2C_ADR+0),a\r
omf_0:\r
	in	a,(I2C_UART_TXLVL)\r
	cp	b\r
	jr	c,omf_0\r
	cp	c\r
	jr	nc,omf_2\r
	ld	c,a\r
omf_2:\r
	ld	a,c\r
	add	a,2\r
	out	(VI2C_BLEN),a\r
	ld	a,2			;start write transaction\r
	out	(VI2C_CTRL),a\r
\r
	ld	hl,outbuf+2\r
	ld	(outptr),hl\r
	ld	a,(outcnt)\r
	sub	c\r
	ld	(outcnt),a\r
	jr	z,omfex\r
\r
	push	de\r
	ld	d,h\r
	ld	e,l\r
	ld	b,0\r
	add	hl,bc\r
	ld	c,a\r
	ldir\r
	pop	de\r
omfex:\r
	pop	bc\r
	pop	hl\r
	ret\r
ENDIF\r
;\r
;	get character from modem; return zero if none available.\r
;	for IOBYT systems, the modem port has already been selected.\r
;	destroys bc, de, hl.\r
;\r
inpmdm:\r
if 0\r
	in	a,(I2C_UART_LSR) ;Get the port status into A.\r
	and	RXRDY		;See if the input ready bit is on.\r
	ret	z		;If not then return.\r
\r
	in	a,(I2C_UART_MCR)	;debug\r
	xor	RTS\r
	out	(I2C_UART_MCR),a\r
\r
	in	a,(I2C_UART_RHR);If so, get the char.\r
	ret\r
endif\r
\r
if 1\r
	ld	a,(inpcnt)\r
	dec	a\r
	jp	m,imdrdi2c	;buffer empty\r
	ld	(inpcnt),a\r
	ld	hl,(inpptr)\r
	ld	a,(hl)		;return buffered char\r
	inc	hl\r
	ld	(inpptr),hl\r
	ret\r
\r
imdrdi2c:\r
	in	a,(I2C_UART_RXLVL)	;get rx fifo count\r
	or	a\r
	ret	z			;fifo is empty, return 0\r
\r
	; prepare fifo read\r
	inc	a			;+ slave address\r
	ld	(VI2C_BLEN),a\r
	ld	hl,inbuf\r
	ld	a,h\r
	out	(VI2C_ADR+1),a\r
	ld	a,l\r
	out	(VI2C_ADR+0),a\r
	inc	hl\r
	ld	(hl),0			;select subaddr 0 (RHR) for next read\r
	ld	a,3			;write 1 byte (subaddr.), then read fifo\r
	ld	(VI2C_CTRL),a\r
	in	a,(VI2C_CTRL)		;get i2c result\r
	xor	01h\r
	and	11h			;transfer completed?\r
	jr	nz,imrdex\r
	in	a,(VI2C_BLEN)		;get actual transfer count\r
\r
	sub	2			;- (slave address + char to return now)\r
	jr	c,imrdex\r
	ld	(inpcnt),a		;save new buffer count\r
	ld	a,(hl)\r
	inc	hl\r
	ld	(inpptr),hl\r
	ret\r
\r
imrdex:\r
	xor	a\r
	ret\r
endif\r
\r
	.8080\r
\r
;\r
;	flsmdm - flush comm line.\r
;	Modem is selected.\r
;	Currently, just gets characters until none are available.\r
;\r
flsmdm:\r
	call	inpmdm		; Try to get a character\r
	ora	a		; Got one?\r
	jnz	flsmdm		; If so, try for another\r
	ret			; Receiver is drained.	Return.\r
\r
\r
;\r
;	lptstat - get the printer status. Return a=0 if ok, or 0ffh if not.\r
lptstat:\r
IF iobyte	;[33]\r
	call	bprtst		; get status\r
ENDIF	;iobyte[33]\r
IF NOT iobyte	;[33]\r
	xra	a		; assume it is ok.. this may not be necessary\r
ENDIF	;iobyte [33]\r
	ret\r
;\r
;	outlpt - output character in E to printer\r
;	console is selected.\r
;	preserves de.\r
;\r
outlpt:\r
	push	d		; save DE in either case\r
	call	prtflt		; go through printer filter [30]\r
	ana	a		; if A = 0 do nothing,\r
	jz	outlp1		; if a=0 do nothing\r
\r
outlp1:	pop	d		; restore saved register pair\r
	ret\r
\r
; delchr - make delete look like a backspace.  Unless delete is a printing\r
;	character, we just need to print a backspace. (we'll output clrspc\r
;	afterwards)\r
delchr:\r
\r
	mvi	e,bs		;get a backspace\r
	jmp	outcon\r
\r
; erase the character at the current cursor position\r
clrspc:	mvi	e,' '\r
	call	outcon\r
	mvi	e,bs		;get a backspace\r
	jmp	outcon\r
\r
; erase the current line\r
clrlin:	lxi	d,eralin\r
	jmp	prtstr\r
\r
; erase the whole screen, and go home. preserves b (but not c)\r
clrtop:	lxi	d,erascr\r
	jmp	prtstr\r
\r
\r
sysver:	db	'AVR-CP/M'\r
	db	'$'\r
\r
\r
clk_div:\r
	db	1		;default div\r
\r
inpptr:	dw	0\r
inpcnt:	db	0\r
inbuf:\r
	db	SC16IS740_ADDR\r
	ds	VI2C_BSIZ-1\r
\r
\r
outptr:	dw	outbuf+2\r
outcnt:	db	0\r
outbuf:\r
	db	SC16IS740_ADDR\r
	db	0		;RHR subaddress\r
	ds	OUTSIZE\r
\r
\r
IF lasm\r
LINK CPXVDU.ASM		; get terminal defs etc\r
ENDIF	;lasm\r