put char-i/o in banked memory

[z180-stamp-cpm3.git] / cbios / bioskrnl.180

	title	'Root module of relocatable BIOS for CP/M 3.0'\r
\r
	; version 1.0 15 Sept 82\r
\r
	include config.inc\r
	include	z180reg.inc\r
\r
\r
;		  Copyright (C), 1982\r
;		 Digital Research, Inc\r
;		     P.O. Box 579\r
;		Pacific Grove, CA  93950\r
\r
\r
;   This is the invariant portion of the modular BIOS and is\r
;	distributed as source for informational purposes only.\r
;	All desired modifications should be performed by\r
;	adding or changing externally defined modules.\r
;	This allows producing "standard" I/O modules that\r
;	can be combined to support a particular system\r
;	configuration.\r
\r
ctlQ	equ	'Q'-'@'\r
ctlS	equ	'S'-'@'\r
\r
ccp	equ	0100h		; Console Command Processor gets loaded\r
				; into the TPA\r
\r
	cseg			; GENCPM puts CSEG stuff in common memory\r
\r
\r
    ; variables in system data page\r
\r
	extrn @covec,@civec,@aovec,@aivec,@lovec ; I/O redirection vectors\r
	extrn @mxtpa			; addr of system entry point\r
	extrn @bnkbf			; 128 byte scratch buffer\r
\r
    ; initialization\r
\r
	extrn hwinit,?init		; general initialization and signon\r
	extrn ?ldccp,?rlccp		; load & reload CCP for BOOT & WBOOT\r
\r
    ; user defined character I/O routines\r
\r
	extrn ?ci,?co,?cist,?cost	; each take device in <B>\r
	extrn ?cinit			; (re)initialize device in <C>\r
	extrn @ctbl			; physical character device table\r
\r
    ; disk communication data items\r
\r
	extrn @dtbl			; table of pointers to XDPHs\r
	public @adrv,@rdrv,@trk,@sect	; parameters for disk I/O\r
	public @dma,@dbnk,@cnt		;    ''       ''   ''  ''\r
\r
    ; memory control\r
\r
	public @cbnk			; current bank\r
	extrn ?xmove,?move		; select move bank, and block move\r
	extrn ?bank			; select CPU bank\r
\r
    ; clock support\r
\r
	extrn ?time			; signal time operation\r
\r
	include modebaud.inc		; define mode bits\r
\r
\r
    ; External names for BIOS entry points\r
\r
	public ?boot,?wboot,?const,?conin,?cono,?list,?auxo,?auxi\r
	public ?home,?sldsk,?sttrk,?stsec,?stdma,?read,?write\r
	public ?lists,?sctrn\r
	public ?conos,?auxis,?auxos,?dvtbl,?devin,?drtbl\r
	public ?mltio,?flush,?mov,?tim,?bnksl,?stbnk,?xmov\r
\r
	public bs$stack\r
\r
\r
    ; BIOS Jump vector.\r
\r
	; All BIOS routines are invoked by calling these\r
	;	entry points.\r
\r
?boot:	jp	boot		; initial entry on cold start\r
?wboot:	jp	wboot		; reentry on program exit, warm start\r
\r
?const:	jp	const		; return console input status\r
?conin:	jp	conin		; return console input character\r
?cono:	jp	conout		; send console output character\r
?list:	jp	list		; send list output character\r
?auxo:	jp      auxout		; send auxiliary output character\r
?auxi:	jp      auxin		; return auxiliary input character\r
\r
?home:	jp	home		; set disks to logical home\r
?sldsk:	jp	seldsk		; select disk drive, return disk parameter info\r
?sttrk:	jp	settrk		; set disk track\r
?stsec:	jp	setsec		; set disk sector\r
?stdma:	jp	setdma		; set disk I/O memory address\r
?read:	jp	read		; read physical block(s)\r
?write:	jp	write		; write physical block(s)\r
\r
?lists:	jp	listst		; return list device status\r
?sctrn:	jp	sectrn		; translate logical to physical sector\r
\r
?conos:	jp	conost		; return console output status\r
?auxis:	jp	auxist		; return aux input status\r
?auxos:	jp	auxost		; return aux output status\r
?dvtbl:	jp	devtbl		; return address of device def table\r
?devin:	jp	?cinit		; change baud rate of device\r
\r
?drtbl:	jp	getdrv		; return address of disk drive table\r
?mltio:	jp	multio		; set multiple record count for disk I/O\r
?flush:	jp	flush		; flush BIOS maintained disk caching\r
\r
?mov:	jp	?move		; block move memory to memory\r
?tim:	jp	?time		; Signal Time and Date operation\r
?bnksl:	jp	bnksel		; select bank for code execution and default DMA\r
?stbnk:	jp	setbnk		; select different bank for disk I/O DMA operations\r
?xmov:	jp	?xmove		; set source and destination banks for one operation\r
\r
	jp	0		; reserved for future expansion\r
	jp	0		; reserved for future expansion\r
	jp	0		; reserved for future expansion\r
