Add new driver: cfio

[z180-stamp-cpm3.git] / cbios / cpm3slr.lib

;	Macro Definitions for CP/M3 BIOS Data Structures.\r
\r
	; dtbl	<dph0,dph1,...>		- drive table\r
\r
	; dph	translate$table,	- disk parameter header\r
	;	disk$parameter$block,\r
	;	checksum$size,			(optional)\r
	;	alloc$size			(optional)\r
\r
	; skew	sectors,		- skew table\r
	;	skew$factor,\r
	;	first$sector$number\r
\r
	; dpb	physical$sector$size,	- disk parameter block\r
	;	physical$sectors$per$track,\r
	;	number$tracks,\r
	;	block$size,\r
	;	number$dir$entries,\r
	;	track$offset,\r
	;	checksum$vec$size		(optional)\r
\r
\r
;	Drive Table.  Contains 16 one word entries.\r
\r
dtbl macro ?list\r
    local ?n\r
?n  defl 0\r
    irp ?drv,<?list>\r
?n  defl ?n+1\r
	dw	?drv\r
    endm\r
\r
    if ?n > 16\r
.' Too many drives.  Max 16 allowed'\r
	exitm\r
    endif\r
\r
    if ?n < 16\r
	rept (16-?n)\r
	dw	0\r
	endm\r
    endif\r
 endm\r
\r
dph macro ?trans,?dpb,?csize,?asize\r
    local ?csv,?alv\r
	dw ?trans		; translate table address\r
	db 0,0,0,0,0,0,0,0,0	; BDOS Scratch area\r
	db 0			; media flag\r
	dw ?dpb			; disk parameter block\r
    if not nul ?csize\r
      if ?csize = 0\r
	dw 0			; permanently mounted, no checksum vector\r
      else\r
	dw ?csv			; checksum vector\r
      endif\r
    else\r
	dw 0FFFEh		; checksum vector alloc'd by GENCPM\r
    endif\r
    if not nul ?asize\r
	dw ?alv			; allocation vector\r
    else\r
	dw 0FFFEh		; alloc vector allocated by GENCPM\r
    endif\r
	dw 0fffeh,0fffeh,0fffeh	; dirbcb, dtabcb, hash alloc'd\r
				; by GENCPM\r
	db 0			; hash bank\r
\r
    if not nul ?csize\r
      if ?csize <> 0\r
?csv	ds	?csize		; checksum vector\r
      endif\r
    endif\r
    if not nul ?asize\r
?alv	ds	?asize		; allocation vector\r
    endif\r
\r
    endm\r
\r
dpb macro ?psize,?pspt,?trks,?bls,?ndirs,?off,?ncks\r
    local ?spt,?bsh,?blm,?exm,?dsm,?drm,?al0,?al1,?cks,?psh,?psm\r
    local ?n\r
;; physical sector mask and physical sector shift\r
    ?psh	defl 0\r
    ?n		defl ?psize/128\r
    ?psm	defl ?n-1\r
	rept 8\r
	?n	defl ?n/2\r
 	    if ?n = 0\r
	    exitm\r
	    endif\r
	?psh	defl ?psh + 1\r
	endm\r
    ?spt	defl ?pspt*(?psize/128)\r
\r
    ?bsh	defl 3\r
    ?n		defl ?bls/1024\r
	rept 8\r
	?n	defl ?n/2\r
	    if ?n = 0\r
	    exitm\r
	    endif\r
	?bsh	defl ?bsh + 1\r
	endm\r
    ?blm	defl ?bls/128-1\r
    ?size	defl (?trks-?off)*?spt\r
    ?dsm	defl ?size/(?bls/128)-1\r
\r
    ?exm	defl ?bls/1024\r
	if ?dsm > 255\r
	    if ?bls = 1024\r
.'Error, can''t have this size disk with 1k block size'\r
	    exitm\r
	    endif\r
	?exm	defl ?exm/2\r
	endif\r
    ?exm	defl ?exm-1\r
    ?all	defl 0\r
    ?n		defl (?ndirs*32+?bls-1)/?bls\r
	rept ?n\r
	?all	defl (?all shr 1) or 8000h\r
	endm\r
    ?al0	defl high ?all\r
    ?al1	defl low ?all\r
    ?drm	defl ?ndirs-1\r
    if not nul ?ncks\r
    	?cks	defl ?ncks\r
    else\r
	?cks	defl ?ndirs/4\r
    endif\r
	dw	?spt		; 128 byte records per track\r
	db	?bsh,?blm	; block shift and mask\r
	db	?exm		; extent mask\r
	dw	?dsm		; maximum block number\r
	dw	?drm		; maximum directory entry number\r
	db	?al0,?al1	; alloc vector for directory\r
	dw	?cks		; checksum size\r
	dw	?off		; offset for system tracks\r
	db	?psh,?psm	; physical sector size shift\r
				; and mask\r
    endm\r
\r
;\r
gcd macro ?m,?n\r
	    ;;	greatest common divisor of m,n\r
		    ;;	produces value gcdn as result\r
		    ;;	(used in sector translate table generation)\r
    ?gcdm	defl ?m	;;variable for m\r
    ?gcdn	defl ?n	;;variable for n\r
    ?gcdr	defl 0	;;variable for r\r
	rept 65535\r
	?gcdx	defl ?gcdm/?gcdn\r
	?gcdr	defl ?gcdm - ?gcdx*?gcdn\r
	    if ?gcdr = 0\r
	    exitm\r
	    endif\r
	?gcdm	defl ?gcdn\r
	?gcdn	defl ?gcdr\r
	endm\r
    endm\r
\r
skew macro ?secs,?skf,?fsc\r
;;	generate the translate table\r
    ?nxtsec	defl 0	;;next sector to fill\r
    ?nxtbas	defl 0	;;moves by one on overflow\r
    gcd %?secs,?skf\r
    ;;	?gcdn = gcd(?secs,skew)\r
    ?neltst	defl ?secs/?gcdn\r
    ;;	neltst is number of elements to generate\r
    ;;	before we overlap previous elements\r
    ?nelts	defl ?neltst	;;counter\r
	rept ?secs	;;once for each sector\r
	db	?nxtsec+?fsc\r
	?nxtsec	defl ?nxtsec+?skf\r
	    if ?nxtsec >= ?secs\r
	    ?nxtsec	defl ?nxtsec-?secs\r
	    endif\r
	?nelts	defl ?nelts-1\r
	    if ?nelts = 0\r
	    ?nxtbas	defl ?nxtbas+1\r
	    ?nxtsec	defl ?nxtbas\r
	    ?nelts	defl ?neltst\r
	    endif\r
	endm\r
    endm\r