Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpscmd.asm

; CPSCMD.ASM\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others. \r
;\r
;\r
;       This file provides a user oriented way of parsing commands.\r
;       It is similar to that of the COMND JSYS in TOPS-20.\r
;\r
; revision history (latest first):\r
;\r
;edit 13, 17-Jan-1991 by MF. Modified "cmifil" routine to zero the entire\r
;	fcb (not just the extent) to fix a bug in the COPY command which\r
;	prevented successive COPY commands from working properly.\r
;edit 12, 16-Jan-1991 by MF. Modified routine "cmkeyw" to ignore leading\r
;	spaces/tabs before a keyword. This apparently was the intent in\r
;	"prompt" and "repars" (at least for command-lines) as the variable \r
;	"cmsflg "is set upon command parse and reparse. The intent was ,\r
;	subverted, however, as "cmkeyw" did not reset the flag to ignore\r
;	leading white space for each search thru the key tables (even though\r
;	the buffer pointer to the keyword entered was reset). The fix was\r
;	to reset the "spaces seen" flag (cmsflg) after "cmkey2" so that\r
;	it is reset each time a new table entry is compared to the text\r
;	the user has entered from the keyboard/TAKE-file etc. The upshot\r
;	of all this is that the kluge code in "cminbf" at "cminb0" designed\r
;	to force Kermit to ignore leading white space on command-lines in\r
;	TAKE-files and on the CP/M command-line is no longer needed and,\r
;	therefore, has been eliminated. Also modify "comnd" to expect leading\r
;	spaces for functions other than "get keyword".\r
;edit 11, 26-Dec-1990 by MF. Modified routines to ignore leading white space\r
;	in lines from TAKE-files as well as during input from the CP/M\r
;	command-line  (form-feeds are now considered white space under these\r
;	circumstances).\r
;edit 10, 8-Sep-1990 by Mike Freeman.  Modified routines to ignore leading\r
;	spaces/tabs when processing Kermit commands from the CP/M\r
;	command-line.\r
;	Added flag CMBFLG to allow initial word on a command-line\r
;	to be blank (useful for Remote commands such as Remote CWD etc).\r
;	Added flag cmqflg to prevent character-echoing while entering\r
;	commands so Remote CWD etc can have nonechoing password entry.\r
; edit 9, 15 June, 1987 by OBSchou.  Bug fixing to allow a second filename\r
;	(quiet) be entered as d:<blank>.  Previous revision put the drive name \r
;	in first character of FCB, I put that character back to a space.\r
;\r
; edit 8, 12 June, 1987 by OBSchou.  Addedin code in cmkeyw to print\r
;	20 lines of help, then pause for a key from the user befor\r
;	proceeding with help.\r
;\r
; edit 7, 11 March, 1987 by OBSchou for Richard Russell, BBC.  He writes:\r
;	Bug in cmtext which prevented use of octal characters (\nnn) fixed.\r
;\r
; edit 6, 18 June, 1986 by OBSchou, Loughborough University, Leics. UK\r
;       added code to parse a number from user input.  Added check to make \r
;       sure the input command buffer does not overflow the limit.\r
;\r
; edit 5a: 7 March, 1986.  OBSchou. Added stuff rom MJ Carter.  He writes:\r
;       7th May 85, MJ Carter [majoc], Nottingham University\r
;       Code in cmifil() put one too many spaces in the FCB; this caused \r
;       the BDOS of the British Micro Mimi to search for exteny 32,\r
;       rather than extent 0, so era() always said "can't find file"\r
;       Puttig a null at the point in question ought to fix 9 it.\r
;\r
; edit 5: 6-Feb-85 by Charles Carvalho\r
;       Make ffussy a runtime (rather than assembly-time) switch, to\r
;       eliminate conditional assembly in system-independent module.\r
;       Don't allow _%|()/\ in filenames if ffussy set; my CP/M manual\r
;       disallows those, too.\r
;\r
; edit 4: 13-Jan-85 by Vanya J.Cooper Pima Commun. College Tel: 602-884-6809\r
;\r
;pcc006 2-jan-85        VJC     modules:cp4cmd,cp4utl\r
;       Problems with "?" in filespecs.  On reparse, may cause action\r
;       flag to be reset at wrong point, requiring multiple <CR>'s\r
;       to terminate the line or other weird stuff.  Also need to\r
;       check flag and complain if wild-cards illegal.\r
\r
;pcc007 2-Jan-85        vjc     modules:cp4def,cp4cmd\r
;       Cmifil is too fussy about what characters to accept in a\r
;       filespec.  My CP/M manual says any printable character is ok\r
;       except <>.,;:?*[], and lower case.  In practice, even those work\r
;       sometimes.  Kermit itself uses '&' if file warning is on,\r
;       and then won't let you reference the file.  Allow all\r
;       printable characters except those above.  Add conditional\r
;       ffussy, so that if not ffussy, all special characters will be\r
;       allowed, just convert lower to upper-case.\r
\r
; edit 3: July 8, 1984 (CJC)\r
;       integrate Toad Hall changes for LASM compatibility: CP4CPM is linked\r
;       by CP4WLD, and links CP4UTL.\r
;       \r
; edit 2: June 5, 1984 (CJC)\r
;       formatting and documentation; delete unnecessary code at cminb7; add\r
;       module version string.\r
;\r
; edit 1: May, 1984 (CJC)\r
;       extracted from CPMBASE.M80 version 3.9; modifications are described in\r
;       the accompanying .UPD file.\r
\r
cmdver:	db	'CPSCMD.ASM (13)  17-Jan-1991$'	; name, edit number, date\r
\r
;       This routine prints the prompt in DE and specifies the reparse\r
;       address.\r
;       called by:  kermit\r
\r
prompt:	pop	h		;Get the return address.\r
	push	h		;Put it on the stack again.\r
	shld	cmrprs		;Save it as the address to go to on reparse.\r
	lxi	h,0		;Clear out hl pair.\r
	dad	sp		;Get the present stack pointer.\r
	shld	cmostp		;Save for later restoral.\r
	xchg			;Save the pointer to the prompt.\r
	shld	cmprmp\r
	xchg\r
	lxi	h,cmdbuf\r
	shld	cmcptr		;Initialize the command pointer.\r
	shld	cmdptr\r
	xra	a\r
	sta	cmaflg		;Zero the flags.\r
	sta	cmccnt\r
