Convert line endings to CP/M format (cr/lf).

[kermit-80.git] / cpxsys.asm

IF NOT lasm\r
.printx * CPXSYS.ASM *\r
ENDIF	;NOT lasm\r
;	KERMIT - (Celtic for "FREE")\r
;\r
;	This is the CP/M-80 implementation of the Columbia University\r
;	KERMIT file transfer protocol.\r
;\r
;	Version 4.0\r
;\r
;	Copyright June 1981,1982,1983,1984,1985\r
;	Columbia University\r
;\r
; Originally written by Bill Catchings of the Columbia University Center for\r
; Computing Activities, 612 W. 115th St., New York, NY 10025.\r
;\r
; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,\r
; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many\r
; others.\r
;\r
;	This file contains the system-dependent code and data for KERMIT.\r
;	It will be probably be broken into independent files to generate\r
;	overlays for the various systems, one or more overlay possible\r
;	from each file.	 For now, we will leave it in one piece.\r
;\r
; revision history:\r
;\r
;\r
; Edit 40, 28-Aug-89 by Mike Freeman of Bonneville Power Administration,\r
;	P.O. Box 491, Vancouver WA 98666 USA, Telephone (206)690-2307:\r
;	Home address:  301 N.E. 107th Street; Vancouver, WA 98685 USA\r
;	Home telephone:  (206)574-8221\r
;	added support for Hewlett-Packard HP-125 Business Assistant computer\r
;	running a HP-modified CP/M Version 2.2; communications on\r
;	DAta Comm 1 or Data Comm 2 (8th-bit quoting must be used on\r
;	Data Comm 2 to transfer binary files as Data Comm 2 only supports\r
;	a 7-bit data path); printer cannot be used with communications on\r
;	Data Comm 2 (the printer port).\r
; edit 39, 4 August, 1987b by OBSchou for Charles Lasner re. DECMATE II\r
;	fixes to set xon/off control off for the duration of Kermit-80.\r
;\r
;	His header reads:\r
;\r
;	IBM mode restore program\r
;\r
;	This routine must be run after using CP4DMF (and KERMIT-80) to restore\r
;	the normal handling of XON/XOFF; the user may also elect to cold-boot\r
;	the DECMATE instead.\r
;\r
;	acknowledgments and limitations.\r
;\r
;	This program is based on DECMATE specific implementation details\r
;	provided by Walt Lamia of DEC. It is of course, specific to DECMATE\r
;	implementations of CP/M-80 for DECMATE II, III, III-plus, etc.\r
;\r
;	usage consists of merely:\r
;\r
;	CP4DMF			run xon/xoff disable program\r
;	KERMIT80		then run kermit\r
;	<KERMIT-80 commands used normally here, including SET IBM ON>\r
;	CP4DMU			run this program to restore normal XON\r
;\r
;	unless CP4DMU is run following KERMIT-80, the normal handling of\r
;	XON/XOFF provided by KERMIT-80 will not work (cold boot is another\r
;	alternative).\r
;\r
;	[Note - These edits now included in the init/de-init code]\r
;\r
; edit 38, 23 July, 1987 by OBSchou.  Moved out commonly used code \r
;	to CPXCOM.ASM, and adjusted this (ond other family) files accordingly.\r
;	Also filtered out code now in other family files.\r
;\r
; edit 37 , 15 July 1987 by OBSchou for David Moore, who has submitted \r
;	code for Teletek SYSTEMASTER (teletek) and for an ADM 22 terminal.\r
;\r
; edit 36 28 Jan 87 by OBSchou.\r
;	Removed the printx etc and should only have this file if a system\r
;	does not have a family file.\r
;\r
; edit 35 1st Dec 1986 by OBSchou.  Added test for Amstrad PCW range (PCW)\r
;	Links to CPXPCW.ASM, which was submitted by Ian Young, Lattice \r
;	Logic Systems.\r
;\r
; edit 34 20 August by OBSchou for Brian Robertson, Aberdeen University:\r
;	I have discovered a bug in my code for the BBC/Z80 version of Kermit.  \r
;	At startup the transmitter baud rate is read from the serial ULA.  \r
;	The TX and RX baud rates are then reset to this value and the \r
;	value is stored in location 'baud:' for the STATUS (or SHOW) \r
;	command.  That is how it is supposed to work !	Unfortunately \r
;	my code at present "misreads" the initial TX baud rate	- there \r
;	is some bit manipulation that needs to be done to extract the \r
;	correct value.\r
;\r
; edit 33 30-May-86 OBSchou.  Added two new enties to the overly.  One for \r
;	printer status and the other for the address of the family of \r
;	computer using the overlay.  If it is still in CPXSYS.ASM then it \r
;	is a dollar only.\r
;\r
;edit 32, 27 May, 1986 by OBSchou Loughborough University for\r
;	B Robertson, Aberdeen Univ. Computing Centre. Any mistakes my fault.\r
;	Add support for APPLE II with serial cards based on the 6850 ACIA.\r
;	Mod 380Z support to allow both MDS (5 1/4" discs) and FDS (8" discs)\r
;	configurations.\r
;\r
; edit 31, 22 April, 1986, OBSchou.  \r
;	Kermit version 4.06 starts here. All previous edits have been \r
;	put aside (leave in a BWR file?).  Hived off some definitions \r
;	to the CPSDEF.ASM file as that is where they belong.  \r
;	Start on splitting off individual \r
;	systems from this huge file.  It is done using the LINK facility \r
;	LASM.  We link to a collection of systems under CPXxxx.ASM.\r
;	I have started with the systems I know, the Torch, Cifer and \r
;	pci2651.  These will all be held under CPXTOR.ASM\r
;\r
;\r
; Keep module name, edit number, and last revision date in memory.\r
family:	db	'CPXSYS.ASM (40)  28-Aug-89 $'	; now a family...\r
;\r
\r
\r
; Processor speed in units of 100KHz\r
; for cpt85xx, advance, apple,bbc,px8 & rm380z timing loop [12]\r
IF rm380z \r
cpuspd	SET	40		; 4.0 MHz CPU\r
ENDIF; rm380z \r
\r
IF disc	OR mmate OR s1008 OR access \r
cpuspd	SET	40		; 4.0 MHz CPU\r
ENDIF	;disc OR mmate OR s1008 OR access \r
\r
IF bbc	;[9]\r
cpuspd	SET	60		; BBC with 6Mhz Z80\r
ENDIF;bbc\r
\r
\r
; the basics...\r
\r
IF gener\r
batio	EQU	056H	;I/O byte CON=BAT,LIST=CRT,READER=RDR,PUNCH=PTP\r
defio	EQU	095H	;I/O byte CON=CRT,LIST=LPT,READER=RDR,PUNCH=PTP\r
crtio	equ	01010101B	; use CRT: device\r
ptrio	equ	01010110B	; use PTR: device\r
ttyio	equ	00000000B	; use TTY: device\r
uc1io	equ	01010111B	; use UC1: device\r
ur1io	equ	01101010B	; use UR1: device\r
ur2io	equ	01111110B	; use UR2: device\r
ENDIF;gener\r
\r
IF robin\r
batio	EQU	056H	;I/O byte CON=BAT,LIST=CRT,READER=RDR,PUNCH=PTP\r
defio	EQU	095H	;I/O byte CON=CRT,LIST=LPT,READER=RDR,PUNCH=PTP\r
lptio	EQU	054H	;I/O byte CON=TTY,LIST=CRT,READER=PTR,PUNCH=PTP\r
gppio	EQU	057H	;I/O byte CON=UC1,LIST=CRT,READER=RDR,PUNCH=PTP\r
ENDIF;robin\r
\r
\r
IF dmII	OR bbc	;[22]\r
batio	EQU	042H	;I/O byte CON=BAT,LIST=CRT,READER=RDR\r
defio	EQU	081H	;I/O byte CON=CRT,LIST=LPT,READER=RDR\r
ENDIF;dmII\r
\r
IF mikko\r
batio	EQU	10110010B ; I/O byte console => serial line\r
defio	EQU	10000001B ; I/O byte console => CRT and Keyboard\r
ENDIF;mikko\r
;\f\r
IF lobo	;[hh]\r
mnport	EQU	0F7E4H	;Modem data port A\r
mnprts	EQU	0F7E5H	;Modem status/conrtol port A\r
baudrt	EQU	0F7D0H	;Baud rate port A\r
output	EQU	04H	;Transmit buffer empty\r
input	EQU	01H	;Receive data available\r
z80	SET	TRUE	;a good z80, here\r
ENDIF;lobo\r
\r
IF osi\r
mnport	EQU	0CF01H	;Modem data port\r
mnprts	EQU	0CF00H	;Modem status port\r
output	EQU	02H	;Transmitter empty\r
input	EQU	01H	;Input data available\r
z80	SET	FALSE	;I don't know...\r
ENDIF;osi\r
\r
IF vector\r
mnport	EQU	04H	;Modem data port\r
mnprts	EQU	05H	;Modem status port\r
output	EQU	01H	;Transmitter empty\r
input	EQU	02H	;Input data available\r
z80	SET	FALSE	;I don't know...\r
ENDIF;vector\r
\r
IF delphi		;[7]\r
mnport	EQU	22H	;[7] Modem data port\r
mnprts	EQU	23H	;[7] Modem status port\r
output	EQU	01H	;[7] Transmitter empty\r
input	EQU	02H	;[7] Input data available\r
baudrt	equ	29h	;[7] Baud rate port for channel 2 (default)\r
z80	SET	true	;[7] We're using the z80 side of the dual processor\r
ENDIF;[7] delphi\r
\r
IF trs80\r
;NEEDS display definition (e.g. trs80lb or trs80pt)\r
mnport	EQU	0F4H	;Modem data port (0F5H for port B)\r
mnprts	EQU	0F6H	;Modem status port (0F7H for port B)\r
output	EQU	04H	;Transmitter empty\r
input	EQU	01H	;Input data available\r
z80	SET	TRUE	;[hh] All TRS-80's but the CoCo\r
ENDIF;trs80\r
\r
IF teletek\r
mnport	EQU	00H	;Modem data port (02 for port B (console))\r
mnprts	EQU	01H	;Modem status port (03 for port B (console))\r
baudrt	EQU	08H	;ctc0 control port (09 for port B (console))\r
output	EQU	04H	;Transmitter empty\r
input	EQU	01H	;Input data available\r
z80	SET	TRUE	;All Teleteks\r
ENDIF;teletek\r
\r
IF osbrn1\r
;Osborne 1 uses 6850 ACIA, but memory mapped.  Derived from Apple.\r
BAUDRT	EQU	0EFC1H	;Memory location where baud rates are stored.\r
OSTOP	EQU	4000H	;Where we move OSMOVE to at startup\r
OSPORT	EQU	2A01H	;Communications Port.\r
OSPRTS	EQU	2A00H	;Communications Port Status.\r
OUTPUT	EQU	02H	;Output Buffer Empty.\r
INPUT	EQU	01H	;Input Register Full.\r
OSBIN1	EQU	57H	;First Init Character for 6850 ACIA (Reset)\r
;(I would have thought 03, but prom code writes 57 there)\r
OSBI12	EQU	55H	;Second Init Character for ACIA (8-bits, 1200)\r
OSBI03	EQU	56H	;Second init char. for ACIA (8 bits, 300)\r
;(don't ask.. I don't know why SETUP writes 55 and 56 either)\r
z80	SET	TRUE	;[hh] a z80 here, also\r
ENDIF;osbrn1\r
\r
IF robin\r
;Those definitions below that are commented out are just for information\r
;***** NOT generally found in distributed documentation ****\r
\r
;pbausl EQU	90H	;The Baud-Rate register.\r
prntst	EQU	49H	;Printer\r
;prndat EQU	48H\r
contst	EQU	41H	;Console\r
;condat EQU	40H\r
gentst	EQU	51H	;General port.\r
;gendat EQU	50H\r
comtst	EQU	59H	;COMM-Port\r
;comdat EQU	58H\r
;output EQU	01H	;Output ready bit.\r
;input	EQU	02H	;Input ready bit.\r
z80	SET	TRUE	; This one's a Z80.\r
ENDIF;robin\r
\r
IF s1008	;[29]\r
mnport	equ	00		;printer port data\r
mnprts	equ	01		;printer port status\r
output	equ	4		;transmitter ready\r
input	equ	2		;receiver ready\r
z80	equ	FALSE		;not important\r
ENDIF;s1008 [29]\r
\r
IF mmate	;[29]\r
mnport	EQU	89H		;MODEM data port\r
mnprts	EQU	8BH		;MODEM status/control port\r
output	EQU	04H		;Transmit buffer empty, ready to send\r
input	EQU	01H		;Receive data available\r
baudrt	EQU	93H		;MODEM baud rate port\r
			;NOTE - also used for console\r
