Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpxcom.asm

IF NOT lasm\r
.printx * CPXCOM.ASM *\r
ENDIF	; NOT lasm\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;       This file contains part common code required for most if not all\r
;	systems.  Specifiacally, SYSINIT, INIADR, MOVER, and DELAY to name\r
;	the most important ones.\r
;\r
; revision history:\r
;\r
; edit 1, 21st July 1987 by OBSchou.  Regretably, I have had to include\r
;	some system dependent IFs, mainly for CRT, TORCH and OSI.  Inclusion\r
;	here means simpler family files later on. (Regrettably, the delay\r
;	loop for APMMDM differs too.)\r
;\r
; Set the fuzzy timeout value.  Range is 1 (VERY short) through 0ffffH to zero\r
; (maximum).  The actual duration is a function of the loop length and the\r
; processor speed.  For now, we'll make it zero for everybody, but feel free\r
; to change it for your system.\r
; [OBS] make it a little less than max, say 1000H.  More useful.\r
fuzval  EQU     1000H\r
\r
;\r
;       System-dependent initialization\r
;       Called once at program start.\r
sysinit:\r
;\r
; [13]  Had to move this call to here, as the prtstr routine needs this\r
; before the config message is sent out.  It has only been moved.\r
;\r
	call	iniadr	;Initialize the BIOS addresses\r
	mvi	c,gtiob	;Get current I/O byte\r
	call	bdos	;From CP/M\r
	sta	coniob	;Remember where console is\r
	mvi	c,getvnm	; get the BDOS version number (e.g. 22H, 31H)\r
	call	bdos\r
	mov	a,l\r
	sta	bdosvr		; and store it away for future reference\r
	lxi	d,cfgmsg	; "configured for "\r
	call	prtstr\r
	lxi	d,sysver	; get configuration we're configured for\r
	call	prtstr		; print it.\r