;	mvi	a,0FFH		;Try it this way (Daphne.)\r
;	sta	cmsflg\r
	call	prcrlf		;Print a CR/LF [Toad Hall]\r
	jmp	prprmp		;Print the prompt.  [Toad Hall]\r
;\f\r
;       This address is jumped to on reparse.\r
;       here from:  cmcfrm, cmkeyw, cmifil, cminbf\r
\r
repars:	lhld	cmostp		;Get the old stack pointer.\r
	sphl			;Make it the present one.\r
	lxi	h,cmdbuf\r
	shld	cmdptr\r
;	mvi	a,0FFH		;Try it this way (Daphne.)\r
;	sta	cmsflg\r
	lhld	cmrprs		;Get the reparse address.\r
	pchl			;Go there.\r
\r
;       This address can be jumped to on a parsing error.\r
;       here from:  cmkeyw, cminbf\r
\r
prserr:	lhld	cmostp		;Get the old stack pointer.\r
	sphl			;Make it the present one.\r
	lxi	h,cmdbuf\r
	shld	cmcptr		;Initialize the command pointer.\r
	shld	cmdptr\r
	xra	a\r
	sta	cmaflg		;Zero the flags.\r
	sta	cmccnt\r
;	mvi	a,0FFH		;Try it this way (Daphne.)\r
;	sta	cmsflg\r
	call	prcrlf		;Print a CR/LF  [Toad Hall]\r
	call	prprmp		;Print the prompt  [Toad Hall]\r
;* Instead return to before the prompt call.\r
	lhld	cmrprs\r
	pchl\r
;\f\r
;       This routine parses the specified function in A.  Any additional\r
;       information is in DE and HL.\r
;       Returns +1 on success\r
;               +4 on failure (assumes a JMP follows the call)\r
;       called by:  log, setcom, read, send, xmit, dir, era, keycmd, cfmcmd\r
;	and CPSREM\r
\r
comnd:	sta	cmstat		;Save what we are presently parsing.\r
	call	cminbf		;Get chars until an action or a erase char.\r
	push	psw		;[MF]Save function\r
	mvi	a,0ffh		;[MF]Expect leading spaces\r
	sta	cmsflg		;[MF]...\r
	pop	psw		;[MF]Restore function\r
	cpi	cmcfm		;Parse a confirm?\r
	jz	cmcfrm		;Go get one.\r
	cpi	cmkey		;Parse a keyword?\r
	jz	cmkeyw		;Try and get one.\r
	cpi	cmifi		;Parse an input file spec?\r
	jz	cmifil		;Go get one.\r
	cpi	cmifin		;Input file-spec silent?\r
	jz	cmifil		;do as he wishes\r
	cpi	cmofi		;Output file spec?\r
	jz	cmofil		;Go get one.\r
	cpi	cmtxt		;Parse arbitrary text?\r
	jz	cmtext		;Go do it.\r
	cpi	cmnum		;[7] Parse a number?\r
	jz	cmnumb		;[7] go do it\r
	lxi	d,cmer00	;"?Unrecognized COMND call"\r
	call	prtstr\r
	ret\r
;\f\r
;       This routine parses arbitrary text up to a CR.\r
;       Accepts DE:     address to put text\r
;       Returns in A:   number of chars in text (may be 0)\r
;                DE:    updated pointer\r
;       called by: comnd\r
\r
cmtext:	xra	a		; clear counters erc for slashes etc\r
	sta	slshsn		; if we are in a slash sequence\r
	sta	slashn		; the octal number being entered\r
	sta	slashc		; number of characters entered\r
\r
	xchg			;Put the pointer to the dest in HL.\r
	shld	cmptab		;Save the pointer.\r
	mvi	b,0		;Init the char count\r
cmtxt1:	call	cmgtch		;Get a char.\r
	ora	a		;Terminator?\r
	jp	cmtx3		;No, put in user space. [rtr] was cmtx5\r
	ani	7FH		;Turn off minus bit.\r
	cpi	esc		;An escape?\r
	jnz	cmtxt2		;No.\r
	mvi	c,conout\r
	mvi	e,bell		;Get a bell.\r
	call	bdos\r
	xra	a\r
	sta	cmaflg		;Turn off the action flag.\r
	lhld	cmcptr		;Move the pointer to before the escape.\r
	dcx	h\r
	shld	cmcptr\r
	shld	cmdptr\r
	lxi	h,cmccnt	;Get the char count.\r
	dcr	m		;Decrement it by one.\r
	jmp	cmtxt1		;Try again.\r
\r
cmtxt2:	cpi	'?'             ;Is it a question mark?\r
	jz	cmtxt4		;If so put it in the text. [rtr] was cmtx3\r
	cpi	ff		;Is it a formfeed?\r
	cz	clrtop		;If so blank the screen.\r
	mov	a,b		;Return the count.\r
	lhld	cmptab		;Return updated pointer in HL.\r
	xchg\r
	jmp	rskp		;Return success.\r
\r
cmtx3:	cpi	'\'             ; slash?\r
	jnz	cmtx3a		; nope, so try something else\r
	lda	slshsn		; a slash already entered?\r
	ana	a\r
	cma			;[rtr]\r
	jnz	cmtx3a		; yes, so assume its a valid slash to enter\r
	sta	slshsn		; make sure the flag is set for next time routnd\r
	jmp	cmtxt1		; get another character\r