z80	SET	TRUE\r
ENDIF;mmate [29]\r
\r
IF disc	;[29]\r
mnport	EQU	05		;Discovery 83U port B data\r
mnprts	EQU	04		;Discovery 83U port B status/command\r
output	EQU	04		;Transmit buffer empty\r
input	EQU	01		;Receiver ready\r
z80	SET	TRUE\r
ENDIF;disc [29]\r
\r
IF cmemco		;[25]\r
tuart	EQU	020H	;TU-ART address\r
mnport	EQU	tuart+1	;Modem data port\r
mnprts	EQU	tuart	;Modem status port\r
output	EQU	080H	;Transmitter empty\r
input	EQU	040H	;Input data available\r
baudrt	EQU	tuart	;Baud rate port\r
;Note:	Needs terminal definition \r
z80	SET	TRUE	;This one's a Z80.\r
ENDIF;cmemco\r
\r
IF cpt85xx\r
baudrt	EQU	4Ch		; Baud rate generater (National MM5307)\r
mnport	EQU	4Bh		; Comm port data register (Intel 8251)\r
mnprts	EQU	4Ah		; Comm port command/status register\r
output	EQU	01h		; Transmitter buffer empty flag\r
input	EQU	02h		; Reciver buffer full flag\r
TxEmpty	EQU	04h		; Transmitter empty flag\r
z80	SET	FALSE		; It's really an 8080 [or 8085 ... same thing]\r
ENDIF;cpt85xx\r
\r
IF mmdI	;Morrow MicroDecision - the single-board one\r
mnport	EQU	0FEH	;Morrow Printer UART data port\r
mnprts	EQU	0FFH	;Morrow Printer UART command/status\r
output	EQU	01H	;Output ready bit.\r
input	EQU	02H	;Input	ready bit.\r
;Note:	Needs terminal definition \r
z80	SET	FALSE	;I don't know...\r
ENDIF;mmdI\r
\r
IF bbc		;[22]\r
osbyte	EQU	0FFF4H	; OS entry point\r
osword	EQU	0FFF1H	; "    "     "\r
term	EQU	0FFC8H	;Terminal mode OS entry\r
z80	SET	TRUE\r
ENDIF;[22] bbc\r
\r
;Two types of 380Z system\r
IF rm380zm		;[27] MDS - 5 1/4" discs\r
mnport	EQU	0C8H	;Modem data port\r
mnprts	EQU	0C9H	;Modem status port\r
ENDIF;[32] rm380zm\r
\r
IF rm380zf	;[32] FDS - 8" discs\r
mnport	EQU	0E8H	;Modem data port\r
mnprts	EQU	0E9H	;Modem status port\r
ENDIF;[32] rm380zf\r
\r
IF rm380z	;[32] Common to both systems\r
output	EQU	01H	;Transmitter buffer empty\r
input	EQU	02H	;Input data available\r
TxEmpty	EQU	04h	;Transmitter empty flag\r
z80	SET	TRUE\r
ENDIF;[22] rm380z\r
\r
IF px8	; [29]\r
z80	SET	TRUE\r
mnprts	EQU	0dh	; used in sending a break\r
ENDIF	;px8 [29]\r
\r
IF mdI	;Morrow Decision I - the big sucker\r
mnport	equ	48H		; Modem data port.\r
mnprts	equ	4DH		; Modem status port.\r
output	equ	20H		; Transmitter empty.\r
input	equ	1		; Input data available.\r
mbase	equ	48H		; Base address of Multi I/O port\r
				;   selector area.\r
