Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpsmit.asm

; CPSMIT.ASM\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others. \r
;\r
;       This file contains the system-independent initialization, the main\r
;       loop, and the commands that don't have any place better to go.\r
;	All the SET xxx and status routines now in CPSCOM.ASM as CPSMIT.ASM\r
;	was getting too big.\r
;\r
; revision history:\r
;\r
;edit 30, 29-Mar-1991 by MF. When looking up a TAKE-file in a TAKE command\r
;	and the file is not found, complain if it's not the first TAKE of\r
;	the current program execution (the automatic TAKE of KERMIT.INI)\r
;edit 29, 25-Mar-1991 by MF. Add STAY command as a synonym for SET NO-EXIT\r
;	command per Martin J. Carter of Nottingham University in the U.K.\r
;edit 28, 21-Mar-1991 by MF. Modify code after "inp2a" in INPUT command\r
;	so a ^C will halt TAKE-file processing\r
;edit 27, 27-Feb-1991 by MF. Add QUIT as a synonym for EXIT per code of\r
;	Dr. Martin J. Carter of Nottingham University, U.K. Recognizing QUIT\r
;	helps those who forget they're not in MS-Kermit, C-Kermit,\r
;	Kermit-32 etc. Also add commands so that CONNECT, RECEIVE and SEND may\r
;	be abbreviated to C,  R and S, respectively.\r
;edit 26, 5-Nov-1990 by MF.  Cosmetic changes to main HELP messages for\r
;	COPY and RENAME commands.\r
;edit 25, 1-Nov-1990 by MF.  Made the following command-name changes in the\r
;	interest of uniformity of nomenclature (per suggestions of FDC):\r
;	FCOPY to COPY, FRENAME to RENAME and STRING to OUTPUT.\r
;	This means we'll have to type "CO" for CONNECT and "REC" for \r
;	RECEIVE but with REMOTE now with us we have to do the latter anyway.\r
;edit 24, 18-Sep-1990 by MF.  Implemented FRENAME command to rename a\r
;	CP/M file.\r
;edit 23, 9-Sep-1990 by MF.  Implemented commands to be sent to a\r
;	remote Kermit Server (Remote commands).\r
;	Implemented setting of packet sizes for RECEIVE and SEND.\r
;	Put DIRECTORY/STRING help texts in proper alphabetical position.\r
; edit 22, July 6th, 1987 by OBSchou.  Added a dummy Commandline to be\r
;	loaded for debugging purposes as DDT destroys any command line at 80H\r
;	Also fixed a bug or two...\r
;\r
; edit 21, April 8th, 1987.\r
;	Various bits, including more SET SENDRECEIVE options, and make \r
;	PADDING and PADCHAR valid options.  Have I wasted my time, or \r
;	there still systems that use padding??  Fixed a bug in the INPUT\r
;	command so we know how many characters there are to check for. Also\r
;	hived off the SET commands to make a new file, CPSCOM.ASM thereby\r
;	reducing the size of CPSMIT.ASM.  Also rename COPY command to FCOPY\r
;	hence retaining a single C to imply connect.\r
;\r
; edit 20, March 30, 1987 by OBSchou.  \r
;	added code for no exit to CPM if a command tail is done (optional)\r
;	by the SET NO-EXIT command.  Added bits for SET AUTORECEIVE to enable \r
;	or inhibit automatic receive of several files (if something is coming \r
;	along from the remote side, do a receive. Toss first packet away.)  \r
;	This is first step to SERVER???\r
;	Also added back the INPUT command.\r
;\r
; edit 19, March 16, 1987.  Moved the code to check for and execute \r
;	command tails (See Richard Russells submission below).  \r
;	Added flags to exit to CP/M after executing a command tail.  \r
;	The KERMIT.INI file is taken before the command tail is issued.\r
;\r
; edit 18, March 11, 1987 by OBSchou.\r
;	Added in code for TYPE <file> and PRINT <file>.  Hope to add COPY \r
;	later on.  Also added in code submitted by Richard Russel, to accept\r
;	a command tail on entry to kermit (eg KERMIT CONNECT).  This facility\r
;	if used, will replace the automatic TAKE function on loading Kermit.\r
;	Unfortunately, you will not be dropped back to CP/M after the command\r
;	In the future, it may be possible to either accept several commands\r
;	on the command tail, and possibly accept the automatic TAKE facility\r
;	as well.  Low on my list of things to do.\r
;\r
; edit 17, January 28, 1987 by OBSchou for DJ Roberts of Leicester\r
;	Also added a couple of fixes [obs]\r
;\r
; 	DJR  January 1987  David J. Roberts.\r
;          USER made a SET option\r
;          STATUS output placed in alphabetical order\r
;          Report DEBUG mode and default disk \r
;          Name of LOG file on SHOW/STATUS display\r
;\r
;\r
; edit 16 December 1st, OBSchou.  Fixed bug in that if the overlay is not in\r
;	place or correct then prtstr is not called to print the error message\r
;	(As prtstr has been moved out of the system independent code)\r
;\r
; edit 15 November 10, 1986 by OBSchou.  Re-inserted Pause and Break \r
;       commands for release.\r
;\r
; edit 14 August 29, 1986.  Removed PAUSE,BREAK,INPUT and SET CASE as \r
;       these have not been fully coded or debugged.  (For next \r
;       version of Kermit-80...). Also tidied up a bit.\r
;\r
; 13 by OBSchou for Godfrey Nix.  He writes:\r
;       edit August 11,1986      Godfrey Nix, Nottingham University [gnn]\r
;       To insert code for setting the packet start character on\r
;       both send and receive packets (default is still 01H)\r
;       and make GET and RECEIVE to be separate;\r
;       use with edits to CP4PKT, CP4UTL\r
;\r
; edit 12: 19 June, 1986 by OBSchou.  Added PAUSE and BREAK facility.\r
;       Breaks simulate a call to sysint which tests for a B being passed.\r
;       Note this is only useful if the system dependent code supports breaks,\r
;       and an appropriate message is returned if breaks are not possible.\r
;       Also added is the command entry for INPUT, which waits for a string\r
;       from the host for a given time.  The time is a very variable counter\r
;       incremented every BDOS call.  Trial and error will give a reasonable\r
;       value.  STRING acceps a string from the use and then sends it on \r
;       to the host.  These new commands allow a user to (almost) set up auto\r
;       log on files, where BREAKS/INPUT/STRING/STRING partially emulate a user\r
;       (AI LURES OK and all that).  Still could do with a test, eg if not a\r
;       correctly returned string go back n steps.  This would make a fairly \r
;       simple TAKE command a lot more complicated.\r
;\r
;edit 11: 30 May, 1986 OBSchou.  Added in a couple of more routines and such\r
;\r
;edit 10: 27 May, 1986 OBSchou.  Added in support for USER function\r
;       removed XMIT test and routine, but also added SET FLOW-CONTROL\r
;       (set for XON/XOFF flow control in both directions) and a \r
;       SET CASE-SENSITIVE ON/OFF (if on => a # A, if ON => a=A)\r
;\r
;edit 9: 13 May, 1986 OBSchou, Loughborough University, UK\r
;       Added in code for SET XMIT character to allow setting of the\r
;       character to wait for from the host during TRANSMIT.  It is\r
;       a line feed by default.  Also added a TAKE command, to take: commands\r
;       from a named disk file.  If a file is TAKEn, then all BDOS calls \r
;       are trapped and tested for console input.  If so, we substitute a \r
;       character (or buffer) from the TAKE file specified.\r
;       This may also be used in the future for a CPKERMIT.INI \r
;       to be evaluated during Kermit initialsation.\r
;\r
; edit 8: February 6, 1895\r
;       Add a PORT status/show routine for those machines that have more\r
;       than one they can talk to. It also required a port storage variable\r
;       a la SPEED and the necessary code to handle it in the SET routine.\r
;       [Hal Hostetler]\r
;\r
; edit 7: 13-Jan-85 by Vanya J.Cooper Pima Commun. College Tel: 602-884-6809\r
;\r
;pcc003-pcc005  2-Jan-85        vjc     modules:cp4mit,cp4tt,cp4utl\r
;       These edits must all be installed together and change the way\r
;       logging is handled.  The log file spec is moved to a separate\r
;       fcb, and not opened until an actual CONNECT command is given.\r
;       This takes care of a NASTY bug that if you used any other file\r
;       command between the LOG and CONNECT, the log file would get\r
;       written over the last file used.  This also allows logging to\r
;       be "permanently" enabled until an CLOSE (new command) for all\r
;       CONNECT sessions, like most other kermits do.  If a log file\r
;       already exists, it will be appended to.  Also add two new\r
;       CONNECT mode commands <esc>Q to suspend logging and <esc>R to\r
;       resume.  <esc>R means something else during TRANSMIT, but\r
;       logging is never on then, so there shouldn't be any conflict.\r
;       I also changed the write code, so that it can handle one more\r
;       character after the XOFF is send to stop the host.  This allows\r
;       a little "slop" for systems that don't stop immediately (such\r
;       as TOPS10), but it didn't help much.\r
;\r
;pcc012 4-Jan-85        vjc     modules:cp4mit,cp4tt,cp4utl\r
;       Use the big buffer for the log file.  Move the log file back\r
;       into the common fcb and only save the drive, name, and\r
;       extension between connects.  Add new routines to cp4utl to\r
;       create or append to an existing file, and to conditionally\r
;       advance buffers only if in memory.  Remove edit pcc003 that\r
;       allows one more character after the xoff, since it didn't\r
;       really work very well and does not fit in well with the way\r
;       the buffer advancing routines are set up.  If someone still\r
;       thinks this would be useful, it could be put back in with a\r
;       little more work.\r
;       \r
;       While testing this edit, I also noticed another bug that\r
;       the command parsing routines do not limit or check the\r
;       length of command lines or file specs, trashing what ever\r
;       comes after them.  Currently because of where the fcb and\r
;       command buffer are located, this does not usually cause a\r
;       problem, but could if an extremely long line was typed in,\r
;       or in the future multiple fcbs defined elsewhere in memory\r
;       were used.  Maybe this should be put on the bug list\r
;       somewhere.\r
;\r
;pcc013 8-Jan-85        vjc     modules:cp4mit,cp4utl,cp4typ\r
;       Replace CLOSE command to cancel session logging to SET\r
;       LOGGING ON/OFF.  This seems to fit in with the command\r
;       structure better.  Default the log file to KERMIT.LOG\r
;       incase no previous LOG command.  Logging is also enabled\r
;       by LOG command, as before.\r
;\r
; edit 6: September 8, 1984\r
;       Add VERSION command, to display the internal version strings.\r
;       Move command tables here from CP4UTL, and translate string\r
;       lengths in them to decimal (how many fingers do YOU got?).\r
;       Replace some jump tables with dispatch addresses in tables.\r
;       Make help text for SET command consistent with top level help text.\r
;\r
; edit 5: August 21, 1984\r
;       Add word at 0100H to allow us to exit cleanly from DDT (shifting\r
;       entry section by two bytes).\r
;\r
; edit 4: August 3, 1984 (CJC)\r
;       Remove "mover" from entry section, as it now lives in CP4SYS.\r
;\r
; edit 3: July 27, 1984 (CJC)\r
;       Merge LASM support from Toad Hall: most of CP4MIT is now in CP4UTL.\r
;       When assembling with LASM, CP4MIT is linked by CP4DEF; it links to\r
;       CP4PKT.  Add SET TACTRAP command.  Separate out display routines so\r
;       we can eventually do "SHOW <parameter>".  Save both bytes of baud\r
;       rate in speed, and check both bytes when displaying baud rate.  Move\r
;       header info to CP4KER.ASM.  Add onoff and chkkey routines to simplify\r
;       SET command (Toad Hall)\r
;\r
; edit 2: June 8, 1984\r
;       formatting and documentation; delete unreferenced variables and some\r
;       unnecessary labels; move setpar here from cp4pkt; add module version\r
;       string; make this version 4.01.\r
;\r
; edit 1: May, 1984\r
;       extracted from CPMBASE.M80 version 3.9; modifications are described\r
;       in the accompanying .UPD file.\r
\r
;\f\r
	ASEG\r
	ORG	100H\r
