Add AVR-CP/M system (cpxac.asm) and a Makefile

[kermit-80.git] / cpxbbi.asm

IF NOT lasm\r
.printx * CPXBBI.ASM *\r
ENDIF	;NOT lasm\r
;       KERMIT - (Celtic for "FREE")\r
;\r
;       This is the CP/M-80 implementation of the Columbia University\r
;       KERMIT file transfer protocol.\r
;\r
;       Version 4.08\r
;\r
;       Copyright June 1981,1982,1983,1984,1985\r
;       Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;\r
;\r
; revision history:\r
;\r
;edit 4, 7-Jan-1991 by MF. Added code to support the Ampro Little Board.\r
;	The code was contributed by Jay S. Rouman; 913 North Drive;\r
;	Mt. Pleasant, MI 48858 (voice (517)773-7887).\r
; edit 3, 23 July by OBSchou to massage file to suit CPXCOM.ASM\r
;\r
; edit 2 23 May 1987 by C.J.MILES@UMRCC.\r
;	Reorganised file to be similar in structure to that\r
;	of the Amstrad sys-dep file. Added hangup in clear\r
;	screen options in CONNECT mode.\r
;\r
; edit 1 10 May 1987 by Chris Miles (C.J.MILES@UMRCC)\r
;        Removed Kaypro, Xerox and Big Board from CPXSYS.ASM\r
;        and grouped them into this file as CPXBBI.ASM.\r
;\r
;\r
;\r
; Original code broken off and modified by:\r
;\r
; Chris Miles\r
; 344, Claremont Road,\r
; Rusholme,\r
; MANCHESTER,\r
; M14 6WB.\r
;\r
; Tel: (061) 226 7839\r
;\r
\r
;\r
; 		*** MAIN CODE START ***\r
;\r
;\r
; Keep module name, edit number, and last revision date in memory.\r
\r
sysedt: db      'CPXSYS.ASM (35) 01-Dec-86$'\r
family: db	'CPXBBI.ASM (4)  7-Jan-1991$'\r
\r
\r
; Assembly time message announcing which version we're building\r
\r
IF kpii\r
.printx * Assembling Kaypro II KERMIT-80 *\r
ENDIF\r
\r
IF xer820\r
.printx * Assembling Xerox 820 KERMIT-80 *\r
ENDIF\r
\r
IF bbII\r
.printx * Assembling BigBoard II KERMIT-80 *\r
ENDIF\r
\r
IF ampro\r
.printx * Assembling Ampro Little Board KERMIT-80 *\r
ENDIF\r
\r
z80	EQU	TRUE	; They all use Z80s\r
\r
IF xer820\r
defesc  EQU     ']'-100O        ;The default escape character for Xerox\r
ENDIF;xer820\r
\r
IF kpII\r
defesc  EQU     '\'-100O        ;The default escape character for Kaypro\r
ENDIF;kpII\r
\r
; If one of the above, default to VT52-EMULATION ON.\r
IF kpII OR xer820\r
vtval   EQU     1\r
ENDIF;kpII OR xer820\r
\r
\r
;\r
; Specific machine hardware information\r
;\r
IF bbI\r
mnport  equ     04h             ; Modem data port\r
mnprts  equ     06h             ; Modem status port\r
output  equ     04h             ; Transmit buffer empty\r
input   equ     01h             ; Receive data available\r
baudrt  equ     00h             ; Baud rate port for channel A\r
ENDIF;bbI\r
\r
\r
IF bbII\r
mnport  equ     80h             ; Modem data port (SIO channel A)\r
mnprts  equ     81h             ; Modem status port\r
output  equ     04h             ; Transmit buffer empty\r
input   equ     01h             ; Receive data available\r
baudrt  equ     89h             ; Baud rate port for channel A\r
ENDIF;bbII\r
\r
IF ampro\r
mnport  equ     88h             ; Modem data port (SIO channel B)\r
mnprts  equ     8Ch             ; Modem status port\r
output  equ     04h             ; Transmit buffer empty\r
input   equ     01h             ; Receive data available\r
baudrt  equ     50h             ; Baud rate port for channel B\r
ENDIF;ampro\r
;\r
\r
sysxin:		;continuation of system initialisation code\r
        lxi     d,siotbl        ; Load the address of the status able\r
        mvi     c,siolen        ; Length of status table\r
siolup: 			; Loop back here for each command byte\r
        ldax    d               ; Load the first byte into A\r
        inx     d               ; Index the pointer\r
        out     mnprts          ; Send it to the status port\r
        dcr     c               ; Decrement the byte counter\r
        jnz     siolup          ; Jump back for more commands\r
        ret                     ; return from system-dependent routine\r