\r
\r
	; BOOT\r
	;	Initial entry point for system startup.\r
\r
	dseg			; this part can be banked\r
\r
boot:\r
	ld	sp,bs$stack\r
\r
	call	hwinit		; first time hardware initialisation\r
\r
	ld	bc,16*256 + 0	; initialize all 16 character devices\r
c$init$loop:\r
	push	bc\r
	call	?cinit\r
	pop	bc\r
	inc	c\r
	djnz	c$init$loop\r
\r
	call	?init		; perform any additional system initialization\r
				; and print signon message\r
\r
	ld	bc,16*256+0\r
	ld	hl,@dtbl	; init all 16 logical disk drives\r
d$init$loop:\r
	push	bc		; save remaining count and abs drive\r
	ld	e,(hl)\r
	inc	hl\r
	ld	d,(hl)\r
	inc	hl		; grab @drv entry\r
	ld	a,e\r
	or	d\r
	jr	z,d$init$next	; if null, no drive\r
	push	hl		; save @drv pointer\r
	push	de\r
	pop	ix		; XDPH address in <DE>\r
	ld	b,(ix-2)\r
	ld	(@ADRV),bc	; save absolute and relative drive code\r
	ld	l,(ix-4)\r
	ld	h,(ix-3)	; get init pointer\r
	call	ipchl		; call init routine\r
	pop	hl		; recover @drv pointer\r
d$init$next:\r
	pop	bc		; recover counter and drive #\r
	inc	c\r
	djnz	d$init$loop	; and loop for each drive\r
	jp	boot$1\r
\r
	cseg	; following in resident memory\r
\r
boot$1:\r
	call	set$jumps\r
	call	?ldccp		; fetch CCP for first time\r
	jp	ccp\r
\r
\r
	; WBOOT\r
	;	Entry for system restarts.\r
\r
wboot:\r
	ld	sp,bs$stack\r
	call	set$jumps	; initialize page zero\r
	call	?rlccp		; reload CCP\r
	jp	ccp		; then reset jmp vectors and exit to ccp\r
\r
\r
set$jumps:\r
\r
  if banked\r
	ld	a,1\r
	call	?bnksl\r
  endif\r
\r
	ld	a,0C3h		; jp opcode\r
	ld	(0),a\r
	ld	(5),a		; set up jumps in page zero\r
	ld	hl,?wboot\r
	ld	(1),hl		; BIOS warm start entry\r
	ld	hl,(@MXTPA)\r
	ld	(6),hl		; BDOS system call entry\r
	ret\r
\r
\r
	ds bs$stack$size\r
bs$stack	equ $\r
\r
\r
	; DEVTBL\r
	;	Return address of character device table\r
\r
devtbl:\r
	ld	hl,@ctbl\r
	ret\r
\r
\r
	; GETDRV\r
	;	Return address of drive table\r
\r
getdrv:\r
	ld	hl,@dtbl\r
	ret\r
\r
\r
\r
	; LIST\r
	;	List Output.  Send character in <C>\r
	;			to all selected devices.\r
\r
list:\r
	ld	hl,(@lovec)	; fetch list output bit vector\r
	jr	out$scan\r