\r
; The CCP invokes programs with a CALL 100H, with the stack pointer set to\r
; 100H.  When we exit to CP/M, we do so with a RET, avoiding a warm boot.\r
; Unfortunately, DDT starts programs with a jump, not a call, so when we\r
; attempt to return to CP/M, we blow the stack and use the word at 100H as\r
; the new PC.  Put a 0 there so we reboot instead of dying horribly.\r
; (Fortunately, this happens to be two NOP's).\r
	dw	0\r
	jmp	start	; Bypass entry section\r
\r
;\r
;       Entry section for system-independent part.  This contains\r
;       jumps to routines needed by the system support module.\r
;\r
entries:\r
	jmp	kermit		; reentry address\r
	jmp	nout		; output HL in decimal\r
entsiz	equ	$-entries	; length of entry section\r
;\r
;       End of entry section.  As a consistency check, the expected\r
;       length of this section is stored by the system-dependent\r
;       module in the linkage section at the end of Kermit, and\r
;       tested at initialization.\r
\r
mitver:	db	'CPSMIT.ASM (30) 29-Mar-1991$'	; name, edit number, date\r
;\f\r
;\r
;       Initialization\r
;\r
start:	lxi	h,0		; Clear out hl pair\r
	dad	sp		; and fetch the system stack pointer\r
	shld	oldsp		; and save for later restoral\r
	lxi	sp,stack	; move in our own stack.\r
	lxi	d,version	; print Kermit version\r
	call	prtstx		;  before we do too much (Use fudged prtstr)\r
	mvi	c,rddrv		;Get our logged in drive\r
	call	BDOS\r
	inr	a		;relative 1\r
	sta	CURDSK		;and save it for later\r
\r
	lda	vtflg		; [OBS] Hangover from VT52 ems not possible...\r
	cpi	0ffh		; ... if 0ff stored, assume terminal = off\r
	mvi	a,vtdefo\r
	jnz	start0\r
	sta	vtflg		; if 0ffh make it VT52 off\r
start0:\r
\r
\r
IF debug\r
;vvvvvvvvvvvvvvvv remove this for run time\r
; OBS edit 22 - add in a dummy command line to 80H\r
	lxi	h,dcomln	;[22] load up dummy command line\r
	lxi	d,81h		;[22] where to put it\r
	lxi	b,endcoml-dcomln\r
	mov	a,c		; get length to a\r
	sta	80h		; ... and save as command line length\r
	call	mover		; ... and save rest of line\r
	jmp	starta\r
dcomln:	db	'set baud 4800',semico\r
	db	'set dir on',semico\r
	db	'dir'\r
	db	0,0	; just to make up space\r
endcoml:\r
;^^^^^^^^^^^^^^^^ remove this for run time\r
ENDIF	;debug\r
\r
\r
starta:\r
;\r
;       Make sure the overlay is in place...\r
;\r
	lhld	lnkflg\r
	mov	a,h\r
	ora	l		; if lnkflg is still zero,\r
	jz	start1		;  the configuration overlay is missing.\r
	lxi	d,-lnksiz	; if it's not equal to lnksiz,\r
	dad	d		;  we've probably got the wrong\r
	mov	a,h		;  version of the configuration overlay.\r
	ora	l\r
	jnz	start2\r
	lhld	lnkent		; make sure the overlay knows how long\r
	lxi	d,-entsiz	; our entry section is, so they don't miss.\r
	dad	d\r
	mov	a,h\r
	ora	l\r
	jnz	start2\r
				; might be ok.\r
	lxi	h,bdos		; set xbdos address to bdos trap in our code.\r
	shld	xbdos+1		; (they may never use it...)\r
	call	sysinit		; do system-dependent initialization\r
	lda	bufsec		; get the max no of buffers allowed by system\r
	sta	maxbsc		; save for SET BUFFER use to compare\r
	lxi	d,inms26	; offer some advice on getting help\r
	call	prtstr\r
	lxi	h,buff		;[19] we copy any potential command tail across\r
	lxi	d,cbuff\r
	lxi	b,80h		;[19] copy all 128 bytes.  May use none.\r
	call	mover\r
	lda	80h		; see if there is a command tail...\r
\r
	ana	a\r
\r
\r
\r
; Remove for runtime use\r
;	xra	a		; make out there is no command tail\r
; Runtime => no XRA above\r
\r
	jz	startz\r
	dcr	a\r
	jz	startz		; one character tail...\r
	lda	takflg		; if more characters, say we are have tail\r
	ori	10h		; set bit 4\r
	sta	takflg\r
	sta	nexitf		; exit back to CP/M after command line\r
startz:\r
	mvi	a,0ffh		; when here, system basically initiallised,...\r
	sta	initflg		; apart from KERMIT.INI, so say initialised.\r
\r
	call	take1		;[9] take a KERMIT.INI file\r
	xra	a		;[MF] Say we've done it\r
	sta	initak		;[MF] ...\r
	jmp	kermit		; Start main loop.\r
\r
start1:	lxi	d,erms20	; "Kermit has not been configured"\r
	call	prtstx		; print error message (Use bodge for prtstr)\r
	jmp	exit2		;  and exit.\r
\r
start2:	lxi	d,erms21	; "Consistency check on configuration failed"\r
	call	prtstx		; print error message\r
	jmp	exit2		;  and exit.\r
;\f\r
;This is the main KERMIT loop.  It prompts for and gets the users commands.\r
\r
kermit:	lxi	sp,stack	; get new stack pointer, old one might be bad.\r
	call	selcon		; make sure console is selected.\r
	xra	a\r
	sta	mfflg1		;reset MFNAME\r
	sta	mfflg2		;ditto\r
	sta	mfflg3\r
	sta	getrxflg	; clear the get/receive flag\r
				;0=> receive, non 0 => get\r
	sta	cmbflg		;[MF]Initial keyword must not be blank\r
	sta	cmqflg		;[MF]Allow character-echoing during commands\r
	sta	remtxt		;[MF] Clear remote-text-to-screen flag\r
	lda	curdsk		; update the prompt\r
	adi	'A'-1\r
	sta	kerm1+2\r
	call	getun		;[11] get the user number into temp1/2\r
	lda	temp1+1		;[11] get ms value of user number\r
	cpi	'0'		;[11] less than 10 => do a space\r
	jnz	kerm4		;[11] else do MS digit of user number\r
	mvi	a,' '		;[11]\r
kerm4:	sta	kerm1		;[11]\r
	lda	temp1		;[11] get ls digit of user number\r
	sta	kerm1+1		;[11] save that\r
	lda	takflg		; are we in TAKE or command line??\r
	ani	11h		; strip out both bits\r
	jnz	kerm5		; still in either or both...\r
	lda	nexitf		; if neither, and no-exit-flag set, we quit.\r
	ana	a\r
	jnz	exit		;... back to CP/M, else as you were...\r
kerm5:\r
	lxi	d,kerm\r
	call	prompt		;Prompt the user.\r
\r
kerm7:	lxi	d,comtab\r
	lxi	h,tophlp\r
	call	keycmd		; Get a keyword\r
	xchg			; Get result (dispatch address) into HL\r
	pchl			; Dispatch.\r
\r
;       here from: log, setcom, read, cfmcmd\r
kermt3:	lxi	d,ermes3	;"Not confirmed"\r
	call	prtstr\r
	jmp	kermit		;Do it again.\r
\r
;       Structure of command table:\r
;\r
;       1) Number of entries.\r
;       2) Each entry is arranged as follows:\r
;               a) length of command in bytes.\r
;               b) 'name of command and $-sign'\r
;               c) address of routine to process command\r
;\r
;       ---> Note this command table is in alphabetic order.\r
;\r
\r
comtab:	db	32	; added remote\r
			;[obs] added in COPY command, now called FCOPY\r
			;[obs] removed remote simply to issue V4.09\r
				;[MF]Make FCOPY/FRENAME COPY/RENAME for\r
				;[MF]Version 4.10\r
				;[MF]Add QUIT as a synonym for EXIT and\r
				;[MF]C, R and S as abbreviations for\r
				;[MF]CONNECT, RECEIVE and SEND, respectively\r
				;[MF]Add STAY as a synonym for SET NO-EXIT\r
	db	5, 'BREAK$'\r
		dw break\r
	db	3, 'BYE$'\r
		dw bye\r
	db	1,'C$'\r
	dw	telnet		;[MF]Abbreviation for CONNECT\r
	db	7, 'CONNECT$'\r
		dw telnet\r
	db	4,'COPY$'\r
		dw copy\r
	db	9, 'DIRECTORY$'\r
		dw dir\r
	db	5, 'ERASE$'\r
		dw era\r
	db	4, 'EXIT$'\r
		dw exit\r
	db	6, 'FINISH$'\r
		dw finish\r
	db	3, 'GET$'\r
		dw read		; [gnn] entry for GET\r
	db	4, 'HELP$'\r
		dw help\r
	db      5, 'INPUT$'\r
		dw input\r
	db	3, 'LOG$'\r
		dw log\r
	db	6, 'LOGOUT$'\r
		dw logout\r
	db	6, 'OUTPUT$'\r
		dw string\r
	db	5, 'PAUSE$'\r
		dw pause\r
	db	5, 'PRINT$'\r
		dw printf	;[obs] print a file\r
	db	4,'QUIT$'\r
	dw	exit		;[MF]Synonym for EXIT\r
	db	1,'R$'\r
	dw	read0		;[MF]Abbreviation for RECEIVE\r
	db	7, 'RECEIVE$'\r
		dw read0	; [gnn] not same as GET now\r
	db	6, 'REMOTE$'\r
		dw remote\r
	db	6,'RENAME$'\r
	dw	rename		;[MF]\r
	db	1,'S$'\r
	dw	send		;[MF]Abbreviation for SEND\r
	db	4, 'SEND$'\r
		dw send\r
	db	3, 'SET$'\r
		dw setcom\r
	db	4, 'SHOW$'\r
		dw show\r
	db	6, 'STATUS$'\r
		dw status\r
	db	4,'STAY$'\r
	dw	noexit		;STAY (SET NO-EXIT)\r
	db	4, 'TAKE$'			;[9]\r
		dw take\r
	db	8, 'TRANSMIT$'\r
		dw xmit\r
	db	4, 'TYPE$'\r
		dw type		;[obs] type a file command\r
	db	7, 'VERSION$'\r
		dw shover\r