\r
cmtx3a:\r
;	lxi	h,cmaflg	;Point to the action flag.\r
;	mvi	m,0		;Set it to zero.\r
	mov	e,a		; save it in case we are interpreting a slash\r
	lda	slshsn		; slash already entered?\r
	ana	a		; test flag\r
	mov	a,e		; restore it in case...\r
	jz	cmtx5		; not a slash seen, so enter as a normal character\r
	cpi	'\'\r
	jnz	cmtx3b		; \\ not detected\r
	lda	slashn		; else get number\r
	jmp	cmtx5b		; and enter it ( in the case of \n or \nn)\r
				; here if an octal number of 1 or 2 digits\r
				; entered instead of 3, followed by \ again\r
\r
cmtx3b:\r
	sui	30h		; else it should be an octal number\r
	jm	cmtxt6		; if not a digit complain\r
	cpi	8		; ditto\r
	jp	cmtxt6		;[rtr] was cmtxt\r
	mov	e,a		; else add it to the number already entered\r
	lda	slashn\r
	add	a\r
	add	a\r
	add	a		; multiply by 8\r
	add	e\r
	sta	slashn\r
	lda	slashc		; get the count\r
	inr	a\r
	sta	slashc		; plus one.  If three then a number entered\r
	cpi	3\r
	lda	slashn		; get the number in case...\r
	jz	cmtx5\r
	jmp	cmtxt1		; else loop\r
\r
cmtxt4:	lhld	cmdptr		;[rtr] Get a pointer into the buffer\r
	inx	h		;[rtr] Bump past '?'\r
	shld	cmdptr		;[rtr]\r
cmtx5:	call	cmtx5c\r
	jmp	cmtxt1		; put this into a subroutine\r
\r
cmtx5b:\r
	call	cmtx5c		; here if we see \n\ or \nn\ rather than \nnn\\r
	mvi	a,'\'           ; so send slash number to buffer, \r
	sta	slshsn		; re-store a slash seen\r
	jmp	cmtxt1		; try next one\r
\r
cmtx5c:\r
	inr	b		;Increment the count.\r
	lhld	cmptab		;Get the pointer.\r
	mov	m,a		;Put the char in the array.\r
	inx	h\r
	shld	cmptab		;Save the updated pointer.\r
	xra	a		; clear slash counters etc\r
	sta	slashc\r
	sta	slashn\r
	sta	slshsn\r
	ret			; and exit\r
\r
cmtxt6:	lxi	d,cmer05	; complain - not a valid \ parameter\r
	call	prtstr\r
	jmp	kermit		; and try another command\r
	ds	20h		; for debugging\r
;\f\r
;       This routine gets a number from user input.\r
;       Called by: comnd\r
;\r
cmnumb:	lxi	h,0		; make sure the number is zero to start with\r
	shld	number\r
cmnum0:	call	cmgtch		; get another character\r
	ora	a		; if negative then its an action\r
	jp	cmnum1		; nope, so (possibly) valid input\r
	ani	7fh		; else lets see what it is...\r
	cpi	esc		; do not know what to do with this one...\r
	cpi	' '             ; if it is a space then either a return or more\r
	jnz	cmnum2		; else\r
	jmp	rskp		; space is a deliminter\r
	dw	0		; set three bytes aside for a jump/call\r
	dw	0		; and then another three just in case...\r
	dw	0		; making 6 bytes\r
cmnum2:	cpi	'?'             ; user is curious\r
	jz	gnum2\r
	cpi	cr		; end of input?\r
	jz	cmnumx\r
gnum1:	jmp	prserr		; did not under stand this, so error\r
cmnumx:	dw	0\r
	dw	0\r
	jmp	rskp		; return ok\r
\r
gnum2:	lhld	number		; get the number.. if at all entered\r
	mov	a,l\r
	ora	h		; if hl = 0 then possibly no number entered\r
	lxi	d,cmin02	; say confirm...or more on line\r
	jnz	gnum21		; else say enter a return\r
	lxi	d,cmin01	; say enter a number\r
gnum21:	call	prtstr		; say it\r
	call	prcrlf		; do a lf\r
	call	prprmp		; another reprompt\r
	lhld	cmdptr		; get pointer of string already entered\r
	mvi	m,'$'           ; dollar it to  set end of line\r
	lhld	cmcptr\r
	dcx	h		; decrement and save the buffer pointer\r
	shld	cmcptr\r
	lxi	d,cmdbuf\r
	call	prtstr		; print what has already been entered\r
	xra	a\r
	sta	cmaflg		; turn the action flag off\r
	jmp	repars		; and try again\r
\r
	mvi	a,cmcfm		; parse a confirm\r
dw	0\r
dw	0\r
dw	0\r
dw	0\r
dw	0	; some space to patch...\r
dw	0\r
\r
cmnum1:	ani	7fh		; here for a (potentially) valid number\r
	sui	'0'             ; less ascii bias\r
	jc	gnum3\r
	cpi	10		; if 10 or more its still bad\r
	jnc	gnum3\r
	cmc\r
	lhld	number		; now multiply number by ten and add the new value\r
	push	h\r
	pop	d\r
	dad	h		; hl = hl * 2\r
	dad	h		; * 4\r
	dad	d		; * 5\r
	dad	h		; * 10\r
	mvi	d,0\r
	mov	e,a		; add de to hl...\r
	dad	d\r
	shld	number\r
	jmp	cmnum0\r
;\r
gnum3:	lxi	d,cmer04	; invalid number...\r
	call	prtstr\r
	jmp	rskp\r
;\r
\r
;\f\r
;       This routine gets a confirm.\r
;       called by: comnd\r
\r
cmcfrm:	call	cmgtch		;Get a char.\r
	ora	a		;Is it negative (a terminator;a space or\r
				;a tab will not be returned here as they\r
				;will be seen as leading white space.)\r
	rp			;If not, return failure.\r
	ani	7FH		;Turn off the minus bit.\r
	cpi	esc		;Is it an escape?\r
	jnz	cmcfr2\r
	mvi	c,conout\r
	mvi	e,bell		;Get a bell.\r
	call	bdos\r
	xra	a\r
	sta	cmaflg		;Turn off the action flag.\r
	lhld	cmcptr		;Move the pointer to before the escape.\r
	dcx	h\r
	shld	cmcptr\r
	shld	cmdptr\r
	lxi	h,cmccnt	;Get the char count.\r
	dcr	m		;Decrement it by one.\r
	jmp	cmcfrm		;Try again.\r
