Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpxapp.asm

IF NOT lasm\r
.printx * CPXAPP.ASM *\r
ENDIF	;NOT lasm\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;       This file contains the system-dependent code and data for KERMIT.\r
;       It will be probably be broken into independent files to generate\r
;       overlays for the various systems, one or more overlay possible\r
;       from each file.  For now, we will leave it in one piece.\r
;\r
; revision history:\r
; edit 2, 22 July, 1987 by OBSchou.  Massaged code to work with CPXCOM.ASM\r
;\r
; edit 1, 2nd June, 1987 by OBSchou.  Extracted all Apple related code.\r
;\r
;\f\r
;      Family is the string used in VERSION to say which of several \r
;       smaller overlay files are used.  These are (will be) derived from \r
;       the juge CPXSYS.ASM file, in which case we will never get here.  \r
;       Just a Dollar, but put a sting in for a family of machines.\r
;\r
family:	db      'CPXAPP.ASM (2)  22-jul-87$'    ; Used for family versions....\r
;\r
	\r
IF apple\r
.printx	* Assembling KERMIT-80 for the Apple ][	*\r
ENDIF;apple\r
IF apmmdm\r
.printx	*   with Z80 Softcard &	Micromodem II	*\r
ENDIF;apmmdm\r
IF ap6551\r
.printx	*     with Z80 Softcard	& 6551 ACIA	*\r
ENDIF;ap6551\r
IF ap6850;[32]\r
.printx	*     with Z80 Softcard	& 6850 ACIA	*\r
ENDIF;ap6850 [32]\r
IF apcps;[22]\r
.printx	*     with Softcard & CPS Multifunction	card	 *\r
ENDIF;apcps\r
\r
;\r
\r
IF ap6551 OR ap6850 OR apcps;[9] [14]\r
				;jb eg. Apple SSC, Videx PSIO, Basis 108\r
apslot	EQU	2		;jb set equal to slot containing serial card\r
				;jb  set to 1 for Basis built-in port\r
ENDIF;jb ap6551 [9] apcps ap6850 [14]\r
IF ap6850	;[14] offset in slot I/O space for ACIA registers\r
		;e.g. PACT=00,01: AIO-I=05,04: AIO-II=0D,0C: Aristocard=0B,0A\r
apdat	EQU	0DH		;data reg.=0E080h+apslot*10h*apdat\r
apstat	EQU	0CH		;comm/stat reg.=0E080h+apslot*10h+apstat\r
ENDIF;ap6850\r
\r
\r
IF apmmdm\r
;APPLE Slot 2 contains Micromodem II.\r
MNPORT	EQU	0E0A7H	;Communications Port.\r
mnprts	EQU	0E0A6H	;Communications Port Status.\r
mnmodm	EQU	0E0A5H	;Modem Control Port.\r
orgmod	EQU	8EH	;Modem Originate Mode.\r
OUTPUT	EQU	02H	;Output Buffer Empty.\r
INPUT	EQU	01H	;Input Register Full.\r
apinc1	EQU	03H	;First Init Character for 6850 ACIA (Reset)\r
apinc2	EQU	11H	;Second Init Character for ACIA (8-bits)\r
apoffh	EQU	80H	;Set if OFFHOOK\r
AP300	EQU	1	;300 Baud\r
z80	EQU	TRUE	;Z80 Softcard\r
ENDIF;apmmdm\r
\r
IF ap6551		;jb\r
mnport	EQU	0E088H+(10H*apslot)	;jb Communications Port.\r
mnprts	EQU	0E089H+(10H*apslot)	;jb Communications Port Status.\r
mnprtc	EQU	0E08BH+(10H*apslot)	;jb Communications Control\r
mnprtm	EQU	0E08AH+(10H*apslot)	;jb Communications Master (command)\r
output	EQU	10H		;jb Output Buffer Empty.\r
input	EQU	08H		;jb Input Register Full.\r
mncinb	EQU	18H		;jb Control Port Initialization Byte\r
				;jb  (8-bit, no parity, 1-stop, 1200 baud)\r
mnminb	EQU	0BH		;jb Master Port Initialization Byte\r
				;jb  (DTR, RTS, no interrupts)\r
z80	EQU	TRUE		;Z80 Softcard\r
ENDIF;ap6551\r
\r
IF ap6850 ;[32]\r
mnport	EQU	0E080H+(10H*apslot)+apdat	;Communications Port.\r
mnprts	EQU	0E080H+(10H*apslot)+apstat	;Communications Port Status.\r
OUTPUT	EQU	02H		;Output Buffer Empty.\r
INPUT	EQU	01H		;Input Register Full.\r
apinc1	EQU	03H		;First Init Character for 6850 ACIA (Reset)\r
apinc2	EQU	15H		;Second Init Character for ACIA (8 data, 1 stop bit)\r
z80	EQU	TRUE		;Z80 Softcard\r
ENDIF;[32] ap6850\r
\r
IF apcps		;[22]\r
mnport	EQU	0E0FAH+(100H*apslot)	; Communications Port.\r
mnprts	EQU	0E0FBH+(100H*apslot)	; Communications Port Status.\r
mnprtc	EQU	0E0FEH+(100H*apslot)	; Communications Control\r
output	EQU	1		; Output Buffer Empty.\r
input	EQU	2		; Input Register Full.\r
TxEmpty	EQU	04h		; Transmitter empty flag\r
apmod1	EQU	4EH		; Mode Byte 1 (1 stop, no parity,8-bit, 16x)\r
				; Mode Byte 2 is speed control byte\r
apcmd	EQU	37H		; Command Byte (RTS,Error reset,RxE,DTR,TxE)\r
z80	EQU	TRUE		;Z80 Softcard\r
ENDIF;[22] apcps\r
\r
IF apple \r
defesc	EQU	']'-100O        ;The default escape character.\r
ENDIF;apple \r
\r
\r
; default to VT52-EMULATION ON.\r
\r
vtval	EQU	1\r
\r
\r
\r
sysxin:		; continuation of systemm dependent initialisation code\r
\r
IF ap6551\r
	lda	mnprtc		; read control port\r
	ani	0fH		; extract low order nybble\r
	sta	speed		; store as comm line speed\r
	sta	speed+1		;  (16 bits, to match speed table entries)\r
	mvi	a,mnminb	;jb initialization routine\r
	sta	mnprts		;jb\r
	sta	mnprtm		;jb initialize master (command) port\r
	mvi	a,mncinb	;jb\r
	sta	mnprtc		;jb initialize control port\r
ENDIF;ap6551\r
\r
IF ap6850 ;[32]\r
	mvi	a,apinc1	;Init ACIA\r
	sta	mnprts\r
	mvi	a,apinc2	;Set ACIA bits per character\r
	sta	mnprts\r
ENDIF;[32] ap6850\r
\r
IF apcps		;[22]\r
	lxi	h,3737h		;Default 1200 baud\r
	shld	speed		;Store as port speed\r
	xchg\r
	call	sysspd		;Initialise the port\r
ENDIF;[22] apcps\r
\r
	ret			; return from system-dependent routine\r
\r
;\f\r
\r
;\r
;       system-dependent termination processing\r
;       If we've changed anything, this is our last chance to put it back.\r
sysexit:\r
\r
	ret\r
\r
;\r
;       system-dependent processing for start of CONNECT command\r
;\r
syscon:\r
IF apmmdm\r
	call	ckdial		;See if dialing is required.\r
	 jmp	kermit		;Go to command loop if aborted.\r
ENDIF;apmmdm\r
\r
	ret\r
\r
conmsg:		; Messages printed when entering transparent (CONNECT) mode:\r
;\f\r
\r
IF apmmdm\r
;This code was mostly taken from\r
;       APMODEM.ASM V2.1\r
;       Based on MODEM.ASM by Ward Christensen\r
;       Modified for the Apple ][ by Gordon Banks 1-Jan-81\r
;       Micromodem ][ dialer option by Dav Holle  2-Feb-81\r
;       Code modified for KERMIT by Scott Robinson 14-Oct-82\r
;\r
;Come here to see if we need to dial a number.\r
;\r
ckdial:	lda	mnport		;access the data port\r
	lda	mnprts		;check status\r
	ani	4		;do we already have carrier?\r
	jz	rskp		;Yes, just continue\r
	xra	a		;Hangup Phone for starters\r
	sta	mnmodm\r
	lxi	b,1000		;Delay for a second\r
	call	delay\r
	mvi	a,8FH		;orgmod+ap300+apoffh\r
	sta	holdd		;storing mode for after dialing\r
	mvi	A,8DH		;Go Offhook to start dialing sequence\r
	sta	mnmodm\r
	mvi	a,apinc1	;Init ACIA\r
	sta	mnport\r
	mvi	a,apinc2	;Set ACIA bits per character\r
	sta	mnport\r
\r
	lxi	b,2500		;wait 2.5 seconds for dial tone\r
	call	delay\r
	lxi	d,dialms	;Ask the user for the number\r
	call	prtstr\r
;\r
gtdial:	mvi	c,conin		;Get a character\r
	call	bdos\r
	push	psw		;save it\r
	cpi	30H		;is it big enough to dial?\r
	jc	dialed		;no\r
	cpi	3AH		;is it too big to dial?\r
	jnc	dialed		;yes\r
	ani	0FH		;ok, it's a digit, get its value\r
	jnz	dialnz		;dial nonzero digits as-is\r
	mvi	A,10		;dial zero as ten\r
;\r
dialnz:	mov	e,a		;count pulses in E-reg\r
dopuls:	mvi	a,0DH		;put it on-hook\r
	sta	mnmodm\r
	lxi	b,61		;61-millisec pulse\r
	call	delay\r
	mvi	a,8DH		;take it off-hook again...\r
	sta	mnmodm\r
	lxi	b,39		;39-millisec delay between pulses\r
	call	delay\r
	dcr	e		;any more pulses to do?\r
	jnz	dopuls		;yep, do 'em\r
	lxi	b,600		;delay 600 msecs between digits\r
	call	delay\r
;\r
dialed:	pop	psw		;get back the char\r
	cpi	cr		;do we have a CR (done dialing)?\r
	jnz	gtdial		;no, keep on dialin'\r
	lxi	d,dialm2\r
	call	prtstr\r
\r
tictoc:	mvi	c,dconio	;Direct console input.\r
	mvi	e,0FFH\r
	call	bdos\r
	ora	a		;Have a charcter?\r
	jnz	nodial		;If so we abort\r
	lda	mnport		;access the data port\r
	lda	mnprts		;get modem status\r
	ani	4		;carrier?\r
	jnz	tictoc		;No\r
;\r
	lda	holdd		;get the old modem control byte\r
	sta	mnmodm		;turn our carrier on\r
\r
	lxi	d,dialm3\r
	call	prtstr\r
	jmp	rskp\r
nodial:	xra	a		;Hangup the modem.\r
	sta	mnmodm\r
	ret			;Return to abort the command.\r
;\r
holdd:	db	0		;Modem setup code\r
dialms:	DB	'Number to Dial: $'\r
dialm2:	DB	CR,LF,'Awaiting Carrier....(any key aborts)$'\r
dialm3:	DB	cr,lf,'Connected.',CR,LF,'$'\r
;\r
;DELAY wait for the number of millisecs in B,C\r
;\r
delay:	push	b		;save B,C\r
	push	d		;save D,E\r
	inr	b		;bump B for later DCR\r
;\r
delay1:	mvi	e,126		;delay count for 1 millisec (Apple Z80\r
				;clock=2.041MHz)\r
;\r
delay2:	dcr	e		;count\r
	jnz	delay2		;down\r
;\r
	dcr	c		;more millisecs?\r
	jnz	delay1		;yes\r
	dcr	b		;no - more in hi byte?\r
	jnz	delay1		;yes\r
	pop	d		;no,    restore D,E\r
	pop	b		;       restore B,C\r
	ret\r
ENDIF;apmmdm\r
;\f\r
\r
;\r
;       syscls - system-dependent close routine\r
;       called when exiting transparent session.\r
;\r
syscls:\r
	ret\r
;\f\r
\r
;\r
;       sysinh - help for system-dependent special functions.\r
;       called in response to <escape>?, after listing all the\r
;       system-independent escape sequences.\r
;\r
sysinh:\r
IF apmmdm OR apcps OR ap6850 ;\r
	lxi	d,inhlps	; we got options...\r
	call	prtstr		; print them.\r
ENDIF	;apmmdm OR apcps OR ap6850\r
\r
	ret\r
\r
\r
;additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
inhlps:\r
\r
IF apcps OR ap6850\r
	db	cr,lf,'B  Transmit a BREAK'\r
ENDIF;apcps OR ap6850\r
\r
IF apmmdm \r
	db	cr,lf,'D  Drop the line'\r
ENDIF;apmmdm \r
\r
	db	'$'                     ;[hh] table terminator\r
\r
;\r
;       sysint - system dependent special functions\r
;       called when transparent escape character has been typed;\r
;       the second character of the sequence is in A (and in B).\r
;       returns:\r
;       non-skip: sequence has been processed\r
;       skip:   sequence was not recognized\r
sysint:	ani	137O		; convert lower case to upper, for testing...\r
IF apmmdm\r
	cpi	'D'             ;Disconnect Modem?\r
	jnz	intc00		;No.\r
	xra	a		;Yes, hangup the modem\r
	sta	mnmodm\r
	ret			; command has been executed\r
intc00:\r
ENDIF;apmmdm\r
\r
IF ap6850 OR apcps		; [22] [25] ... some more\r
	cpi	'B'             ; send break?\r
	jz	sendbr		; yes, go do it.  return nonskip when through.\r
ENDIF;[22] ap6850 OR apcps \r
\r
	jmp	rskp		; take skip return - command not recognized.\r
\r
\r
;\f\r
\r
IF ap6850 ;[32]\r
sendbr:\r
;\r
;       Ensure that the transmitter has finished sending buffered chars\r
sndbr1:	lda	mnprts		; get UART status\r
	ani	output		; everything sent?\r
	jz	sndbr1		; no, wait a bit more\r
;\r
; Begin sending a break\r
	mvi	a,apinc2\r
	ori	60h		;transmit break level, CTS high\r
	sta	mnprts\r
;\r
; Wait for 250 milliseconds (using hundredths second delay routine)\r
	mvi	a,25\r
	call	delay\r
;\r
; Resume normal operation\r
	mvi	a,apinc2\r
	sta	mnprts\r
;\r
	ret			;done\r
ENDIF;[32] ap6850\r
\r
IF apcps		;[22]\r
sendbr:\r
;\r
;       Ensure that the transmitter has finished sending buffered chars\r
sndbr1:	lda	mnprts		; get UART status\r
	ani	TxEmpty		; everything sent?\r
	jz	sndbr1		; no, wait a bit more\r
;\r
;       Unmask command register\r
	mvi	a,80h\r
	sta	mnprtc\r
;\r
;       Begin sending a break by setting bit in UART command register\r
	mvi	a,3Fh		; Set TxEna, DTR, RxEna, SBreak, ErrRst, RTS\r
	sta	mnprts\r
;\r
;       Wait for 250 milliseconds (using hundredths second delay routine)\r
	mvi	a,25\r
	call	delay\r
;\r
;       Resume normal operation by clearing the SendBreak command bit\r
	mvi	a,37h		;Set TxEna, DTR, RxEna, ErrRst, RTS\r
	sta	mnprts\r
;\r
;       Remask command register\r
	mvi	a,0\r
	sta	mnprtc\r
;\r
	ret			;done\r
ENDIF;[22] apcps\r
\r
;\f\r
\r
;\r
;       sysflt - system-dependent filter\r
;       called with character in E.\r
;       if this character should not be printed, return with A = zero.\r
;       preserves bc, de, hl.\r
;       note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
sysflt:\r
	mov	a,e		; get character for testing\r
\r
	ret\r
\r
;       mdmflt - modem filter [30]\r
;       called with character to be sent to printer in E\r
;       with parity set as appropriate.\r
;       return with accumulator = 0 do do nothing,\r
;                               <> 0 to send char in E.\r
mdmflt:\r
	mov	a,e		;[30] get character to test\r
	ret\r
\r
\r
\r
;       prtflt - printer filter [30]\r
;       called with character to be sent to printer in E\r
;       returns with a = 0 to do nothing\r
;                    a <> 0 to print it.\r
;\r
;       this routine for those printer that automatically insert\r
;       a lf on cr, or cr for lf.  Should this be shifted to \r
;       the system indep. stuff, in say 4.06?\r
prtflt:\r
	mov	a,e		; [30] get character to test\r
\r
	ret\r
\r
\r
;\f\r
\r
;\r
; system-dependent processing for BYE command.\r
;  for apmmdm, heath, and lobo, hang up the phone.\r
sysbye:\r
IF apmmdm\r
	xra	a		;Hangup our end, too.\r
	sta	mnmodm\r
ENDIF;apmmdm\r
\r
	ret\r
;\f\r
\r
;       This is the system-dependent command to change the baud rate.\r
;       DE contains the two-byte value from the baud rate table; this\r
;       value is also stored in 'speed'.\r
sysspd:\r
\r
; Set the speed for Apple with 6551 ACIA\r
IF ap6551\r
	lda	mnprtc		;jb read control port\r
	ani	0F0H		;jb zap low order nybble\r
	ora	e		;jb put rate in low order nybble\r
	sta	mnprtc		;jb send to control port\r
	ret\r
ENDIF;ap6551\r
\r
; Set the speed for Apple with CPS Multifunction card\r
IF apcps		;[22]\r
	mvi	a,80h\r
	sta	mnprtc\r
	lda	mnprts		;read command register to reset 2651\r
	mvi	a,apmod1	;first mode byte\r
	sta	mnport\r
	mvi	a,4		;waste some time before sending second byte\r
spdwt:	dcr	a		; 4 T-states\r
	jnz	spdwt		; 10 T-states\r
	mov	a,e		;second mode byte is speed byte\r
	sta	mnport\r
	mvi	a,apcmd		;command byte\r
	sta	mnprts\r
	xra	a\r
	sta	mnprtc\r
	ret\r
ENDIF;[22] apcps\r
\r
\r
IF ap6551					;jb\r
spdtbl:	db	0DH				;jb 13 entries\r
	db	03H,'110$',     03H,03H ;jb\r
	db	04H,'1200$',    08H,08H ;jb\r
	db	05H,'134.5$',   04H,04H ;jb\r
	db	03H,'150$',     05H,05H ;jb\r
	db	04H,'1800$',    09H,09H ;jb\r
	db	05H,'19200$',   0FH,0FH ;jb\r
	db	04H,'2400$',    0AH,0AH ;jb\r
	db	03H,'300$',     06H,06H ;jb\r
	db	04H,'3600$',    0BH,0BH ;jb\r
	db	04H,'4800$',    0CH,0CH ;jb\r
	db	03H,'600$',     07H,07H ;jb\r
	db	04H,'7200$',    0DH,0DH ;jb\r
	db	04H,'9600$',    0EH,0EH ;jb\r
\r
sphtbl:	db	cr,lf,'  110    134.5  150    300    600   1200   1800'\r
	db	cr,lf,' 2400   3600   4800   7200   9600  19200$'\r
ENDIF;ap6551\r
\r
IF apcps		;[22]\r
spdtbl:	db	10H				; 16 entries\r
	db	03H,'110$',     32h,32h\r
	db	04H,'1200$',    37h,37h\r
	db	05H,'134.5$',   33h,33h\r
	db	03H,'150$',     34h,34h\r
	db	04H,'1800$',    38h,38h\r
	db	05H,'19200$',   3fh,3fh\r
	db	04H,'2000$',    39h,39h\r
	db	04H,'2400$',    3ah,3ah\r
	db	03H,'300$',     35h,35h\r
	db	04H,'3600$',    3bh,3bh\r
	db	04H,'4800$',    3ch,3ch\r
	db	02H,'50$',      30h,30h\r
	db	03H,'600$',     36h,36h\r
	db	04H,'7200$',    3dh,3dh\r
	db	02H,'75$',      31h,31h\r
	db	04H,'9600$',    3eh,3eh\r
\r
sphtbl:	db	cr,lf,'   50    75   110    134.5  150    300    600   1200'\r
	db	cr,lf,' 1800  2000  2400   3600   4800   7200   9600  19200$'\r
ENDIF;[22] apcps\r
\r
\r
\r
; The following conditionals were once a huge if not statement.  There\r
; wasn't enough room to add the lobo to the list, so it had to be broken\r
; into 2, which you can't do with an if not.  I redid it as two ifs and\r
; applied them to those that wouldn't set baud. [Hal Hostetler]\r
IF apmmdm OR ap6850 ;[32]\r
spdtbl	equ	0		; SET BAUD not supported.\r
sphtbl	equ	0\r
ENDIF;appmdm OR ap6850 [32]\r
;\r
;\r
;       no ports available for Apple\r
prttbl	EQU	0		;SET PORT not supported\r
prhtbl	EQU	0\r
\r
;\r
;\f\r
\r
;       This is the system-dependent SET PORT command.\r
;       HL contains the argument from the command table.\r
sysprt:\r
\r
	ret\r
;\f\r
\r
;\r
;       selmdm - select modem port\r
;       selcon - select console port\r
;       selmdm is called before using inpmdm or outmdm;\r
;       selcon is called before using inpcon or outcon.\r
;       For iobyt systems, diddle the I/O byte to select console or comm port;\r
;       For Decision I, switches Multi I/O board to console or modem serial\r
;       port.  [Toad Hall]\r
;       For the rest, does nothing.\r
;       preserves bc, de, hl.\r
selmdm:\r
	ret\r
\r
selcon:\r
	ret\r
;\f\r
\r
;       Get character from console, or return zero.\r
;       result is returned in A.  destroys bc, de, hl.\r
;\r
inpcon:\r
	mvi	c,dconio	;Direct console I/O BDOS call.\r
	mvi	e,0FFH		;Input.\r
	call	BDOS\r
	ret\r
;\f\r
\r
;\r
;       Output character in E to the console.\r
;       destroys bc, de, hl\r
;\r
outcon:\r
\r
	mvi	c,dconio	;Console output bdos call.\r
	call	bdos		;Output the char to the console.\r
	ret\r
;\f\r
\r
;\r
;       outmdm - output a char from E to the modem.\r
;               the parity bit has been set as necessary.\r
;       returns nonskip; bc, de, hl preserved.\r
outmdm:\r
IF apple \r
	push	h\r
outmd1:	lxi	h,mnprts	;address of the port status register\r
outmd2:	mov	a,m		; get port status in A\r
	ani	output		;Loop till ready.\r
	jz	outmd2\r
outmd3:	lxi	h,mnport	;address of port data register\r
	mov	m,e		; write the character\r
	pop	h\r
	ret\r
ENDIF;apple \r
\r
\r
\r
\r
;\f\r
\r
;\r
;       get character from modem; return zero if none available.\r
;       for IOBYT systems, the modem port has already been selected.\r
;       destroys bc, de, hl.\r
inpmdm:\r
IF apple \r
inpmd1:	lda	mnprts		;Get the port status into A.\r
	ani	input		;See if the input ready bit is on.\r
	rz			;If not then return.\r
inpmd2:	lda	mnport		;If so, get the char.\r
ENDIF;apple\r
\r
\r
ret			; return with character in A\r
\r
\r
;\r
;       flsmdm - flush comm line.\r
;       Modem is selected.\r
;       Currently, just gets characters until none are available.\r
\r
flsmdm:	call	inpmdm		; Try to get a character\r
	ora	a		; Got one?\r
	jnz	flsmdm		; If so, try for another\r
	ret			; Receiver is drained.  Return.\r
;\f\r
\r
;\r
;       lptstat - get the printer status. Return a=0ffh if ok, or 0 if not.\r
lptstat:\r
	xra	a\r
	ret\r
\r
;\r
;       outlpt - output character in E to printer\r
;       console is selected.\r
;       preserves de.\r
outlpt:\r
	push	d		; save DE in either case\r
	call	prtflt		; go through printer filter [30]\r
	ana	a		; if A = 0 do nothing,\r
	jz	outlp1		; [30] if a=0 do nothing\r
\r
	mvi	c,lstout\r
	call	bdos		;Char to printer\r
\r
outlp1:	pop	d		; restore saved register pair\r
	ret\r
;\f\r
\r
;\r
;       Screen manipulation routines\r
;       csrpos - move to row B, column C\r
;\r
;       csrpos for terminals that use a leadin sequence followed\r
;        by (row + 31.) and (column + 31.)\r
;\r
csrpos:	push	b		; save coordinates\r
	lxi	d,curldn	; get cursor leadin sequence\r
	call	prtstr		; print it\r
	pop	h		; restore coordinates\r
	mov	a,h		; get row\r
	adi	(' '-1)         ; space is row one\r
	mov	e,a\r
	push	h\r
	call	outcon		; output row\r
	pop	h\r
	mov	a,l		; get column\r
	adi	(' '-1)         ; space is column one\r
	mov	e,a\r
	jmp	outcon		; output it and return\r
\r
;\r
; delchr - make delete look like a backspace.  Unless delete is a printing\r
;       character, we just need to print a backspace. (we'll output clrspc\r
;       afterwards)\r
;       For Kaypro and Vector General, delete puts a blotch on the screen.\r
;       For Apple and Osborne 1, delete moves but doesn't print.\r
delchr:\r
\r
	lxi	d,delstr\r
	jmp	prtstr\r
\r
; erase the character at the current cursor position\r
clrspc:	mvi	e,' '\r
	call	outcon\r
	mvi	e,bs		;get a backspace\r
	jmp	outcon\r
\r
; erase the current line\r
clrlin:	lxi	d,eralin\r
	jmp	prtstr\r
\r
; erase the whole screen, and go home. preserves b (but not c)\r
clrtop:	lxi	d,erascr\r
	jmp	prtstr\r
\r
IF apple\r
sysver:	db	'Apple II CP/M$'\r
outlin:	db	('^'-100O),esc,'Y',cr,lf,'  $'\r
erascr:	db	('^'-100O),esc,'Y$'     ;Clear screen and go home.\r
eralin:	db	cr,esc,'T$'             ;Clear line.\r
delstr:	db	bs,bs,'$'               ; Adjust for delete\r
curldn:	db	esc,'=$'                ;Cursor lead-in\r
ttab:					;Table start location.\r
ta:	db	('K'-100O),'$',0,0      ;Cursor up.\r
tb:	db	12O,'$',0,0             ;Cursor down.\r
tc:	db	('F'-100O),'$',0,0      ;Cursor right.\r
td:	db	'$',0,0,0               ;(can't) Cursor left\r
te:	db	'$',0,0,0               ;(can't) Clear display\r
tf:	db	'$',0,0,0               ;(can't) Enter graphics mode\r
tg:	db	'$',0,0,0               ;(can't) Exit graphics mode\r
th:	db	('^'-100O),'$',0,0      ;Cursor home.\r
ti:	db	('K'-100O),'$',0,0      ;Reverse linefeed.\r
tj:	db	esc,'Y$',0              ;Clear to end of screen.\r
tk:	db	esc,'T$',0              ;Clear to end of line.\r
ENDIF;apple\r
\r
ovlend	equ	$	; End of overlay\r
\r
	END\r