Add AVR-CP/M system (cpxac.asm) and a Makefile

[kermit-80.git] / cpxpcw.asm

IF NOT lasm\r
.printx * CPXPCW.ASM *\r
ENDIF	;NOT lasm\r
;\r
; KERMIT - (Celtic for "FREE")\r
;\r
; This is the CP/M-80 implementation of the Columbia University\r
; KERMIT file transfer protocol.\r
;\r
; Version 4.08\r
;\r
; Copyright June 1981,1982,1983,1984,1985\r
; Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; This file contains the system-dependent code and data for KERMIT\r
; on the Amstrad range of personal computers.\r
;\r
;\r
; Revision history:\r
;\r
;edit 9, 22-Jan-1991 by MF. Added "sysinit" code at "init04" from Kermit\r
;	version 4.08 which had been left out of version 4.09 to reserve\r
;	space for the Amstrad's I/O buffers. Amstrad Kermit now stores\r
;	files correctly (version 4.09 had garbled files). Again,\r
;	this fix comes from Mr. D. P. Arnot of the Scottish Agricultural\r
;	College in the UK.\r
;edit 8, 16-Jan-1991 by MF. Added a "bs" left out of "delstr" per\r
;	instruction from David P. Arnot of Scottish Agricultural\r
;	College, Auchincruive, Ayr, UK.\r
;	E-mail:  <D.P.Arnot@edinburgh.ac.uk>\r
; edit 7, 22 July 1987 by OBSchou to massage code to fit with CPXCOM.ASM\r
;	Had to rename bcnout to bcnot as the former label clashed with\r
;	one of the same name in CPXCOM.ASM.  Sorry, folks.\r
;\r
; edit 6, 14th July, 1987 by OBSchou for Phillip Wade, Hull University\r
;	Computer Centre.  Change to delchr routine for PCW machines, \r
;	as character 127 decimal is a printing character on \r
;	the Amstrad PCW.  The routine has been replaced \r
;	by a bs,space,bs,bs string. (OBS Comment - why a total of THREE bs?)\r
;\r
; edit 5 9 May 1987 by C.J.MILES@UK.AC.UMRCC\r
;	Hangup phone and clear screen options added to\r
;	terminal mode.\r
;\r
; edit 4 23 March 1987 by C.J.MILES@UK.AC.UMRCC\r
;	Use direct input drom SIO for CPC machines instead\r
;	of using BDOS. Improvement reduces time for file\r
;	transfer to 65% of time used by BDOS method.\r
;	Add reverse Prestel baud rate.\r
;\r
; edit 3 20 March 1987 by Chris Miles (C.J.MILES@UK.AC.UMRCC)\r
;	(Greater Manchester Archaeological Unit, Manchester Univ.).\r
;	Added support for Amstrad CPC CP/M Plus machines,\r
;	Added 31250 baud rate option,\r
;	Bug fixed in sending BREAK,\r
;	Bug fixed in 1200/75 baud setup\r
;	Machine and CP/M version checks added.\r
;\r
; edit 2 11 Febuary, 1987 by OBSchou for Ian Young.\r
;	Changes to the send break routine to change two lines of code from\r
;		ori	018h		; send break, Tx enable\r
;	and	ori	0008h		; Tx enable \r
;\r
;	to	ori	01ah		; send break, Tx enable, RTS\r
;	and	ori	00ah		; Tx enable, RTS\r
;\r
;	This is a bug fix to hopefully keep RTS actve during breaks.\r
;\r
; [Ed. (OBSchou) 21/1/87.\r
; This file linked FROM cpxsys.asm, so do NOT rename this\r
; file.  The diffculty of needing a HUGE CPXSYS.ASM file on your floppy\r
; only to act as a switcher remains, but hopefully will be better in \r
; the future.  If you ARE stuck, then rename this CPXSYS.ASM but add the\r
; label SYSEDT: to the FAMILY label.  A bit messy.]\r
;\r
;\r
; The "author" of this system-dependent file is:\r
;\r
;  Ian A. Young\r
;  Lattice Logic Ltd\r
;  9 Wemyss Place\r
;  Edinburgh\r
;\r
; Some other addresses:\r
;\r
;  ian@latlog.uucp\r
;  ...seismo!mcvax!ukc!latlog!ian\r
; or c/o OBSchou@uk.ac.lut.multics\r
;\r
; ... although much of the code concerned was written by others.\r
;\r
\r
\r
; Keep module name, edit number, and last revision date in memory.\r
\r
;sysedt:	db	'CPXSYS.ASM (36) 20-Mar-87$'\r
family:	db	'CPXPCW.ASM (9)  22-Jan-1991$'\r
\r
\r
;\r
; Assembly-time message announcing which version we are building\r
;\r
\r
IF pcw\r
.printx	* Assembling Amstrad PCW Kermit-80 *\r
ENDIF\r
\r
IF cpc\r
.printx	* Assembling Amstrad CPC Kermit-80 *\r
ENDIF\r
\r
;\r
; Miscellany of parameter settings\r
;\r
z80	EQU	TRUE 		; all Amstrads have a Z80.\r
defesc	EQU	'\'-100O	; The default escape character.\r
vtval	EQU	0 		; we don't need VT52 emulation\r
\r
;\r
; Amstrad CPC machines use 16 bit I/O address decoding and therefore\r
; the Z80 instructions OUT (C),A and IN A,(C) must be defined.\r
;\r
outc	EQU	79edh		; IN	A,(C)\r
inpc	EQU	78edh		; OUT	(C),A\r
\r
;\r
; hardware information\r
;\r
; There is a Z80-DART (Mostek/SGS 8470) at I/O addresses E0..E3 (PCW)\r
; and FADC..FADD (CPC), and a 8253 programmable divider running it at\r
; E4..E7 (PCW) and FBDC..FBDF (CPC)\r
;\r
\r
input	EQU	01h		; input data available\r
output	EQU	04h		; output buffer ready\r
\r
IF pcw\r
mnport	EQU	0E0h		; data register for SIO\r
mnprts	EQU	0E1h		; control register for SIO\r
ctc0	EQU	0E4h		; 8253 load counter 0\r
ctc1	EQU	0E5h		; 8253 load counter 1\r
ctcmod	EQU	0E7h		; 8253 write mode word\r
ENDIF\r
\r
IF cpc\r
mnport	EQU	0FADCh		; data register for SIO\r
mnprts	EQU	0FADDh		; control register for SIO\r
ctc0	EQU	0FBDCh		; 8253 load counter 0\r
ctc1	EQU	0FBDDh		; 8253 load counter 1\r
ctcmod	EQU	0FBDFh		; 8253 write mode word\r
ENDIF\r
\r
;\r
; SIO input buffering\r
;\r
siosz	EQU	4096		; size of SIO input buffer\r
siomsk	EQU	4095		; mask for wrapping buffer round\r
\r
;\r
; Extended BIOS jump-block addresses; reached through USERF\r
;\r
sainit	EQU	00B6h		; initialise SIO\r
sabaud	EQU	00B9h		; set baud rate\r
saparm	EQU	00BCh		; fetch SIO parameters\r
teask	EQU	00BFh		; find out cursor position\r
cdvers	EQU	00E3h		; get version numbers\r
cdinfo	EQU	00E6h		; get BIOS system information\r
\r
;\r
; System-dependent initialization\r
; Called once at program start.\r
sysxin:		; continuation of system initialzation \r
;\r
; check for correct CP/M version\r
;\r
	mvi	c,12		; get CP/M version BDOS call\r
	call	bdos\r
	mov	a,l		; check if CP/M Plus\r
	cpi	31h\r
	jz	init08\r
	lxi	d,wrong2	; point to error message\r
	call	prtstr\r
	mvi	c,0		; warm boot\r
	call	bdos\r