\r
cmcfr2:	cpi	'?'             ;Curious?\r
	jnz	cmcfr3\r
	lxi	d,cmin00	;Print something useful.\r
	call	prtstr\r
	call	prcrlf		;Print a crlf.  [Toad Hall]\r
	call	prprmp		;Reprint the prompt  [Toad Hall]\r
	lhld	cmdptr		;Get the pointer into the buffer.\r
	mvi	a,'$'           ;Put a $ there for printing.\r
	mov	m,a\r
	lhld	cmcptr\r
	dcx	h		;Decrement and save the buffer pointer.\r
	shld	cmcptr\r
	lxi	d,cmdbuf\r
	call	prtstr\r
	xra	a		;Turn off the action flag.\r
	sta	cmaflg\r
	jmp	repars		;Reparse everything.\r
\r
cmcfr3:	cpi	ff		;Is it a form feed?\r
	cz	clrtop		;If so blank the screen.\r
	jmp	rskp\r
;\f\r
;       This routine parses a keyword from the table pointed\r
;       to in DE.  The format of the table is as follows:\r
;\r
;       addr:   db      n       ;Where n is the # of entries in the table.\r
;               db      m       ;M is the size of the keyword.\r
;               db      'string$' ;Where string is the keyword.\r
;               db      a,b     ;Where a & b are pieces of data\r
;                               ;to be returned.  (Must be two of them.)\r
;\r
;       The keywords must be in alphabetical order.\r
;**** Note:  The data value a is returned in registers A and E.  The\r
;****   data value b is returned in register D.  This allows the two data\r
;       bytes to be stored as:\r
;               dw      xxx\r
;       and result in a correctly formatted 16-bit value in register pair\r
;       DE.\r
;       called by: comnd\r
\r
cmkeyw:	shld	cmhlp		;Save the help.\r
	xchg			;Get the address of the table.\r
	shld	cmptab		;Save the beginning of keyword tab for '?'.\r
	mov	b,m		;Get the number of entries in the table.\r
	inx	h\r
	shld	cmkptr\r
	lhld	cmdptr		;Save the command pointer.\r
	shld	cmsptr\r
cmkey2:	mov	a,b		;Get the number of entries left.\r
	ora	a		;Any left?\r
	rz			;If not we failed.\r
	mvi	a,0ffh		;[MF]Make sure we ignore leading spaces\r
	sta	cmsflg		;[MF]...\r
	lhld	cmkptr\r
	mov	e,m		;Get the length of the keyword.\r
	inx	h\r
cmkey3:	dcr	e		;Decrement the number of chars left.\r
	mov	a,e\r
	cpi	0FFH		;Have we passed the end?\r
	jm	cmkey5		;If so go to the next.\r
	call	cmgtch		;Get a char.\r
	ora	a		;Is it a terminator?\r
	jp	cmkey4		;If positive, it is not.\r
	ani	7FH		;Turn off the minus bit.\r
	cpi	'?'\r
	jnz	cmky31\r
	xra	a\r
	sta	cmaflg		;Turn off the action flag.\r
	lxi	h,cmccnt	;Decrement the char count.\r
	dcr	m\r
;* Must go through the keyword table and print them.\r
	lhld	cmhlp		;For now print the help text.\r
	xchg\r
	call	p20ln		;[8] print at most 20 lines then pause\r
;	call	prtstr\r
	call	prcrlf		;Print a crlf  [Toad Hall]\r
	call	prprmp		;Reprint the prompt  [Toad Hall]\r
	lhld	cmdptr		;Get the pointer into the buffer.\r
	mvi	a,'$'           ;Put a $ there for printing.\r
	mov	m,a\r
	lhld	cmcptr\r
	dcx	h		;Decrement and save the buffer pointer.\r
	shld	cmcptr\r
	lxi	d,cmdbuf\r
	call	prtstr\r
	jmp	repars		;Reparse everything.\r
\r
cmky31:	cpi	esc		;Is it an escape?\r
	jnz	cmky35\r
	xra	a\r
	sta	cmaflg		;Turn off the action flag.\r
	push	d\r
	push	b\r
	push	h\r
	call	cmambg\r
	jmp	cmky32		;Not ambiguous.\r
	mvi	c,conout\r
	mvi	e,bell\r
	call	bdos		;Ring the bell.\r
	lhld	cmcptr		;Move the pointer to before the escape.\r
	dcx	h\r
	shld	cmcptr\r
	shld	cmdptr\r
	lxi	h,cmccnt	;Get the char count.\r
	dcr	m		;Decrement it by one.\r
	pop	h\r
	pop	b\r
	pop	d\r
	inr	e		;Increment the left to parse char count.\r
	jmp	cmkey3\r
\r
cmky32:	lhld	cmcptr		;Pointer into buffer.\r
	dcx	h		;Backup to the escape.\r
	xchg\r
	pop	h\r
	push	h\r
cmky33:	mov	a,m		;Get the next char.\r
	cpi	'$'             ;Finished?\r
	jz	cmky34\r
	inx	h\r
	xchg\r
	mov	m,a		;Move it into the buffer.\r
	inx	h\r
	xchg\r
	lda	cmccnt		;Increment the char count.\r
	inr	a\r
	sta	cmccnt\r
	jmp	cmky33\r
\r
cmky34:	lda	cmccnt		;Get the character count.\r
	inr	a		;Increment and save it.\r
	sta	cmccnt\r
	xchg			;Put the command buffer pointer in HL.\r
	mvi	a,' '           ;Get a blank.\r
	mov	m,a		;Put it in the command buffer.\r
	inx	h		;Increment the pointer\r
	shld	cmcptr		;Save the updated pointer.\r
	shld	cmdptr\r
	pop	h\r
	push	h\r
	xchg\r
	call	prtstr		;Print the rest of the keyword.\r
	mvi	c,conout\r
	mvi	e,' '\r
	call	bdos		;Print a blank.\r
	pop	h\r
	pop	b\r
	pop	d\r
	jmp	cmky37\r
