Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpspk1.asm

; CPSPK1.ASM\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others. \r
;\r
;       This file contains the (system-independent) routines that implement\r
;       the KERMIT protocol, and the commands that use them:\r
;       RECEIVE, SEND, FINISH, and LOGOUT.\r
;\r
; revision history:\r
;\r
;edit 23, 16-Jan-1991 by MF. The bug of (22) was not fixed (although\r
;	the error described needed to be corrected). Really fixed the bug this:\r
;	time. changed "lda 'E'" after "ptch9b" to "mvi a,'E'" -- Zilog\r
;	mnemonic thinking must've addled my brain!\r
;edit 22, 14-Jan-1991 by MF. Fix bug in the code which sends an "E" packet\r
;	to the remote Kermit on encountering "disk full" so that\r
;	uncontrollified <CR><LF> is not copied to the packet data area (and\r
;	hence sent to the remote Kermit). This should fix a bug reported\r
;	by Russell Lang of Monash University in Australia wherein a PC\r
;	running Kermit in Server mode complained of invalid characters when\r
;	receiving the "disk full" error packet from CP/M Kermit.\r
;edit 21 of 3-Jan-1991 by MF. Reverse part of edit 20 which flushes comm\r
;	input at EOF send: the problem of multiple copies of packets being\r
;	sent when a stream of files being sent is partially interrupted with\r
;	^X has been fixed by modifying "inchr" in CPSPK2.ASM.\r
;edit 20, 2-Jan-1991 by MF. Tightened up code just after "sdata1" and around\r
;	"sdat14". Added code to flush comm input after user has typed ^X\r
;	or ^Z to interrupt file sends so that duplicate packets are not\r
;	sent after the interrupt character (especially ^X) has been typed.\r
;edit 19, 14-Dec-1990 by MF.  Place "<<>>" around "F" and "X" packets coming\r
;	as replies to REMOTE commands a la VMS Bliss Kermit.\r
;	Also type each character of "X" or "F" packet explicitly in case\r
;	dollar-signs are part of the filename (as in VMS Bliss Kermit\r
;	when a REMOTE TYPE is given and SET FILE NAMING FULL is in effect).\r
;	Expanded code is at label rfil3f.\r
;edit 18, 27-Nov-1990 by MF. Fix bug introduced with edit 17 which resulted\r
;	in "E" packet being sent twice when receiving file(s) and disk-full\r
;	occurred. Sorry about that, folks!\r
;edit 17, 27-Nov-1990 by MF. When receiving files, make the decision as to\r
;	whether to delete a partially-received file on a "disk full"\r
;	condition subject to the setting of the SET INCOMPLETE-FILES\r
;	switch in conformity with the behavior of MSDOS Kermit.\r
;	An "E" packet is still sent to the remote Kermit. Also try to close\r
;	any incomplete file whether deleting it or not (labels rdat16 and\r
;	rdat3a). If keeping incomplete files, try to write outstanding\r
;	buffers to disk, giving an error if the disk is full.\r
;edit 16, 23-Nov-1990 by MF. When receiving, cause the file being written\r
;	to disk to **always** be deleted and an "E" packet to be sent when a\r
;	"disk full" condition is encountered (per suggestion of\r
;	RJL@MONU1.CC.MONASH.EDU.AU).\r
;edit 15, 15-Nov-1990 by MF.  Changed code for the Receive Complete state\r
;	to always go into RECEIVE if AUTORECEIVE is on.  This will happen\r
;	most of the time anyway as most mainframe Kermits issue a prompt\r
;	after a single SEND command (wild-carded or not), thus guaranteeing\r
;	that the modem status check of Kermit-80 ver. 4.09 would **always**\r
;	have characters ready for input (the mainframe Kermit's prompt),\r
;	defeating the status check and the Console input check (originally\r
;	intended to drop the user out of the loop if he/she typed a key with\r
;	no comm input present).  Eliminate "any key" message there also.\r
;	the user can drop out by hitting ^C.\r
;	Of course, none of the foregoing applies if the Receive Complete\r
;	state occurs as the result of a "Get" command where Autoreceive\r
;	is meaningless and we just drop back to Kermit command-level.\r
;edit 14, 1-Oct-1990 by MF.  Added code to send an "I" packet before an\r
;	"R" packet in GET command.\r
;	Modified routine "sinit" to ignore "E" packets when sending an\r
;	"i" packet (per KPROTO.DOC).\r
;edit 13, 14-Sep-1990 by MF.  Added code to implement SET FILE COLLISION\r
;	and SET INCOMPLETE commands.\r
;edit 12, 9-Sep-1990 by MF.  Added code to prevent packet counts\r
;	from being displayed during Remote commands.  Fixed\r
;	AUTORECEIVE 	code, file colision Rename algorithm and eliminated\r
;	multiple display of initial messages during GET/RECEIVE.\r
; edit 11, 28 July, 1987 by OBSchou.  Commented out capas etc support\r
;	(Long packets etc) as this is not worth the effort coding... but\r
;	I have left what WAS done for any enthusiast.  Also set in a few\r
;	to NOT write to screen if SET TERMINAL QUIET set.  Hopefully speeds\r
;	up transfers on systems taking forever to update screens.\r
;\r
; edit 10, 8 April, 1987 by OBSchou.  Tarted up all sorts of bits n bobs\r
;	to cope with all the new aditions for Kermit-80 V 4.09\r
;	Look for the [10] for most cahnges.  spar and rpar largely replaced\r
;\r
; edit 9, March 30th by OBSchou.  Set bits for automatically receiving\r
;	another file if a remote sender sends files in seperate sessions.\r
;	The code simply checks the serial line, and if there is some\r
;	activity, assume its another SEND INIT packet.  As there is no\r
;	simple way to go to receive with the control-a, just ignore the\r
;	packet.  Causes one retry on the sender, but so what.  Really \r
;	should make it a server gizzmo.\r
;\r
; edit 8: January 28, 1987 by OBSchou\r
;	Two major issues: firstly split CPSPKT.ASM into CPSPK(1 2).ASM\r
;	making it far easier to handle this file.\r
;	Second, some mode to the GET routines to correctly print the file\r
;	name instead of the fireworks.  Trouble was with GET <file> <file>\r
;	and RECEIVE <file>.  However, new bugs discovered...\r
;\r
; edit 7: August 11, 1986    Godfrey N. Nix [gnn] Nottingham University\r
;       To ignore echoed packets (ie send 'S' receive 'S' before 'A');\r
;       To allow character other than SOH for packet header (see also\r
;                       updates to CP4MIT and CP4UTL for other code needed);\r
;       To permit SEND and RECEIVE to specify a host filename which\r
;                       is of a different structure to that of CP/M.\r
;\r
; edit 6a: [OBSchou] 7 March, 1985.\r
;       Edited file with additions from MJ Carter.  He writes:\r
;       25th September 1985, M J Carter [majoc], Nottingham University\r
;       Code in gofil() amended, for exactly the same reasons to the \r
;       alteration to cmifil() in cpscmd.asm.  If there is any deep\r
;       reason why gofil() has to be used instead of a call to comnd(cmofil), \r
;       I can't see it.  The bug (on a British Micro Mimi 803) caused \r
;       gofil() to overwrite existing files in GET and RECEIVE, even \r
;       with file warning SET ON.\r
;\r
;edir 6: November 22, 1984\r
;       Change SEND's 'Unable to find file' error exit from calling\r
;       error3 to calling prtstr instead.  I don't know about you, but\r
;       I greatly dislike having messages dumped into pre-existing\r
;       junk on the screen where I have to spend lots of time hunting\r
;       for them.  [Hal Hostetler]\r
;\r
; edit 5: September 9, 1984\r
;       Call flsmdm in init to flush old input when starting transfers.\r
;       Select console before returning from inpkt.\r
;       Replace inline code with calls to makfil/clofil to set up for\r
;       multisector buffering on output.\r
;       Remove superfluous call to clrlin in error3.\r
;\r
; edit 4: August 21, 1984 (CJC)\r
;       Fix comment in inpkt: packet is terminated by NUL on return, not CR.\r
;       If debugging, display the outgoing packet before putting the EOL\r
;       character on, so the dumped packet doesn't get overwritten.\r
;\r
; edit 3: July 27, 1984\r
;       add link directive for LASM.  CP4PKT is linked by CP4MIT, and links\r
;       to CP4TT.  Add Toad Hall TACtrap to permit operations through a TAC.\r
;\r
; edit 2: June 8, 1984\r
;       formatting and documentation; remove some unused labels; move setpar\r
;       to cp4mit.m80; add module version string; make all arithmetic on\r
;       'pktnum' modulo 64; apply defaults correctly for missing parameters\r
;       in send-init packet (and corresponding ack).\r
;\r
; edit 1: May, 1984\r
;       extracted from CPMBASE.M80 version 3.9; modifications are described\r
;       in the accompanying .UPD file.\r
;\r
pk1ver:	db	'CPSPK1.ASM (23) 16-Jan-1991$'	; name, edit number, date\r
\r
;       GET command   [gnn]\r
;       here from: kermit\r
\r
read:	mvi	a,0ffh		;[obs 8] we are doing a get\r
	sta	getrxflg	;[obs 8] so set flag\r
	lxi	d,remdat	;Where to put the text (if any.)\r
	mvi	a,cmtxt\r
	call	comnd		;Get either some text or a confirm.\r
	jmp	kermt3		; Didn't get anything.\r
	ora	a		;Get any chars?\r
	jz	kermt3		;[gnn] GET must have a filename\r
	sta	rdl		;Store the number of chars.\r
	xchg			;Get pointer into HL.\r
	mvi	m,'$'		;Put in a dollar sign for printing.\r
	call	init		;Clear the line and initialize the buffers.\r
	lda	quietd		; quiet display?\r
	ana	a\r
	jz	read01		;[MF]No, go ahead and position cursor\r
	call	prcrlf		;[MF]Yes, keep from overwriting the prompt\r
	jmp	read00		;[MF]and write filename\r
read01:	call	scrfln		;Position cursor [MF]\r
read00:	lxi	d,remdat	;Print the file name, in either case\r
	call	prtstr\r
	jmp	read0a		;[gnn] go get local name if any\r
\r
\r
; enter here for RECEIVE command  [gnn]\r
read0:	mvi	a,0		;[gnn]\r
	sta	rdl		;[gnn][MF] flag entry as receive, not get\r
	sta	getrxflg	;[obs 8] doing a receive, so reset flag\r
	call	init		;clear line, initialise buffers\r
read0a:	lxi	d,remnam	;[gnn] save local name here\r
	mvi	a,cmtxt		;[gnn]\r
	call	comnd		;[gnn] read second filename if present\r
	jmp	kermt3		;[gnn]  error exit\r
	sta	remlen		;[gnn] save length of name, may be zero\r
	sta	getrxflg	;[obs 8] May also be receive <fnam> so \r
				;[obs 8]pretend get for printing filename\r
	lda	rdl		;[gnn] look at first name\r
	ora	a		;[gnn] receive or get?\r
	jz	read1		;[gnn] receive\r
\r
	mvi	a,'I'		;[MF]Set state to send "I" packet\r
	sta	state		;[MF]...\r
\r
;       jmp     read12		;[obs] [gnn] does not want this\r
\r
read1:	;call   init		;Clear the line and initialize the buffers.\r
read12:	xra	a\r
	sta	czseen		;Clear the ^X/^Z flag initially.\r
	lxi	h,0\r
	shld	numpkt		;Set the number of packets to zero.\r
	shld	numrtr		;Set the number of retries to zero.\r
	sta	pktnum		;Set the packet number to zero.\r
	sta	numtry		;Set the number of tries to zero.\r
	lda	quietd		; quiet display?\r
	ana	a\r
	jnz	read13		; yes, so dont write...\r
	call	scrnrt		;Position cursor\r
	lxi	h,0\r
	call	nout		;Write the number of retries.\r
read13:	lda	rdl		;[MF]Get or receive?\r
	ora	a		;[MF]...\r
	jnz	read2		;[MF]Get, don't reset state\r
	mvi	a,'R'\r
	sta	state		;Set the state to receive initiate.\r
	;...\r
;\f\r
;RECEIVE state table switcher.\r
\r
read2:	lda	quietd		; noisy display?\r
	ana	a\r
	jnz	read21		; no, a quiet one\r
	lda	remtxt		;[MF] In Remote command?\r
	ora	a\r
	jnz	read21		;[MF] Yes, don't write to screen\r
	call	scrnp		;Position cursor\r
	lhld	numpkt\r
	call	nout		;Write the current packet number.\r
read21:	lda	state		;Get the state.\r
	cpi	'D'		;Are we in the DATA receive state?\r
	jnz	read22\r
	call	rdata\r
	jmp	read2\r
\r
read22:	cpi	'X'		; F packet but not an F packet?\r
	jnz	read3		; nope, so try next one\r
	call	rfile		; 'get' the filename (but dont open it)\r
	jmp	read2\r
\r
read3:	cpi	'F'		;Are we in the FILE receive state?\r
	jnz	read4\r
	call	rfile		;Call receive file.\r
	jmp	read2\r
\r
read4:	cpi	'R'		;Are we in the Receive-Initiate state?\r
	jnz	read5\r
	call	rinit\r
	lda	state		;[jd] get new state\r
	cpi	'F'		;[jd] went into receive state?\r
	jnz	read2		;[jd] no\r
	lxi	d,inms24	;[jd] yes, get receiving... message\r
	call	finmes		;[jd] go print it\r
	jmp	read2\r
\r
read5:	cpi	'C'		;Are we in the Receive-Complete state?\r
	jnz	read6\r
	lxi	d,infms3	;Put in "Complete" message.\r
	lda	czseen		;Or was it interrupted?\r
	ora	a		; .  .  .\r
	jz	read5a		;No.\r
	xra	a		;Yes, clear flag.\r
	sta	czseen		; ...\r
	lxi	d,inms13	;Issue "interrupted" message.\r
read5a:	lda	remtxt		;[MF] Doing a Remote command?\r
	ora	a\r
	cz	finmes		;Print completion message in right place if not\r
;\r
	lda	rdl		;[MF]Receive or Get?\r
	ora	a		;[MF]...\r
	jnz	kermit		;[MF]Get, Autoreceive means nothing.\r
	lda	autorc		; see if we want autoreceives\r
	ana	a\r
	jz	kermit		;[MF]No autoreceives, so drop out\r
	lxi	d,autmes	;[MF]Yes, tell the user what we're doing\r
	call	prtstr		;[MF]...\r
	jmp	read1		;[MF]Try another Receive (we get one\r
				;[MF]retry from the sender as the ^A is lost)\r
\r
read6:	cpi	'Y'		;[MF]Simple ack (from remote command)?\r
	jz	kermit		;[MF]Yes\r
\r
	cpi	'I'		;[MF]Exchanging parameters via info packet?\r
	jnz	read7		;[MF]No\r
	call	sinit		;[MF]Yes, send the packet\r
	lda	state		;[MF]Now see what happened\r
	cpi	'X'		;[MF]Did we exchange parameters successfully?\r
	jz	read6a		;[MF]Yes, go send the filespec\r
	cpi	'A'		;[MF]No, are we in abort state?\r
	jnz	read2		;[MF]No, try again\r
	jmp	kermit		;[MF]Yes, it's a real disaster, we must stop\r
read6a:	lda	rdl		;[MF]Get length of filespec\r
	sta	argblk+1	;[MF]as length of packet\r
	mov	c,a		;[MF]We must copy the filespec\r
	mvi	b,0		;[MF]...\r
	lxi	h,remdat	;[MF]from the temporary buffer\r
	lxi	d,data		;[MF]to the packet data area\r
	call	mover		;[MF]Do it.\r
; for GET we must send the name of the file we want [gnn]\r
\r
	mvi	a,'1'		;Start with single character checksum\r
	sta	curchk		;Save the type\r
	xra	a		;Start a packet zero.\r
	sta	argblk\r
	mvi	a,'R'		;Receive init packet.\r
	call	spack		;Send the packet.\r
	jmp	kermt3		; Die!\r
	xra	a\r
	sta	czseen		;Clear the ^X/^Z flag initially.\r
	lxi	h,0\r
	shld	numpkt		;Set the number of packets to zero.\r
	sta	pktnum		;Set the packet number to zero.\r
	sta	numtry		;Set the number of tries to zero.\r
	mvi	a,'R'		;[MF]Set state to Receive-Initiate\r
	sta	state		;[MF]...\r
	jmp	read21		;[MF]and go around again\r
				;[MF]without retyping packet-number\r
\r
read7:	cpi	'A'		;Are we in the Receive-"Abort" state?\r
	jnz	read8\r
read8:	lxi	d,infms4	;Anything else is equivalent to "abort".\r
	call	finmes\r
	jmp	kermit\r
;\f\r
;       Receive routines\r
\r
;       Receive init\r
;       called by: read\r
\r
rinit:	lda	numtry		;Get the number of tries.\r
	cpi	imxtry		;Have we reached the maximum number of tries?\r
	jm	rinit2\r
	lxi	d,ermes4\r
	call	error3		;Move cursor and print an error message.\r
	jmp	abort		;Change the state to abort.\r
\r
rinit2:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	mvi	a,'1'		;Reset block check type to single character\r
	sta	curchk		;Store as current type for initialization\r
	call	rpack		;Get a packet.\r
	jmp	nak		; Trashed packet: nak, retry.\r
	cpi	'S'		;Is it a send initiate packet?\r
	jnz	rinit3		;If not see if its an error.\r
rini2a:	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	lda	argblk		;Returned packet number.  (Synchronize them.)\r
	call	countp\r
	lda	argblk+1	;Get the number of arguments received.\r
	lxi	h,data		;Get a pointer to the data.\r
	call	spar		;Get the data into the proper variables.\r
	lxi	h,data		;Get a pointer to our data block.\r
	call	rpar		;Set up the receive parameters.\r
	sta	argblk+1	;Store the returned number of arguments.\r
	mvi	a,'Y'		;Acknowledge packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	lda	inichk		;Now switch to agreed upon check-type\r
	sta	curchk		;For all future packets\r
	mvi	a,'F'		;Set the state to file send.\r
	sta	state\r
	ret\r
\r
rinit3:	cpi	'E'		;Is it an error packet.\r
	jnz	nak0		;If not NAK whatever it is.\r
	call	error\r
	jmp	abort\r
;\f\r
;       Receive file\r
;       called by: read\r
\r
rfile:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	rfile1\r
	lxi	d,ermes5\r
	call	error3		;Move cursor and print an error message.\r
	jmp	abort		;Change the state to abort.\r
\r
rfile1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	call	rpack		;Get a packet.\r
	jmp	nak		; Trashed packet: nak, retry.\r
	cpi	'S'		;Is it a send initiate packet?\r
	jnz	rfile2		; No, try next type.\r
	lda	oldtry		;Get the number of tries.\r
	cpi	imxtry		;Have we reached the maximum number of tries?\r
	jm	rfil12		;If not proceed.\r
	lxi	d,ermes4\r
	call	error3		;Move cursor and print an error message.\r
	jmp	abort		;Change the state to abort.\r
\r
rfil12:	inr	a		;Increment it.\r
	sta	oldtry		;Save the updated number of tries.\r
	lda	pktnum		;Get the present packet number.\r
	dcr	a		;Decrement\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number\r
	cmp	b		;Is the packet's number one less than now?\r
	jnz	nak0		;No, NAK and try again.\r
	call	updrtr		;Update the retry count.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	lxi	h,data		;Get a pointer to our data block.\r
	call	rpar		;Set up the parameter information.\r
	sta	argblk+1	;Save the number of arguments.\r
	mvi	a,'Y'		;Acknowledge packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	ret\r
\r
rfile2:	cpi	'Z'		;Is it an EOF packet?\r
	jnz	rfile3		; No, try next type.\r
	lda	oldtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	rfil21		;If not proceed.\r
	lxi	d,ermes6\r
	call	error3		;Move cursor and print an error message.\r
	jmp	abort		;Change the state to abort.\r
\r
rfil21:	call	tryagn\r
	ret\r
\r
rfile3:	cpi	'F'		;Start of file?\r
	jnz	rfil3b\r
	mov	c,a		;[MF]Save packet type\r
	lda	remtxt		;[MF]Doing a remote server command?\r
	ora	a		;[MF]...\r
	mov	a,c		;[MF]Restore packet type\r
	jnz	rfil3d		;[MF]If yes, same as x packet\r
	call	compp\r
	jnz	nak0		;No, NAK it and try again.\r
	call	countp\r
	mov	c,a		;[MF]\r
	lda	remtxt		;[MF]Doing a remote command?\r
	ora	a		;[MF]...\r
	mov	a,c		;[MF]\r
	jnz	rfil3a		;[MF]Yes, don't open a file\r
	call	gofil		;Get a file to write to, and init output buffer.\r
	jmp	abort\r
rfil3a:	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	call	ackp\r
	mvi	a,'D'		;Set the state to data receive.\r
	sta	state\r
	lda	czseen		;Check if we punted a file\r
	cpi	'Z'		;and didn't want any more\r
	rz			;If that was the request, keep telling other end\r
	xra	a		;Otherwise, clear flag (^X is only for one file)\r
	sta	czseen		;And store the flag back\r
	ret\r
\r
rfil3b:	cpi	'X'		;Start of 'file?' , but not a file?\r
	jnz	rfile4\r
rfil3d:	call	compp\r
	jnz	nak0		;No, NAK it and try again.\r
	call	countp\r
\r
	call	selcon		;[MF]Select Console\r
	lda	argblk+1	; get length\r
	ora	a		;[MF]Anything to write?\r
	jz	rfil3e		;[MF]No\r
	push	psw		;[MF]Yes, save character count\r
	mvi	e,'<'		;[MF]Write "<<" as in VMSKermit\r
	push	d		;[MF]...\r
	call	outcon		;[MF]...\r
	pop	d		;[MF]...\r
	call	outcon		;[MF]...\r
	pop	psw		;[MF]Restore character count\r
	lxi	h,data		; lets write the filename (?) to display\r
rfil3f:	push	psw		;[MF]Save loop counter\r
	mov	e,m		;[MF]Get character to write\r
	inx	h		;[MF]and increment character pointer\r
	push	h		;[MF]Save the pointer\r
	call	outcon		;[MF]Write character to display\r
	pop	h		;[MF]Restore pointer\r
	pop	psw		;[MF]and loop counter\r
	dcr	a		;[MF]Decrement the counter\r
	jnz	rfil3f		;[MF]Display entire filename\r
	mvi	e,'>'		;[MF]Put in ">>" as in VMSKermit\r
	push	d		;[MF]...\r
	call	outcon		;[MF]...\r
	pop	d		;[MF]...\r
	call	outcon		;[MF]...\r
	call	prcrlf		;[MF]New line\r
rfil3e:	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	call	ackp\r
	mvi	a,'D'		; expecting a D packet\r
	sta	state\r
	lda	czseen		;Check if we punted a file\r
	cpi	'Z'		;and didn't want any more\r
	rz			;If that was the request, keep telling other end\r
	xra	a		;Otherwise, clear flag (^X is only for one file)\r
	sta	czseen		;And store the flag back\r
	ret\r
\r
rfile4:	cpi	'B'		;End of transmission.\r
	jnz	rfile5\r
	call	compp\r
	jnz	nak0		;No, NAK it and try again.\r
	xra	a		;No data.  (Packet number already in argblk).\r
	sta	argblk+1\r
	mvi	a,'Y'		;Acknowledge packet.\r
	call	spack		;Send the packet.\r
	jmp	abort\r
	mvi	a,'C'		;Set the state to complete.\r
	sta	state\r
	ret\r
\r
rfile5:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	call	error\r
	jmp	abort\r
;\f\r
;       Receive data\r
;       called by: read\r
\r
rdata:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	rdata1\r
	lxi	d,erms10\r
	call	error3		;Display error message.\r
rdat16:	lda	remtxt		;[MF]Is a Remote command in progress?\r
	ora	a		;[MF]...\r
	jnz	abort		;[MF]Yes, don't worry about file disposition\r
	lda	incflg		;[MF]Are we keeping incomplete files?\r
	ora	a		;[MF]...\r
	jnz	rdat17		;[MF]Yes\r
	lxi	d,fcb		;[MF]No, close the file, ignoring errors\r
	push	d		;[MF]while protecting the pointer\r
	mvi	c,closf		;[MF]...\r
	call	bdos		;[MF]...\r
	pop	d		;[MF]Now delete the file, ignoring errors\r
	mvi	c,delf		;[MF]...\r
	call	bdos		;[MF]...\r
	jmp	abort		;Change the state to abort.\r
rdat17:	call	clofil		;[MF]Try to close the file, writing\r
				;[MF]outstanding buffers to disk\r
	jmp	rdat37		;[MF]We can't, the disk is full\r
	jmp	abort		;[MF]Change the state to "abort"\r
\r
rdata1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	call	rpack		;Get a packet.\r
	jmp	nak		; Trashed packet: nak, retry.\r
	cpi	'D'		;Is it a data packet?\r
	jnz	rdata2		; No, try next type.\r
	call	compp		;check for correct packet number (zero flag = ok)\r
	jz	rdat14		;its correct\r
	lda	oldtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	rdat12		;If not proceed.\r
	lxi	d,erms10\r
	call	error3		;Display err msg.\r
	jmp	rdat16		;[MF]Change the state to abort.\r
\r
rdat12:	call	tryagn\r
	ret\r
\r
rdat14:	call	countp\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	lda	argblk+1	;Get the length of the data.\r
	call	ptchr\r
	jmp	rdat3b		;[MF] Unable to write out chars;abort.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	sta	argblk+1	;No data.  (Packet number still in argblk.)\r
	mov	c,a		;Assume no data\r
	lda	czseen		;Check if control-X typed\r
	ora	a		; .  .  .\r
	jz	rdat15		;Zero if not typed\r
	mov	c,a		;Get the type of character typed\r
	mvi	a,1		;One data character\r
	sta	argblk+1	;Save the count\r
	mov	a,c		;Get the possible data character\r
	sta	data		;Store in data area\r
rdat15:	mvi	a,'Y'		;Acknowledge packet.\r
	call	spack		;Send the packet.\r
	jmp	rdat16		;[MF]\r
	ret\r
\r
rdata2:	cpi	'F'		;Start of file?\r
	jnz	rdata3		; No, try next type.\r
	lda	oldtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	rdat21		;If not proceed.\r
	lxi	d,ermes5\r
	call	error3		;Display err msg.\r
	jmp	rdat16		;[MF]Change the state to abort.\r
\r
rdat21:	call	tryagn\r
	ret\r
\r
rdata3:	cpi	'Z'		;Is it a EOF packet?\r
	jnz	rdata4		;Try and see if its an error.\r
	call	compp\r
	jnz	nak0		;No, NAK it and try again.\r
	call	countp\r
	lda	argblk+1	;Get the data length\r
	cpi	1		;Have one item?\r
	jnz	rdat33		;If not, ignore data\r
	lda	data		;Yes, get the character\r
	cpi	'D'		;Is it a 'D' for discard?\r
	jz	rdat36		;If so, punt file\r
rdat33:	lda	remtxt		;[MF]Writing text to disk?\r
	ora	a		;[MF]...\r
	  jnz	rdat38		;[MF]No, don't close file\r
	call	clofil		;Finish off the file.\r
	jmp	rdat37		; Give up if the disk is full.\r
rdat38:	xra	a		;Since we kept the file,\r
	sta	czseen		;don't say it was discarded.\r
	lda	numtry		;Get the number of tries. [MF]\r
	sta	oldtry		;Save it. [MF]\r
	call	ackp		;[MF]\r
	jmp	rdat39		;[MF]and get ready to get more files\r
rdat36:	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	call	ackp\r
	lda	remtxt		;[MF]Is a Remote command in progress?\r
	ora	a		;[MF]...\r
	jnz	rdat39		;[MF]Yes, don't worry about file disposition\r
	lda	dscflg		;[MF]Is the file being punted because\r
	ora	a		;[MF]of a collision?\r
	jnz	rdat39		;[MF]Yes, don't delete the existing file\r
	lda	incflg		;[MF]No, are we keeping incomplete files?\r
	ora	a		;[MF]...\r
	jnz	rdat3a		;[MF]Yes\r
	lxi	d,fcb		;[MF]No, close the file,\r
	mvi	c,closf		;[MF]ignoring errors\r
	push	d		;[MF]...\r
	call	bdos		;[MF]...\r
	pop	d		;[MF]Now delete the file,\r
	mvi	c,delf		;[MF]ignoring errors\r
	call	bdos		;[MF]...\r
	jmp	rdat39		;[MF]and continue\r
rdat3a:	call	clofil		;[MF]Try to close the file, writing\r
				;[MF]outstanding buffers to disk\r
	jmp	rdat37		;[MF]Can't, disk is full\r
rdat39:	mvi	a,'F'\r
	sta	state\r
	ret\r
\r
rdat37:	call	ptchr9		; Send "?Disk full" on the error line [MF]\r
				; and to the remote Kermit [MF]\r
rdat3b:	lda	remtxt		;[MF]Doing a Remote command?\r
	ora	a		;[MF]...\r
	jnz	abort		;[MF]Yes, just abort\r
	lxi	d,fcb		;[MF]Close the file, ignoring errors\r
	push	d		;[MF]Protect fcb pointer\r
	mvi	c,closf		;[MF]...\r
	call	bdos		;[MF]...\r
	pop	d		;[MF]Restore pointer\r
	lda	incflg		;[MF]Are we keeping incomplete files?\r
	ora	a		;[MF]...\r
	jnz	abort		;[MF]Yes, just abort transfer\r
	mvi	c,delf		;[MF]No, delete the file, ignoring errors\r
	call	bdos		;[MF]...\r
	jmp	abort		;[MF] abort transfer\r
\r
rdata4:	cpi	'E'		;Is it an error packet.\r
	jnz	rdat16		;[MF]\r
	call	error\r
	jmp	rdat16		;[MF]\r
;\f\r
;       SEND command\r
;       here from: kermit\r
\r
send:	mvi	a,cmifi		;Parse an input file spec.\r
	lxi	d,fcb		;Give the address for the FCB.\r
	call	comnd\r
	jmp	kermit		; Give up on bad parse.\r
;       section to get remote filename [gnn]\r
	lxi	d,remnam	;[gnn] where to put filename\r
	mvi	a,cmtxt		;[gnn] \r
	call	comnd		;[gnn] get the text to end of the line\r
	jmp	kermt3		;[gnn] failure in reading buffer\r
	sta	remlen		;[gnn] save length (may be zero)\r
;\r
	xra	a\r
	sta	mfflg1		; clear flags...\r
	sta	mfflg2\r
	sta	mfflg3		;[gnn]\r
	sta	fcbcnt		;[gnn] clear fcbcount\r
	lxi	h,fcb0		;[gnn] and fcb pointer\r
	shld	xfcbptr\r
;\r
	call	mfname		;handle (multi) files\r
	jnc	send14		;got a valid file-name\r
	lxi	d,erms15\r
	call	prtstr		;Display error msg. ([hh] where it's visible)\r
	jmp	kermit\r
\r
send14:	call	init		;Clear the line and initialize the buffers.\r
	xra	a\r
	sta	pktnum		;Set the packet number to zero.\r
	sta	numtry		;Set the number of tries to zero.\r
	sta	wrn8		;[jd] we haven't sent the 8-bit-lost warning\r
	lxi	h,0\r
	shld	numpkt		;Set the number of packets to zero.\r
	shld	numrtr		;Set the number of retries to zero.\r
	lda	quietd		; a quiet display?\r
	ana	a\r
	jnz	send15		; yup, dont write\r
	call	scrnrt		;Position cursor\r
	lxi	h,0\r
	call	nout		;Write the number of retries.\r
send15:	mvi	a,'1'		;Reset to use single character checksum\r
	sta	curchk		;For startup\r
	mvi	a,'S'\r
	sta	state		;Set the state to receive initiate.\r
	;...\r
;\f\r
;SEND state table switcher\r
\r
send2:	lda	quietd		; a quiet display?\r
	ana	a\r
	jnz	send21		; yes, so dont write\r
	call	scrnp		;Position cursor\r
	lhld	numpkt\r
	call	nout		;Write the packet number.\r
send21:	lda	state		;Get the state.\r
	cpi	'D'		;Are we in the data send state?\r
	jnz	send3\r
	call	sdata\r
	jmp	send2\r
\r
send3:	cpi	'F'		;Are we in the file send state?\r
	jnz	send4\r
	call	sfile		;Call send file.\r
	jmp	send2\r
\r
send4:	cpi	'Z'		;Are we in the EOF state?\r
	jnz	send5\r
	call	seof\r
	jmp	send2\r
\r
send5:	cpi	'S'		;Are we in the send initiate state?\r
	jnz	send6\r
	call	sinit\r
	lda	state		;[jd] get state back\r
	cpi	'F'		;[jd] into file send state yet?\r
	jnz	send2		;[jd] no\r
	lxi	d,inms23	;[jd] yes, print sending...\r
	call	finmes		;[jd] \r
	jmp	send2\r
\r
send6:	cpi	'B'		;Are we in the eot state?\r
	jnz	send7\r
	call	seot\r
	jmp	send2\r
\r
send7:	cpi	'C'		;Are we in the send complete state?\r
	jnz	send8		;No...\r
	lxi	d,infms3	;Yes, write "Complete" message.\r
	lda	czseen		;Or was it interrupted?\r
	ora	a		; .  .  .\r
	jz	send7a		;No.\r
	lxi	d,inms13	;Yes, then say "Interrupted" instead.\r
send7a:	call	finmes\r
	jmp	kermit\r
\r
send8:	cpi	'A'		;Are we in the send "abort" state?\r
	jnz	send9\r
	lxi	d,infms4	;Print  message.\r
	call	finmes\r
	jmp	kermit\r
\r
send9:	lxi	d,infms4	;Anything else is equivalent to "abort".\r
	call	finmes\r
	jmp	kermit\r
;\f\r
;       Send routines\r
\r
;       Send initiate\r
;       called by: send\r
\r
sinit:	lda	numtry		;Get the number of tries.\r
	cpi	imxtry		;Have we reached the maximum number of tries?\r
	jm	sinit2\r
	lxi	d,erms14\r
	call	error3		;Display ermsg\r
	jmp	abort		;Change the state to abort.\r
\r
sinit2:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	mvi	a,'1'		;Reset to use single character checksum\r
	sta	curchk		;For startup\r
	lda	chktyp		;Get our desired block check type\r
	sta	inichk		;Store so we tell other end\r
	lxi	h,data		;Get a pointer to our data block.\r
	call	rpar		;Set up the parameter information.\r
	sta	argblk+1	;Save the number of arguments.\r
	lda	numpkt		;Get the packet number.\r
	sta	argblk\r
	lda	state		; load state (I or S)\r
\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	call	rpack		;Get a packet.\r
	jmp	r		; Trashed packet don't change state, retry.\r
	cpi	'Y'		;ACK?\r
	jnz	sinit3		;If not try next.\r
	call	compp		;compare packets. If ok, zero flag set\r
	rnz			;If not try again.\r
	call	countp		;increment packet number modulo 64\r
	lda	argblk+1	;Get the number of pieces of data.\r
	lxi	h,data		;Pointer to the data.\r
	call	spar		;Read in the data. (decode what they want)\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	lda	state		; se if S or I state\r
	cpi	'I'		; I state, so set X as next state\r
	jnz	sinita\r
sinitb:	mvi	a,'X'\r
	sta	state\r
	ret\r
\r
sinita:	lda	inichk		;Get the agreed upon block check type\r
	sta	curchk		;Store as type to use for packets now\r
	mvi	a,'F'		;Set the state to file send. (Assumed)\r
	sta	state\r
	call	getfil		;Open the file.\r
	ret			; assume success; mfname thinks the file exists.\r
\r
sinit3:	cpi	'N'		;NAK?\r
	jnz	sinit4		;If not see if its an error.\r
	call	updrtr		;Update the number of retries.\r
	lda	pktnum		;Get the present packet number.\r
	inr	a		;Increment\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number.\r
	cmp	b		;Is the packet's number one more than now?\r
	rnz			;If not assume its for this packet, go again.\r
	xra	a\r
	sta	numtry		;Reset number of tries.\r
	mvi	a,'F'		;Set the state to file send.\r
	sta	state\r
	ret\r
\r
sinit4:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	lda	state		;[MF]Get state\r
	cpi	'I'		;[MF]If an "I" packet was sent,\r
	jz	sinitb		;[MF]Ignore the error, pretend success\r
	call	error		;[MF]else display the error info\r
	jmp	abort		;[MF]and abort\r
;\f\r
;       Send file header\r
;       called by: send\r
;[5a] Question [majoc]: Why could not the filename\r
;     parsing have been done by comnd, like all the rest?\r
\r
sfile:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	sfile1\r
	lxi	d,erms14\r
	call	error3\r
	jmp	abort		;Change the state to abort.\r
\r
sfile1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	xra	a		;Clear A\r
	sta	czseen		;No control-Z or X seen\r
	lxi	h,data		;Get a pointer to our data block.\r
	shld	datptr		;Save it.\r
; use remote name if given, else use local name [gnn]\r
	lda	remlen		;[gnn] anything given?\r
	ora	a		;[gnn] \r
	jnz	sfile4		;[gnn] use remote name\r
\r
	lxi	h,fcb+1		;Pointer to the file name in the FCB.\r
	shld	fcbptr		;Save position in FCB.\r
	mvi	b,0		;No chars yet.\r
	mvi	c,0\r
sfil11:	mov	a,b\r
	cpi	8H		;Is this the ninth char?\r
	jnz	sfil12		;If not proceed.\r
	mvi	a,'.'		;Get a dot.\r
	lhld	datptr\r
	mov	m,a		;Put the char in the data packet.\r
	inx	h\r
	shld	datptr		;Save position in data packet.\r
	inr	c\r
sfil12:	inr	b		;Increment the count.\r
	mov	a,b\r
	cpi	0CH		;Twelve? \r
	jp	sfil13\r
	lhld	fcbptr\r
	mov	a,m\r
	ani	7fH		;Turn off CP/M 2 or 3's high bits.\r
	inx	h\r
	shld	fcbptr		;Save position in FCB.\r
	cpi	'!'		;Is it a good character?\r
	jm	sfil11		;If not get the next.\r
	lhld	datptr\r
	mov	m,a		;Put the char in the data packet.\r
	inx	h\r
	shld	datptr		;Save position in data packet.\r
	inr	c\r
	jmp	sfil11		;Get another.\r
\r
sfil13:	mov	a,c		;Number of char in file name.\r
	sta	argblk+1\r
	lhld	datptr\r
	mvi	a,'$'\r
	mov	m,a		;Put in a dollar sign for printing.\r
	lda	quietd		; a quiet display\r
	ana	a\r
	jnz	sfi13a		; yes, dont write\r
	call	scrfln		;Position cursor\r
sfi13a:	lxi	d,data		;Print the file name though, in either case\r
	call	prtstr\r
	lda	pktnum		;Get the packet number.\r
	sta	argblk\r
	mvi	a,'F'		;File header packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	call	rpack		;Get a packet.\r
	jmp	r		; Trashed packet don't change state, retry.\r
	cpi	'Y'		;ACK?\r
	jnz	sfile2		;If not try next.\r
	call	compp\r
	rnz			;If not hold out for the right one.\r
sfil14:	call	countp\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	sta	bytes		;[10] clear the "bytes transferred" counter\r
	sta	bytes+1		;[10]\r
	sta	bytes+2		;[10]\r
	sta	bytes+3		;[10]\r
	call	gtchr		;Fill the first data packet\r
	jmp	sfil16		;Error go see if its EOF.\r
;                              	;Got the chars, proceed.\r
	sta	size		;Save the size of the data gotten.\r
	mvi	a,'D'		;Set the state to data send.\r
	sta	state\r
	ret\r
\r
sfil16:	cpi	0FFH		;Is it EOF?\r
	jnz	abort		;If not give up.\r
	mvi	a,'Z'		;Set the state to EOF.\r
	sta	state\r
	ret\r
\r
sfile2:	cpi	'N'		;NAK?\r
	jnz	sfile3		;Try if error packet.\r
	call	updrtr		;Update the number of retries.\r
	lda	pktnum		;Get the present packet number.\r
	inr	a		;Increment\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number.\r
	cmp	b		;Is the packet's number one more than now?\r
	rnz			;If not go try again.\r
	jmp	sfil14		;Just as good as a ACK;go to the ACK code.\r
\r
sfile3:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	call	error\r
	jmp	abort\r
\r
; copy remote name into packet to send [gnn]\r
sfile4:	xchg			;[gnn] keep pointer to packet\r
	lxi	h,remnam	;[gnn] set pointer to name\r
	mov	c,a		;[gnn] keep count of length\r
	mov	b,a		;[gnn] and set as loop counter\r
sfil41:	mov	a,m		;[gnn] get a character\r
	stax	d		;[gnn] copy it to packet\r
	inx	h		;[gnn] \r
	inx	d		;[gnn] move pointers\r
	dcr	b		;[gnn] \r
	mov	a,b		;[gnn] \r
	ora	a		;[gnn] done them all?\r
	jnz	sfil41		;[gnn] repeat until done\r
	xchg			;[gnn] get final position\r
	shld	datptr		;[gnn] and save it\r
	jmp	sfil13		;[gnn] now go and send packet\r
\r
;\f\r
;       Send data\r
;       called by: send\r
\r
sdata:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	sdata1\r
	lxi	d,erms14\r
	call	error3\r
	jmp	abort		;Change the state to abort.\r
\r
sdata1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	lxi	h, data		;Get a pointer to our data block.\r
	shld	datptr		;Save it.\r
	lxi	h,filbuf	;Pointer to chars to be sent.\r
	shld	cbfptr		;Save position in char buffer.\r
	mvi	b,1		;First char.\r
sdat11:	lhld	cbfptr\r
	mov	a,m\r
	inx	h\r
	shld	cbfptr		;Save position in char buffer.\r
	mov	c,a		;[jd] preserve character temporarily\r
	lda	quot8		;[jd] doing eighth-bit quoting?\r
	ora	a		;[jd] \r
	mov	a,c		;[jd] restore char\r
	jnz	sdat4		;[jd] using eighth-bit quoting, no warning\r
	lda	parity		;[jd] get parity\r
	cpi	parnon		;[jd] none?\r
	mov	a,c		;[jd] restore character\r
	jz	sdat4		;[jd] no parity, leave char alone\r
	lda	wrn8		;[jd] look at warning flag\r
	ora	a		;[jd] have we already given the warning?\r
	jnz	sdat5		;[jd] yes, skip this\r
	mov	a,c		;[jd] restore character...\r
	ani	80h		;[jd] examine parity\r
	jz	sdat5		;[jd] no parity, no warning.\r
	call	parwrn		;[jd] ...print warning - parity lost\r
	mvi	a,0ffh		;[jd] remember that we sent the message\r
	sta	wrn8		;[jd]\r
sdat5:	mov	a,c		;[jd] restore character again\r
	ani	7fh		;[jd] strip parity so not checksummed\r
sdat4:	lhld	datptr\r
	mov	m,a		;Put the char in the data packet.\r
	inx	h\r
	shld	datptr		;Save position in data packet.\r
	inr	b		;Increment the count.\r
	lda	size		;Get the number of chars in char buffer.\r
	cmp	b		;Have we transfered that many?\r
	jp	sdat11		;If not get another.\r
	lda	size		;Number of char in char buffer.\r
	sta	argblk+1\r
	lda	pktnum		;Get the packet number.\r
	sta	argblk\r
	mvi	a,'D'		;Data packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	call	rpack		;Get a packet.\r
	jmp	r		; Trashed packet don't change state, retry.\r
	cpi	'Y'		;ACK?\r
	jnz	sdata2		;If not try next.\r
	call	compp\r
	rnz			;If not hold out for the right one.\r
	lda	argblk		;Get the packet number back\r
	call	countp\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	lda	argblk+1	;Get the data length\r
	cpi	1		;Check if only 1 character?\r
	jnz	sdat15		;If not, just continue\r
	lda	data		;Got one character, get it from data\r
	cpi	'Z'		;Want to abort entire stream?\r
	jnz	sdat14		;If not, check for just this file\r
	sta	czseen		;Yes, remember it\r
	jmp	sdat16		;[MF] and set EOF state\r
sdat14:	cpi	'X'		;Desire abort of current file?\r
	jnz	sdat15		;If not, just continue\r
	sta	czseen		;Yes, remember that\r
	jmp	sdat16		;[MF] and set EOF\r
sdat15:	lda	czseen		;Also get control-Z flag\r
	ora	a		;Check if either given\r
	jz	sdat12		;If neither given, continue\r
sdat16:	mvi	a,'Z'		;Change state to EOF\r
	sta	state		; .  .  .\r
	ret			;And return\r
\r
sdat12:	call	gtchr\r
	jmp	sdat13		;Error go see if its EOF.\r
	sta	size		;Save the size of the data gotten.\r
	ret\r
\r
sdat13:	cpi	0FFH		;Is it EOF?\r
	jnz	abort		;If not give up.\r
	mvi	a,'Z'		;Set the state to EOF.\r
	sta	state\r
	ret\r
\r
sdata2:	cpi	'N'		;NAK?\r
	jnz	sdata3		;See if is an error packet.\r
	call	updrtr		;Update the number of retries.\r
	lda	pktnum		;Get the present packet number.\r
	inr	a		;Increment\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number.\r
	cmp	b		;Is the packet's number one more than now?\r
	rnz			;If not go try again.\r
	jmp	sdat12		;Just as good as a ACK;go to the ACK code.\r
\r
sdata3:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	call	error\r
	jmp	abort\r
;\f\r
;       Send EOF\r
;       called by: send\r
\r
seof:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	seof1\r
	lxi	d,erms14\r
	call	error3\r
	jmp	abort		;Change the state to abort.\r
\r
seof1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	lda	pktnum		;Get the packet number.\r
	sta	argblk\r
	xra	a\r
	sta	argblk+1	;No data.\r
	lda	czseen		;Check if C-Z or C-X typed\r
	ora	a		; .  .  .\r
	jz	seof14		;If not aborted, just keep going\r
	mvi	a,'D'		;Tell other end to discard packet\r
	sta	data		;Store in data portion\r
	mvi	a,1		;One character\r
	sta	argblk+1	;Store the length\r
seof14:	mvi	a,'Z'		;EOF packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	call	rpack		;Get a packet.\r
	jmp	r		; Trashed packet don't change state, retry.\r
	cpi	'Y'		;ACK?\r
	jnz	seof2		;If not try next.\r
	call	compp\r
	rnz			;If not hold out for the right one.\r
seof12:	call	countp\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	mvi	c,closf		;Close the file.\r
	lxi	d,fcb\r
	call	bdos\r
;* Check if successful\r
	lda	czseen		;Desire abort of entire stream?\r
	cpi	'Z'		;Desire abort of entire stream?\r
	jz	seof13		;If so, just give up now\r
	call	mfname		;Get the next file.\r
	jc	seof13		; No more.\r
	call	getfil		;and open it (assume success)\r
	xra	a		;Clear A\r
	sta	czseen		;Since we have not aborted this file\r
	mvi	a,'F'		;Set the state to file send.\r
	sta	state\r
	ret\r
\r
seof13:	mvi	a,'B'		;Set the state to EOT.\r
	sta	state\r
	ret\r
\r
seof2:	cpi	'N'		;NAK?\r
	jnz	seof3		;Try and see if its an error packet.\r
	call	updrtr		;Update the number of retries.\r
	lda	pktnum		;Get the present packet number.\r
	inr	a		;Increment\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number.\r
	cmp	b		;Is the packet's number one more than now?\r
	rnz			;If not go try again.\r
	jmp	seof12		;Just as good as a ACK;go to the ACK code.\r
\r
seof3:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	call	error\r
	jmp	abort\r
;\f\r
;       Send EOT\r
;       called by: send\r
\r
seot:	lda	numtry		;Get the number of tries.\r
	cpi	maxtry		;Have we reached the maximum number of tries?\r
	jm	seot1\r
	lxi	d,erms14\r
	call	error3\r
	jmp	abort		;Change the state to abort.\r
\r
seot1:	inr	a		;Increment it.\r
	sta	numtry		;Save the updated number of tries.\r
	lda	pktnum		;Get the packet number.\r
	sta	argblk\r
	xra	a\r
	sta	argblk+1	;No data.\r
	mvi	a,'B'		;EOF packet.\r
	call	spack		;Send the packet.\r
	jmp	abort		; Failed, abort.\r
	call	rpack		;Get a packet.\r
	jmp	r		; Trashed packet don't change state, retry.\r
	cpi	'Y'		;ACK?\r
	jnz	seot2		;If not try next.\r
	call	compp\r
	rnz			;If not hold out for the right one.\r
seot12:	call	countp\r
	lda	numtry		;Get the number of tries.\r
	sta	oldtry		;Save it.\r
	xra	a\r
	sta	numtry		;Reset the number of tries.\r
	mvi	a,'C'		;Set the state to file send.\r
	sta	state\r
	ret\r
\r
seot2:	cpi	'N'		;NAK?\r
	jnz	seot3		;Is it error.\r
	call	updrtr		;Update the number of retries.\r
	lda	pktnum		;Get the present packet number.\r
	inr	a		;Increment\r
	ani	3FH		; modulo 64\r
	mov	b,a\r
	lda	argblk		;Get the packet's number.\r
	cmp	b		;Is the packet's number one more than now?\r
	rnz			;If not go try again.\r
	jmp	seot12		;Just as good as a ACK;go to the ACK code.\r
\r
seot3:	cpi	'E'		;Is it an error packet.\r
	jnz	abort\r
	call	error\r
	jmp	abort\r
;\f\r
;       This routine sets up the data for init packet (either the\r
;       Send_init or ACK packet).\r
;       called by: rinit, rfile, sinit\r
;\r
; Called by rinit, rfile and sinit.  See what WE want from the other fella\r
;\r
; [11] by OBS - Stripped out all the new capas code etc and reverted\r
;	to Good Ol' Basic Kermit again!\r
;	Those keen should study the followin gode with care, and remove\r
;	or add semicolons as indicated.\r
;\r
; See also SPAR which decodes what comes in.  It also decodes bits in \r
;	the "capability" fields.  (Two CAPAS files allowed from remote\r
;	machines, but we will only send one at max.)  Note that not all \r
;	if any of the capability bits will be used.\r
;\r
; Definitions - init packet (data section only.. rest of header assumed OK)\r
;	Byte 0	Maximum length I want to send\r
;	     1	The Timeout I want you to use\r
;	     2	Number of PAD characters I want tot use (May be null)\r
;	     3	The PAD character I want to use (May be Null)\r
;	     4	The End-of-Line character I will use (Carriage Return)\r
;	     5	The control character Quote Character I will use (#)\r
;	     6	The parity bit Quote Character I will use (&)\r
;	     7	The Checktype I will use\r
;	     8	The repeat prefix I will use (Null, as we cannot to repeats)\r
;	     9	Capability Byte 0 (See SPAR for defs)\r
;	    10	Capability byte 1 ( --- " --- but we will not send it.)\r
;	    11	The number of packets I will send per window (not used)\r
;	    12  MAXL1 - Long packet size, ms count\r
;	    13	MAXL2 - Long packet size, ls count\r
;\r
;\r
; Enter with HL pointing to the "data" part of the packet.\r
\r
;\r
; older part of rpar follows...\r
;\r
;\r
rpar:	lda	rpsiz		;Get the receive packet size.\r
	adi	space		;Add a space to make it printable.\r
	mov	m,a		;Put it in the packet.\r
	inx	h		;Point to the next char.\r
	lda	rtime		;Get the receive packet time out.\r
	adi	space		;Add a space.\r
	mov	m,a		;Put it in the packet.\r
	inx	h\r
	lda	rpad		;Get the number of padding chars.\r
	adi	space\r
	mov	m,a\r
	inx	h\r
	lda	rpadch		;Get the padding char.\r
	adi	100O		;Uncontrol it.\r
	ani	7FH\r
	mov	m,a\r
	inx	h\r
	lda	reol		;Get the EOL char.\r
	adi	space\r
	mov	m,a\r
	inx	h\r
	lda	rquote		;Get the quote char.\r
	mov	m,a\r
	inx	h\r
	mvi	m,'Y'		;[jd] we know how to do 8-bit quoting\r
	lda	parity		;[jd]\r
	cpi	parnon		;[jd] parity none?\r
	jz	rpar1		;[jd] yes, keep going\r
	lda	qbchr		;[jd] no, better request 8-bit quoting\r
	mov	m,a\r
\r
rpar1:\r
	inx	h		;Advance to next\r
	lda	chktyp		;Get desired block check type\r
	mov	m,a		;Store it\r
	inx	h		;Advance pointer\r
\r
; Comment out the next two lines for capas etc.  WILL require debugging\r
	mvi	a,8		; this id the older end for this routine.  May be useful.\r
	ret\r
\r
; [11] Rest not needed for now, commented out\r
; [10] (to ret)\r
; New additions to rpar follows...\r
\r
;	lda	rcap1		; get the first capability byte\r
;	ani	3eh		; mask out bit 0, ie only one CAPAS byte\r
;	adi	space		; tochar it\r
;	mov	m,a\r
;	inx	h\r
;	mvi	m,space		; No windows, ie space to packet\r
;	inx	h\r
;	push	h		; we need the HL regs for maths.\r
;	lhld	rdpkt		; get receive packet length\r
;	lxi	d,95		; we want hl div 95 and hl mod 95\r
;	call	divide		; return with divsion in hl, remainder in de\r
;	mov	a,l		; two sets of bytes\r
;	pop	h\r
;	adi	space		; tochar(maxl1)\r
;	mov	m,a\r
;	inx	h\r
;	mov	a,l\r
;	adi	space		; tochar(maxl2)\r
;	mov	m,a\r
;\r
; done all, set databytes = 12 and return\r
;	mvi	a,12		; 12 bits of data\r
;	ret\r
\r
;[11] End of commented out code for rpar\r
\r
\r
;\f\r
;       This routine reads in all the send_init packet information.\r
;       called by: rinit, sinit\r
\r
;[11] As for rpar, restore the "old" kermit code for non-capas Kermit.\r
;[10] (to ret at end)\r
;\r
; SPAR - routine to decode parameters received from the remote end\r
;\r
;	Called by rinit,sinit\r
;\r
;	Entry:	a: Number of databytes in packet\r
;		hl: Pointer to "data" part of packet\r
;\r
;spar:	sta	temp4		; save for a while\r
;				; first clear some variables\r
;	lda	dspsiz		; get default "send" packet length\r
;	sta	spktl\r
;	lda	dstime		; get default time-out\r
;	sta	stimeo\r
;	xra	a		; set no pad characters by default\r
;	sta	spad\r
;	lda	dspadc		; get the default padding character\r
;	sta	spadc\r
;	mvi	a,cr		; default end of line character (CR)\r
;	sta	seol\r
;	mvi	a,dsquot	; default quote character\r
;	sta	squote\r
;	mvi	a,dsbqut	; default binary quote character\r
;	sta	qbchr\r
;	mvi	a,dschkt	; set checktype = 1 for inits\r
;	sta	inichk\r
;	mvi	a,space		; no repeat prefixing ( otherwise ~)\r
;	sta	srept\r
;\r
; Now follows the "capabilities" bits... 5 bits per capas byte.\r
;\r
; 	Note: Before extracting any data bits, apply unchar() to get the \r
;	six ls bits.  If bit 0 = 1 the a subsequent capaa byte follows\r
;\r
;	Byte0:	Bit 0:	Set to 1 if there are subsequent CAPAS bytes\r
;		    1:	(Cap. 5) Set to 1 for long packets.  Second byte\r
;			AFTER the last capas byte has packet length DIV 95\r
;			and Thire byte has length MOD 95\r
;		    2:	(Cap. 4) Sliding Windows.  If used, first byte AFTER\r
;			last capas byte has TOCHAR(no. of packets in window)\r
;		    3:	(Cap. 3) Ability to accept "A" (attribute packets)\r
;		    4:	(Cap. 2) Reserved\r
;		    5:	(Cap. 1) Reserved\r
;	Byte 2 onward: not used in this implementation. Any capas bytes sent \r
;		will be stored, however.\r
;\r
;	lda	temp4		; get the number of bytes to test\r
;	mov	c,a		; to a count register\r
;	mov	a,m		; get first byte\r
;	call	decc		; unchar it, and decrement c\r
;	sta	spsiz		; save a send packet size\r
;	jz	sparx		; if no more, exit\r
;\r
;	mov	a,m		; get timout\r
;	call	decc\r
;	sta	stime		; save timeout\r
;	jz	sparx\r
;\r
;	mov	a,m		; get pad characters\r
;	call	decc	\r
;	sta	spadc		; save it\r
;	jz	sparx\r
;\r
;	mov	a,m		; get pad character count\r
;	call	decc\r
;	sta	spad\r
;	jz	sparx\r
;\r
;	mov	a,m		; get send EOL\r
;	call	decc\r
;	sta	seol\r
;	jz	sparx\r
;\r
;	mov	a,m		; get control quote character\r
;	call	decc\r
;	sta	squote\r
;	jz	sparx\r
;\r
;	mov	a,m		; get binary (parity) quote char\r
;	mov	b,a		; this time we actually WANT accumulator\r
;	cpi	space		; are we doing 8th bit quoteing\r
;	jz	spar1		; dont know, assume not\r
;	cpi	'N'		; definately not?\r
;	jz	spar1\r
;	cpi	'Y'		; definately - use &\r
;	jz	spar2\r
;	sta	squote		; else save the new character\r
;spar2:	lda	parity		; see if we are using the parity bit\r
;	cpi	parnon		; no parity => no quoting\r
;	jz	spar3		; yup, so use the default quote character &\r
;\r
;spar1:	xra	a		; save not quoting\r
;	sta	squote\r
;spar3:	call	decc		; update counters etc\r
;	jz	sparx\r
;\r
;	mov	a,m		; get repeat prefixing\r
;	call	decc\r
;	push	psw		; save flags\r
;	cpi	space-32	; we want it?\r
;	jz	spar4\r
;	sta	srept\r
;spar4:	pop	psw		; restore flags\r
;	jz	sparx\r
;\r
;	lxi	d,scapas	; point to start of capability byte(s)\r
;	push	psw		; must do this...\r
;spar5:	pop	psw		; cos we restore the spack\r
;	mov	a,m\r
;	call	decc		; get scap1 (or n)\r
;	sta	scap1\r
;	push	psw\r
;	ani	01		; another byte following?\r
;	jnz	spar5\r
;	pop	psw		; see if any other data bytes (Windows etc)\r
;	jz	sparx\r
;\r
;	mov	a,m		; get window size\r
;	call	decc\r
;	sta	swindo\r
;	jz	sparx\r
;\r
;	mov	a,m		; get long packets ms bits\r
;	call	decc		;\r
;	mov	d,a		; unchared ms bits-ish\r
;	mov	a,m\r
;	call	decc		; ls bits-ish\r
;	push	h		; and we are doing maths\r
;	push	b		; and an intermediate result in c\r
;	push	psw		; we want flags  and the ls bits...\r
;	mvi	b,0\r
;	mov	c,d		; get ms bits-ish to bc\r
;	push	b		; get number to hl\r
;	pop	h\r
; now multipy by 95\r
;	dad	h		;*2\r
;	dad	h		;*4\r
;	dad	h		;*8\r
;	dad	h		;*16\r
;	push	h		; *16 to ...\r
;	pop	d		; ... de\r
;	dad	h		;*32\r
;	dad	d		; *(32+16) = *48\r
;	dad	h		; *96\r
;	mov	a,l		; *(96-1)\r
;	sub	c\r
;	mov	l,a\r
;	mov	a,0\r
;	sbb	h\r
;	mov	h,a\r
;	pop	psw		; restore ls bitsish\r
;	mov	e,a\r
;	mvi	d,0\r
;	dad	d		; *95 + ls bits. Phew.\r
;	shld	sdpkt		; save long packet length\r
;	pop	b\r
;	pop	h		; restore regs\r
;\r
;sparx:	ret			; if here, (assume) no more data to read in\r
;[10] routines required follow\r
;decc:	mov	a,m		; get data byte\r
;	sui	space		; unchar it\r
;	inx	h		; increment input pointer\r
;	dcr	c		; decrement data counter\r
;	ret			; return\r
;[10] end or spar replacement\r
\r
;[11] Restore older spar....\r
; Older spar follows...\r
spar:	sta	temp4		;Save the number of arguments.\r
; Initialize some variables to their required default values, so we use\r
; the right values even if the remote Kermit doesn't send the full packet:\r
;                              	; we don't do anything with timeout values yet.\r
;                              	; no default pad count/pad character?\r
	mvi	a,cr		; EOL character = carriage-return\r
	sta	seol\r
	mvi	a,'#'		; quote character = '#'\r
	sta	squote\r
	mvi	a,'&'		; eighth-bit quote character = '&'\r
	sta	qbchr\r
	mvi	a,'1'		; block-check = 1-character-checksum\r
	sta	inichk\r
; \r
	mov	a,m		;Get the max packet size.\r
	sbi	space		;Subtract a space.\r
	sta	spsiz		;Save it.\r
	lda	temp4\r
	cpi	3		;Fewer than three pieces?\r
	rm			;If so we are done.\r
	inx	h\r
	inx	h		;Increment past the time out info.\r
	mov	a,m		;Get the number of padding chars.\r
	sbi	space\r
	sta	spad\r
	lda	temp4\r
	cpi	4		;Fewer than four pieces?\r
	rm			;If so we are done.\r
	inx	h\r
	mov	a,m		;Get the padding char.\r
	adi	100O		;Re-controlify it.\r
	ani	7FH\r
	sta	spadch\r
	lda	temp4\r
	cpi	5		;Fewer than five pieces?\r
	rm			;If so we are done.\r
	inx	h\r
	mov	a,m		;Get the EOL char.\r
	sbi	space\r
	sta	seol\r
	lda	temp4\r
	cpi	6		;Fewer than six pieces?\r
	rm			;If so we are done.\r
	inx	h\r
	mov	a,m		;Get the quote char.\r
	sta	squote\r
	lda	temp4		;Get the amount of data supplied\r
	cpi	7		;Have an 8-bit quote?\r
	rm			;If not there, all done\r
	inx	h		;Yes, get the character\r
	mvi	a,0		;[jd] \r
	sta	quot8		;[jd] assume not quoting\r
	mov	a,m		;Get the supplied character\r
	cpi	'N'		;[jd] No?\r
	jz	spar1		;[jd] then don't try to do it\r
	cpi	space		;[jd] maybe they don't know about it...\r
	jz	spar1		;[jd] then don't try to do it.\r
	cpi	'Y'		;[jd] Yes?\r
	jnz	spar2		;[jd] if not 'Y', assume it's a quote char.\r
	lda	parity		;[jd] using parity?\r
	cpi	parnon		;[jd] no, don't need quoting...\r
	jz	spar1		;[jd] \r
	mvi	a,0ffh		;[jd] else turn on...\r
	sta	quot8		;[jd] ...quote flag\r
	jmp	spar1\r
\r
;[11] Note: If capas etc required, beware of the next two lables, as these \r
; are used elswhere.\r
\r
spar2:	sta	qbchr		;[jd] use their quote char (should validate)\r
	mvi	a,0ffh\r
	sta	quot8		;[jd] turn quote flag and fall thru...\r
\r
spar1:	lda	temp4		;Determine if block check type given\r
	cpi	8		;Is the field there?\r
	rm			;If not, all done\r
	inx	h		;Point to the character\r
	mov	a,m		;Get the value\r
	mov	b,a		;Copy value\r
	lda	chktyp		;Get our type\r
	cmp	b		;Is it our desired type?\r
	rnz			; If not, use default (1-character-checksum)\r
	sta	inichk		; Match, store as type to use after init\r
	ret			; and return\r
;[10] end of replacement\r
;[11] end of replacement of replacement (ie back to original code)\r
;\f\r
\r
;       Copy characters from packet to disk (or screen)\r
;       called by: rdata\r
\r
ptchr:	sta	temp1		;Save the size.\r
	lda	remtxt		;[MF]Get remote command flag\r
	ora	a		;[MF]Remote command in progress?\r
	jnz	ptchr0		;[MF]Yes, don't check for file collisions\r
	lda	flwflg		;[MF]Get File Warning (Set Collision) flag\r
	cpi	3		;[MF]SET COLLISION DISCARD?\r
	jnz	ptchr0		;[MF]No\r
	lda	dscflg		;[MF]Yes, get "discard" flag\r
	ora	a		;[MF]Discarding file?\r
	jz	ptchr0		;[MF]No\r
	mvi	a,'X'		;[MF]Yes, simulate a user rejection\r
	sta	czseen		;[MF]...\r
	jmp	rskp		;[MF]and pretend success\r
ptchr0:				;[MF]\r
	lxi	h,data		;Beginning of received packet data.\r
	shld	outpnt		;Remember where we are.\r
	lda	rquote\r
	mov	b,a		;Keep the quote char in b.\r
	mvi	c,0		;[jd] assume no 8-bit quote char\r
	lda	quot8		;[jd] doing 8-bit quoting?\r
	ora	a\r
	jz	ptchr1		;[jd] no, keep going\r
	lda	qbchr		;[jd] else get 8-bit quote char\r
	mov	c,a		;[jd] keep this in c\r
ptchr1:	lxi	h,temp1\r
	dcr	m		;Decrement # of chars in packet.\r
	jm	rskp		;Return successfully if done.\r
	lda	remtxt		; to screen only?\r
	ana	a\r
	jnz	ptchr2		; dont do any disk stuff\r
	lxi	h,chrcnt	;Number of chars remaining in dma.\r
	dcr	m		;Decrement.\r
	jp	ptchr2		;Continue if space left.\r
	call	outbuf		;Output it if full.\r
	jmp	ptchr9		; Error return if disk is full.\r
ptchr2:	lhld	outpnt		;Get position in output buffer.\r
	mov	a,m		;Grab a char.\r
	inx	h\r
	shld	outpnt		;and bump pointer.\r
	mvi	e,0		;[jd] assume nothing to OR in.\r
	cmp	c		;[jd] is it the binary quote char?\r
	jnz	ptch2a		;[jd] no, keep going\r
	mvi	e,80h		;[jd] include parity bit\r
	lda	temp1\r
	dcr	a\r
	sta	temp1		;[jd] decrement character count\r
	mov	a,m		;[jd] get next character\r
	inx	h\r
	shld	outpnt\r
ptch2a:	cmp	b		;Is it the quote char?\r
	jnz	ptchr3		;[jd] changed to ptchr3 so includes parity\r
	mov	a,m		;Get the quoted character\r
	inx	h\r
	shld	outpnt		;and bump pointer.\r
	lxi	h,temp1\r
	dcr	m		;Decrement # of chars in packet.\r
	mov	d,a		;Save the char.\r
	ani	80H		;Turn off all but the parity bit.\r
	ora	e		;[jd] let parity come from either (???)\r
	mov	e,a		;Save the parity bit.\r
	mov	a,d		;Get the char.\r
	ani	7FH		;Turn off the parity bit.\r
	cmp	b		;Is it the quote char?\r
	jz	ptchr3		;If so just go write it out.\r
	cmp	c		;[jd] maybe it's the 8-bit prefix character?\r
	jz	ptchr3		;[jd] then don't controllify.\r
	mov	a,d		;Get the char.\r
	adi	40H		;Make the character a control char again.\r
	ani	7FH		;Modulo 128.\r
ptchr3:	ora	e		;Or in the parity bit.\r
	sta	temp3		; save for a while\r
	lda	remtxt		; to screen or disk?\r
	ana	a\r
	lda	temp3\r
	jz	ptch31		; to disk\r
	push	h\r
	push	d\r
	push	b\r
	mov	e,a		; to display\r
	mvi	c,dconio\r
	call	bdos\r
	pop	b\r
	pop	d\r
	pop	h\r
	jmp	ptchr1		; continue\r
\r
ptch31:	lhld	bufpnt		;Destination buffer.\r
	mov	m,a		;Store it.\r
	inx	h\r
	shld	bufpnt		;Update the pointer\r
	jmp	ptchr1		;and loop to next char.\r
\r
ptchr9:	lxi	d,erms11	; "?Disk full"\r
	push	d		;[MF] Save pointer\r
	call	error3		; put it on the error line\r
	pop	d		;[MF] Restore pointer\r
	lxi	h,data		;[MF] Where to put the message for "e" packet\r
	lda	argblk		;[MF] Get packet-number\r
	call	countp		;[MF]Increment it\r
	sta	argblk		;[MF] as packet to send\r
	xra	a		;[MF] Zero length of packet data\r
	sta	temp1		;[MF] ...\r
ptch9a:	ldax	d		;[MF] Get a character to copy\r
	cpi	cr		;[MF] No more to copy?\r
	jz	ptch9b		;[MF] Yes, we can send the packet\r
	mov	m,a		;[MF] No, copy the character\r
	inx	d		;[MF] and increment source/dest pointers\r
	inx	h		;[MF] ...\r
	lda	temp1		;[MF] Get character count\r
	inr	a		;[MF] and increment it\r
	sta	temp1		;[MF] ...\r
	jmp	ptch9a		;[MF] Copy entire error message\r
ptch9b:	mvi	m,0		;[MF]Put in a zero\r
	lda	temp1		;[MF] Get number of characters in the message\r
	sta	argblk+1	;[MF] and store as number of packet data chars\r
	mvi	a,'E'		;[MF] Make it an error packet\r
	call	spack		;[MF] Send the error packet\r
	nop			;[MF] Don't really care if\r
	nop			;[MF] the send fails since we're\r
	nop			;[MF] bombing off anyway\r
	ret			; take error return.\r
;\f\r
;       Fill a data packet from file\r
;       called by: sfile, sdata\r
\r
gtchr:	lda	squote		;Get the quote char.\r
	mov	c,a		;Keep quote char in c.\r
	lda	curchk		;Get current block check type\r
	sui	'1'		;Get the extra overhead\r
	mov	b,a		;Get a copy\r
	lda	spsiz		;Get the maximum packet size.\r
	sui	5		;Subtract the overhead.\r
	sub	b		;Determine max packet length\r
	sta	temp1		;This is the number of chars we are to get.\r
	lxi	h,filbuf	;Where to put the data.\r
	shld	cbfptr		;Remember where we are.\r
	mvi	b,0		;No chars.\r
gtchr1:	lda	temp1\r
	dcr	a		;Decrement the number of chars left.\r
	jp	gtchr2		;Go on if there is more than one left.\r
	mov	a,b		;Return the count in A.\r
	jmp	rskp\r
\r
gtchr2:	sta	temp1\r
	lda	chrcnt		;Space left in the DMA.\r
	dcr	a\r
;* Can improve order here.\r
	jm	gtchr3\r
	sta	chrcnt\r
	jmp	gtchr4\r
\r
gtchr3:	call	inbuf		;Get another buffer full.\r
	jmp	gtch30		; If no more return what we got.\r
	jmp	gtchr4		;If we got some, proceed.\r
\r
gtch30:	mov	a,b		;Return the count in A.\r
	ora	a		;Get any chars?\r
	jnz	rskp		;If so return them.\r
	jmp	gtceof		;If not, say we found the end of the file.\r
\r
gtchr4:	lhld	bufpnt		;Position in DMA.\r
	mov	a,m		;Get a char from the file.\r
	inx	h\r
	shld	bufpnt\r
	mov	d,a		;Save the char.\r
	ani	80H		;Turn off all but parity.\r
	mov	e,a		;Save the parity bit.\r
	jz	gtch4a		;[jd] no parity, skip this check...\r
	lda	quot8		;[jd] doing eighth-bit quoting?\r
	ora	a\r
	jz	gtch4a		;[jd] no, just proceed normally\r
	lda	temp1		;[jd] get space remaining\r
	cpi	2		;[jd] 3 chrs left (one cnted already)?\r
	jm	gtchr9		;[jd] no, skip this\r
	dcr	a		;[jd] decrement space remaining\r
	sta	temp1		;[jd] put back.\r
	lhld	cbfptr		;[jd] Position in character buffer.\r
	lda	qbchr		;[jd] get quote character\r
	mov	m,a		;]jd] Put the quote char in the buffer.\r
	inx	h		;[jd] increment destination buffer pointer\r
	shld	cbfptr		;[jd] store the pointer back\r
	inr	b		;[jd] Increment the char count.\r
	mvi	e,0		;[jd] no parity bit to OR in.\r
;[jd] fall thru...\r
\r
gtch4a:	mov	a,d		;Restore the char.\r
	ani	7FH		;Turn off the parity.\r
	mov	d,a		;[jd] save here for later...\r
	cpi	space		;Compare to a space.\r
	jm	gtchr5		;If less then its a control char, handle it.\r
	cpi	del		;Is the char a delete?\r
	jz	gtchr5		;Go quote it.\r
	lda	quot8		; Are we doing 8th-bit quoting?\r
	ora	a\r
	jz	gtch4c		; if not, skip this test and restore character.\r
	lda	qbchr		; get 8th-bit quote character\r
	cmp	d		; same as current character?\r
	jz	gtch4b		; yes, have to quote it...\r
gtch4c:	mov	a,d		; no. get character back again.\r
	cmp	c		;Is it the quote char?\r
	jnz	gtchr8		;If not proceed.\r
gtch4b:	lxi	h,temp1		;[jd] point to char count\r
	dcr	m		;[jd] decrement (know room for at least one)\r
	lhld	cbfptr		;Position in character buffer.\r
	mov	m,c		;Put the (quote) char in the buffer.\r
	inx	h\r
	shld	cbfptr\r
	inr	b		;Increment the char count.\r
	mov	a,d		;[jd] restore character again\r
	jmp	gtchr8\r
\r
gtchr5:	\r
	;[gnn] ignore parity for checking\r
;       ora     e		;Turn on the parity bit.\r
\r
	cpi	('Z'-100O)     	;Is it a ^Z?\r
	jnz	gtchr7		;If not just proceed.\r
	lda	cpmflg		;Was the file created by CPM...\r
	cpi	1		;in ASCII-mode ?\r
	jz	gtch52		;Control-Z stops text\r
	cpi	2		;in BINARY mode?\r
	jz	gtchr6		;Yes, pass the ^Z\r
;At this point file-mode is DEFAULT.\r
;If the rest of the record is filled with ^Zs, we're at EOF, otherwise\r
;its a regular character.\r
	lhld	bufpnt		;since CHRCNT is ZERO at EOF-time\r
	lda	chrcnt		;(set by INBUF5 B.G.E)\r
	mov	d,a		;Get the number of chars left in the DMA.\r
gtch51:	dcr	d\r
	mov	a,d\r
	jp	gtch53		;Any chars left?\r
gtch52:	xra	a		;If not, get a zero.\r
	sta	chrcnt		;Say no more chars in buffer.\r
	mov	a,b		;Return the count in A.\r
	jmp	rskp\r
\r
;Scan rest of buffer for non ^Z -- If we find a non ^Z, fall into gtchr6.\r
;If we get to the end of the buffer before finding a non ^Z, fall into gtch52.\r
gtch53:	mov	a,m		;Get the next char.\r
	inx	h		;Move the pointer.\r
	cpi	('Z'-100O)     	;Is it a ^Z?\r
	jz	gtch51		;If so see if the rest are.\r
\r
gtchr6:	mvi	a,('Z'-100O)   	;Restore the ^Z.\r
gtchr7:	sta	temp2		;Save the char.\r
	lxi	h,temp1		;Point to the char total remaining.\r
	dcr	m		;Decrement it.\r
	lhld	cbfptr		;Position in character buffer.\r
	mov	m,c		;Put the quote in the buffer.\r
	inx	h\r
	shld	cbfptr\r
	inr	b		;Increment the char count.\r
	lda	temp2		;Get the control char back.\r
	adi	40H		;Make the non-control.\r
	ani	7fH		;Modulo 200 octal.\r
gtchr8:	lhld	cbfptr		;Position in character buffer.\r
	ora	e		;Or in the parity bit.\r
	mov	m,a		;Put the char in the buffer.\r
	inx	h\r
	shld	cbfptr\r
	inr	b		;Increment the char count.\r
	jmp	gtchr1		;Go around again.\r
\r
gtchr9:	;[jd] not enough room left in buffer...\r
	lhld	bufpnt\r
	dcx	h\r
	shld	bufpnt		;[jd] back up over last character\r
	lxi	h,chrcnt	;[jd] point to character count\r
	inr	m		;[jd] increment it\r
	mov	a,b		;[jd] count of chars transferred\r
	jmp	rskp		;[jd] return it\r
\r
gtceof:	mvi	a,0FFH		;Get a minus one.\r
	ret\r
;\f\r
\r
; Little code to allow some expansion of code without changing\r
;  every futher address, only up to the end of this file.\r
;   TO BE REMOVED FRO RELEASE!\r
\r
;	org ($+100h) AND 0FF00H\r
\r
IF	lasm\r
	LINK	CPSPK2		;[obs] Link to part two of the packet file\r
ENDIF	;lasm\r