\r
; List of commands to set up SIO channel A for asynchronous operation.\r
\r
siotbl: DB      18H             ; Channel reset\r
        DB      18H             ; another, in case register 0 wasn't selected\r
        DB      04H             ; Select register 4\r
        DB      44H             ; 1 stop bit, clock*16\r
        DB      01H             ; Select register 1\r
        DB      00H             ; No interrupts enabled\r
        DB      03H             ; Select register 3\r
        DB      0C1H            ; Rx enable, 8 bit Rx character\r
        DB      05H             ; Select register 5\r
        DB      0EAH            ; Tx enable, 8 bit Tx character,\r
                                ;  raise DTR and RTS\r
siolen  equ     $-siotbl        ; length of command list\r
\r
\r
;\r
; sysexit - System-dependent termination processing\r
; 	    if we've changed anything, this is our last\r
;	    chance to put it back.\r
;\r
sysexit:\r
        ret\r
\r
;\r
; syscon - System-dependent processing for start\r
;	   of CONNECT command.\r
;\r
syscon:\r
	lxi	d,conmsg\r
	call	prtstr\r
        ret\r
\r
conmsg:         ; Messages printed when entering transparent (CONNECT) mode:\r
	db	cr,lf,'$'\r
;\r
; syscls - system-dependent close routine\r
;          called when exiting transparent session.\r
;\r
syscls:\r
        ret\r
;\r
; sysinh - help for system-dependent special functions.\r
;          called in response to <escape>?, after listing\r
;          all the system-independent escape sequences.\r
;\r
sysinh:\r
        lxi     d,inhlps        ; we got options...\r
        call    prtstr          ; print them.\r
        ret\r
\r
\r
; additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
inhlps:\r
        db      cr,lf,'B  Transmit a BREAK'\r
	db	cr,lf,'H  Hangup using DTR'\r
	db	cr,lf,'W  Wipe screen clear'\r
	db	'$'\r
\r
; sysint - system dependent special functions\r
;          called when transparent escape character has been typed;\r
;          the second character of the sequence is in A (and in B).\r
;          returns:-\r
;                non-skip: sequence has been processed\r
;                skip    : sequence was not recognized\r
;\r
sysint: ani     137O            ; convert lower case to upper, for testing...\r
        cpi     'B'             ; send break ?\r
        jz      sendbr          ; then jump to send break routine\r
	cpi	'H'		; hang up ?\r
	jz	hangup		; then jump to hangup routine\r
	cpi	'W'		; clear screen ?\r
	jz	clrtop		; then jump to clear screen routine\r
        jmp     rskp            ; take skip return - command not recognized.\r
\r
;\r
; Hangup and Break routines\r
;\r
hangup:\r
	mvi	d,0ah		; set up hangup bit mask\r
	mvi	e,255		; time for hangup is 2 1/2 secs\r
	jmp	setbit		; skip Tx empty test\r
\r
sendbr:\r
	mvi	d,9ah		; set up break bit mask\r
	mvi	e,30		; time for break is 300 ms\r
\r
sndbr1: mvi     a,1             ; select Read Register 1\r
        out     mnprts\r
        in      mnprts          ; read the contents\r
        ani     1               ; test "all done" flag\r
        jz      sndbr1          ; loop until it's nonzero.\r
;\r
; Next, set the break or DTR bit on the SIO\r
;\r
setbit:	\r
	mvi     a,5		; select Write Register 5\r
        out     mnprts\r
        mvi     a,6ah		; Tx enable, 8 bit Tx character,\r
	ora	d		; OR with appropriate bit mask\r
	out     mnprts          ; \r
;\r
;       Now, delay for duration of hangup or break\r
        mov     a,e		; delay count\r
        call    delay\r
;\r
;       Time's up. Put transmitter back in normal state and return.\r
        mvi     a,5             ; select Write Register 5\r
        out     mnprts\r
        mvi     a,0eah		; Tx enable, 8 bit Tx character,\r
        out     mnprts          ;.\r
        ret                     ; done.\r
\r
; sysflt - system-dependent filter\r
;          called with character in E.\r
;          if this character should not be printed, return with A = zero.\r
;          preserves bc, de, hl.\r
;          note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
;\r
sysflt:\r
        mov     a,e             ; get character for testing\r
	ret\r
\r
;\r
; sysbye - system-dependent processing for BYE command.\r
;\r
sysbye:\r
        ret\r