;\r
init08:		;[OBS] Moved the Cinfigured for message out as\r
		;[OBS]   it is in CPXCOM.ASM\r
;\r
; get addresses of BIOS routines\r
;\r
; BIOS USERF is used to get to extended BIOS routines\r
;\r
	lhld	1		; warm boot vector\r
	lxi	d,87		; offset to USERF vector\r
	dad	d		; DE now has USERF vector address\r
	shld	userf+1		; ready for jumping to...\r
;\r
; BIOS routines for fast character I/O\r
;\r
	lhld	1		; warm boot vector (#1)\r
	lxi	d,3\r
	dad	d		; next is #2, CONST\r
	shld	bcnst+1\r
	dad	d		; next is #3, CONIN\r
	shld	bcnin+1\r
	dad	d		; next is #4, CONOUT\r
	shld	bcnot+1		;[obs] Was bcnout, but this conflicts\r
				;[obs] with a label in CPXCOM.ASM\r
	dad	d		; next is #5, LIST\r
	shld	blist+1\r
	dad	d		; next is #6, AUXOUT\r
	dad	d		; next is #7, AUXIN\r
	shld	baxin+1\r
	lhld	1		; warm boot vector again\r
	lxi	d,002Ah		; offset to LISTST (#15)\r
	dad	d\r
	shld	lptstat+1\r
	lhld	1		; warm boot vector again\r
	lxi	d,0033h		; offset to AUXIST (#18)\r
	dad	d\r
	shld	baxist+1\r
;\r
; check if running on correct Amstrad\r
;\r
	call	userf\r
	dw	cdvers\r
IF pcw\r
	cpi	0\r
ENDIF\r
IF cpc\r
	cpi	1\r
ENDIF\r
	jnz	init06\r
	lxi	d,wrong1	; point to error message\r
	call	prtstr\r
	mvi	c,0\r
	call	bdos\r
;\r
; verify presence of SIO board by asking the BIOS.\r
;\r
init06:	call	userf		; C gets 00 if not fitted\r
	dw	cdinfo\r
	xra	a		; a <- 0\r
	ora	c		; zero => no serial port\r
	jnz	init03		; non-zero => OK\r
	lxi	d,nosio		; snooty message...\r
	call	prtstr\r
	mvi	c,0		; warm boot out of here\r
	call	bdos\r
init03:\r
;\r
; find initial baud rate and other information\r
;\r
	call	userf		; gives B=rx baud, C=tx baud, D=stop bits,\r
				; E=parity, H=rx bits, L=tx bits.\r
	dw	saparm		; get SIO parameters\r
	push	h		; save bit settings\r
	mov	a,b		; if TX and RX speeds same, they are OK\r
	cmp	c\r
	jz	init01\r
	cpi	8		; rx=1200?\r
	jnz	init02		; no, can't be Prestel\r
	mov	a,c\r
	cpi	2		; tx=75?\r
	jnz	init02		; no, can't be Prestel\r
	lxi	b,0		; otherwise 1200/75 comes out as 0s.\r
init01:	push	b		; assign value to SPEED\r
	pop	h\r
	shld	speed\r
init02:				; here if we leave it as is\r
	pop	h		; get bit settings\r
	mov	a,l		; no of TX data bits set\r
	sui	5		; make into 00, 01, 10, 11.\r
	rrc\r
	rrc\r
	rrc\r
	sta	txbits		; we may need it later\r
;\r
; set handshake mode: there are two parts to this, interrupts and\r
; hardware handshake. The MODE byte used by the firmware expresses\r
; this combination as -(int*2 + hand*1).  Thus, both options on would\r
; be (-3) or 0FDh.\r
;\r
; Here, we set the interrupt part of the mode on; it helps the BIOS cope.\r
; Unfortunately, >sigh<, according to Soft971, this will only work\r
; if you have BIOS V1.4 or higher.  I have no idea what would happen\r
; if we tried random hanshake mode flags with lower versions, so we\r
; just skip over if it would be dangerous...\r
;\r
	call	userf		; fetch all parameters\r
	dw	saparm\r
	sta	orgmode		; remember original mode for later\r
\r
	call	userf		; get BIOS version to B,C\r
	dw	cdvers\r
	mov	a,b		; BIOS major version number (eg 1)\r
	ora	a		; if zero, too low...\r
	jz	init04\r
	cpi	1		; if not 1, definitely OK\r
	jnz	init05\r
	mov	a,c		; otherwise, its 1.X; want >= 4\r
	cpi	4\r
	jm	init04		; <4 => too low\r
\r
init05:	call	userf		; get the original flags back\r
	dw	saparm\r
	xri	0FFh		; make mode into bit mask\r
	inr	a\r
	ori	2		; set interrupt mode\r
	xri	0FFh		; turn back into mode value\r
	inr	a\r
	call	userf		; feed change back to BIOS\r
	dw	sainit\r
init04:				; come here if not setting mode\r
\r
; Locate large buffers for multi-sector I/O and SIO input buffering.\r
; Space above ovlend is available for buffers; we have pretty well the machine\r
; to ourselves in an Amstrad PCW because they all gave 61K TPAs. We don't even\r
; bother to perform any checking.\r
; We don't want to use more than maxsec for disk buffers because\r
; if we use too many, the remote end could time out while we're\r
; writing to disk.  maxsec is system-dependent, but for now we'll just\r
; use 8Kbytes.  If you get retransmissions and other protocol errors after\r
; transferring the first maxsec sectors, lower maxsec.\r
;\r
maxsec  EQU     (8*1024)/bufsiz ; 8K / number of bytes per sector\r
\r
        lxi     h,ovlend+siosz  ; get start of buffer\r
        shld    bufadr          ; store in linkage section\r
        mvi     a,maxsec        ; get size of buffer, in sectors\r
        sta     bufsec          ; store that, too.\r
\r
\r
        ret                     ; return from system-dependent routine\r
\r
;\r
; message complaining about wrong Amstrad machine\r
;\r
wrong1:	db	'Error -   This Kermit will only run on the Amstrad '\r
IF pcw\r
	db	'PCW 8256/8512'\r
ENDIF\r
IF cpc\r
	db	'CPC 464/664/6128'\r
ENDIF\r
	db	cr,lf,'$'\r
;\r
; message complaining about version of CP/M being used\r
;\r
wrong2:	db	'Error - Incorrect CP/M version, needs CP/M 3.x'\r
	db	cr,lf,'$' \r
;\r
; message complaining of no SIO board\r
;\r
nosio:	db	'Error -   No SIO option fitted to this machine'\r
	db	cr,	lf, '$'\r
\r
;\r
; jumps to BIOS character I/O routines.\r
; Addresses filled in by initialisation code above.\r
;\r
bcnst:	jmp	$-$		; console status\r
bcnin:	jmp	$-$		; console input\r
bcnot:	jmp	$-$		; console output [obs - was bcnout]\r
blist:	jmp	$-$		; printer output\r
baxin:	jmp	$-$		; aux port input\r
baxist:	jmp	$-$		; aux port status\r
lptstat:jmp	$-$		; printer status\r
\r
;\r
; Other BIOS routines\r
;\r
userf:	jmp	$-$		; call extended BIOS function\r
\r
;\r
; saved value of some original parameters\r
;\r
orgmode:ds	1\r
txbits:	ds	1\r
\r
;\r
; system-dependent termination processing\r
; If we've changed anything, this is our last chance to put it back.\r
sysexit:\r
	call	userf		; fetch firmware parameters\r
	dw	saparm\r
	lda	orgmode		; replace with original mode\r
	call	userf		; inform BIOS\r
	dw	sainit\r
	ret\r
\r
;\r
; system-dependent processing for start of CONNECT command\r
;\r
syscon:\r
	lxi	d,conmsg	; how to get escape char message\r
	call	prtstr\r
	ret\r
\r
conmsg:		; Messages printed when entering transparent (CONNECT) mode:\r
IF pcw\r
	db	'(Use boxed minus key next to space bar to generate a Control-\)'\r
ENDIF\r
	db	cr,lf,'$'\r
\r
;\r
; syscls - system-dependent close routine\r
; called when exiting transparent session.\r
;\r
syscls:\r
	ret\r
\r
;\r
; sysinh - help for system-dependent special functions.\r
; called in response to <escape>?, after listing all the\r
; system-independent escape sequences.\r
;\r
sysinh:\r
	lxi	d,inhlps	; we got options...\r
	call	prtstr		; print them.\r
	ret\r
\r
;\r
; additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
;\r
inhlps:\r
	db	cr,lf,'B  Transmit a BREAK'\r
	db	cr,lf,'H  Hangup using DTR'\r
	db	cr,lf,'W  Wipe screen clear'\r
	db	'$'			;[hh] table terminator\r
\r
;\r
; sysint - system dependent special functions\r
; called when transparent escape character has been typed;\r
; the second character of the sequence is in A (and in B).\r
; returns:\r
;         non-skip: sequence has been processed\r
;         skip    : sequence was not recognized\r
;\r
sysint:	ani	137O		; convert lower case to upper, for testing...\r
	cpi	'B'		; send break ?\r
	jz	sendbr		; yes, go do it.  return nonskip when through.\r
	cpi	'H'		; hang up ?\r
	jz	hangup\r
	cpi	'W'		; clear screen ?\r
	jz	clrtop\r
	jmp	rskp		; take skip return - command not recognized.\r
\r
;\r
; Hangup (drop DTR) and Break send routine\r
;\r
\r
hangup:\r
	mvi	d,0ah		; set up hangup bit mask\r
	mvi	e,255		; time for hangup is 2 1/2 secs\r
	jmp	setbit		; skip Tx empty test\r
\r
sendbr:\r
	mvi	d,9ah		; set up break bit mask\r
	mvi	e,30		; time for break is 300 ms\r
\r
sndbr1:	mvi	a,1		; select Read Register 1\r
\r
IF pcw	; allow 8 bit I/O instructions\r
	out	mnprts\r
	in	mnprts		; read the contents\r
ENDIF\r
\r
IF cpc	; use 16 bit I/O instructions\r
	lxi	b,mnprts\r
	dw	outc		; OUT	(C),A\r
	dw	inpc		; IN	A,(C)\r
ENDIF\r
\r
	ani	1		; test "all done" flag\r
	jz	sndbr1		; loop until it's nonzero.\r
;\r
; Next, set the break or hangup bit on the SIO.\r
;\r
setbit:\r
	mvi	a,5		; select Write Register 5\r
IF pcw\r
	out	mnprts\r
ENDIF\r
IF cpc\r
	dw	outc		; OUT	(C),A\r
ENDIF\r
	lda	txbits		; get txbits (already in correct bit positions)\r
	ora	d		; send break, Tx Enable, RTS\r
IF pcw\r
	out	mnprts\r
ENDIF\r
IF cpc\r
	dw	outc		; OUT	(C),A\r
ENDIF\r
\r
;\r
; Now, delay for duration of hangup or break\r
;\r
	mov	a,e		; delay count\r
	call	delay\r
;\r
; Time's up. Put transmitter back in normal state and return.\r
;\r
	mvi	a,5		; select Write Register 5\r
IF pcw\r
	out	mnprts\r
ENDIF\r
IF cpc\r
	lxi	b,mnprts\r
	dw	outc		; OUT	(C),A\r
ENDIF\r
	lda	txbits		; get txbits again\r
	ori	8ah		; Reset break, Tx Enable, RTS\r
IF pcw\r
	out	mnprts\r
ENDIF\r
IF cpc	\r
	dw	outc		; OUT	(C),A\r
ENDIF\r
	ret			; done.\r
\r
;\r
; sysflt - system-dependent filter\r
; called with character in E.\r
; if this character should not be printed, return with A = zero.\r
; preserves bc, de, hl.\r
; note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
;\r
sysflt:\r
	mov	a,e		; get character for testing\r
	ret\r
;\r
; system-dependent processing for BYE command.\r
;\r
sysbye:\r
	ret\r
\r
;\r
; This is the system-dependent command to change the baud rate.\r
; DE contains the two-byte value from the baud rate table; this\r
; value is also stored in 'speed'.\r
;\r
sysspd:\r
	push	d		; move to HL for firmware\r
	pop	h\r
	mov	a,h		; if h=0 then Prestel rates\r
	ora	a\r
	jnz	spd01		; if not 1200/75 then skip\r
	lxi	h,0802H		; else set 1200/75 into HL\r
	jmp	spd03		; jump to normal setup\r
\r
spd01:	cpi	11h		; if h=11h then reverse Prestel\r
	jnz	spd02		; if not 75/1200 then skip\r
	lxi	h,0208h		; else set 75/1200 into HL\r
	jmp	spd03		; jump to normal setup\r
\r
spd02:	cpi	10h		; if h=10h then 31250 baud\r
	jnz	spd03		; if not 31250 then skip to normal setup\r
	mvi	a,36h		; set 8253 for mode 2 binary count\r
	lxi	b,ctcmod	; output to CTC mode register\r
	dw	outc\r
	lxi	b,ctc0		; select transmit clock\r
	mov	a,4		; timer value for 31250 (04h)\r
	dw	outc\r
	mov	a,0		; timer value for 31250 (04h)\r
	dw	outc\r
	lxi	b,ctc0		; select receive clock\r
	mov	a,4		; timer value for 31250 (04h)\r
	dw	outc\r
	mov	a,0		; timer value for 31250 (04h)\r
	dw	outc\r
	ret\r
\r
spd03:	call	userf		; set whatever we have now...\r
	dw	sabaud		; using BIOS routine\r
	ret\r
\r
;\r
; Speed tables\r
; (Note that speed tables MUST be in alphabetical order for later\r
; lookup procedures, and must begin with a value showing the total\r
; number of entries.  The speed help tables are just for us poor\r
; humans.\r
;\r
; db string length,string,divisor (2 identical bytes or 1 word)\r
;\r
spdtbl:	db	12h			;18 entries\r
	db	03h,'110$', 03h,03h\r
	db	04h,'1200$', 08h,08h\r
	db	07h,'1200/75$', 00h,00h	; real values faked up when required\r
	db	05h,'134.5$', 04h,04h\r
	db	03h,'150$', 05h,05h\r
	db	04h,'1800$', 09h,09h\r
	db	05h,'19200$', 0fh,0fh\r
	db	04h,'2400$', 0ah,0ah\r
	db	03h,'300$', 06h,06h\r
	db	05h,'31250$',10h,10h	; flag to direct setup routine\r
	db	04h,'3600$', 0bh,0bh\r
	db	04h,'4800$', 0ch,0ch\r
	db	02h,'50$', 01h,01h\r
	db	03h,'600$', 07h,07h\r
	db	04h,'7200$', 0dh,0dh\r
	db	02h,'75$', 02h,02h\r
	db	07h,'75/1200$',11h,11h	; real values faked up when required\r
	db	04h,'9600$', 0eh,0eh\r
\r
sphtbl:	db	cr,lf,lf\r
	db	'Normal rates: 50    75    110   134.5 150   300   600'\r
	db	cr,lf\r
	db	'              1200  1800  2400  3600  4800  7200  9600  19200'\r
	db	cr,lf,lf\r
	db	'High speed  : 31250 (only between Amstrads)'\r
	db	cr,lf,lf\r
	db	'Split rates : 1200/75 (Rx=1200, Tx=  75)'\r
	db	cr,lf\r
	db	'              75/1200 (Rx=  75, Tx=1200)'\r
	db	cr,lf,'$'\r
\r
;\r
; This is the system-dependent SET PORT command.\r
; HL contains the argument from the command table.\r
;\r
sysprt:\r
	ret\r
\r
prttbl	equ	0		; SET PORT is not supported\r
prhtbl	equ	0\r
\r
;\r
; selmdm - select modem port\r
; selcon - select console port\r
; selmdm is called before using inpmdm or outmdm;\r
; selcon is called before using inpcon or outcon.\r
; preserves bc, de, hl.\r
;\r
selmdm:\r
selcon:\r
	ret\r
\r
;\r
; Get character from console, or return zero.\r
; result is returned in A.  destroys bc, de, hl.\r
;\r
inpcon:\r
	call	bcnst		; get console status\r
	ora	a		; anything there?\r
	rz			; no, forget it\r
	jmp	bcnin		; yes, get the character\r
\r
;\r
; Output character in E to the console.\r
; destroys bc, de, hl\r
;\r
outcon:\r
	mov	a,e		; TAB?\r
	cpi	tab\r
	jz	out001\r
	mov	c,e		; set correct arg register\r
	jmp	bcnot		; output to console via BIOS [obs was bcnout]\r
\r
;\r
; perform tab expansion ourselves\r
;\r
out001:	call	userf		; get column in L\r
	dw	teask\r
	mov	a,l		; a <- column 0..n\r
	ani	7		; column 0..7\r
	xri	0FFh		; not(col 0..7)\r
	adi	9		; a is 8-(colf7)\r
out002:	ora	a		; any left?\r
	rz			; return if not\r
	dcr	a		; one less now, anyhow\r
	push	psw		; save over BIOS call (just in case)\r
	mvi	c,' '		; print one space\r
	call	bcnot		;[obs was bcnout]\r
	call	suck		; in case any stuff coming in\r
	pop	psw		; fetch count back\r
	jmp	out002		; and go round again\r
\r
;\r
; outmdm - output a char from E to the modem.\r
;  the parity bit has been set as necessary.\r
; returns nonskip; bc, de, hl preserved.\r
outmdm:\r
IF cpc\r
	push	b		; save BC for CPC 16 bit I/O\r
ENDIF\r
outmd1:\r
	call	xsuck		; keep checking for incoming characters\r
IF pcw\r
	in	mnprts		; get the output done flag.\r
ENDIF\r
IF cpc\r
	lxi	b,mnprts\r
	dw	inpc		; IN	A,(C)\r
ENDIF\r
	ani	output		; is it set?\r
	jz	outmd1		; if not, loop until it is.\r
	mov	a,e\r
IF pcw\r
	out	mnport		; output it.\r
ENDIF\r
IF cpc\r
	lxi	b,mnport\r
	dw	outc		; OUT	(C),A\r
	pop	b		; restore BC\r
ENDIF\r
	ret\r
\r
;\r
; get character from modem; return zero if none available.\r
; destroys bc, de, hl.\r
;\r
inpmdm:\r
	call	suck		; get any characters pending\r
	lhld	sioct		; count of chars in buffer\r
	mov	a,h		; or together to get result\r
	ora	l\r
	rz			; not got any, return now\r
\r
	dcx	h		; down count\r
	shld	sioct\r
\r
	lhld	siord		; read pointer\r
	mov	c,m		; fetch character ** NB TO C FOR NOW **\r
\r
	lxi	d,1-ovlend	; bump pointer, subtract base\r
	dad	d\r
	mov	a,h		; mask high byte of offset\r
	ani	siomsk/256\r
	mov	h,a\r
	lxi	d,ovlend	; add in base again\r
	dad	d\r
	shld	siord\r
\r
	mov	a,c		; get to proper register\r
	ret\r
\r
;\r
; flsmdm - flush comm line.\r
; Modem is selected.\r
; Currently, just gets characters until none are available.\r
\r
flsmdm:	call	inpmdm		; Try to get a character\r
	ora	a		; Got one?\r
	jnz	flsmdm		; If so, try for another\r
	ret			; Receiver is drained.  Return.\r
\r
;\r
; SIO input buffer handling.  The buffer pointers are held as pointers into\r
; the buffer. The read pointer\r
; is to the next unused character, the write pointer to the next unused space.\r
;\r
siord:	dw	ovlend		; next char to read\r
siowr:	dw	ovlend		; next char to write\r
sioct:	dw	0		; number in buffer\r
\r
xsuck:	push	d		; save regs version of suck\r
	push	b\r
	push	h\r
	call	suck\r
	pop	h\r
	pop	b\r
	pop	d\r
	ret\r
\r
;\r
; suck\r
;\r
; this routine is called whenever it would be possible that some\r
; characters might be available in the SIO device; they are all\r
; transferred (there may be up to 4 pending) to the buffer.\r
;\r
; all registers are destroyed\r
;\r
suck:\r
IF pcw\r
	call	baxist		; check input status via BDOS\r
	ora	a		; check if zero\r
ENDIF\r
IF cpc\r
	lxi	b,mnprts	; get input status directly\r
	dw	inpc		; IN A,(C)\r
	ani	input		; mask for Rx ready\r
ENDIF\r
	rz			; return if no\r
\r
IF pcw\r
	call	baxin		; fetch character via BDOS\r
ENDIF\r
IF cpc\r
	lxi	b,mnport	; fetch character directly from SIO\r
	dw	inpc		; IN A,(C)\r
ENDIF\r
\r
	lhld	siowr		; write pointer\r
	mov	m,a		; put character\r
\r
	lxi	d,1-ovlend	; take off base, bump pointer\r
	dad	d\r
	mov	a,h		; top byte of offset\r
	ani	siomsk/256	; masked off\r
	mov	h,a\r
	lxi	d,ovlend	; add on base again\r
	dad	d\r
	shld	siowr		; replace pointer\r
\r
	lhld	sioct		; bump count in buffer\r
	inx	h\r
	shld	sioct\r
\r
	jmp	suck		; go round in case any more\r
\r
;\r
; outlpt - output character in E to printer\r
; console is selected.\r
; preserves de.\r
outlpt:\r
	push	d		; save DE in either case\r
	mov	c,e		; correct arg register\r
	call	blist\r
	pop	d		; restore saved register pair\r
	ret\r
\r
;\r
; Screen manipulation routines\r
; csrpos - move to row B, column C\r
;\r
; csrpos for terminals that use a leadin sequence followed\r
;  by (row + 31.) and (column + 31.)\r
;  or (row) and (column)\r
;\r
csrpos:	push	b		; save coordinates\r
	lxi	d,curldn	; get cursor leadin sequence\r
	call	prtstr		; print it\r
	pop	h		; restore coordinates\r
	mov	a,h		; get row\r
	adi	(' '-1)		; space is row one\r
	mov	e,a\r
	push	h\r
	call	outcon		; output row\r
	pop	h\r
	mov	a,l		; get column\r
	adi	(' '-1)		; space is column one\r
	mov	e,a\r
	jmp	outcon		; output it and return\r
\r
;\r
; delchr - make delete look like a backspace.  Unless delete is a printing\r
; character, we just need to print a backspace. (we'll output clrspc\r
; afterwards)\r
; For Kaypro and Vector General, delete puts a blotch on the screen.\r
; For Apple and Osborne 1, delete moves but doesn't print.\r
delchr:\r
IF pcw	;[6] OBS for Phillip Wade\r
	lxi	d,delstr	;[5] send a string rather than a single character\r
	call	prtstr\r
\r
delstr:	db	bs,' ',bs,'$'	;[OBS] Was bs,space,bs,bs\r
ENDIF	;pcw\r
\r
	mvi	e,bs		;get a backspace\r
	jmp	outcon\r
\r
; erase the character at the current cursor position\r
clrspc:	mvi	e,' '\r
	call	outcon\r
	mvi	e,bs		;get a backspace\r
	jmp	outcon\r
\r
; erase the current line\r
clrlin:	lxi	d,eralin\r
	jmp	prtstr\r
\r
; erase the whole screen, and go home. preserves b (but not c)\r
clrtop:	lxi	d,erascr\r
	jmp	prtstr\r
\r
\r
IF pcw\r
sysver:	db	'Amstrad PCW with SIO option$'\r
ENDIF\r
IF cpc\r
sysver:	db	'Amstrad CPC with CP/M Plus$'\r
ENDIF\r
\r
outlin:	db	esc,'H',esc,'J',cr,lf,'                $'\r
\r
erascr:	db	esc,'H',esc,'J$'	;Clear screen and go home.\r
eralin:	db	cr,esc,'K$'		;Clear line.\r
curldn:	db	esc,'Y$'		;cursor leadin\r
ttab:					;Table start location.\r
ta:	db	esc,'A$',0		;Cursor up.\r
tb:	db	esc,'B$',0		;Cursor down.\r
tc:	db	esc,'C$',0		;Cursor right.\r
td:	db	esc,'D$',0		;Cursor left\r
te:	db	esc,'E$',0		;Clear display\r
tf:	db	'$',0,0,0		;Enter Graphics Mode\r
tg:	db	'$',0,0,0		;Exit Graphics mode\r
th:	db	esc,'H$',0		;Cursor home.\r
ti:	db	esc,'I$',0		;Reverse linefeed.\r
tj:	db	esc,'J$',0		;Clear to end of screen.\r
tk:	db	esc,'K$',0		;Clear to end of line.\r
\r
ovlend	equ	$	; End of overlay\r
\r
	END\r