Bugfix in outmdm (output buffer flush)

[kermit-80.git] / cpxtm4.asm

;CPXTM4.ASM\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.0\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;       This file contains the system-dependent code and data for various\r
;       Tandy Model 4 running under Montezuma Micro CPM\r
;\r
; This has the Family name of CPXTM4.ASM.\r
;\r
; revision history (last edit first)\r
;\r
; edit 5,  8-Feb-1991 by Lance Tagliapietra of the University of Wisconsin-\r
;       Platteville. Corrected error in the VT52 translation table for\r
;       clearing from the cursor to the end of the line.\r
;\r
; edit 4, 27 October, 1987 by OBSchou.  Massaged into format suitable\r
;       for overlay version 4.09\r
;\r
; Edit 3: Sept 5 1987 GDS Transformed code from Genie III to Tandy Model 4\r
;\r
; Edit 2: Aug 27 1987 GDS Put in code for BREAK and fillited out\r
;         a lot of unnecessary IF's\r
;\r
;Edit 1: Nov. 28, 1986 Geof Smith Clinical Research centre Harrow UK.\r
 \r
 \r
.printx * Assembling for Tandy Model 4*\r
;\r
drtime  EQU     05H     ;Default receive time out interval.\r
;\r
; the basics...\r
;\r
mnport EQU 0EBH\r
mnprts EQU 0EAH\r
output EQU 40H\r
input  EQU 80H\r
lctrl  EQU 0E8H\r
baudpt EQU 0E9H\r
z80    EQU TRUE\r
brkval EQU 0H\r
inout  EQU TRUE\r
 \r
defesc EQU 'X'-100O ;The default escape character.\r
 \r
 \r
;Select initial setting for VT-52 emulation flag.\r
 \r
; default to VT52-EMULATION ON.\r
;\r
vtval   EQU     1\r
;\r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;       Family is the string used in VERSION to say which of several\r
;       smaller overlay files are used.  These are (will be) derived from\r
;       the huge CP4SYS.ASM file, in which case we will never get here.\r
;       Just a Dollar, but put a sting in for a family of machines.\r
;\r
family: db      'CPXTM4.ASM  (5) 8-Feb-91$'     ; Used for family versions....\r
 \r
 \r
;\r
;       System-dependent initialization\r
;       Called once at program start.\r
sysxin:\r
;\r
                        ;Set up 9600 bd, 8bit words, no parity 1stop bit\r
 \r
        mvi     a,0EEH          ;Get byte for desired baud (9600 = CC) and\r
        out     baudpt          ;and put it out of baud port\r
        out     lctrl           ;latch control port with anything\r
        lda     pstore          ;get parity etc and put it out of\r
        out     mnprts          ;port\r
        ret                     ; return from system-dependent routine\r
 \r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;\r
;       system-dependent termination processing\r
;       If we've changed anything, this is our last chance to put it back.\r
sysexit:\r
        ret\r
;\r
;       system-dependent processing for start of CONNECT command\r
;\r
syscon:\r
        ret\r
 \r
conmsg:         ; Messages printed when entering transparent (CONNECT) mode:\r
;-------------------------------------------------------------------------------\r
;   --\r
;\r
;       syscls - system-dependent close routine\r
;       called when exiting transparent session.\r
;\r
syscls:\r
       ret\r
;-------------------------------------------------------------------------------\r
;   ---\r
;\r
;       sysinh - help for system-dependent special functions.\r
;       called in response to <escape>?, after listing all the\r
;       system-independent escape sequences.\r
;\r
sysinh:\r
        lxi     d,inhlps        ; we got options...\r
        call    prtstr          ; print them.\r
        ret\r
 \r
 \r
;additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
inhlps:\r
 \r
        db      cr,lf,'B  Transmit a BREAK'\r
 \r
        db      '$'                     ;[hh] table terminator\r
 \r
;\r
;       sysint - system dependent special functions\r
;       called when transparent escape character has been typed;\r
;       the second character of the sequence is in A (and in B).\r
;       returns:\r
;       non-skip: sequence has been processed\r
;       skip:   sequence was not recognized\r
sysint: ani     137O            ; convert lower case to upper, for testing...\r
        cpi     'B'             ; send break?\r
        jz      sendbr          ; yes, go do it.  return nonskip when through.\r
 \r
        jmp     rskp            ; take skip return - command not recognized.\r
 \r
 \r
;-------------------------------------------------------------------------------\r
sendbr:\r
;\r
;       Ensure that the transmitter has finished sending buffered chars\r
sndbr1: in      mnprts          ; get UART status\r
        ani     output         ; everything sent?\r
        jz      sndbr1          ; no, wait a bit more\r
;\r
;       Begin sending a break by setting bit in UART command register\r
        mvi     a,brkval           ;  SBreak,\r
        out     lctrl\r
        out     mnprts\r
;\r
 \r