;	db	4, 'USER$'			; removed [DRJ]\r
;		dw user				;[10] removed [DRJ]\r
; top-level help message. Caps indicate keywords.\r
; this text is also printed by the HELP command.\r
\r
tophlp:	\r
	db	cr,lf,'BREAK to send a break to the host'\r
	db	cr,lf,'BYE to host (LOGOUT) and exit to CP/M'\r
	db	cr,lf,'CONNECT to host on selected port'\r
	db	cr,lf,'COPY to copy a CP/M file'\r
	db	cr,lf,'DIRECTORY of current used Micro-disk'\r
	db	cr,lf,'ERASE a CP/M file'\r
	db	cr,lf,'EXIT to CP/M'\r
	db	cr,lf,'FINISH running Kermit on the host'\r
	db	cr,lf,'GET a file from the host'\r
	db	cr,lf,'HELP by giving this message'\r
	db	cr,lf,'INPUT to make the micro wait for a string from the host'\r
	db	cr,lf,'LOG the terminal sessions to a file'\r
	db	cr,lf,'LOGOUT the host'\r
	db	cr,lf,'OUTPUT to send a specified string to the host'\r
	db	cr,lf,'PAUSE to wait for a little time'\r
	db	cr,lf,'PRINT a file to the printer'\r
	db	cr,lf,'QUIT to CP/M'\r
	db	cr,lf,'RECEIVE file from host'\r
	db	cr,lf,'REMOTE to send commands to a remote server'\r
	db	cr,lf,'RENAME to rename a CP/M file'\r
	db	cr,lf,'SEND file to host'\r
	db	cr,lf,'SET a parameter'\r
	db	cr,lf,'SHOW the parameters'\r
	db	cr,lf,'STATUS of Kermit'\r
	db	cr,lf,'STAY at Kermit command-level after a command tail'\r
	db	cr,lf,'TAKE commands from a file'		;[9]\r
	db	cr,lf,'TRANSMIT file to host (in connect state)'\r
	db	cr,lf,'TYPE a file to the console'\r
	db	cr,lf,'VERSION of Kermit running'		;[pcc005]\r