\r
\r
	; AUXOUT\r
	;	Auxiliary Output. Send character in <C>\r
	;			to all selected devices\r
\r
auxout:\r
	ld	hl,(@aovec)	; fetch aux output bit vector\r
	jr	out$scan\r
\r
\r
	; CONOUT\r
	;	Console Output.  Send character in <C>\r
	;			to all selected devices\r
\r
conout:\r
\r
	ld	hl,(@covec)	; fetch console output bit vector\r
\r
out$scan:\r
	ld	b,0		; start with device 0\r
co$next:\r
	add	hl,hl		; shift out next bit\r
	jr	nc,not$out$device\r
	push	hl		; save the vector\r
;	push	bc		; save the count and character\r
;not$out$ready:\r
;	call	coster\r
;	or	a\r
;	jr	z,not$out$ready\r
;	pop	bc\r
	push	bc		; restore and resave the character and device\r
	call	?co		; if device selected, print it\r
	pop	bc		; recover count and character\r
	pop	hl		; recover the rest of the vector\r
not$out$device:\r
	inc	b		; next device number\r
	ld	a,h\r
	or	l		; see if any devices left\r
	jr	nz,co$next	; and go find them...\r
	ret\r
\r
\r
	; LISTST\r
	;	List Output Status.  Return true if\r
	;		all selected list output devices\r
	;		are ready.\r
\r
listst:\r
	ld	hl,(@lovec)	; get list output bit vector\r
	jr	ost$scan\r
\r
\r
	; AUXOST\r
	;	Auxiliary Output Status.  Return true if\r
	;		all selected auxiliary output devices\r
	;		are ready.\r
\r
auxost:\r
	ld	hl,(@aovec)	; get aux output bit vector\r
	jr	ost$scan\r
\r
\r
	; CONOST\r
	;	Console Output Status.  Return true if\r
	;		all selected console output devices\r
	;		are ready.\r
\r
conost:\r
	ld	hl,(@covec)	; get console output bit vector\r
\r
ost$scan:\r
	ld	b,0		; start with device 0\r
cos$next:\r
	add	hl,hl		; check next bit\r
	push	hl		; save the vector\r
	push	bc		; save the count\r
	ld	a,0FFh		; assume device ready\r
	call	c,coster	; check status for this device\r
	pop	bc		; recover count\r
	pop	hl		; recover bit vector\r
	or	a		; see if device ready\r
	ret	z			; if any not ready, return false\r
	inc	b		; drop device number\r
	ld	a,h\r
	or	l		; see if any more selected devices\r
	jr	nz,cos$next\r
	or	0FFh		; all selected were ready, return true\r
	ret\r
\r
	; check for output device ready, including optional\r
	;	xon/xoff support\r
coster:\r
	ld	l,b\r
	ld	h,0		; make device code 16 bits\r
	push	hl		; save it in stack\r
	add	hl,hl\r
	add	hl,hl\r
	add	hl,hl		; create offset into device characteristics tbl\r
	ld	de,@ctbl+6\r
	add	hl,de		; make address of mode byte\r
	ld	a,(hl)\r
	and	mb$xon$xoff\r
	pop	hl		; recover console number in <HL>\r
	jp	z,?cost		; not a xon device, go get output status direct\r
	ld	de,xofflist\r
	add	hl,de		; make pointer to proper xon/xoff flag\r
	call	cist1		; see if this keyboard has character\r
	ld	a,(hl)\r
	call	nz,ci1		; get flag or read key if any\r
	cp	ctlq\r
	jr	nz,not$q	; if its a ctl-Q,\r
	ld	a,0FFh 		;	set the flag ready\r
not$q:\r
	cp	ctls\r
	jr	nz,not$s	; if its a ctl-S,\r
	ld	a,00h		;	clear the flag\r
not$s:\r
	ld	(hl),a		; save the flag\r
	call 	cost1		; get the actual output status,\r
	and	(hl)		; and mask with ctl-Q/ctl-S flag\r
	ret			; return this as the status\r
\r
cist1:				; get input status with <BC> and <HL> saved\r
	push	bc\r
	push	hl\r
	call	?cist\r
	pop	hl\r
	pop	bc\r
	or	a\r
	ret\r