\r
cmky35:	push	h\r
	push	d\r
	call	cmambg\r
	jmp	cmky36\r
	lxi	d,cmer01\r
	call	prtstr		;Say its ambiguous.\r
	jmp	prserr		;Give up.\r
\r
cmky36:	pop	d\r
	pop	h\r
cmky37:	inr	e		;Add one incase it is negative.\r
	mvi	d,0\r
	dad	d		;Increment past the keyword.\r
	inx	h		;Past the $.\r
	mov	e,m		;Get the data.\r
	inx	h\r
	mov	d,m\r
	mov	a,e\r
	jmp	rskp\r
\r
cmkey4:	cpi	'a'             ;Is it less than a?\r
	jm	cmky41		;If so don't capitalize it.\r
	cpi	'z'+1           ;Is it more than z?\r
	jp	cmky41		;If so don't capitalize it.\r
	ani	137O		;Capitalize it.\r
cmky41:	mov	d,m		;Get the next char of the keyword.\r
	inx	h\r
	cmp	d		;Match?\r
	jz	cmkey3		;If so get the next letter.\r
\r
cmkey5:	mvi	d,0\r
	mov	a,e		;Get the number of chars left.\r
	ora	a		;Is it negative?\r
	jp	cmky51\r
	mvi	d,0FFH		;If so, sign extend.\r
cmky51:	dad	d		;Increment past the keyword.\r
	lxi	d,0003H		;Plus the $ and data.\r
	dad	d\r
	shld	cmkptr\r
	dcr	b		;Decrement the number of entries left.\r
	lhld	cmsptr		;Get the old cmdptr.\r
	shld	cmdptr		;Restore it.\r
;* check so we don't pass it.\r
	jmp	cmkey2		;Go check the next keyword.\r
;\f\r
;       Test keyword for ambiguity.\r
;       returns: nonskip if ambiguous, skip if OK.\r
;       called by: cmkeyw\r
\r
cmambg:	dcr	b		;Decrement the number of entries left.\r
	rm			;If none left then it is not ambiguous.\r
	inr	e		;This is off by one;adjust.\r
	mov	c,e		;Save the char count.\r
	mov	a,e\r
	ora	a		;Any chars left?\r
	rz			;No, it can't be ambiguous.\r
	mvi	d,0\r
	dad	d		;Increment past the keyword.\r
	mvi	e,3		;Plus the $ and data.\r
	dad	d\r
	mov	b,m		;Get the length of the keyword.\r
	inx	h\r
	xchg\r
	lhld	cmkptr		;Get pointer to keyword entry.\r
	mov	a,m		;Get the length of the keyword.\r
	sub	c		;Subtract how many left.\r
	mov	c,a		;Save the count.\r
	cmp	b\r
	jz	cmamb0\r
	rp			;If larger than the new word then not amb.\r
cmamb0:	lhld	cmsptr		;Get the pointer to what parsed.\r
cmamb1:	dcr	c		;Decrement the count.\r
	jm	rskp		;If we are done then it is ambiguous.\r
	xchg			;Exchange the pointers.\r
	mov	b,m		;Get the next char of the keyword\r
	inx	h\r
	xchg			;Exchange the pointers.\r
	mov	a,m		;Get the next parsed char.\r
	inx	h\r
	cpi	'a'             ;Is it less than a?\r
	jm	cmamb2		;If so don't capitalize it.\r
	cpi	'z'+1           ;Is it more than z?\r
	jp	cmamb2		;If so don't capitalize it.\r
	ani	137O\r
cmamb2:	cmp	b		;Are they equal?\r
	rnz			;If not then its not ambiguous.\r
	jmp	cmamb1		;Check the next char.\r
;\f\r
;       cmofil - parse output filespec\r
;       cmifil - parse input filespec\r
;       here from: comnd\r
\r
cmofil:	mvi	a,0		;Don't allow wildcards.\r
;       jmp     cmifil          ;For now, the same as CMIFI.\r
cmifil:	sta	cmfwld		;Set wildcard flag\r
	xchg			;Get the fcb address.\r
	shld	cmfcb		;Save it.\r
	mvi	e,0		;Initialize char count.\r
	mvi	m,0		;Set the drive to default to current.\r
	inx	h\r
	shld	cmfcb2\r
	xra	a		;Initialize counter.\r
cmifi0:	mvi	m,' '           ;Blank the FCB.\r
	inx	h\r
	inr	a\r
;       cpi     0CH             ;Twelve? [5a dont use this]\r
	cpi	0Bh		; [majoc 850585] Eleven?\r
	jm	cmifi0\r
cmif0a:				;[MF]Zero entire fcb, not just the extent\r
	mvi	m,0		; [majoc 850507] Specify extent 0\r
	inx	h		;[MF]Increment fcb byte pointer\r
	inr	a		;[MF]Increment fcb byte count\r
	cpi	32		;[MF]Done with fcb?\r
	jm	cmif0a		;[MF]No, zero until done\r
cmifi1:	call	cmgtch		;Get another char.\r
	ora	a		;Is it an action character?\r
	jp	cmifi2\r
	ani	7FH		;Turn off the action bit.\r
	cpi	'?'             ;A question mark?\r
	jnz	cmif12\r
	lda	cmfwld		;[pcc006] Wildcards allowed?\r
	ora	a		;[pcc006]\r
	jz	cmif11		;[pcc006] complain if not\r
	lhld	cmdptr		;[jd] Increment buffer pointer\r
	inx	h		;[jd] that was decremented in cmgtch\r
	shld	cmdptr		;[jd] since we want this chr\r
	lda	cmcptr		;[pcc006] get lsb of real input pointer\r
	cmp	l		;[pcc006] is this the last chr input?\r
	jnz	cmif1a		;[pcc006] no, don't reset action flag\r
	xra	a		;[pcc006] yes, reset action flag\r
	sta	cmaflg		;[pcc006] \r