;	db	cr,lf,'USER to set a different user number' ;removed [DJR]\r
	db	'$'		;[obs] added it here to allow for expansion\r
\r
;\f\r
;       This is the BREAK command.  It sends a 'B' to the system dependent\r
;       interrupt routines (test for escape-cokebottle xxx) and do a break\r
;       if the overlay can.  Else, we tell user not to be so silly.\r
break:	call	cfmcmd		; get return\r
	mvi	a,'B'		; were gonna do a break if the overlay can\r
	call	sysint		; try doing it..\r
	jmp	kermit		; if we can do it, else\r
	lxi	d,inms12	;... say not implemented\r
	jmp	kermit\r
\r
;\r
;\r
;       This is the BYE command.  It tells the remote KERSRV to logout,\r
;       then exits.\r
\r
bye:	call	cfmcmd\r
	call	logo		;Tell the main frame to logout.\r
	jmp	kermit		;If it fails, don't exit.\r
	call	sysbye		; success. do system-dependent cleanup\r
	jmp	exit1		;Exit Kermit.\r
\r
;       This is the EXIT command.  It leaves KERMIT and returns to CP/M.\r
;       alternate entries: exit1, from BYE command;\r
;       exit2, from initialization (if it fails)\r
\r
exit:	call	cfmcmd		; confirm...\r
exit1:	call	sysexit		; do system-dependent termination\r
exit2:	\r
	jmp	0		; return to CP/M via JUMP instead of RET.\r
	\r