;\r
; This is the system-dependent command to change the baud rate.\r
; DE contains the two-byte value from the baud rate table; this\r
; value is also stored in 'speed'.\r
;\r
sysspd:\r
\r
; Set the speed for bigboard II\r
IF bbII\r
        di                      ; don't let anything between the data bytes\r
        mvi     a,01000111b     ; get the command byte (load time constant)\r
        out     baudrt          ; output it to CTC\r
        mov     a,e             ; Get the parsed value.\r
        out     baudrt          ; Tell the baud rate generator.\r
        ei                      ; end of critical section\r
        ret\r
ENDIF;bbII\r
\r
\r
; Set the speed for bigboard I\r
IF bbI\r
        mov     a,e             ; get the parsed value\r
        out     baudrt          ; Tell the baud rate generator.\r
        ret\r
ENDIF;bbI\r
\r
; set the speed for the Ampro Little Board\r
if ampro\r
	mvi	e,3fh		; offset to port b ctc 3f hex bytes\r
	call	getbios\r
	mvi	a,47h		; counter mode,ctc reset,value follows\r
	mov	m,a		; store value\r
	lda	speed+1		; get ctc divisor\r
	inx	h		; location of ctc divisor\r
	mov	m,a		; store new divisor\r
;\r
; set up wr4 clock divisor according to mspeed\r
;\r
	mvi	e,50h		; offset to dart wr4\r
	call	getbios\r
	mvi	a,3fh		; mask for wr4 clock bits\r
	ana	m		; mask off bits\r
	mov	m,a		; and save to wr4\r
	lda	speed		; get clock flag\r
	ora	a		; set flags, zero = 300 bps\r
	mvi	a,80h		; x32 clock bit\r
	jz	lbps		; setup wr4 for 300 bps x32 clock\r
;\r
;  set up wr4 value for 1200 bps x16 clock 'hl' has wr4 loc\r
;\r
hbps:	mvi	a,40h		; x16 clock\r
;\r
;  setup wr4 value for 300 bps x32 clock 'hl' has wr4 loc\r
;\r
lbps:	ora	m		; set clock bits saving parity\r
	mov	m,a		; store new clock divisor to wr4 value\r
;\r
;  initialize sio/dart\r
;\r
intsio:	lxi	h,intend\r
	push	h		; set up for return\r
	mvi	e,36h		; offset to ioinit\r
	call	getbios\r
	pchl			; we pushed return address\r
intend:	ret\r
\r
;\r
;  return bios location in 'hl' called with offset in 'e'\r
;\r
getbios:\r
	lhld	1		; get bios location\r
	mvi	d,0		; clear 'd'\r
	dad	d\r
	ret\r