cmif1a:	mvi	a,'?'           ;[pcc006] get it back in A\r
	jmp	cmifi8		;Treat like any other character\r
\r
cmif12:	cpi	esc		;An escape?\r
	jnz	cmif13\r
;Try to recognize file-spec a'la TOPS-20\r
	xra	a\r
	sta	cmaflg		;Turn off the action flag.\r
	lhld	cmcptr		;Move the pointer to before the escape.\r
	dcx	h\r
	shld	cmcptr\r
	shld	cmdptr\r
	lxi	h,cmccnt	;Get the char count.\r
	dcr	m		;Decrement it by one.\r
	mov	a,e		;Save character count up to now.\r
	sta	temp1\r
	cpi	9		;Past '.'?\r
	jm	cmfrec		;No.\r
	dcr	a		;Yes, don't count point.\r
cmfrec:	lhld	cmfcb2		;Fill the rest with CP/M wildcards.\r
cmfrc1:	cpi	11		;Done?\r
	jp	cmfrc2		;Yes.\r
	mvi	m,'?'\r
	inx	h\r
	inr	a\r
	jmp	cmfrc1\r
\r
cmfrc2:	mvi	c,sfirst	;Find first matching file?\r
	lhld	cmfcb\r
	xchg\r
	call	bdos\r
	cpi	0FFH\r
	jz	cmfrc9		;No, lose.\r
	lxi	h,fcbblk	;Copy first file spec.\r
	call	fspcop\r
	lxi	h,fcbblk+10H	;Get another copy (in case not ambiguous).\r
	call	fspcop\r
	mvi	c,snext		;More matching specs?\r
	lhld	cmfcb\r
	xchg\r
	call	bdos\r
	cpi	0FFH\r
	jz	cmfrc3		;Only one.\r
	lxi	h,fcbblk+10H	;Copy second file spec.\r
	call	fspcop\r
cmfrc3:	lxi	d,fcbblk	;Start comparing file names.\r
	lxi	h,fcbblk+10H\r
	lda	temp1		;Bypass characters typed.\r
	cpi	9		;Past '.'?\r
	jm	cmfrc4		;No.\r
	dcr	a		;Yes, don't count point.\r
cmfrc4:	mvi	c,0\r
cmfrl1:	cmp	c		;Bypassed?\r
	jz	cmfrl2		;Yes.\r
	inx	d\r
	inx	h\r
	inr	c\r
	jmp	cmfrl1		;Repeat.\r
\r
cmfrl2:	mov	a,c		;Get file name characters processed.\r
	cpi	11		;All done?\r
	jz	cmfrc5		;Yes.\r
	cpi	8		;End of file name?\r
	jnz	cmfrl3		;No.\r
	lda	temp1		;Exactly at point?\r
	cpi	9\r
	jz	cmfrl3		;Yes, don't output a second point.\r
	mvi	a,'.'           ;Output separator.\r
	call	cmfput\r
cmfrl3:	ldax	d		;Get a character from first file spec.\r
	inx	d\r
	mov	b,m		;Get from second file spec.\r
	inx	h\r
	cmp	b		;Compare.\r
	jnz	cmfrc5		;Ambiguous.\r
	inr	c		;Same, count.\r
	cpi	' '             ;Blank?\r
	jz	cmfrl2		;Yes, don't output.\r
	call	cmfput		;Put character into buffer.\r
	jmp	cmfrl2		;Repeat.\r
\r
cmfrc5:	mov	a,c		;Get count of characters processed.\r
	sta	temp1		;Save it.\r
	mvi	a,'$'           ;Get terminator.\r
	call	cmfput		;Put it into buffer.\r
	lhld	cmdptr		;Output recognized characters.\r
	xchg\r
	mvi	c,prstr\r
	call	bdos\r
	lhld	cmcptr		;Remove terminator from buffer.\r
	dcx	h\r
	shld	cmcptr\r
	lxi	h,cmccnt\r
	dcr	m\r
	lda	temp1		;Characters processed.\r
	cpi	11		;Complete file name.\r
	jz	repars		;Yes, don't beep.\r
\r
cmfrc9:	mvi	c,conout\r
	mvi	e,bell\r
	call	bdos		;Ring the bell.\r
	jmp	repars\r
;\f\r
;       Continue file spec parsing.\r
\r
cmif13:	mov	a,e		;It must be a terminator.\r
	ora	a		;Test the length of the file name.\r
	jz	cmifi9		;If zero complain.\r
	cpi	0DH\r
	jp	cmifi9		;If too long complain.\r
	jmp	rskp		;Otherwise we have succeeded.\r
\r
cmifi2:	cpi	'.'\r
	jnz	cmifi3\r
	inr	e\r
	mov	a,e\r
	cpi	1H		;Any chars yet?\r
	jz	cmifi9		;No, give error.\r
	cpi	0AH		;Tenth char?\r
	jp	cmifi9		;Past it, give an error.\r
	mvi	c,9H\r
	mvi	b,0\r
	lhld	cmfcb\r
	dad	b		;Point to file type field.\r
	shld	cmfcb2\r
	mvi	e,9H		;Say we've gotten nine.\r
	jmp	cmifi1		;Get the next char.\r
\r
cmifi3:	cpi	':'\r
	jnz	cmifi4\r
	inr	e\r
	mov	a,e\r
	cpi	2H		;Is it in the right place for a drive?\r
	jnz	cmifi9		;If not, complain.\r
	lhld	cmfcb2\r
	dcx	h		;Point to previous character.\r
	mov	a,m		;Get the drive name.\r
	sui	'@'             ;Get the drive number.\r
	shld	cmfcb2		;Save pointer to beginning of name field.\r
	mvi	m,space		;[obs] restore a space in FCB\r
	dcx	h		;Point to drive number.\r
	mov	m,a		;Put it in the fcb.\r
	mvi	e,0		;Start character count over.\r
	jmp	cmifi1\r