;	lhld	oldsp		;Get back the system stack\r
;	sphl			;and restore it.\r
;	ret			;Then return to system.\r
\r
;       Input command.  Syntax:\r
;               INPUT [Wait period] [string]\r
;       where\r
;               Wait period is a time period to wat for\r
;               string is a string to expect back from the host.  Control\r
;                       characters are entered as \ and an octal number.\r
;\r
;       I can see uses for this command from other routines...\r
;\r
input:	mvi	a,cmnum		; first get the number\r
	call	comnd		; get it\r
	jmp	kermit		; if we dont understand it...\r
	lhld	number\r
	shld	waitp		; and save as the wait period\r
	lxi	d,stbuff	; where to put the string\r
	mvi	a,cmtxt		; get text\r
	call	comnd\r
	jmp	kermit		; not quite correct...\r
	sta	strcnt		; string count returned in a\r
	call	cfmcmd		; get a confirm\r
\r
	lhld	waitp		; multiply the number by\r
	dad	h\r
	dad	h		; ... 4\r
	dad	h		; ... 8\r
	inx	h		; but make sure it is at least 1\r
	shld	waitp		; and save it away again\r
	shld	waitp1		; save in case we need to reset counter\r
\r
; Right, now wait for characters comming from the line, within the\r
;	time allowed (very fuzzy).  Compare with STRING buffer\r
;\r
inp1:	xra	a\r
	sta	repcnt		; clear the host prompt chars.counter\r