\r
cost1:				; get output status, saving <BC> & <HL>\r
	push	bc\r
	push	hl\r
	call	?cost\r
	pop	hl\r
	pop	bc\r
	or	a\r
	ret\r
\r
ci1:				; get input, saving <BC> & <HL>\r
	push	bc\r
	push	hl\r
	call	?ci\r
	pop	hl\r
	pop	bc\r
	ret\r
\r
\r
	; AUXIST\r
	;	Auxiliary Input Status.  Return true if\r
	;		any selected auxiliary input device\r
	;		has an available character.\r
\r
auxist:\r
	ld	hl,(@aivec)	; get aux input bit vector\r
	jr	ist$scan\r
\r
\r
	; CONST\r
	;	Console Input Status.  Return true if\r
	;		any selected console input device\r
	;		has an available character.\r
\r
const:\r
	ld	hl,(@civec)	; get console input bit vector\r
\r
ist$scan:\r
	ld	b,0		; start with device 0\r
cis$next:\r
	add	hl,hl		; check next bit\r
	ld	a,0		; assume device not ready\r
	call	c,cist1	; check status for this device\r
	or	a\r
	ret	nz		; if any ready, return true\r
	inc	b		; next device number\r
	ld	a,h\r
	or	l		; see if any more selected devices\r
	jr	nz,cis$next\r
	xor	a		; all selected were not ready, return false\r
	ret\r
\r
\r
	; AUXIN\r
	;	Auxiliary Input.  Return character from first\r
	;		ready auxiliary input device.\r
\r
auxin:\r
	ld	hl,(@aivec)\r
	jr	in$scan\r
\r
\r
	; CONIN\r
	;	Console Input.  Return character from first\r
	;		ready console input device.\r
\r
conin:\r
	ld	hl,(@civec)\r
\r
in$scan:\r
	push	hl		; save bit vector\r
	ld	b,0\r
ci$next:\r
	add	hl,hl		; shift out next bit\r
	ld	a,0		; insure zero a  (nonexistant device not ready).\r
	call	c,cist1		; see if the device has a character\r
	or	a\r
	jr	nz,ci$rdy	; this device has a character\r
	inc	b		; else, next device\r
	ld	a,h\r
	or	l		; see if any more devices\r
	jr	nz,ci$next	; go look at them\r
	pop	hl		; recover bit vector\r
	jr	in$scan		; loop til we find a character\r
\r
ci$rdy:\r
	pop	hl		; discard extra stack\r
	jp	?ci\r
\r
\r
;-------------------------------------------------------------------------------\r
; Utility Subroutines\r
\r
\r
ipchl:		; vectored CALL point\r
	jp	(hl)\r
\r
\r
\r
	; BNKSEL\r
	;	Bank Select.  Select CPU bank for further execution.\r
\r
bnksel:\r
	ld	(@cbnk),a	; remember current bank\r
	jp	?bank		; and go exit through users\r
				; physical bank select routine\r
\r
\r
xofflist:\r
	db	-1,-1,-1,-1,-1,-1,-1,-1		; ctl-s clears to zero\r
	db	-1,-1,-1,-1,-1,-1,-1,-1\r
\r
	dseg	; following resides in banked memory\r
\r
;	Disk I/O interface routines\r
\r
\r
	; SELDSK\r
	;	Select Disk Drive.  Drive code in <C>.\r
	;		Invoke login procedure for drive\r
	;		if this is first select.  Return\r
	;		address of disk parameter header\r
	;		in <HL>\r
\r
seldsk:\r
	ld	a,c		; save drive select code\r
	ld	(@adrv),a\r
	ld	b,0		; create index from drive code\r
	ld	hl,@dtbl\r
	add	hl,bc		; get pointer to dispatch table\r
	add	hl,bc\r
	ld	a,(hl)\r
	inc	hl\r
	ld	h,(hl)\r
	ld	l,a		; point at disk descriptor\r
	ld	(@xdph),hl	; save descriptor pointer\r
	or	h\r
	ret	z 		; if no entry in table, no disk\r
\r
	ld	a,e		; examine login bit\r
	and	1\r
	ret	nz\r