\r
cmifi4:	cpi	'*'\r
	jnz	cmifi7\r
	lda	cmfwld		;Wildcards allowed?\r
	cpi	0\r
	jz	cmif11		;No,complain\r
	mov	a,e\r
	cpi	8H		;Is this in the name or type field?\r
	jz	cmifi9		;If its where the dot should be give up.\r
	jp	cmifi5		;Type.\r
	mvi	b,8H		;Eight chars.\r
	jmp	cmifi6\r
\r
cmifi5:	mvi	b,0CH		;Three chars.\r
cmifi6:	lhld	cmfcb2		;Get a pointer into the FCB.\r
	mvi	a,'?'\r
	mov	m,a		;Put a question mark in.\r
	inx	h\r
	shld	cmfcb2\r
	inr	e\r
	mov	a,e\r
	cmp	b\r
	jm	cmifi6		;Go fill in another.\r
	jmp	cmifi1		;Get the next char.\r
\r
cmifi7:	cpi	'!'             ;[pcc007] control chr or space?\r
	jm	cmifi9		;[pcc007] yes, illegal\r
	mov	h,a		;[5] stash input char for a bit\r
	lda	ffussy		;[5]  while we check the fussy flag\r
	ora	a		;[5] set the flags accordingly\r
	mov	a,h		;[5] restore the input character\r
	jz	cmif7a		;[5] if ffussy=0, allow <>.,;:?*[]\r
;[5] So far, we've eliminated "action characters" (including question),\r
;[5] period, colon, asterisk, control characters, and space.\r
;[5] That leaves us %(),/;<=>[\]_| to check for.\r
	cpi	'%'             ;[5]\r
	jz	cmifi9		;[5]\r
	cpi	'('             ;[5]\r
	jz	cmifi9		;[5]\r
	cpi	')'             ;[5]\r
	jz	cmifi9		;[5]\r
	cpi	','             ;[pcc007] weed out comma\r
	jz	cmifi9		;[pcc007]\r
	cpi	'/'             ;[5]\r
	jz	cmifi9		;[5]\r
	cpi	'9'+1           ;[pcc007] anything else 21H-39H is ok\r
	jm	cmifi8		;[pcc007] except '*' never gets here\r
	cpi	'@'             ;[pcc007] all of 3AH-3FH is illegal\r
	jm	cmifi9		;[pcc007]\r
	cpi	'['             ;[pcc007] [\] also illegal\r
	jm	cmifi8		;[pcc007]\r
	cpi	']'+1           ;[pcc007]\r
	jm	cmifi9		;[pcc007]\r
	cpi	'_'             ;[5]\r
	jz	cmifi9		;[5] (If I was doing CP/M, I would have\r
	cpi	'|'             ;[5]  just eliminated all them funny chars\r
	jz	cmifi9		;[5]  instead of a random selection)\r
cmif7a:				;[5]\r
	cpi	'a'             ;[pcc007] if not lower case its ok\r
	jm	cmifi8		;[pcc007] (DEL never gets here)\r
	cpi	'z'+1           ;[pcc007] only convert letters\r
	jp	cmifi8		;[pcc007]\r
	ani	137O		;Capitalize.\r
cmifi8:	lhld	cmfcb2		;Get the pointer into the FCB.\r
	mov	m,a		;Put the char there.\r
	inx	h\r
	shld	cmfcb2\r
	inr	e\r
	jmp	cmifi1\r
\r
cmifi9:	lda	cmstat\r
	cpi	cmifin		;"silent"?\r
	jz	r		;Yes,let him go w/o check\r
	lxi	d,cmer02\r
cmif10:	mvi	c,prstr\r
	call	bdos\r
	ret\r
\r
cmif11:	lxi	d,cmer03	;Complain about wildcards.\r
	jmp	cmif10\r
\r
;\f\r
\r
;       copy filename from buffer\r
;       called with HL = destination, A = position (0-3) in buffer\r
;       called by: cmifil\r
\r
fspcop:	push	psw		;Save A.\r
	lxi	d,buff		;Get the right offset in the buffer.\r
	rlc\r
	rlc\r
	rlc\r
	rlc\r
	rlc\r
	add	e\r
	inr	a		;Bypass drive spec.\r
	mov	e,a\r
	mvi	b,11		;Copy file name.\r
fspcp1:	ldax	d\r
	inx	d\r
	mov	m,a\r
	inx	h\r
	dcr	b\r
	jnz	fspcp1\r
	pop	psw		;Restore A.\r
	ret\r
\r
;       append character in A to command buffer\r
;       called by: cmifil\r
\r
cmfput:	push	h		;Save H.\r
	lhld	cmcptr		;Get buffer pointer.\r
	mov	m,a		;Store in buffer.\r
	inx	h\r
	shld	cmcptr\r
	lxi	h,cmccnt	;Count it.\r
	inr	m\r
	pop	h		;Restore H.\r
	ret\r
;\f\r
;       Read characters from the command buffer.\r
;       called by:  cmtext, cmcfrm, cmkeyw, cmifil\r
\r
cmgtch:	push	h\r
	push	b\r
cmgtc1:	lda	cmaflg\r
	ora	a		;Is it set.\r
	cz	cminbf		;If the action char flag is not set get more.\r
	lhld	cmdptr		;Get a pointer into the buffer.\r
	mov	a,m		;Get the next char.\r
	inx	h\r
	shld	cmdptr\r
	cpi	' '             ;Is it a space?\r
	jz	cmgtc2\r
	cpi	tab		;Or a tab?\r
	jnz	cmgtc3\r
cmgtc2:	lda	cmsflg		;Get the space flag.\r
	ora	a		;Was the last char a space?\r
	jnz	cmgtc1		;Yes, get another char.\r
	mvi	a,0FFH		;Set the space flag.\r
	sta	cmsflg\r
	mvi	a,' '\r
	pop	b\r
	pop	h\r
	jmp	cmgtc5\r