inp2:	lhld	waitp		; have we waited long enough\r
	dcx	h\r
	shld	waitp		; count less one\r
	mov	a,h		; test to see if both zero\r
	ora	l\r
	jnz	inp20		; nope\r
	mvi	a,3		; error is three ie total failure\r
	sta	errorc\r
	jmp	inp5		; take error exit\r
\r
inp20:	call	rd1chl		; read a character from the line\r
	ani	7fh		; set flags\r
	jnz	inp4		; Not zero => we have a character from host\r
	call	ckchr		; see if *WE* have a character from console\r
	push	psw		; restore to modem\r
	call	selmdm		; reselect the modem port\r
	pop	psw\r
	ani	7fh		; strip parity (should not be there)\r
	jnz	inp2a		; if a null, try again\r
	lda	strcnt		; if the string length is zero, dont wait.\r
	ana	a\r
	jnz	inp2		; so loop back again\r
	jmp	kermit		; else drop out\r
\r
inp2a:	cpi	cntlc		; do we want to abort?\r
;[MF]Change following line\r
;	jz	kermit		; in which case exit back to command loop\r
	jnz	inp2b		;[MF] No\r
	lda	takflg		;[MF] Yes, are we TAKEing\r
	ani	1		;[MF] commands from a file?\r
	cnz	closet		;[MF] Yes, close and reset to get\r
				;[MF] commands from the command-line\r
	jmp	kermit		;[MF] and exit back to command loop\r