\r
	push	ix\r
	ld	ix,(@xdph)\r
	ld	a,(ix-2)\r
	ld	(@RDRV),a	; get relative drive\r
	ld	l,(ix-6)	; get address of LOGIN routine\r
	ld	h,(ix-5)\r
	ex	(sp),ix\r
	pop	de\r
	call	ipchl		; call LOGIN\r
	ld	hl,(@xdph)	; recover DPH pointer\r
	ret\r
\r
\r
	; HOME\r
	;	Home selected drive.  Treated as SETTRK(0).\r
\r
home:\r
	ld	bc,0		; same as set track zero\r
\r
\r
	; SETTRK\r
	;	Set Track. Saves track address from <BC>\r
	;		in @TRK for further operations.\r
\r
settrk:\r
	ld	(@trk),bc\r
	ret\r
\r
\r
	; SETSEC\r
	;	Set Sector.  Saves sector number from <BC>\r
	;		in @sect for further operations.\r
\r
setsec:\r
	ld	(@sect),bc\r
	ret\r
\r
\r
	; SETDMA\r
	;	Set Disk Memory Address.  Saves DMA address\r
	;		from <BC> in @DMA and sets @DBNK to @CBNK\r
	;		so that further disk operations take place\r
	;		in current bank.\r
\r
setdma:\r
	ld	(@dma),bc\r
\r
	ld	a,(@cbnk)	; default DMA bank is current bank\r
				; fall through to set DMA bank\r
\r
	; SETBNK\r
	;	Set Disk Memory Bank.  Saves bank number\r
	;		in @DBNK for future disk data\r
	;		transfers.\r
\r
setbnk:\r
	ld	(@dbnk),a\r
	ret\r
\r
\r
	; SECTRN\r
	;	Sector Translate.  Indexes skew table in <DE>\r
	;		with sector in <BC>.  Returns physical sector\r
	;		in <HL>.  If no skew table (<DE>=0) then\r
	;		returns physical=logical.\r
\r
sectrn:\r
	ld	l,c\r
	ld	h,b\r
	ld	a,d\r
	or	e\r
	ret	z\r
	ex	de,hl\r
	add	hl,bc\r
	ld	l,(hl)\r
	ld	h,0\r
	ret\r
\r
\r
	; READ\r
	;	Read physical record from currently selected drive.\r
	;		Finds address of proper read routine from\r
	;		extended disk parameter header (XDPH).\r
\r
read:\r
	ld	ix,(@xdph)	; get drive descriptor pointer\r
	ld	l,(ix-8)	; get read routine entry\r
	ld	h,(ix-7)\r
	jp	(hl)\r
\r
\r
	; WRITE\r
	;	Write physical sector from currently selected drive.\r
	;		Finds address of proper write routine from\r
	;		extended disk parameter header (XDPH).\r
\r
write:\r
	ld	ix,(@xdph)	; get drive descriptor pointer\r
	ld	l,(ix-10)	; get write routine entry\r
	ld	h,(ix- 9)\r
	jp	(hl)\r
\r
\r
\r
	; MULTIO\r
	;	Set multiple sector count. Saves passed count in\r
	;		@CNT\r
\r
multio:\r
	ld	(@cnt),a\r
	ret\r
\r
\r
	; FLUSH\r
	;	BIOS deblocking buffer flush.  Not implemented.\r
\r
flush:\r
	xor	a\r
	ret			; return with no error\r
\r
\r
; disk communication data items\r
;     do not change order. sd driver depends on this\r
\r
@xdph:	ds	2		; pointer to currently selected drives dph\r
@adrv:	ds	1		; currently selected disk drive\r
@rdrv:	ds	1		; controller relative disk drive\r
@trk:	ds	2		; current track number\r
@sect:	ds	2		; current sector number\r
@dma:	ds	2		; current DMA address\r
@dbnk:	db	0		; bank for DMA operations\r
@cnt:	db	0		; record count for multisector transfer\r
\r
\r
	cseg	; common memory\r
\r
@cbnk:	db	0		; bank for processor operations\r
\r
\r
	end\r