;       Wait for 250 milliseconds (using hundredths second delay routine)\r
        mvi     a,25\r
        call    delay\r
;\r
;       Resume normal operation by clearing the SendBreak command bit\r
        lda     pstore            ;get parity etc value\r
        out     lctrl               ;latch control port\r
        out     mnprts              ;and set values\r
;\r
        ret                     ;done\r
 \r
;\r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;\r
;       sysflt - system-dependent filter\r
;       called with character in E.\r
;       if this character should not be printed, return with A = zero.\r
;       preserves bc, de, hl.\r
;       note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
sysflt:\r
        mov     a,e             ; get character for testing\r
        ret\r
 \r
;       mdmflt - modem filter [30]\r
;       called with character to be sent to modem in E\r
;       with parity set as appropriate.\r
;       return with accumulator = 0 do do nothing,\r
;                               <> 0 to send char in E.\r
mdmflt: mov     a,e\r
        ret\r
 \r
 \r
 \r
;       prtflt - printer filter [30]\r
;       called with character to be sent to printer in E\r
;       returns with a = 0 to do nothing\r
;                    a <> 0 to print it.\r
;\r
;       this routine for those printer that automatically insert\r
;       a lf on cr, or cr for lf.  Should this be shifted to\r
;       the system indep. stuff, in say 4.06?\r
prtflt:\r
        mov     a,e             ; [30] get character to test\r
        ret\r
 \r
 \r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;\r
; system-dependent processing for BYE command.\r
;  for apmmdm, heath, and lobo, hang up the phone.\r
sysbye:\r
        ret\r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;       This is the system-dependent command to change the baud rate.\r
;       DE contains the two-byte value from the baud rate table; this\r
;       value is also stored in 'speed'.\r
sysspd:\r
                        ;Set up baud rate 8bit words, no parity 1stop bit\r
 \r
        mov     a,e             ;get get speed into a\r
        out     baudpt          ;output it as well\r
        lda     pstore          ;get parity etc\r
        out     lctrl           ;do it resetting DLAB at same time\r
        out     mnprts\r
        ret\r
 \r
pstore:     db 6CH  ;Default value for parity word length and stop bits\r
 \r
spdtbl: db    10h               ;17 entries\r
     db     03h,'110$',     22H,22H\r
     db     04h,'1200$',     77H,77H\r
     db     05h,'134.5$',     33H,33H\r
     db     03h,'150$',     44H,44H\r
     db     04h,'1800$',     88H,88H\r
     db     05h,'19200$',    0FFH,0FFH\r
     db     04h,'2000$',     99H,99H\r
     db     04h,'2400$',    0AAH,0AAH\r
     db     03h,'300$',     55H,55H\r
     db     04h,'3600$',    0BBH,0BBH\r
     db     04h,'4800$',    0CCH,0CCH\r
     db     02h,'50$',     00H,00H\r
     db     03h,'600$',     66H,66H\r
     db     04h,'7200$',    0DDH,0DDH\r
     db     02h,'75$',     11H,11H\r
     db     04h,'9600$',    0EEH,0EEH\r
 \r
sphtbl: db     cr,lf,'   50      75    110    134.5  150    300    600   1200'\r
     db     cr,lf,' 1800   2000   2400   3600   4800   7200   9600  19200  $'\r
 \r
;       This is the system-dependent SET PORT command.\r
;       HL contains the argument from the command table.\r
sysprt:\r
        ret\r
;\r
prttbl  equ     0               ; SET PORT not supported\r
prhtbl  equ     0\r
 \r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;\r
;       selmdm - select modem port\r
;       selcon - select console port\r
;       selmdm is called before using inpmdm or outmdm;\r
;       selcon is called before using inpcon or outcon.\r
;       For iobyt systems, diddle the I/O byte to select console or comm port;\r
;       For Decision I, switches Multi I/O board to console or modem serial\r
;       port.  [Toad Hall]\r
;       For the rest, does nothing.\r
;       preserves bc, de, hl.\r
selmdm:\r
        ret\r
 \r
selcon:\r
        ret\r
;\r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
 \r
;       Get character from console, or return zero.\r
;       result is returned in A.  destroys bc, de, hl.\r
;\r
inpcon:\r
        mvi     c,dconio        ;Direct console I/O BDOS call.\r
        mvi     e,0FFH          ;Input.\r
        call    BDOS\r
 \r
        ret\r
;\r
;       Output character in E to the console.\r
;       destroys bc, de, hl\r
;\r
outcon:\r
 \r
        mvi     c,dconio        ;Console output bdos call.\r
        call    bdos            ;Output the char to the console.\r
 \r
        ret\r