;\r
ENDIF;ampro\r
\r
;\r
;       Speed tables\r
; (Note that speed tables MUST be in alphabetical order for later\r
; lookup procedures, and must begin with a value showing the total\r
; number of entries.  The speed help tables are just for us poor\r
; humans.\r
\r
;       db      string length,string,divisor (2 identical bytes or 1 word)\r
; [Toad Hall]\r
\r
IF bbI\r
spdtbl: db      10h                     ;16 entries\r
        db      03h,'110$',     02h,02h\r
        db      04h,'1200$',    07h,07h\r
        db      05h,'134.5$',   03h,03h\r
        db      03h,'150$',     04h,04h\r
        db      04h,'1800$',    08h,08h\r
        db      05h,'19200$',   0fh,0fh\r
        db      04h,'2000$',    09h,09h\r
        db      04h,'2400$',    0ah,0ah\r
        db      03h,'300$',     05h,05h\r
        db      04h,'3600$',    0bh,0bh\r
        db      04h,'4800$',    0ch,0ch\r
        db      02h,'50$',      00h,00h\r
        db      03h,'600$',     06h,06h\r
        db      04h,'7200$',    0dh,0dh\r
        db      02h,'75$',      01h,01h\r
        db      04h,'9600$',    0eh,0eh\r
\r
sphtbl: db      cr,lf,'   50     75    110    134.5  150    300    600   1200'\r
        db      cr,lf,' 1800   2000   2400   3600   4800   7200   9600  19200$'\r
ENDIF;bbI\r
\r
IF bbII\r
spdtbl: db      8                       ; 8 entries\r
        db      04h,'1200$',    20h,20h\r
        db      05h,'19200$',   02h,02h\r
        db      04h,'2400$',    10h,10h\r
        db      03h,'300$',     80h,80h\r
        db      05h,'38400$',   01h,01h\r
        db      04h,'4800$',    08h,08h\r
        db      03h,'600$',     40h,40h\r
        db      04h,'9600$',    04h,04h\r
\r
sphtbl: db      cr,lf,'   300   600  1200  2400  4800  9600 19200 38400$'\r
ENDIF;bbII\r
\r
\r
IF ampro\r
spdtbl: db      6                       ; 6 entries\r
        db      04h,'1200$',    1,104\r
        db      04h,'2400$',    1,52\r
        db      03h,'300$',     0,208\r
        db      04h,'4800$',    1,26\r
        db      03h,'600$',     1,208\r
        db      04h,'9600$',    1,13\r
\r
sphtbl: db      cr,lf,'   300  600  1200  2400  4800  9600$'\r
ENDIF;ampro\r
\r
; This is the system-dependent SET PORT command.\r
; HL contains the argument from the command table.\r
;\r
sysprt:\r
        ret\r
;\r
\r
prttbl  equ     0               ; SET PORT is not supported\r
prhtbl  equ     0\r
\r
;\r
; selmdm - select modem port\r
; selcon - select console port\r
; selmdm is called before using inpmdm or outmdm;\r
; selcon is called before using inpcon or outcon.\r
; preserves BC, DE, HL.\r
;\r
selmdm:\r
selcon:\r
        ret\r
;\r
; Get character from console, or return zero.\r
; result is returned in A.  destroys bc, de, hl.\r
;\r
inpcon:\r
        mvi     c,dconio        ;Direct console I/O BDOS call.\r
        mvi     e,0FFH          ;Input.\r
        call    BDOS\r
        ret\r
;\r
;\r
;       Output character in E to the console.\r
;       destroys bc, de, hl\r
;\r
outcon:\r
\r
        mvi     c,dconio        ;Console output bdos call.\r
        call    bdos            ;Output the char to the console.\r
\r
        ret\r
;\r
;\r
;       outmdm - output a char from E to the modem.\r
;               the parity bit has been set as necessary.\r
;       returns nonskip; bc, de, hl preserved.\r
outmdm:\r
        in      mnprts          ;Get the output done flag.\r
        ani     output          ;Is it set?\r
        jz      outmdm          ;If not, loop until it is.\r
        mov     a,e\r
        out     mnport          ;Output it.\r
        ret\r
\r
\r
;\r
;       get character from modem; return zero if none available.\r
;       destroys bc, de, hl.\r
inpmdm:\r
        in      mnprts          ;Get the port status into A.\r
        ani     input           ;See if the input ready bit is on.\r
        rz                      ;If not then return.\r
        in      mnport          ;If so, get the char.\r
\r
	ret                     ; return with character in A\r
\r
\r
;\r
;       flsmdm - flush comm line.\r
;       Modem is selected.\r
;       Currently, just gets characters until none are available.\r
\r
flsmdm: call    inpmdm          ; Try to get a character\r
        ora     a               ; Got one?\r
        jnz     flsmdm          ; If so, try for another\r
        ret                     ; Receiver is drained.  Return.\r
;\r
;       lptstat - get the printer status. Return a=0ffh if ok, or 0 if not.\r
lptstat:\r
        xra     a               ; assume it is ok.. this may not be necessary\r
        ret\r
\r
;\r
;       outlpt - output character in E to printer\r
;       console is selected.\r
;       preserves de.\r
outlpt:\r
        push    d               ; save DE in either case\r
        ana     a               ; if A = 0 do nothing,\r
        jz      outlp1          ; [30] if a=0 do nothing\r
        mvi     c,lstout\r
        call    bdos            ;Char to printer\r
outlp1: pop     d               ; restore saved register pair\r
        ret\r
;\f\r
\r
;\r
;       Screen manipulation routines\r
;       csrpos - move to row B, column C\r
;\r
;       csrpos for terminals that use a leadin sequence followed\r
;        by (row + 31.) and (column + 31.)\r
;\r
IF NOT (bbII OR ampro)			;[obs I think ]\r
csrpos: push    b               ; save coordinates\r
        lxi     d,curldn        ; get cursor leadin sequence\r
        call    prtstr          ; print it\r
        pop     h               ; restore coordinates\r
        mov     a,h             ; get row\r
        adi     (' '-1)         ; space is row one\r
        mov     e,a\r
        push    h\r
        call    outcon          ; output row\r
        pop     h\r
        mov     a,l             ; get column\r
        adi     (' '-1)         ; space is column one\r
        mov     e,a\r
        jmp     outcon          ; output it and return\r
ENDIF	; NOT bbII OR ampro\r
\r
;\r
; delchr - make delete look like a backspace.  Unless delete is a\r
;          printing character, we just need to print a backspace\r
;          (we'll output clrsp afterwards)\r
delchr:\r
\r
IF bbI\r
        lxi     d,delstr\r
        jmp     prtstr\r
ENDIF;bbI\r
\r
\r
IF NOT bbI\r
        mvi     e,bs            ;get a backspace\r
        jmp     outcon\r
ENDIF;NOT bbI\r
\r
; erase the character at the current cursor position\r
clrspc: mvi     e,' '\r
        call    outcon\r
        mvi     e,bs            ;get a backspace\r
        jmp     outcon\r
\r
; erase the current line\r
clrlin: lxi     d,eralin\r
        jmp     prtstr\r
\r
; erase the whole screen, and go home. preserves b (but not c)\r
clrtop: lxi     d,erascr\r
        jmp     prtstr\r
\r
; If its a BigBoard or Ampro, we need a terminal, so link to CPXVDU.ASM\r
IF bbII\r
sysver:	db	'Big Board II$'\r
ENDIF;bbII\r
\r
IF ampro\r
sysver:	db	'Ampro Little Board$'\r
ENDIF;ampro\r
\r
IF (bbII AND lasm)	; we need a terminal as well\r
LINK CPXVDU.ASM\r
ENDIF	;(bbII AND lasm)\r
\r
IF (ampro AND lasm)	; we need a terminal as well\r
LINK CPXVDU.ASM\r
ENDIF	;(ampro AND lasm)\r
\r
;If here, we are Kaypro or Xerox 820, or if from M80, we should skip\r
; a few lines if Bigboard.\r
\r
IF kpii\r
sysver:\r
ttytyp:	db	'Kaypro II$'\r
outlin:	db	subt,cr,lf,tab,tab,'$'\r
erascr:	db	subt,'$'                ;Clear screen and home.\r
eralin:	db	cr,18H,'$'              ;Clear line.\r
curldn:	db	esc,'=$'                ;Cursor lead-in\r
delstr:	db	bs,' ',bs,bs,'$'        ; adjust for echoing delete character\r
ttab:					;Table start location.\r
ta:	db	0BH,'$',0,0             ;Cursor up.\r
tb:	db	0AH,'$',0,0             ;Cursor down.\r
tc:	db	0CH,'$',0,0             ;Cursor right.\r
td:	db	bs,'$',0,0              ;Cursor left\r
te:	db	subt,'$',0,0            ;Clear display\r
tf:	db	esc,'G$',0              ; Enter Graphics Mode (select Greek)\r
tg:	db	esc,'A$',0              ; Exit Graphics mode (select ASCII)\r
th:	db	1EH,'$',0,0             ; Cursor home.          [UTK016]\r
ti:	db	esc,'E','$',0           ; Reverse linefeed. (insert line)\r
tj:	db	'W'-100O,'$',0,0        ; Clear to end of screen.\r
tk:	db	'X'-100O,'$',0,0        ; Clear to end of line.\r
ENDIF ; kpii\r
;\f\r
\r
IF xer820\r
ttytyp:\r
sysver:	db	'Xerox 820$'\r
outlin:	db	subt,cr,lf,tab,tab,'$'\r
erascr:	db	subt,'$'                ;Clear screen and home.\r
eralin:	db	cr,18H,'$'              ;Clear line.\r
curldn:	db	esc,'=$'                ;Cursor lead-in\r
delstr:	db	bs,' ',bs,bs,'$'        ; adjust for echoing delete character\r
ttab:					;Table start location.\r
ta:	db	0BH,'$',0,0             ;Cursor up.\r
tb:	db	0AH,'$',0,0             ;Cursor down.\r
tc:	db	0CH,'$',0,0             ;Cursor right.\r
td:	db	bs,'$',0,0              ;Cursor left\r
te:	db	subt,'$',0,0            ;Clear display\r
tf:	db	'$',0,0,0               ; Enter Graphics Mode (can't)\r
tg:	db	'$',0,0,0               ; Exit Graphics mode (can't)\r
th:	db	1EH,'$',0,0             ; Cursor home.          [UTK016]\r
ti:	db	0BH,'$',0,0             ; Reverse linefeed. (cursor up)\r
tj:	db	11H,'$',0,0             ; Clear to end of screen.\r
tk:	db	18H,'$',0,0             ; Clear to end of line.\r
ENDIF ; xer820\r
ovlend	equ	$	; End of overlay\r
\r
	END\r