put char-i/o in banked memory

[z180-stamp-cpm3.git] / cbios / chario.180

	title	'Character I/O Module for the Modular CP/M 3 BIOS'\r
	page	255\r
	.z80\r
\r
\r
\r
	public ?cinit,?ci,?co,?cist,?cost\r
	public @ctbl\r
\r
\r
	extrn	ff.init,ff.ist,ff.in,ff.ost,ff.out\r
	extrn	as0init,as0ista,as0inp,as0osta,as0out\r
	extrn	as1init,as1ista,as1inp,as1osta,as1out\r
	extrn	_b0call\r
\r
	include config.inc\r
	include	z180reg.inc\r
\r
	include modebaud.inc	; define mode bits and baud equates\r
\r
max$devices equ	3\r
\r
\r
;--------------------------------------------------------------\r
; Init character device\r
;     c: device\r
\r
	cseg\r
?cinit:				; init devices\r
	b0call	_cinit\r
	ret\r
\r
	dseg\r
_cinit:\r
	ld	b,c\r
	call	vector$io\r
	dw	ff.init\r
	dw	as0init\r
	dw	as1init\r
	dw	rret\r
\r
\r
;--------------------------------------------------------------\r
; Character input\r
;     b: device\r
;    return:\r
;     a: input char\r
\r
	cseg\r
?ci:				; character input\r
	b0call	_ci\r
	ret\r
\r
	dseg\r
_ci:\r
	call	vector$io\r
	dw	ff.in\r
	dw	as0inp\r
	dw	as1inp\r
	dw	null$input\r
\r
;--------------------------------------------------------------\r
; Input status\r
;     b: device\r
;    return:\r
;     a: 0ffh if char available, else 0\r
\r
	cseg\r
?cist:				; character input\r
	b0call	_cist\r
	ret\r
\r
	dseg\r
_cist:				; character input status\r
	call	vector$io\r
	dw	ff.ist\r
	dw	as0ista\r
	dw	as1ista\r
	dw	null$status\r
\r
;--------------------------------------------------------------\r
; Character output\r
;     b: device\r
;     c: output char\r
;    return:\r
;     a: output char\r
\r
	cseg\r
?co:				; character input\r
	b0call	_co\r
	ret\r
\r
	dseg\r
_co:				; character output\r
	call	vector$io\r
	dw	ff.out\r
	dw	as0out\r
	dw	as1out\r
	dw	rret\r
\r
\r
;--------------------------------------------------------------\r
; Output status\r
;     b: device\r
;    return:\r
;     a: 0ffh if device ready for next output char, else 0\r
\r
\r
	cseg\r
?cost:				; character input\r
	b0call	_cost\r
	ret\r
\r
	dseg\r
_cost:				; character output status\r
	call	vector$io\r
	dw	ff.ost\r
	dw	as0osta\r
	dw	as1osta\r
	dw	ret$true\r
\r
;--------------------------------------------------------------\r
\r
	dseg\r
vector$io:\r
	pop	hl\r
	push	de\r
	ld	de,max$devices	; default if\r
	ld	a,b		;\r
	cp	e             	;    b > max$devices\r
	jr	nc,exist\r
	ld	e,a\r
exist:\r
	add	hl,de\r
	add	hl,de\r
\r
	ld	e,(hl)\r
	inc	hl\r
	ld	d,(hl)\r
	ex	de,hl\r
	pop	de\r
	jp	(hl)\r
\r
\r
null$input:\r
	ld	a,1Ah\r
rret:\r
	ret\r
ret$true:\r
	or	0FFh\r
	ret\r
\r
null$status:\r
	xor	a\r
	ret\r
\r
;--------------------------------------------------------------\r
\r
	cseg\r
@ctbl:\r
	db	'AVRCON'	; device 0\r
	db	mb$in$out\r
	db	baud$none\r
\r
	db	'ASCI0 '	; device 1\r
	db	mb$in$out+mb$serial+mb$soft$baud\r
	db	baud$9600\r
\r
	db	'ASCI1 '	; device 2\r
	db	mb$in$out+mb$serial+mb$soft$baud\r
	db	baud$19200\r
\r
	db	0		; table terminator\r
\r
\r
	end\r