;\r
;\r
;       outmdm - output a char from E to the modem.\r
;               the parity bit has been set as necessary.\r
;       returns nonskip; bc, de, hl preserved.\r
outmdm:\r
 \r
        in      mnprts          ;Get the output done flag.\r
        ani     output          ;Is it set?\r
        jz      outmdm          ;If not, loop until it is.\r
        mov     a,e\r
        out     mnport          ;Output it.\r
        ret\r
 \r
;--------------------------------------------------------------------------\r
;\r
;       get character from modem; return zero if none available.\r
;       for IOBYT systems, the modem port has already been selected.\r
;       destroys bc, de, hl.\r
inpmdm:\r
;Note: modem port should already be selected for mdI.  [Toad Hall]\r
        in      mnprts          ;Get the port status into A.\r
        ani     input           ;See if the input ready bit is on.\r
        rz                      ;If not then return.\r
        in      mnport          ;If so, get the char.\r
        ret                     ; return with character in A\r
 \r
 \r
;\r
;       flsmdm - flush comm line.\r
;       Modem is selected.\r
;       Currently, just gets characters until none are available.\r
 \r
flsmdm: call    inpmdm          ; Try to get a character\r
        ora     a               ; Got one?\r
        jnz     flsmdm          ; If so, try for another\r
        ret                     ; Receiver is drained.  Return.\r
;-----------------------------------------------------------------------------\r
;\r
;       lptstat - get the printer status. Return a=0 if ok, or 0ffh if not.\r
lptstat:\r
        xra     a               ; assume it is ok.. this may not be necessary\r
        ret\r
 \r
;\r
;       outlpt - output character in E to printer\r
;       console is selected.\r
;       preserves de.\r
outlpt:\r
        push    d               ; save DE in either case\r
        call    prtflt          ; go through printer filter [30]\r
        ana     a               ; if A = 0 do nothing,\r
        jz      outlp1          ; [30] if a=0 do nothing\r
 \r
        mvi     c,lstout\r
        call    bdos            ;Char to printer\r
outlp1: pop     d               ; restore saved register pair\r
        ret\r
;------------------------------------------------------------------------------\r
;\r
;       Screen manipulation routines\r
;       csrpos - move to row B, column C\r
;\r
;       csrpos for terminals that use a leadin sequence followed\r
;        by (row + 31.) and (column + 31.)\r
;\r
csrpos: push    b               ; save coordinates\r
        lxi     d,curldn        ; get cursor leadin sequence\r
        call    prtstr          ; print it\r
        pop     h               ; restore coordinates\r
        mov     a,h             ; get row\r
        adi     (' '-1)         ; space is row one\r
        mov     e,a\r
        push    h\r
        call    outcon          ; output row\r
        pop     h\r
        mov     a,l             ; get column\r
        adi     (' '-1)         ; space is column one\r
        mov     e,a\r
        jmp     outcon          ; output it and return\r
 \r
;\r
; delchr - make delete look like a backspace.  Unless delete is a printing\r
;       character, we just need to print a backspace. (we'll output clrspc\r
;       afterwards)\r
;       For Kaypro and Vector General, delete puts a blotch on the screen.\r
;       For Apple and Osborne 1, delete moves but doesn't print.\r
delchr:\r
 \r
        mvi     e,bs            ;get a backspace\r
        jmp     outcon\r
 \r
; erase the character at the current cursor position\r
clrspc: mvi     e,' '\r
        call    outcon\r
        mvi     e,bs            ;get a backspace\r
        jmp     outcon\r
 \r
; erase the current line\r
clrlin: lxi     d,eralin\r
        jmp     prtstr\r
 \r
; erase the whole screen, and go home. preserves b (but not c)\r
clrtop: lxi     d,erascr\r
        jmp     prtstr\r
 \r
;[2] I see no real saving in having all screens in separate file and\r
;therefore have included screen definition here and commented out\r
;the link to VDU file\r
;\r
;\r
;Specific definitions for the Model IV screen\r
;\r
sysver: db 'Tandy Model IV$'\r
outlin: db 1aH,cr,lf,'            $'\r
erascr: db 1AH,'$'\r
eralin: db cr,15H,'$'\r
curldn: db esc,'=$'\r
ttab:\r
ta:     db 0BH,'$',0,0                    ;Cursor up\r
tb:     db 0AH,'$',0,0                    ;Cursor down\r
tc:     db 0CH,'$',0,0                    ;Cursor right\r
td:     db 08H,'$',0,0                    ;Cursor left\r
te:     db 1AH,'$',0,0                    ;Clear display\r
tf:     db 0FH,'$',0,0                    ;Reverse on\r
tg:     db 0EH,'$',0,0                    ;Reverse off\r
th:     db 1EH,'$',0,0                    ;Cursor home\r
ti:     db 0BH,'$',0,0                    ;Reverse linefeed\r
tj:     db 19H,'$',0,0                    ;Clear to end of screen\r
tk:     db 15H,'$',0,0                    ;Clear to end of line\r
 \r
ovlend equ $           ;End of overlay\r
 \r
        END\r