inp2b:	cpi	cntlz		; if control z exit back to command loop\r
	jz	kermit		; else try for other characters [MF]\r
	jmp	inp2\r
\r
inp4:	mov	e,a		; save it for a while\r
	lda	repcnt		; see if this character matches with one in buffer\r
	lxi	h,stbuff	; point to string buffer\r
	add	l		; make hl = hl + a\r
	mov	l,a\r
	mvi	a,0		; ie make hl = hl + character count\r
	adc	h\r
	mov	h,a		; not using xra, as that clears the Carry flag\r
	mov	a,e		; get the character back again\r
	cmp	m		; is it = to what we expect?\r
	jnz	inp1		; no, clear counter and try again\r
	lda	repcnt		; yes, then update the pointer, and ...\r
	inr	a		; ... see if we have received all ...\r
	sta	repcnt		; ... we should have received\r
	lhld	waitp1		; get original counter\r
	shld	waitp		; and reset the loop (timer) counter\r
	mov	e,a		; save length into E again\r
	lda	strcnt		; get the length to compare\r
	sub	e		; if (e) > string length, we have it\r
	jnz	inp2		; else wait for a little longer\r
\r
	xra	a		; no errors\r
	sta	errorc\r
	jmp	kermit		; so say nothing\r
;else if error...\r
\r
inp5:	lxi	d,erms30	; say message not receive in time...\r
	call	prtstr\r
	jmp	kermit		; have string, so exit\r
\r
;\r
;\r
\r
;       This is the HELP command.  It gives a list of the commands.\r
\r
help:	call	cfmcmd\r
	lxi	d,tophlp	;The address of the help message.\r
	call	p20ln		;Print at most 20 lines then pause\r
;	call	prtstr\r
	jmp	kermit\r
;\f\r
;       This is the LOG command.  It logs a session to a file.\r
\r
log:	mvi	a,cmofi		;[pcc005] Parse an output file spec.\r
	lxi	d,fcb		;[pcc012] where to put it\r
	call	comnd\r
	jmp	kermt3\r
	call	cfmcmd\r
	lxi	h,fcb		;[pcc012] copy file name and ext\r
	lxi	d,lognam	;[pcc012] to a safe place\r
	lxi	b,12		;[pcc012] 12 bytes\r
	call	mover		;[pcc012] zap ...\r
	mvi	a,1		;[pcc005] set flag for logging\r
	sta	logflg		;[pcc005]\r
	jmp	kermit		;[pcc005]\r