;\r
;       If we're set up to do special terminal handling, say what kind\r
;       of terminal we expect... (unless it's the generic 'crt')\r
IF termin\r
	lxi	d,witmsg	; " with "\r
	call	prtstr\r
	lxi	d,ttytyp	; terminal type\r
	call	prtstr\r
ENDIF;termin\r
	call	prcrlf		; print CR/LF\r
;\r
; now, to work...\r
;\r
; locate large buffer for multi-sector I/O\r
; What we want to do here is find the ccp.  Space between ovlend and the ccp\r
; is available for buffering, except we don't want to use more than maxsec\r
; buffers (if we use too many, the remote end could time out while we're\r
; writing to disk).  maxsec is system-dependent, but for now we'll just\r
; use 8Kbytes.  If you get retransmissions and other protocol errors after\r
; transferring the first maxsec sectors, lower maxsec.\r
\r
maxsec	EQU	(8*1024)/bufsiz	; 8K / number of bytes per sector\r
\r
	lxi	h,ovlend	; get start of buffer\r
	shld	bufadr		; store in linkage section\r
	mvi	a,maxsec	; get size of buffer, in sectors\r
	sta	bufsec		; store that, too.\r
\r
	call	sysxin		; call system specific init code\r
\r
	ret			; return from system-dependent routine\r
\r
bdosvr:	ds	1		; space to save the BDOS version number\r
IF NOT iobyt\r
coniob:	ds	1		; space to save copy of IO byte\r
ENDIF	;NOT iobyt\r
;\f\r
;       This one is hopefully the last "improvement" in view of GENERIC\r
;Kermit. It uses for Character-I/O the BIOS-routines ( instead of the\r
;"normal" BDOS routines. What does it give us (hopefully) : More speed,\r
;higher chance of success ( I/O byte implemented in BIOS [if at all]),\r
;but no "extra" device handling - that's done by BDOS.\r
;\r
;       How do we "get" the call-adresses?  Location 0 has a JMP Warm-Boot\r
;in CP/M which points into the second location of the BIOS JMP-Vector.  The\r
;next three locations of the JMP-Vector point to the CONSTAT,CONIN,CONOUT\r
;BIOS-routines.  CONOUT wants the character in C.\r
;\r
;- Bernie Eiben\r
\r
iniadr:	lhld	1		;get BIOS Warmstart-address\r
	lxi	d,3		;next adress is CONSTAT in BIOS\r
	dad	d\r
	shld	bconst+1	;stuff it into the call-instruction\r
	lxi	d,3		;next adress is CONIN in BIOS\r
	dad	d\r
	shld	bconin+1	;\r
	lxi	d,3		;next adress is CONOUT in BIOS\r
	dad	d\r
	shld	bcnout+1\r
	lxi	d,3		;next address is LIST in BIOS\r
	dad	d\r
	shld	blsout+1\r
	lxi	d,10*3		; get printer status routine\r
	dad	d\r
	shld	bprtst\r
	ret			;And return\r
\r
bconst:	jmp	$-$		;Call BIOS directly (filled in by iniadr)\r
\r
bconin:	jmp	$-$		;Call BIOS directly (filled in by iniadr)\r
\r
bcnout:	jmp	$-$		;Call BIOS directly (filled in by iniadr)\r
\r
blsout:	jmp	$-$		; ....\r
\r
bprtst:	jmp	$-$		; Call BIOS directly for printer status\r
\r
IF NOT apmmdm	; Shame about this, but the Apple needs a different delay\r
;\r
;[cjc]  Delay routine.  Called with time (hundredths of seconds) in A.\r
;       The inner loop delays 1001 T-states, assuming no wait states are\r
;       inserted; this is repeated CPUSPD times, for a total delay of just\r
;       over 0.01 second. (CPUSPD should be set to the system clock rate,\r
;       in units of 100KHz: for an unmodified Kaypro II, that's 25 for\r
;       2.5 MHz.  Some enterprising soul could determine whether or not the\r
;       Kaypro actually inserts a wait state on instruction fetch (a common\r
;       practice); if so, the magic number at delay2 needs to be decreased.\r
;       (We also neglect to consider time spent at interrupt level).\r
;\r
;       called by: sendbr\r
;       destroys BC\r
\r
delay:	mvi	c,cpuspd	; Number of times to wait 1000 T-states to\r
				;  make .01 second delay\r
delay2:	mvi	b,70		; Number of times to execute inner loop to\r
				;  make 1000 T-state delay\r
delay3:	dcr	b		; 4 T-states (* 70 * cpuspd)\r
	jnz	delay3		; 10 T-states (* 70 * cpuspd)\r
	dcr	c		; 4 T-states (* cpuspd)\r
	jnz	delay2		; 10 T-states (* cpuspd)\r
				; total delay: ((14 * 70) + 14) * cpuspd\r
				;  = 1001 * cpuspd\r
	dcr	a		; 4 T-states\r
	jnz	delay		; 10 T-states\r
	ret			; grand total: ((1001 * cpuspd) + 14) * a\r
ENDIF	; NOT apmmdm\r
;\f\r
;\r
;       Set up screen display for file transfer\r
;       called with kermit version in DE\r
;\r
sysscr: push    d               ; save version for a bit\r
        lxi     d,outlin        ; clear screen, position cursor\r
        call    prtstr          ; do it\r
        pop     d               ; get Kermit's version\r
IF NOT (osi OR crt)             ; got cursor control?\r
        call    prtstr          ; print it\r
        mvi     e,'['           ; open bracket\r
        call    outcon          ; print it (close bracket is in outln2)\r
        lxi     d,sysver        ; get name and version of system module\r
        call    prtstr\r
        lxi     d,outln2        ; yes, print field names\r
        call    prtstr\r
        lda     dbgflg          ; is debugging enabled?\r
        ora     a\r
        rz                      ; finished if no debugging\r
        lxi     d,outln3        ; set up debugging fields\r
        call    prtstr\r
ENDIF;NOT (osi OR crt)\r
        ret\r
;\f\r
;       Calculate free space for current drive\r
;       returns value in HL\r
sysspc:\r
        lda     bdosvr          ;cpm3's alloc vect may be in another bank\r
        cpi     30H             ;cpm3 or later?\r
        jm      cp2spc          ;no: use cp/m 2 algorithm\r
        lda     fcb             ;If no drive, get\r
        ora     a               ; logged in drive\r
        jz      dir180\r
        dcr     a               ;FCB drive A=1 normalize to be A=0\r
        jmp     dir18a\r
\r
dir180: mvi     c,rddrv\r
        call    bdos\r
dir18a: mov     e,a             ;drive in e\r
        mvi     c,getfs         ;get free space BDOS funct\r
        call    bdos            ;returns free recs (3 bytes in buff..buff+2)\r
        mvi     b,3             ;conv recs to K by 3 bit shift\r
dir18b: xra     a               ;clear carry\r
        mvi     c,3             ;for 3 bytes\r
        lxi     h,buff+3        ;point to addr + 1\r
dir18c: dcx     h               ;point to less sig. byte\r
        mov     a,m             ;get byte\r
        rar                     ;carry -> A -> carry\r
        mov     m,a             ;put back byte\r
        dcr     c               ;for all bytes (carry not mod)\r
        jnz     dir18c\r
        dcr     b               ;shift 1 bit 3 times\r
        jnz     dir18b\r
        mov     e,m             ;get least sig byte\r
        inx     h\r
        mov     d,m             ;get most sig byte\r
        xchg                    ;get K free in HL\r
        ret\r
\r
; the rest are CP/M 2.2 systems, so use the alloc vector\r
cp2spc: mvi     c,getalv        ;Address of CP/M Allocation Vector\r
        call    bdos\r
        xchg                    ;Get its length\r
        lhld    bmax\r
        inx     h\r
        lxi     b,0             ;Initialize Block count to zero\r
dir19:  push    d               ;Save allocation address\r
        ldax    d\r
        mvi     e,8             ;set to process 8 blocks\r
dir20:  ral                     ;Test bit\r
        jc      dir20a\r
        inx     b\r
dir20a: mov     d,a             ;Save bits\r
        dcx     h\r
        mov     a,l\r
        ora     h\r
        jz      dir21           ;Quit if out of blocks\r
        mov     a,d             ;Restore bits\r
        dcr     e               ;count down 8 bits\r
        jnz     dir20           ;do another bit\r
        pop     d               ;Bump to next count of Allocation Vector\r
        inx     d\r
        jmp     dir19           ;process it\r
\r
dir21:  pop     d               ;Clear Allocation vector from stack\r
        mov     l,c             ;Copy block to 'HL'\r
        mov     h,b\r
        lda     bshiftf         ;Get Block Shift Factor\r
        sui     3               ;Convert from records to thousands\r
        rz                      ;Skip shifts if 1K blocks\r
dir22:  dad     h               ;Multiply blocks by 'K per Block'\r
        dcr     a\r
        jnz     dir22\r
        ret\r
\r
;      +----|----|----|----|----|----|----|...\r
;    1 |\r
;    2 |                Kermit-80 v4.0 [system]\r
;    3 |\r
;    4 |Number of packets: ____\r
;    5 |Number of retries: ____\r
;    6 |File name: ____________\r
;    7 |<error>...\r
;    8 |<status>...\r
;    9 |RPack: ___(if debugging)...\r
;   10 |\r
;   11 |SPack: ___(if debugging)...\r
;   12 |\r
;   13 |Kermit-80  A:>  (when finished)\r
;\r
; For the PX-8, the display looks like:\r
;           5    10   15   20   25   30   35   40   45   50   55\r
;      +----|----|----|----|----|----|----|----|----|----|----|----|----\r
;    1 |Kermit-80 v4.05 [Epson PX-8]            Number of retries: ____\r
;    2 |Number of packets: ____                 File name: ________.___\r
;    3 |<error>...\r
;    4 |<status>...\r
;    5 |RPack: ___ (if debugging)...\r
;    6 |\r
;    7 |SPack: ___ (if debugging)...\r
;    8 |\r
;    9 |Kermit-80 A:> (when finished)\r
;\r
\r
IF NOT px8 ; [29]\r
nppos   EQU     4*100h+20\r
rtpos   EQU     5*100h+20\r
fnpos   EQU     6*100h+12\r
errlin  EQU     7\r
stlin   EQU     8\r
rplin   EQU     9\r
splin   EQU     11\r
prplin  EQU     13\r
ENDIF ; NOT px8\r
\r
IF px8\r
nppos   EQU     2*100h+20\r
rtpos   EQU     1*100h+59\r
fnpos   EQU     2*100h+51\r
errlin  EQU     3\r
stlin   EQU     4\r
rplin   EQU     5\r
splin   EQU     7\r
prplin  EQU     9\r
ENDIF ; px8 [29]\r
\r
\r
IF NOT (osi OR crt );[26]\r
scrnp:  lxi     b,nppos\r
        jmp     csrpos\r
\r
scrnrt: lxi     b,rtpos\r
        jmp     csrpos\r
\r
scrfln: lxi     b,fnpos\r
        call    csrpos\r
clreol:\r
        lxi     d,tk\r
        jmp     prtstr\r
\r
screrr: lxi     b,errlin*100H+1\r
        call    csrpos\r
        jmp     clreol\r
\r
scrst:  lxi     b,stlin*100H+1\r
        call    csrpos\r
        jmp     clreol\r
\r
rppos:  lxi     b,rplin*100H+8\r
        call    csrpos\r
        jmp     clreol\r
\r
sppos:  lxi     b,splin*100H+8\r
        call    csrpos\r
        jmp     clreol\r
\r
; [29] Modify scrend to make the cursor line conditional on use of debugging\r
; This means that in most cases the entire file transfer will fit on PX-8 lcd\r
scrend: lda     dbgflg\r
        ora     a\r
        jz      scr1nd\r
        lxi     b,prplin*100H+1 ; debugging in use [29]\r
        jmp     scr2nd\r
scr1nd: lxi     b,rplin*100H+1  ; no debugging\r
scr2nd: call    csrpos\r
clreos: lxi     d,tj\r
        jmp     prtstr\r
; [29]  and nop out the rest for now...\r
;\r
;scrend:        lxi     b,prplin*100H+1\r
;       call    csrpos\r
;clreos:        lxi     d,tj\r
;       jmp     prtstr\r
ENDIF;NOT (osi OR crt ) [26]\r
\r
\r
IF osi OR crt   ; no cursor control\r
scrnp:  mvi     e,' '\r
        jmp     outcon\r
\r
scrnrt: mvi     e,' '\r
        call    outcon\r
        mvi     e,'%'\r
        jmp     outcon\r
\r
scrfln:\r
screrr:\r
scrst:\r
scrend: jmp     prcrlf          ;Print CR/LF    [Toad Hall]\r
\r
rppos:  lxi     d,prpack\r
        jmp     prtstr\r
\r
sppos:  lxi     d,pspack\r
        jmp     prtstr\r
ENDIF;osi OR crt\r
\r
; Some frequently-used routines (duplicates of those in CPSMIT):\r
;       prcrlf - output a CR/LF\r
;       prtstr - output string in DE\r
;       rskp - return, skipping over error return\r
prcrlf: lxi     d,crlf\r
prtstr:\r
;  [17] added this  to avoid prtstr.. emulate function 9 call.\r
;	Works on most machines.\r
IF (torch OR px8 OR z80mu)\r
;\r
;       Modified print string as the CP/N (for Nut) system traps control\r
;       characters in a function 9 call.. rot its cotton socks.\r
        push    h\r
        push    d\r
        push    b\r
prtst1:\r
        ldax    d\r
        inx     d\r
        cpi     '$'             ; if a dollar then end of string\r
        jz      prtst2\r
        push    d\r
        mov     e,a\r
	mov	c,a		; also to c if its via conout in BIOS\r
        call    outcon          ; send it to the screen\r
        pop     d\r
        jmp     prtst1\r
\r
prtst2: pop     b\r
        pop     d\r
        pop     h\r
        ret                     ; regs restored.. just in case\r
ENDIF	;(torch OR px8 OR z80mu)\r
\r
IF NOT (torch OR px8 or z80mu)		;ie any machine that can send ctrl chrs via dos call 9\r
	PUSH	H\r
	PUSH	D\r
        push    b\r
        mvi     c,9     ; Dos call 9 (print a string)\r
        call    bdos\r
        pop     b\r
	POP	D\r
	POP	H\r
        ret             ; all done for good machines\r
ENDIF   ;NOT (torch OR px8 OR z80mu)\r
\r
;\r
;	rskp - return to calling address + 3.\r
rskp:   pop     h               ; Get the return address\r
        inx     h               ; Increment by three\r
        inx     h\r
        inx     h\r
        pchl\r
\r
;       Copy block of data\r
;       source in HL, destination in DE, byte count in BC\r
;       called by: cpxsys, mfname\r
;\r
mover:\r
IF NOT z80              ; 8080's have to do it the hard way\r
;OBS assume its an 8080 for now - this will work on Z80s anyway.\r
        mov     a,m\r
        stax    d\r
        inx     h\r
        inx     d\r
        dcx     b\r
        mov     a,b\r
        ora     c\r
        jnz     mover\r
ENDIF;NOT z80\r
IF z80\r
       db      0EDh,0B0h       ; Z80 LDIR instruction\r
ENDIF;z80\r
        ret\r
\r
;\r
;       Miscellaneous messages\r
;\r
crlf:   db      cr,lf,'$'\r
cfgmsg: db      'configured for $'\r
witmsg:	db	' with $'	; Its included if we get here ('with terminal')\r
\r
IF NOT (osi OR crt OR px8)	; [29] got cursor control?\r
outln2:	db	']',cr,lf,cr,lf,'Number of packets:'\r
	db	cr,lf,'Number of retries:'\r
	db	cr,lf,'File name:$'\r
ENDIF;NOT (osi OR crt OR px8)\r
\r
IF px8	; [29]\r
outln2:	db	']           Number of retries:', cr, lf\r
	db	'Number of packets:                     File name:$'\r
ENDIF ; px8 [29]\r
\r
IF NOT (osi OR crt) ; [29]\r
outln3:	db	cr,lf,cr,lf	; debugging messages\r
	db	cr,lf,'Rpack:'\r
	db	cr,lf		; Blank line in case of long packet\r
	db	cr,lf,'Spack:$'\r
ENDIF ; NOT (osi OR crt) [29]\r
\r
IF lasm\r
LINK CPXSWT.ASM\r
ENDIF	;lasm\r
\r