\r
cmgtc3:	push	psw\r
	xra	a\r
	sta	cmsflg		;Zero the space flag.\r
	pop	psw\r
	pop	b\r
	pop	h\r
	cpi	esc\r
	jz	cmgtc5\r
	cpi	'?'             ;Is the user curious?\r
	jz	cmgtc4\r
	cpi	cr\r
	jz	cmgtc4\r
	cpi	lf\r
	jz	cmgtc4\r
	cpi	ff\r
	rnz			;Not an action char, just return.\r
cmgtc4:	push	h\r
	lhld	cmdptr\r
	dcx	h\r
	shld	cmdptr\r
	pop	h\r
cmgtc5:	ori	80H		;Make the char negative to indicate it is\r
	ret			;a terminator.\r
;\f\r
;       Read characters from console into command buffer, processing\r
;       editing characters (^H, ^M, ^J, ^L, ^U, ^X, ?, del).\r
;       called by: comnd, cmgtch\r
\r
cminbf:	push	psw\r
	push	d\r
	push	h\r
	lda	cmaflg		;Is the action char flag set?\r
	ora	a\r
	jnz	cminb9		;If so get no more chars.\r
cminb1:	lxi	h,cmccnt	;Increment the char count.\r
	inr	m\r
	mvi	c,conin		;Get a char.\r
	lda	cmqflg		;[MF]but do we want it echoed?\r
	ora	a		;[MF]...\r
	jz	cmin1b		;[MF]Yup, proceed normally\r
cmin1c:	mvi	e,0ffH		;[MF]Nope, do it with Direct\r
	mvi	c,dconio	;[MF]Console I/O\r
	call	bdos		;[MF]...\r
	ora	a		;[MF]Did the user type anything?\r
	jz	cmin1c		;[MF]No, don't go on until he/she does.\r
	jmp	cmin1a		;[MF]We got a character\r
cmin1b:	call	bdos\r
cmin1a:	lhld	cmcptr		;Get the pointer into the buffer.\r
	mov	m,a		;Put it in the buffer.\r
	inx	h\r
	shld	cmcptr\r
	cpi	25O		;Is it a ^U?\r
	jz	cmnb12		;Yes.\r
	cpi	30O		;Is it a ^X?\r
	jnz	cminb2\r
cmnb12:	call	clrlin		;Clear the line.\r
	call	prprmp		;Print the prompt  [Toad Hall]\r
	lxi	h,cmdbuf\r
	shld	cmcptr		;Reset the point to the start.\r
	lxi	h,cmccnt	;Zero the count.\r
	mvi	m,0\r
	jmp	repars		;Go start over.\r
\r
cminb2:	cpi	10O		;Backspace?\r
	jz	cminb3\r
	cpi	del		;or Delete?\r
	jnz	cminb4\r
	lda	cmqflg		;[MF]If we are echoing characters,\r
	ora	a		;[MF]...\r
	cz	delchr		;Print the delete string. [MF]\r
cminb3:	lda	cmccnt		;Decrement the char count by two.\r
	dcr	a\r
	dcr	a\r
	ora	a		;Have we gone too far?\r
	jp	cmnb32		;If not proceed.\r
	mvi	c,conout	;Ring the bell.\r
	mvi	e,bell\r
	call	bdos\r
	jmp	cmnb12		;Go reprint prompt and reparse.\r
\r
cmnb32:	sta	cmccnt		;Save the new char count.\r
	lda	cmqflg		;[MF]Echoing characters?\r
	ora	a		;[MF]If we are, then\r
	cz	clrspc		;Erase the character. [MF]\r
	lhld	cmcptr		;Get the pointer into the buffer.\r
	dcx	h		;Back up in the buffer.\r
	dcx	h\r
	shld	cmcptr\r
	jmp	repars		;Go reparse everything.\r
\r
cminb4:	cpi	'?'             ;Is it a question mark.\r
	jz	cminb6\r
	cpi	esc		;Is it an escape?\r
	jz	cminb6\r
	cpi	cr		;Is it a carriage return?\r
	jz	cminb5\r
	cpi	lf		;Is it a line feed?\r
	jz	cminb5\r
	cpi	ff		;Is it a formfeed?\r
	jnz	cminb8		;no - just store it and \r
				;test if buffer overflowing, else get another character.\r
	call	clrtop\r
cminb5:	lda	cmbflg		;[MF]Allowing initial blank word (<cr>)?\r
	ora	a		;[MF]...\r
	jnz	cminb6		;[MF]Yes\r
	lda	cmccnt		;Have we parsed any chars yet?\r
	cpi	1\r
	jz	prserr		;If not, just start over.\r
cminb6:	mvi	a,0FFH		;Set the action flag.\r
	sta	cmaflg\r
	jmp	cminb9\r
\r
cminb8:\r
	lda	cmccnt		; get the command character count\r
	cpi	cmbufl		; check for comand buffer length\r
	jm	cminb1		; if less, then all ok\r
	mvi	e,bell		; else beep at user\r
	call	outcon		; send it to the console\r
	lda	cmccnt		; back up one character\r
	dcr	a\r
	sta	cmccnt\r
	lhld	cmcptr		; ditto pointer\r
	dcx	h\r
	shld	cmcptr		; save it again\r
	jmp	cminb1		; and try again\r
\r
cminb9:	pop	h\r
	pop	d\r
	pop	psw\r
	ret\r
;\f\r
;Little utility to print the prompt.  (We do a LOT of these.)  [Toad Hall]\r
;Enters with nothing.\r
;Destroys HL (and I suppose B and DE and A).\r
 \r
prprmp:	mvi	e,cr		; do a cr first\r
	mvi	c,dconio\r
	call	bdos\r
	lhld	cmprmp		;Get the prompt.\r
	xchg\r
	call	prtstr\r
	ret\r
\r
; Little code to allow some expansion of code without changing\r
;  every futher address, only up to the end of this file.\r
;   TO BE REMOVED FOR RELEASE!\r
\r
;	org ($+100h) AND 0FF00H\r
\r
\r
IF	lasm\r
LINK	CPSUTL\r
ENDIF	;lasm  [Toad Hall]\r