new chario

[z180-stamp-cpm3.git] / cbios / chario.180

	title	'Character I/O Module for the Modular CP/M 3 BIOS'\r
	page	255\r
	.z80\r
\r
\r
\r
	public ?cinit,?ci,?co,?cist,?cost\r
	public @ctbl\r
\r
\r
	extrn	ff.init,ff.ist,ff.in,ff.ost,ff.out\r
	extrn	as0init,as0ista,as0inp,as0osta,as0out\r
	extrn	as1init,as1ista,as1inp,as1osta,as1out\r
	extrn	_b0call\r
\r
	include config.inc\r
	include	z180reg.inc\r
\r
	include modebaud.inc	; define mode bits and baud equates\r
\r
max$devices equ	3\r
\r
O_CISTF	equ	0\r
O_CIF	equ	2\r
O_COSTF	equ	4\r
O_COF	equ	6\r
O_INITF	equ	8\r
O_CTBL	equ	10\r
\r
;--------------------------------------------------------------\r
\r
	cseg\r
@ctbl:\r
	db	'USB0  '		; device 0\r
	db	mb$in$out\r
	db	baud$none\r
\r
	db	'ASCI0 '		; device 1\r
	db	mb$in$out+mb$serial+mb$soft$baud\r
	db	baud$19200\r
\r
	db	'ASCI1 '		; device 2\r
	db	mb$in$out+mb$serial+mb$soft$baud\r
	db	baud$19200\r
\r
	db	0				; table terminator\r
\r
\r
	dseg\r
xctbl:\r
	dw	ff_dev\r
	dw	as0_dev\r
	dw	as1_dev\r
	dw	null_dev\r
\r
	rept	16 - ($-xctbl)/2\r
	 dw	0\r
	endm\r
\r
ff_dev:\r
	dw	ff.ist\r
	dw	ff.in\r
	dw	ff.ost\r
	dw	ff.out\r
	dw	ff.init\r
	dw	@ctbl+8*0\r
\r
as0_dev:\r
	dw	as0ista\r
	dw	as0inp\r
	dw	as0osta\r
	dw	as0out\r
	dw	as0init\r
	dw	@ctbl+8*1\r
\r
as1_dev:\r
	dw	as1ista\r
	dw	as1inp\r
	dw	as1osta\r
	dw	as1out\r
	dw	as1init\r
	dw	@ctbl+8*2\r
\r
null_dev:\r
	dw	null$status\r
	dw	null$input\r
	dw	ret$true\r
	dw	rret\r
	dw	rret\r
	dw	0\r
\r
\r
;--------------------------------------------------------------\r
; Init character device\r
;     c: device\r
\r
	cseg\r
?cinit:				; init devices\r
	b0call	_cinit\r
	ret\r
\r
	dseg\r
_cinit:\r
	ld	b,c\r
	ld	hl,O_INITF\r
	jr	vector_io\r
\r
;--------------------------------------------------------------\r
; Character input\r
;     b: device\r
;    return:\r
;     a: input char\r
\r
	cseg\r
?ci:				; character input\r
	b0call	_ci\r
	ret\r
\r
	dseg\r
_ci:\r
	ld	hl,O_CIF\r
	jr	vector_io\r
\r
;--------------------------------------------------------------\r
; Input status\r
;     b: device\r
;    return:\r
;     a: 0ffh if char available, else 0\r
\r
	cseg\r
?cist:				; character input\r
	b0call	_cist\r
	ret\r
\r
	dseg\r
_cist:				; character input status\r
	ld	hl,O_CISTF\r
	jr	vector_io\r
\r
;--------------------------------------------------------------\r
; Character output\r
;     b: device\r
;     c: output char\r
;    return:\r
;     a: output char\r
\r
	cseg\r
?co:				; character input\r
	b0call	_co\r
	ret\r
\r
	dseg\r
_co:				; character output\r
	ld	hl,O_COF\r
	jr	vector_io\r
\r
\r
;--------------------------------------------------------------\r
; Output status\r
;     b: device\r
;    return:\r
;     a: 0ffh if device ready for next output char, else 0\r
\r
\r
	cseg\r
?cost:				; character input\r
	b0call	_cost\r
	ret\r
\r
	dseg\r
_cost:				; character output status\r
	ld	hl,O_COSTF\r
	jr	vector_io\r
\r
;--------------------------------------------------------------\r
\r
	dseg\r
vector_io:\r
	push	de\r
	ex	de,hl\r
\r
	ld	hl,xctbl\r
	ld	a,max$devices\r
	cp	b\r
	jr	c,$+3\r
	ld	a,b\r
	add	a,a\r
	add	a,l\r
	ld	l,a\r
	jr	nc,$+3\r
	inc	h\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a\r
	ex	de,hl\r
	add	hl,de\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a\r
	ex	(sp),hl\r
	ex	de,hl\r
	ret\r
\r
;--------------------------------------------------------------\r
\r
null$input:\r
	ld	a,1Ah\r
rret:\r
	ret\r
ret$true:\r
	or	0FFh\r
	ret\r
\r
null$status:\r
	xor	a\r
	ret\r
\r
	end\r