grpsel	equ	4FH		; Group select port.\r
rbr	equ	48H		; Read Data Buffer.\r
group	equ	1		; Multi I/O Group byte for serial ports.\r
congrp	equ	1		; Serial Port 1 for console\r
mdmgrp	equ	3		; Serial Port 3 for modem.\r
\r
; Following are needed for baud rate changes...[Toad Hall]\r
\r
dlm	equ	49H		; Baud Rate Divisor (Most Sig Bit)\r
dll	equ	48H		; Baud Rate Divisor (Least Sig Bit)\r
ier	equ	49H		; Interrupt Enable Register\r
lcr	equ	4BH		; Line Control Register\r
lsr	equ	4DH		; Line Status Register\r
msr	equ	4EH		; Modem Status Register\r
dlab	equ	80H		; Divisor Latch Access Bit\r
wls0	equ	1		; Word Length Select Bit 0\r
wls1	equ	2		; Word Length Select Bit 1 for 8 bit word\r
stb	equ	4		; Stop bit count - 2 stop bits\r
imask	equ	0		; Interrupt mask (all disabled)\r
z80	SET	TRUE		; This one's a Z80.\r
ENDIF	;mdI   NOTE: needs terminal definition. [Toad Hall]\r
\r
IF mikko\r
sioac	EQU	0FF12H		;SIO channel A register(s) address\r
sioo3	EQU	01000001B	;SIO Write Reg. 3 original setup (?)\r
				;RX 7 bits,synch mode bits 0,RX enable\r
sion3	EQU	11001111B	;SIO Write Reg. 3 KERMIT setup\r
				;RX 8 bits,synch mode bits 0,RX enable\r
sioo4	EQU	01001111B	;SIO Write Reg. 4 original setup (?)\r
				;X16 clock,8 bit synch(ignored),\r
				;2stop bits,par even(on)\r
sion4	EQU	01000100B	;SIO Write Reg. 4 KERMIT setup\r
				;X16 clock,8 bit synch(ignored),\r
				;1stop bit,par off\r
sioo5	EQU	10101010B	;SIO Write Reg. 5 original setup (?)\r
				;DTR,TX 7 bits,TX enable,RTS\r
sion5	EQU	11101010B	;SIO Write Reg. 5 KERMIT setup\r
				;DTR,TX 8 bits,TX enable,RTS\r
txclk	EQU	0FF30H	;Baud rate generator (CTC) for transmitter\r
rxclk	EQU	0FF31H	;Baud rate generator (CTC) for receiver\r
chmask	EQU	0F1F2H	;Mask byte address for SIO ch. A reception\r
z80	SET	TRUE	;It's got a SIO and a CTC, it must be a Z80\r
ENDIF;mikko\r
\r
\r
IF access	;[29]\r
mnport	EQU	40H	;Modem data port A\r
mnprts	EQU	42H	;Modem status/conrtol port A\r
output	EQU	04H	;Transmit buffer empty\r
input	EQU	01H	;Receive data available\r
z80	SET	TRUE	;a good z80, here\r
ENDIF;access [29]\r
\r
\r
IF robin OR dmII\r
z80	SET	TRUE	; This one's a Z80\r
ENDIF;robin OR dmII\r
\r
IF hp125			;[MF]\r
z80	SET	TRUE		;HP-125 uses a Z80\r
ENDIF;hp125 [MF]\r
\r
IF gener OR cpm3	; To be truly generic, we must assume 8080.\r
z80	SET	FALSE\r
ENDIF;gener OR cpm3\r
;\f\r
IF osi\r
defesc	EQU	']'-100O	;The default escape character.\r
ENDIF; osi \r
\r
IF vector\r
defesc	EQU	'~'		;Vector can't type ']'.\r
ENDIF;vector\r
\r
IF mikko OR osbrn1 OR lobo\r
defesc	EQU	'\'-100O	;The default is Control \ -- it's easier B.E.\r
ENDIF;mikko OR osbrn1 OR lobo\r
\r
IF cpt85xx\r
defesc	EQU	'\'-100O	;Still Control-\ (just ran out of room...)\r
ENDIF;cpt85xx\r
\r
IF bbc OR rm380z OR px8 OR access OR S1008	;[22] [29]\r
defesc	EQU	'\'-100O	;Still Control-\ (just ran out of room...)\r
ENDIF	;bbc OR rm380z OR px8 OR access OR s1008[29]\r
\r
IF trs80\r
defesc	EQU	'_'-100O	;CTRL-_ (Down-arrow on TRS-80 keyboard)\r
ENDIF;trs80\r
\r
; Select initial setting for VT-52 emulation flag.\r
\r
IF vt52 ; If console looks like (or is) VT52\r
vtval	EQU	0		;  we don't need VT52 emulation\r
ENDIF;vt52\r
\r
; If none of the above, default to VT52-EMULATION ON.\r
IF NOT (crt OR vt52 OR robin OR dmII OR vt100 OR hp125);[MF]\r
vtval	EQU	1\r
ENDIF;NOT (crt OR vt52 OR robin OR dmII OR vt100 OR hp125)[MF]\r
\r
\r
;	sysxin	- system dependent initialisation code, called from SYSINIT\r
;\r
sysxin:\r
\r
IF dmII\r
; edit added by OBSchou for C. Lasner.	If this dont work, tell me whats\r
;	wrong, as I have no DMII or IBM to play with\r
;\r
;	IBM mode fixup program\r
;\r
;	This routine must be run before attempting to use KERMIT-80 with half\r
;	duplex KERMIT implementations such as CMS-KERMIT, as the 6120 processor\r
;	will otherwise "swallow" the XON character.\r
;\r
;	acknowledgments and limitations.\r
;\r
;	This program is based on DECMATE specific implementation details\r
;	provided by Walt Lamia of DEC. It is of course, specific to DECMATE\r
;	implementations of CP/M-80 for DECMATE II, III, III-plus, etc.\r
;\r
;	usage consists of merely:\r
;\r
;	CP4DMF			run this program\r
;	KERMIT80		then run kermit\r
;	<KERMIT-80 commands used normally here, including SET IBM ON>\r
;	CP4DMU			run companion program to restore normal XON\r
;\r
;	unless CP4DMU is run following KERMIT-80, the normal handling of\r
;	XON/XOFF provided by KERMIT-80 will not work (cold boot is another\r
;	alternative).\r
;\r
;	CP4DMF.ASM\r
;\r
;	last edit:	12-jun-87	20:00:00	Charles J. Lasner (CJL)\r
\r
;oboff	equ	3fh		; offset of outbyt routine for 6120\r
;prtctl	equ	02h		; port control\r
nocoxon	equ	001h		; turn off comm. output XON\r
\r
	lxi	b,(nocoxon * 100h) + prtctl ; c/prtctl, b/no out. xon\r
	call	outbyt\r
	ret			; and return\r