\r
;\r
;       PAUSE [Wait period]. Just wait for a couple of tics...\r
pause:	mvi	a,cmnum		; get the number of the wait period\r
	call	comnd		; get it\r
	jmp	kermit		; we canna do it, so get next command\r
	lhld	number\r
	xchg			; move to d\r
	lhld	clkbit+1	; get clock bits 8 to 23\r
	mov	a,h		; strip ms bit so we have space for a possible carry\r
	ani	7fh\r
	mov	h,a\r
	dad	d		; add the number (ie get the number to wait to\r
	shld	number		; save it somewhere\r
;\r
;       Now, wait for time to be equal to newer NUMBER with Carry\r
ploop:	\r
	call	clock		; increment clock\r
	lda	takflg		; test if keyboard interrupt.. not for takes\r
	ana	a\r
	jnz	ploop1		; do nothing for take command files\r
	mvi	c,dconio	; get status from console\r
	mvi	e,0ffh		; just get the character\r
	call	bdos\r
	ana	a		; if non zero return, then quit\r
	jnz	kermit		; we got something, so quit\r
ploop1:	lhld	number\r
	xchg\r
	lhld	clkbit+1	; get bits 8 to 23\r
	mov	a,h\r
	ani	7fh		; make it 15 bits for a carry...\r
	mov	h,a\r
	mov	a,e		; now, do (DE with carry) - HL\r
	sub	l\r
	mov	e,a\r
	mov	a,d\r
	sbb	h\r
	ora	e		; a = OR of result\r
	jnz	ploop\r
	jmp	kermit		; otherwise we are done.\r
\r
; PRINT - Print a file to the console and printer.  \r
;	This command is active only from the command level, and not \r
;	from the connect state.  Unfortunately, the print command is \r
;	not going to be a background utility.\r
printf:	mvi	a,0ffh		; set the print flag on\r
typent:	sta 	prnfl		; Type file entry.  Common for PRINT and TYPE\r
	call	type		; and do the rest of the print via type\r
	xra	a\r
	sta	prnfl		; next clear the print flag\r
	jmp	kermit\r
\r
; TYPE - Type a file to the console.\r
;	This command is really the same as the print command, but the output\r
;	is not copied to the printer.\r
typef:	xra	a		; we want to clear the printer on flag\r
	jmp	typent		; go to the type entry in printfile above\r
\r
\r
;\f\r
;       This is the TAKE command.  It take input from a file.\r
;       TAKE1 is the entry for automatically TAKE-ing KERMIT.INI (or whatever\r
;       the file name at taknam is) from the default drive\r
;	[18] code added to accept command tails.  See note [18] above\r
;\r
take:	mvi	a,cmifi		;[9] Get filename from user\r
	lxi	d,takfcb	;[9] Take file fcb space\r
	call	comnd		;[9] get the file spec\r
	jmp	kermit		;[9] User failed to specify a good file spec\r
	call	take2		;[MF] Now TAKE the file\r
	jmp	kermit		;[MF] Go back to main Kermit command loop\r
;\r
take1:	lxi	b,12		;[9] copy default drive and file name to take fcb\r
	lxi	d,takfcb\r
	lxi	h,taknam\r
	call	mover		;[9] and do it (all other extents etc are zero)\r
;[MF][30]No longer need the following line\r
;	jmp	take2		; got the file name, now take it.\r
;\r
				;[9] get the file name, now lets open it \r
;\r
take2:\r
	lda	takflg		; check to see we have not tak-take\r
	ani	1		; if set, we are in a take already\r
;[MF]We can do the following test/call more efficiently\r
;	jz	take21\r
;	call	closet		; so close current take file\r
	cnz	closet		;[MF] So close current take file\r
take21:\r
	mvi	c,setdma\r
	lxi	d,takdma	;[9] tell bdos where to send data\r
	call	BDOS\r
	xra	a		;[9] clear all these extents etc\r
	sta	takfcb+14\r
	sta	takfcb+32\r
	lxi	d,takfcb	;[9] open the file\r
	mvi	c,openf		;[9] open the file\r
	call	BDOS\r
	inr	a		;[9] if FF returned, problems\r
;[MF]Complain if failure and not seeking KERMIT.INI\r
;	jz	kermit		;[9] for now, say nowt if no ini file. Else..\r
       jz      ntake           ;[9] We'll say file not found\r
				;[MF] unless the initial TAKE (KERMIT.INI)\r
;	jmp	take3		; a test\r
;	mvi	c,readf		;[9] read first bytes from file\r
;	lxi	d,takfcb	;[9]\r
;	call	BDOS\r
\r
take3:	lxi	h,0\r
	shld	takptr		;[9] point to first byte of take file\r
	lda	takflg		; get current flag\r
	ori	1		;[9] and set flag to tell Kermit we're taking\r
	sta	takflg\r
;[MF][30]Redo next lines so can flag initial TAKE of KERMIT.INI\r
;	call	rnsect		;[9] read a sector\r
;	jmp	kermit		;(Should use a ret, but this will do)\r
	jmp	rnsect		;[9] read a sector and return\r
\r
ntake:	lda	initak		;[MF]Is this the initial TAKE (KERMIT.INI)?\r
	ora	a		;[MF]...\r
	rnz			;[MF]Yes, don't complain\r
	lxi	d,erms15	;[9] Say file not found\r
	call	prtstr\r
;[MF][30]Make next line a "jmp" since we've called TAKE2\r
;	call	rstdma		;[9] reset the DMA addres for other files\r
;	jmp	kermit\r
	jmp	rstdma		;[9] reset the DMA addres for other files\r
				;[MF] and return\r
\r
\r
; Little code to allow some expansion of code without changing\r
;  every futher address, only up to the end of this file.\r
;   TO BE REMOVED FRO RELEASE!\r
\r
;	org ($+100h) AND 0FF00H\r
\r
IF lasm\r
	LINK CPSCOM\r
ENDIF ;lasm\r