\r
;outbyt has been catered for (in break routine)\r
ENDIF	;dmII\r
\r
IF osbrn1	;(Note now no longer needs code > 4000h as it is already there\r
;	lxi	d,ostop		;where we're moving it to\r
;	lxi	h,osmove	;what we're moving\r
;	mvi	b,osmct		;How many bytes we're moving\r
;	call	mover\r
	lda	baudrt		; Find out what speed is current\r
	ani	1\r
	mvi	a,osbi03	; assume 300 baud\r
	jz	osstr1\r
	mvi	a,osbi12	; nope, it's 1200.\r
osstr1:	sta	speed		; save initial speed\r
	sta	speed+1		;  as 16 bits, to match speed table entries\r
	mov	d,a\r
	mov	e,a		; get initial speed in DE\r
	call	sysspd		;set up parity etc.\r
ENDIF;osbrn1\r
\r
IF cpt85xx\r
	mvi	a,80h		; Send UART reset [force idle] by setting\r
	out	baudrt		;    bit 7 of baud rate I/O port\r
	lxi	H,0f0fh		; Clear reset and default to 9600 baud [23]\r
	shld	speed		; store current speed\r
	xchg\r
	call	sysspd		; set default baud rate\r
	mvi	a,4Eh		; Set UART mode to async 16x clock, 8 data\r
	out	mnprts		;    bits, no parity, and 1 stop bit\r
	mvi	a,37h		; Set command to Tx enable, DTR on, Rx enable,\r
	out	mnprts		;    break off, error reset, and RTS on\r
ENDIF	; cpt85x\r
\r
IF bbc		;[22]\r
	lxi	d,modstr	; Set MODE 3\r
	call	prtstr\r
	mvi	a,1		; Set terminal mode on\r
	call	term\r
	mvi	a,0F2H		; Read current transmit speed\r
	lxi	h,0FF00H	; .. 3 lsb of ULA register\r
	call	osbyte		;   FX242,0,255\r
	mov	a,l\r
	ani	7		; Mask of 3 lsb\r
;\r
; Edit of July 22, 1986 by B Robertson, Aberdeen Univ. Computing Centre.\r
; Correct bug in sysinit for BBC  -  reads the initial baud rate at\r
; start up incorrectly.\r
;\r
;\r
	rar			; Reverse order of 3 lsb\r
	rar			; Bit2 now in bit0\r
	jnc	binit1		;\r
	ori	2		; Restore bit1\r
binit1:	ana	a		; Set sign bit as appropriate\r
	jp	binit2		;\r
	ori	4		; Bit0 now in bit2\r
binit2:	ani	7		; Mask off unwanted bits\r
; End of Edit\r
\r
	xri	7		; Stored as 2's complement\r
	inr	a\r
	sta	speed		; Store 16 bit value\r
	sta	speed+1\r
	mov	e,a		; Ensure RX and TX speeds are the same\r
	call	sysspd\r
ENDIF;[22] bbc\r
\r
IF rm380z	;[22]\r
	mvi	e,11h		;Output ctrl-Q to clear autopaging\r
	call	outcon\r
ENDIF;[22] rm380z\r
\r
\r
IF lobo	;[hh]\r
	lxi	d,siotbl	;[hh] address of status table\r
	mvi	c,siolen	;[hh] length of the table\r
siolup:	;[hh] loop here for each command byte\r
	ldax	d		;[hh] load first byte into A\r
	inx	d		;[hh] index pointer to next bute\r
	sta	mnprts		;[hh] send it to status port A\r
	sta	mnprts+2	;[hh] and to status port B\r
	dcr	c		;[hh] decrement the counter\r
	jnz	siolup		;[hh] loop back for more commands\r
	mvi	a,05H		;[hh] value for 300 baud\r
	sta	baudrt		;[hh] starting default for port A\r
	sta	baudrt+4	;[hh] and for port B\r
	sta	speed		;[hh] tell program they're set\r
	mvi	a,0E4H		;[hh] value for port A\r
	sta	port		;[hh] tell program we've set this, too\r
	mvi	a,0D0H		;[hh] port A baud rate value\r
	sta	port+1		;[hh] save this as well, for consistancy\r
ENDIF	;lobo\r
\r
IF mikko\r
	lxi	d,mintbl	;Address of KERMIT Reg values (what)\r
	mvi	c,minlen	;Length of table (how many)\r
	lxi	h,sioac		;Send data to ch. A SIO registers (to where)\r
	call	movmik\r
	mvi	a,0FFH		;Set ch. A mask to use all bits\r
	sta	chmask\r
ENDIF;mikko\r
\r
IF mdI\r
	lxi	h,96		;Default 1200 baud modem port speed\r
	shld	speed		;Store as modem port speed\r
	call	sysspd		;Initialize the port\r
ENDIF;mdI  [Toad Hall]\r
\r
IF cmemco			;[25]\r
	mvi	a,01h		; Reset TU-ART\r
	out	tuart+2\r
	mvi	a,90h		; Set default baud rate (2400), and 1 stop bit\r
	out	tuart\r
	sta	speed		; save for status display\r
	sta	speed+1\r
ENDIF;cmemco\r
\r
IF delphi			;[7]\r
;\r
;	shove the default baud rate (1200) in to the Delphi port address\r
;	for the baud rate generator on port 2, the default port; save this\r
;	value so we can tell what speed is selected.\r
;\r
	mvi	a,07h		;[7] get value for 1200 baud\r
	out	baudrt		;[7] set it for port 2\r
	sta	speed		;[7] save for status display\r
	sta	speed+1\r
ENDIF;[7] delphi\r
\r
IF px8 ; [29]\r
	lda	0f6a9h		; get baud rate value set by CONFIG\r
	sta	px8blk+4	; put into parameter block\r
	mov	h, a		; initialise global speed indicator\r
	mov	l, a\r
	shld	speed\r
	lhld	6		; base of CP/M\r
; buffer starts at ovlend+8192, immediately after sector buffer\r
; We must also allow (800h) for the CCP as Kermit exits with a RET\r
	lxi	d, ovlend+8192+800h  ; calc buffer length\r
	ora	a		; clear carry\r
	db	0edh, 52h	; sbc hl, de\r
	shld	px8blk+2\r
	call	rsopen\r
ENDIF ; px8 [29]\r
\r
IF disc	;[29]\r
;Initialization sequence for Discovery 83U port B\r
;Sets port to 9600 baud, 8 data bits, 1 stop bit, no parity\r
	mvi	a,12		;Register 12\r
	out	mnprts\r
	mvi	a,11		;Low byte of time constant for 9600\r
	out	mnprts\r
	mvi	a,13		;Register 13\r
	out	mnprts\r
	mvi	a,0		;High byte of time constant for 9600\r
	out	mnprts\r
	mvi	a,14		;Register 14\r
	out	mnprts\r
	mvi	a,3		;Enable baud rate generator\r
	out	mnprts\r
	mvi	a,11		;Register 11\r
	out	mnprts\r
	mvi	a,52h		;No Xtal, tclk=rclk=/trxc out=br gen\r
	out	mnprts\r
	mvi	a,4		;Register 4\r
	out	mnprts\r
	mvi	a,44h		;16x clock, 1 stop, no parity\r
	out	mnprts\r
	mvi	a,3		;Register 3\r
	out	mnprts\r
	mvi	a,71h		;rx 8 bit/ch, autoenable, rx enable\r
	out	mnprts\r
	mvi	a,5		;Register 5\r
	out	mnprts\r
	mvi	a,0eah		;tx 8 bit/ch, tx enable, rts\r
	out	mnprts\r
ENDIF;disc [29]\r
;\r
;\f\r
IF mikko			;currently for MIKROMIKKO only\r
; copy command block into memory-mapped SIO.\r
movmik:	di			;disable interrupts\r
movmk1:	ldax	d		;Get a register value\r
	mov	m,a		;Output it\r
	inx	d		;Next value\r
	dcr	c		;Decrement counter\r
	jnz	movmk1		;Repeat until done\r
	ei\r
	ret\r
ENDIF;mikko\r
\r
;\f\r
IF osbrn1\r
osmove:\r
osflag	equ	0EF08H		;Osborne 1 Bank-2 flag\r
;\r
; return modem status in A\r
;\r
OSLDST:\r
	DI\r
	OUT	0\r
	LDA	osprts		;Read the status port\r
	OUT	1\r
	EI\r
	ret\r
;\r
; set modem status from A\r
;\r
OSSTST:\r
	DI\r
	OUT	0\r
	STA	osprts	;Write the control port\r
	jmp	osstex\r
;\r
; read character from modem into A\r
;\r
OSLDDA:\r
	DI\r
	OUT	0\r
	LDA	osport\r
	OUT	1\r
	EI\r
	ret\r
;\r
;	output character in A to modem\r
;\r
OSSTDA:\r
	DI\r
	OUT	0\r
	STA	osport\r
osstex:\r
	OUT	1\r
	mvi	a,1\r
	sta	osflag\r
	EI\r
	ret\r
ENDIF;osbrn1\r
\r
IF lobo\r
; List of commands to set up SIO channel A for asynchronous operation.\r
siotbl:	DB	18H		; Channel reset\r
	DB	18H		; another, in case register 0 wasn't selected\r
	DB	04H		; Select register 4\r
	DB	44H		; 1 stop bit, clock*16\r
	DB	01H		; Select register 1\r
	DB	00H		; No interrupts enabled\r
	DB	03H		; Select register 3\r
	DB	0C1H		; Rx enable, 8 bit Rx character\r
	DB	05H		; Select register 5\r
	DB	0EAH		; Tx enable, 8 bit Tx character,\r
				;  raise DTR and RTS\r
siolen	equ	$-siotbl	; length of command list\r
ENDIF;lobo\r
\r
IF mikko\r
; command list to set SIO chip back to normal state\r
miotbl:	db	3		;reg. 3\r
	db	sioo3\r
	db	5		;reg. 5\r
	db	sioo5\r
	db	4		;reg. 4\r
	db	sioo4\r
	db	0		;reselect reg. 0\r
miolen	equ	$-miotbl	;MikroMikko SIO table length (original values)\r
\r
; command list to set up SIO chip for operation with Kermit\r
mintbl:	db	3		;reg. 3\r
	db	sion3\r
	db	5		;reg. 5\r
	db	sion5\r
	db	4		;reg. 4\r
	db	sion4\r
	db	0		;reselect reg. 0\r
minlen	equ	$-mintbl	;MikroMikko SIO table length (KERMIT values)\r
ENDIF;mikko\r
\r
\r
IF bbc		;[22]\r
modstr:	db	16h,03h,'$'	; String to put screen into MODE 3\r
ENDIF\r
\r
IF px8 ; [29]\r
rsget:	mvi	b, 50h\r
	jmp	rsiox\r
rsinst:	mvi	b, 30h\r
	jmp	rsiox\r
rsput:	mvi	b, 60h\r
	jmp	rsiox\r
rsoutst:mvi	b, 40h\r
	jmp	rsiox\r
rserst:	mvi	b, 90h\r
	jmp	rsiox\r
rsopen:	lxi	h, px8blk	; copy px8blk to px8prm\r
	lxi	d, px8prm\r
	lxi	b, 9\r
	call	mover\r
	mvi	b, 10h		; open code\r
	jmp	rsiox\r
rsclose:mvi	b, 20h		; close code\r
rsiox:	lxi	h, px8prm\r
	lxi	d, 51h		; offset into BIOS jump table\r
	push	h\r
	lhld	1		; start of BIOS\r
	dad	d\r
	xthl			; entry point on stack, px8prm addr in hl\r
	ret			; jump indirect\r
\r
px8prm:	dw	0, 0\r
	db	0, 0, 0, 0, 0	; the param area is overwritten in rsopen\r
px8blk:	dw	ovlend+8192	; buffer address\r
	dw	0		; buffer size - overwritten\r
	db	0		; baud rate - overwritten\r
	db	3		; 8 bits/char\r
	db	0		; no parity, it is done internally\r
	db	1		; 1 stop bit\r
	db	0cfh		; special bits - activate xon/xoff\r
; The documentation suggests that the xon/xoff bit is bit 4, i.e the pattern\r
; should be 0efh, but the top bit is omitted from the diagram. I will try\r
; clearing both bit 4 and bit 5.\r
ENDIF ; px8 [29]\r
\r
IF hp125			;[MF]\r
	lxi	b,73ffh		;Prepare Data Comm 1 to\r
	call	bdos		;Transfer eight-bit data\r
	lxi	d,jbuf		;Point to bios jump-table vector\r
	lxi	b,7effh		;Set up special subfunction code to\r
	call	bdos		;Get rdr routine address\r
	lhld	jbuf+3		;Remember this address\r
	shld	readin+1	;for our eight-bit rdr routine\r
	mvi	a,1		;We want to write into the bios jump table\r
	sta	jbuf+1		;...\r
	lxi	h,readin	;Point to our rdr routine (all 8 bits)\r
	shld	jbuf+3		;as new RDR routine\r
	lxi	d,jbuf		;Point to jump vector argument block\r
	lxi	b,7effh		;Set subfunction code to\r
	call	bdos		;Substitute our rdr routine in dispatch table\r
	lxi	h,mapon1	;Make Data Comm 1 the default port\r
	shld	port		;at program-start\r
	xchg			;Put in DE\r
	call	prtstr		;Print escape sequences to connect\r
				;DAta Comm 1 to rdr/punch\r
ENDIF ;hp125 [MF]\r
\r
	ret			; end of sysxin\r
\r
;\f\r
;	system-dependent termination processing\r
;	If we've changed anything, this is our last chance to put it back.\r
sysexit:\r
\r
IF dmII\r
; Edited by OBSchou for Charles Lasner.	 His bug fix now in Kermit-80:\r
;\r
;	IBM mode restore program\r
;\r
;	This routine must be run after using CP4DMF (and KERMIT-80) to restore\r
;	the normal handling of XON/XOFF; the user may also elect to cold-boot\r
;	the DECMATE instead.\r
;\r
;	acknowledgments and limitations.\r
;\r
;	This program is based on DECMATE specific implementation details\r
;	provided by Walt Lamia of DEC. It is of course, specific to DECMATE\r
;	implementations of CP/M-80 for DECMATE II, III, III-plus, etc.\r
;\r
;	usage consists of merely:\r
;\r
;	CP4DMF			run xon/xoff disable program\r
;	KERMIT80		then run kermit\r
;	<KERMIT-80 commands used normally here, including SET IBM ON>\r
;	CP4DMU			run this program to restore normal XON\r
;\r
;	unless CP4DMU is run following KERMIT-80, the normal handling of\r
;	XON/XOFF provided by KERMIT-80 will not work (cold boot is another\r
;	alternative).\r
;\r
;	CP4DMF.ASM\r
;\r
;	last edit:	12-jun-87	20:00:00	Charles J. Lasner (CJL)\r
;\r
coxon	equ	000h		; enable comm. output XON\r
;oboff	equ	3fh		; offset of outbyt routine for 6120\r
;prtctl	equ	02h		; port control\r
\r
\r
	lxi	b,(coxon * 100h) + prtctl ; c/prtctl, b/with out. xon\r
	call	outbyt		;[OBS] declared elswhere\r
	ret			; and return\r
\r
ENDIF	;dmII\r
\r
IF mikko\r
	lxi	d,miotbl	;Load the adress of original reg values\r
	mvi	c,miolen	;Length of table\r
	lxi	h,sioac		;Send data to ch A SIO registers\r
	call	movmik\r
	mvi	a,07FH		;Set ch A mask to use just 7 bits\r
	sta	chmask\r
ENDIF;mikko\r
\r
IF teletek\r
;Note - This code was handwritten onto the lising I was sent, with the \r
;	comment that David had just thought of the code, so it was \r
;	not on the listing. If you have problems I suggest you \r
;	comment out these few lines.\r
;Bertil Schou.\r
;\r
	di\r
	mvi	a,47h		; reset baud rate to 9600\r
	out	baudrt\r
	mvi	a,08h\r
	out	baudrt\r
	ei\r
ENDIF	;teletek\r
\r
IF cpt85xx\r
	mvi	a,80h		; Reset (force idle) the 8251 UART via bit 7\r
	out	baudrt		;    of the baud rate generater port\r
	mvi	a,00h		; and turn off the baud rate generater\r
	out	baudrt\r
ENDIF;cpt85xx\r
\r
IF bbc	;[22]\r
	mvi	a,0		; Turn off terminal mode\r
	call	term\r
ENDIF;[22] bbc\r
\r
IF px8	;[29]\r
	call	rsclose\r
ENDIF	;px8 [29]\r
\r
IF hp125			;[MF]\r
	lxi	b,74ffh		;Set subfunction code to\r
	call	bdos		;Reset Data Comm 1 for 7-bit data\r
	lhld	readin+1	;Get original rdr routine address\r
	shld	jbuf+3		;and store in jump vector\r
	lxi	d,jbuf		;Point to jump vector\r
	lxi	b,7effh		;Set subfunction code to\r
	call	bdos		;Put original rdr routine back in bios\r
				;dispatch table\r
	lxi	d,mapoff	;Point to escape sequences to\r
	call	prtstr		;Turn off Data Comm 1/2 mappings\r
ENDIF ;hp125 [MF]\r
\r
	ret\r
\r
;\r
;	system-dependent processing for start of CONNECT command\r
;\r
syscon:\r
IF robin OR trs80 OR cpt85xx	;For Robin/TRS80/CPT-85xx, add some more info\r
	lxi	d,conmsg	; about obscure key combinations\r
	call	prtstr\r
ENDIF;robin OR trs80 OR cpt85xx\r
\r
IF osbrn1			;*** This is Software dependent ***\r
	lhld	1		;Modify back-arrow code to DELETE\r
	mvi	l,0		;Get BIOS-start address\r
	lxi	d,85H		;Adress for key-code = XX85H\r
	dad	d\r
	mov	e,m		;Get it in DE\r
	inx	h\r
	mov	d,m\r
	xchg			;Memory pointer to HL\r
	mvi	m,del		;modify the code\r
ENDIF;osbrn1\r
	ret\r
\r
conmsg:		; Messages printed when entering transparent (CONNECT) mode:\r
IF robin	;  for Robin, control-S key is hidden\r
	db	' (Type Left Arrow to send CTRL-S)',cr,lf,'$'\r
ENDIF;robin\r
IF trs80	;  for TRS-80, the preferred escape key is hidden\r
	db	' (Control-_ is the Down-Arrow key on the TRS-80 keyboard)'\r
	db	cr,lf,'$'\r
ENDIF;trs80\r
IF cpt85xx	;  for CPT-85xx, some graphics map "funny" to keyboard in CP/M\r
	db	' (Use	CODE + SHIFT + 1/2  key to generate a Control-\)'\r
	db	cr,lf,'$'\r
ENDIF;cpt85xx\r
;\f\r
;	syscls - system-dependent close routine\r
;	called when exiting transparent session.\r
;\r
syscls:\r
IF osbrn1\r
	lhld	1		;Modify back-arrow code to BACKSPACE\r
	mvi	l,0		;Get BIOS address\r
	lxi	d,85H		;Address for key-code =XX85H\r
	dad	d\r
	mov	e,m		;Get it in DE\r
	inx	h\r
	mov	d,m\r
	xchg			;Address to HL\r
	mvi	m,bs		;Modify code\r
ENDIF;osbrn1\r
	ret\r
;\f\r
;	sysinh - help for system-dependent special functions.\r
;	called in response to <escape>?, after listing all the\r
;	system-independent escape sequences.\r
;\r
sysinh:\r
IF robin OR dmII OR cpt85xx OR lobo \r
	lxi	d,inhlps	; we got options...\r
	call	prtstr		; print them.\r
ENDIF;robin OR dmII OR cpt85xx OR lobo \r
\r
IF bbc OR rm380z ; some more\r
	lxi	d,inhlps	; we got options...\r
	call	prtstr		; print them.\r
ENDIF;[22] bbc OR rm380z \r
\r
IF px8 OR access OR mmate OR disc ;and more...\r
	lxi	d,inhlps	; we got options...\r
	call	prtstr		; print them.\r
ENDIF	;px8 OR access OR mmate OR disc \r
\r
	ret\r
\r
\r
;additional, system-dependent help for transparent mode\r
; (two-character escape sequences)\r
inhlps:\r
\r
IF robin OR dmII OR cpt85xx OR lobo\r
	db	cr,lf,'B  Transmit a BREAK'\r
ENDIF;robin OR dmII OR cpt85xx OR lobo \r
\r
IF bbc OR rm380z \r
	db	cr,lf,'B  Transmit a BREAK'\r
ENDIF;bbc OR rm380z \r
\r
IF px8 OR access OR mmate \r
	db	cr,lf,'B  Transmit a BREAK'\r
ENDIF	;px8 OR access OR mmate \r
\r
IF disc	;[29] [32]\r
	db	cr,lf,'B Transmit a 300ms BREAK'\r
	db	cr,lf,'L Transmit a 5 second BREAK'\r
ENDIF;disc [29]\r
\r
IF lobo\r
	db	cr,lf,'D  Drop the line'\r
ENDIF;lobo\r
\r
	db	'$'			;[hh] table terminator\r
\r
;\r
;	sysint - system dependent special functions\r
;	called when transparent escape character has been typed;\r
;	the second character of the sequence is in A (and in B).\r
;	returns:\r
;	non-skip: sequence has been processed\r
;	skip:	sequence was not recognized\r
\r
sysint:	ani	137O		; convert lower case to upper, for testing...\r
\r
IF robin OR dmII OR cpt85xx OR lobo \r
	cpi	'B'		; send break?\r
	jz	sendbr		; yes, go do it.  return nonskip when through.\r
ENDIF;robin OR dmII OR cpt85xx OR lobo \r
\r
IF bbc OR rm380z ; [22] [25] ... some more\r
	cpi	'B'		; send break?\r
	jz	sendbr		; yes, go do it.  return nonskip when through.\r
ENDIF; bbc OR rm380z \r
\r
IF px8 OR access OR	mmate ;[28] [29] and anothers\r
	cpi	'B'		; send break?\r
	jz	sendbr		; yes, go do it.  return nonskip when through.\r
ENDIF	; px8 OR access OR mmate [28] [29]\r
\r
IF lobo	;[hh]\r
	cpi	'D'		;[hh] disconnect?\r
	jz	discon		;[hh] yes, go do it. nonskip return when done.\r
ENDIF	;lobo\r
\r
IF disc	;[29]\r
	cpi	'B'		;Send short break?\r
	jz	sendbr\r
	cpi	'L'		;Send long break?\r
	jz	sendlbr\r
ENDIF;disc [29]\r
\r
	jmp	rskp		; take skip return - command not recognized.\r
\r
\r
;\f\r
IF robin ;Definitions & code to send a BREAK (ungenerically, no other way).\r
\r
comctl	equ	59h		;VT180 communications port\r
crtctl	equ	41h		;VT180 crt port\r
\r
;VT180 serial port command bits\r
\r
txe	equ	1		;transmit enable\r
dtr	equ	2		;dtr on\r
rxe	equ	4		;rx enable\r
sndbrk	equ	8\r
rerr	equ	10h		;reset error\r
rts	equ	20h		;RTS on\r
reset	equ	40h		;port reset\r
\r
;Send a break to the communications port.\r
;\r
\r
sendbr:	lxi	h,38500		;250 ms(?)\r
	lda	prtadr		;Get address of selected port\r
	mov	c,a		;Into C\r
	mvi	a,sndbrk+dtr\r
;	OUT	C,A		;Want to send to port addressed by C\r
	db	0EDH,079H	;Op code for above instruction\r
sndbr1:	dcx	h		;timing loop...\r
	mov	a,l\r
	ora	h\r
	jnz	sndbr1		;...until over\r
	lda	prtadr		;Get the address for the port\r
	mov	c,a		;Into C\r
	mvi	a,txe+dtr+rxe+rerr+rts	;enable tr/rc, dtr, reset error\r
;	out	c,a		;Z-80 only instruction\r
	db	0EDH,079H	;Op code for above instruction\r
	out	contst		;reset ports\r
	ret\r
ENDIF;robin\r
;\f\r
IF dmII				;[jd] this added to send break on DECmate\r
\r
; DECmate command codes for 6120 I/O processor\r
oboff	equ	3fh		; offset of outbyt routine for 6120\r
prtctl	equ	02h		; port control\r
brdat	equ	06h		; data to tell 6120 to send a break\r
brdur	equ	30		; duration, 30 = 300 ms.\r
\r
sendbr:	lxi	b,(brdat * 100h) + prtctl ; c/prtctl, b/brdat\r
	call	outbyt\r
	lxi	b,brdur*100h		; b/duration, c/0\r
;	fall through into outbyt\r
\r
outbyt:	lhld	1		; get warm boot address\r
	lxi	d,oboff		; offset of outbyt routine\r
	dad	d		; compute address\r
	pchl			; branch there (a callret)\r
\r
ENDIF;dmII\r
;\f\r
IF access OR mmate ;[cjc] send break on Kaypro [29]\r
; Officially, a "break" is 300 milliseconds of "space" (idle line is\r
; "mark").  (or maybe 200 milliseconds; I forget.)  The timing isn't\r
; usually that critical, but we'll make an attempt, at least.  Sending\r
; too long a break can cause some modems to hang up.\r
\r
sendbr:\r
;	First, make sure the transmitter is really empty.  (The SIO sets\r
;	"transmitter buffer empty" when it can accept another character;\r
;	the previous character is still being shifted onto the line.\r
;	Another status bit, "all done", is set to indicate that the\r
;	transmitter is really idle.\r
sndbr1:	mvi	a,1		; select Read Register 1\r
	out	mnprts\r
	in	mnprts		; read the contents\r
	ani	1		; test "all done" flag\r
	jz	sndbr1		; loop until it's nonzero.\r
;\r
;	Next, set the "send break" bit to start the transmitter spacing.\r
	mvi	a,5		; select Write Register 5\r
	out	mnprts\r
	mvi	a,0FAH		; Tx enable, 8 bit Tx character, Send Break,\r
	out	mnprts		;  DTR and RTS on.\r
;\r
;	Now, delay for 30 hundredths of a second\r
	mvi	a,30		; delay count\r
	call	delay\r
;\r
;	Time's up. Put transmitter back in normal state (data byte is the\r
;	same as the one in siotbl: for Write Register 5) and return.\r
	mvi	a,5		; select Write Register 5\r
	out	mnprts\r
	mvi	a,0EAH		; Tx enable, 8 bit Tx character,\r
	out	mnprts		;  DTR and RTS on.\r
	ret			; done.\r
ENDIF;access OR mmate [29]\r
\r
IF lobo	;[hh]	This routine sends a break tone or disconnects a modem\r
;		(those that respond to it) by setting the DTR line low\r
;		for 300 ms.\r
;\r
sendbr:	mvi	a,05H		;[hh] write register 5\r
	call	outctl		;[hh] send it to control port\r
	mvi	a,0FAH		;[hh] value to send break tone\r
	jmp	sndbr1		;[hh]\r
;\r
discon:	mvi	a,05H		;[hh] write register 5\r
	call	outctl		;[hh] send it to the control port\r
	mvi	a,06AH		;[hh] DTR off and break tone on\r
sndbr1:	call	outctl		;[hh] send to control port\r
	mvi	a,30		;[hh] delay count for 300 ms.\r
	call	delay		;[hh] wait a while...\r
	mvi	a,05H		;[hh] write register 5\r
	call	outctl		;[hh] get it's attention\r
	mvi	a,0EAH		;[hh] normal 8 bits, DTR on, RTS on, etc.\r
	call	outctl		;[hh] restore SIO\r
	ret\r
;\r
outctl:	sta	mnprts		;[hh]\r
	ret\r
ENDIF	;lobo\r
;\f\r
IF cpt85xx OR rm380z ;[lmj] [22] [25]\r
sendbr:\r
;\r
;	Ensure that the transmitter has finished sending buffered chars\r
sndbr1:	in	mnprts		; get UART status\r
	ani	TxEmpty		; everything sent?\r
	jz	sndbr1		; no, wait a bit more\r
;\r
;	Begin sending a break by setting bit in UART command register\r
	mvi	a,3Fh		; Set TxEna, DTR, RxEna, SBreak, ErrRst, RTS\r
	out	mnprts\r
;\r
;	Wait for 250 milliseconds (using hundredths second delay routine)\r
	mvi	a,25\r
	call	delay\r
;\r
;	Resume normal operation by clearing the SendBreak command bit\r
	mvi	a,37h		;Set TxEna, DTR, RxEna, ErrRst, RTS\r
	out	mnprts\r
;\r
	ret			;done\r
ENDIF;cpt85xx OR rm380z \r
\r
IF px8 ; [29]\r
sendbr:	mvi	a, 3fh	; set break bit\r
	out	mnprts\r
	mvi	a, 25\r
	call	delay	; wait 250 msec\r
	mvi	a, 37h	; clear break bit\r
	out	mnprts\r
	ret\r
ENDIF ; px8 [29]\r
\r
;\f\r
IF bbc		;[22]\r
sendbr:\r
;\r
;	Ensure that the transmitter has finished sending buffered chars\r
sndbr1:	mvi	a,96h		; get ACIA status\r
	mvi	l,8\r
	call	osbyte		; *FX150,8\r
	mov	a,h\r
	ani	2		; everything sent?\r
	jz	sndbr1		; no, wait a bit more\r
;\r
;	Disable centisecond clock (system VIA) which interferes with break\r
	lxi	h,0FE4Eh	; system VIA interrupt enable register\r
	mvi	a,40H		; disable timer 1\r
	call	wrtiom		; write to I/O processor memory\r
;\r
;	Begin sending a break by setting bit in ACIA control register\r
	mvi	a,9Ch\r
	lxi	h,9F60h		; Set Rxint, Txint, Break, RTS\r
	call	osbyte		; *FX 156,96,159\r
;\r
;	Wait for 250 milliseconds (using hundredths second delay routine)\r
	mvi	a,25\r
	call	delay\r
;\r
;	Resume normal operation by returning old control byte\r
	mvi	a,9Ch\r
	mvi	h,0		;Set TxEna, DTR, RxEna, ErrRst, RTS\r
	call	osbyte		; *FX 156,oldvalue,0\r
;\r
;	Enable centisecond clock (system VIA)\r
	lxi	h,0FE4Eh	; system VIA interrupt enable register\r
	mvi	a,0C0H		; enable timer 1\r
	call	wrtiom		; write to I/O processor memory\r
;\r
	ret			;done\r
;\r
;	Routine to write byte in A to I/O processor memory address\r
;	given by HL\r
wrtiom:\r
	shld	parblk		; store address to parameter block\r
	sta	parblk+4	; store data\r
	lxi	h,parblk	; load hl with address of param block\r
	mvi	a,6		; write I/O processor memory\r
	call	osword		; go do it\r
	ret\r
;\r
parblk:	DS	5		; reserve space for parameter block\r
ENDIF;bbc [22]\r
;\f\r
IF disc	;[29]\r
; This is almost an exact copy of the bbI sendbr routine.\r
; Modifications to include a long break have been made.\r
;\r
; Officially, a "break" is 300 milliseconds of "space" (idle line is\r
; "mark").  (or maybe 200 milliseconds; I forget.)  The timing isn't\r
; usually that critical, but we'll make an attempt, at least.  Sending\r
; too long a break can cause some modems to hang up.\r
\r
sendlbr:\r
	push	d	;save d, this may not be necessary, but safe\r
	mvi	d,17	;do short break 17 times (approx. 5 sec.)\r
	jmp	sndbr1\r
sendbr:\r
	push d\r
	mvi	d,1	;On short break, do only once\r
; First, make sure the transmitter is really empty.  (The SIO sets\r
; "transmitter buffer empty" when it can accept another character;\r
; the previous character is still being shifted onto the line.\r
; Another status bit, "all done", is set to indicate that the\r
; transmitter is really idle.\r
sndbr1:	mvi	a,1		; select Read Register 1\r
	out	mnprts\r
	in	mnprts		; read the contents\r
	ani	1		; test "all done" flag\r
	jz	sndbr1		; loop until it's nonzero.\r
;\r
; Next, set the "send break" bit to start the transmitter spacing.\r
	mvi	a,5		; select Write Register 5\r
	out	mnprts\r
	mvi	a,0FAH		; Tx enable, 8 bit Tx character, Send Break,\r
	out	mnprts		;  DTR and RTS on.\r
;\r
; Now, delay for 30*d hundredths of a second\r
sendbr2:\r
	mvi	a,30		; delay count\r
	call	delay\r
; The following has been added to allow doing .03 delay d times\r
	dcr	d		; decrement # of times to do loop\r
	jnz	sendbr2		; if not done, do again\r
	pop	d		; reload d\r
;\r
; Time's up. Put transmitter back in normal state (data byte is the\r
; same as the one in siotbl: for Write Register 5) and return.\r
	mvi	a,5		; select Write Register 5\r
	out	mnprts\r
	mvi	a,0EAH		; Tx enable, 8 bit Tx character,\r
	out	mnprts		;  DTR and RTS on.\r
	ret			; done.\r
ENDIF	;disc [29]\r
\r
\r
;\r
;	sysflt - system-dependent filter\r
;	called with character in E.\r
;	if this character should not be printed, return with A = zero.\r
;	preserves bc, de, hl.\r
;	note: <xon>,<xoff>,<del>, and <nul> are always discarded.\r
sysflt:\r
	mov	a,e		; get character for testing\r
IF mikko\r
	cpi	'O'-100O	;Control-O's lock keyboard\r
	rnz			; if not control-O, it's ok.\r
	xra	a		; don't allow control-O out.\r
ENDIF;mikko\r
\r
	ret\r
\r
;	mdmflt - modem filter [30]\r
;	called with character to be sent to printer in E\r
;	with parity set as appropriate.\r
;	return with accumulator = 0 do do nothing,\r
;				<> 0 to send char in E.\r
mdmflt:\r
	mov	a,e		;[30] get character to test\r
	ret\r
\r
\r
\r
;	prtflt - printer filter [30]\r
;	called with character to be sent to printer in E\r
;	returns with a = 0 to do nothing\r
;		     a <> 0 to print it.\r
;\r
;	this routine for those printer that automatically insert\r
;	a lf on cr, or cr for lf.  Should this be shifted to \r
;	the system indep. stuff, in say 4.06?\r
prtflt:\r
	mov	a,e		; [30] get character to test\r
	ret\r
\r
\r
;\f\r
; system-dependent processing for BYE command.\r
;  for lobo, hang up the phone.\r
sysbye:\r
IF lobo ;[hh]\r
	call	discon		;[hh] force modem to hang up\r
ENDIF;lobo\r
	ret\r
\r
IF lasm\r
	LINK	CPXSY2.ASM	; If m80 then this ignored\r
ENDIF	; lasm\r