Extended drive table for use with DRIVE.COM, a dynamic drive re-assignment utility.

[z180-stamp-cpm3.git] / cbios / sdio.180

	TITLE 'sd disk handler'\r
\r
;    CP/M-80 Version 3     --  Modular BIOS\r
\r
\r
    ; Disk drive dispatching tables for linked BIOS\r
\r
	public sd0,sd1,sd2,sd3\r
	public sd4,sd5,sd6,sd7\r
\r
    ; Variables containing parameters passed by BDOS\r
\r
	extrn @xdph,@op\r
	extrn @adrv,@rdrv\r
	extrn @trk,@sect,@cnt\r
	extrn @dma,@dbnk\r
\r
    ; System Control Block variables\r
\r
	extrn @ermde		; BDOS error mode\r
\r
    ; Utility routines\r
\r
	extrn ?wboot		; warm boot vector\r
	extrn pr.idx		; print indexed message\r
	extrn pr.inln		; print inline message\r
	extrn pr.errors		; print BIOS disk error header\r
	extrn bnk2phy		; translate banked to physical linear address\r
	extrn msg.sm		; send message to AVR\r
	extrn msg.recv		; receive message from AVR\r
	extrn add_hla		; add <A> to <HL>\r
\r
\r
    ; Port Address Equates\r
\r
	maclib z180reg.inc\r
	maclib config.inc\r
\r
    ; CP/M 3 Disk definition macros\r
\r
	maclib cpm3slr.lib\r
\r
    ; Z180 macro library instruction definitions (ignored by slr180)\r
\r
	maclib z180.lib\r
\r
    ; common control characters\r
\r
cr	equ	13\r
lf	equ	10\r
bell	equ	7\r
\r
\r
	dseg\r
\r
    ; Extended Disk Parameter Headers (XPDHs)\r
\r
	; dph	translate$table,	- disk parameter header\r
	;	disk$parameter$block,\r
	;	checksum$size,			(optional)\r
	;	alloc$size			(optional)\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init0\r
	db	0,0		; relative drive zero\r
sd0:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init1\r
	db	1,0		; relative drive one\r
sd1:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init2\r
	db	2,0		; relative drive zero\r
sd2:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init3\r
	db	3,0		; relative drive one\r
sd3:	dph 0,dpbsimhd512\r
\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init4\r
	db	4,0		; relative drive zero\r
sd4:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init5\r
	db	5,0		; relative drive one\r
sd5:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init6\r
	db	6,0		; relative drive zero\r
sd6:	dph 0,dpbsimhd512\r
\r
	dw	sd$write\r
	dw	sd$read\r
	dw	sd$login\r
	dw	sd$init7\r
	db	7,0		; relative drive one\r
sd7:	dph 0,dpbsimhd512\r
\r
\r
	cseg			; DPB must be resident\r
\r
	; dpb	physical$sector$size,	- disk parameter block\r
	;	physical$sectors$per$track,\r
	;	number$tracks,\r
	;	block$size,\r
	;	number$dir$entries,\r
	;	track$offset,\r
	;	checksum$vec$size		(optional)\r
\r
dpbsimhd512:\r
	dpb 512,8,2048,4096,1024,6,8100h\r
\r
\r
	dseg			; rest is banked\r
\r
; Disk I/O routines for standardized BIOS interface\r
\r
; Initialization entry point.\r
; called for first time initialization.\r
\r
sd$init0:\r
	call	pr.inln			;\r
	dc	'sdio: SD Card driver',cr,lf\r
	ret\r
\r
sd$init1:\r
sd$init2:\r
sd$init3:\r
sd$init4:\r
sd$init5:\r
sd$init6:\r
sd$init7:\r
	ret	; all initialization done by drive 0\r
\r
\r
; This entry is called when a logical drive is about to\r
; be logged into for the purpose of density determination.\r
; It may adjust the parameters contained in the disk\r
; parameter header pointed at by <DE>\r
;\r
;     absolute drive number in @adrv (8 bits)	+0\r
;     relative drive number in @rdrv (8 bits)	+1\r
\r
sd$login:\r
	xor	a\r
	ld	(residual),a\r
	ld	hl,send_msg+1\r
	ld	(hl),0		;login function\r
	inc	hl\r
	ld	bc,(@adrv)\r
	ld	(hl),c		;@adrv\r
	inc	hl\r
	ld	(hl),b		;@rdrv\r
	inc	hl\r
\r
	ex	de,hl		;xdph to hl\r
	xor	a		;bank 0\r
	call	bnk2phy		;phys. linear address\r
	ex	de,hl\r
	ld	(hl),e\r
	inc	hl\r
	ld	(hl),d\r
	inc	hl\r
	ld	(hl),a\r
\r
	ld	hl,send_msg\r
	ld	b,send_msg_login_len\r
	call	msg.sm\r
\r
	ld	hl,recv_msg\r
	ld	b,recv_msg_len	; max receive message len\r
	call	msg.recv\r
\r
	ld	a,(recv_msg_rc)\r
	or	a\r
	ret	z\r
	ld	hl,0\r
	ld	(@xdph),hl\r
	ret			;\r
\r
\r
\r
; disk READ and WRITE entry points.\r
; these entries are called with the following arguments:\r
;\r
;     operation type (r/w)  in @op   (8 bits)	+0\r
;     absolute drive number in @adrv (8 bits)	+1\r
;     relative drive number in @rdrv (8 bits)	+2\r
;     disk track address    in @trk (16 bits)	+3\r
;     disk sector address   in @sect(16 bits)	+5\r
;     multi sector count    in @cnt  (8 bits)	+7\r
;     disk transfer address in @dma (16 bits)	+8\r
;     disk transfer bank    in @dbnk (8 bits)	+10\r
;     pointer to XDPH 	    in <DE>\r
;\r
;     they transfer the appropriate data, perform retries\r
;     if necessary, then return an error code in <A>\r
\r
sd$read:\r
sd$write:\r
	ld	hl,residual	; remainng sectors from last multi io?\r
	ld	a,(hl)\r
	sub	a,1\r
	jr	c,rwc_new_sectors\r
\r
	ld	(hl),a\r
	xor	a\r
	ret\r
\r
rwc_new_sectors:\r
	ld	b,1		; assume 1 sector to transfer\r
	ld	a,(@cnt)\r
	or	a\r
	jr	z,rwc_doit\r
\r
	ld	b,a		; number of sectors to transfer\r
	dec	a		; save remaining\r
	ld	(hl),a\r
	xor	a		; reset multi sector count\r
	ld	(@cnt),a\r
\r
; compute pysical transfer address\r
;     prepare message\r
;     and send it to AVR.\r
\r
rwc_doit:\r
	ld	a,b\r
	ld	hl,@op		;address of arguments\r
	ld	de,send_msg+1\r
	ld	bc,7\r
	ldir\r
	ld	(de),a		;number of sectors\r
	inc	de\r
	push	de\r
	ld	e,(hl)		;dma address\r
	inc	hl\r
	ld	d,(hl)\r
	inc	hl\r
	ld	a,(hl)		;bank\r
	ex	de,hl\r
	call	bnk2phy		;phys. linear address\r
	ex	de,hl\r
	pop	hl\r
	ld	(hl),e\r
	inc	hl\r
	ld	(hl),d\r
	inc	hl\r
	ld	(hl),a\r
\r
retry:\r
\r
	ld	hl,send_msg\r
	ld	b,send_msg_rw_len\r
	call	msg.sm\r
\r
	ld	hl,recv_msg\r
	ld	b,recv_msg_len	; max receive message len\r
	call	msg.recv\r
	ld	a,(recv_msg_rc)\r
	or	a\r
	ret	z		; check status and return to BDOS if no error\r
\r
	ld	hl,print_details\r
	call	pr.errors\r
	jr	z,retry		; Yes, then retry once more\r
				; otherwise,\r
	xor	a\r
	ld	(residual),a\r
	ld	a,(recv_msg_rc)	; return hard error to BDOS\r
	ld	c,0ffh\r
	cp	6		; media changed?\r
	jr	z,e_exit\r
	ld	c,2\r
	cp	5		; disk read only?\r
	jr	z,e_exit\r
	dec	c\r
e_exit:\r
	ld	a,c\r
	ret\r
\r
;-------------------------------------------------------------------------------\r
\r
print_details:\r
	ld	a,(recv_msg_rc)\r
	push	af\r
	and	a,07fh\r
	jr	z,fatfs_err\r
\r
	ld	hl,drvmsg0	; point at first driver error message\r
	call	pr.idx\r
\r
fatfs_err:\r
	pop	af\r
	and	080h\r
	ret	z		; no fatfs error\r
\r
	call	pr.inln\r
	dc	'FatFs: '\r
\r
	ld	hl,fr$msg0	; point at first FatFs message\r
	ld	a,(recv_msg_rc+1)\r
	jp	pr.idx		; return via print routine\r
\r
\r
;-------------------------------------------------------------------------------\r
\r
residual:\r
	db	0\r
\r
send_msg:\r
	db	2	; disk command\r
	ds	1	; subcommand (login/read/write)\r
	ds	1	; @adrv\r
	ds	1	; @rdrv\r
			; -read/write-		-login-\r
	ds	2	; @trk 			xdph address\r
	ds	2	; @sect			  (3 byte)\r
	ds	1	; @cnt\r
	ds	3	; transfer addr\r
send_msg_rw_len equ	$ - send_msg\r
send_msg_login_len equ	7\r
\r
\r
recv_msg:\r
	ds	1	; len\r
	ds	1	; command\r
	ds	1	; subcommand\r
recv_msg_rc:\r
	ds	1	; result code\r
	ds	4	; room for additional parameter\r
recv_msg_len equ $ - recv_msg\r
\r
\r
;-------------------------------------------------------------------------------\r
; error message components\r
    ; general driver errors\r
\r
drvmsg0:	dc	'Unknown Error, '\r
drvmsg1:	dc	'Invalid Parameter(s), '\r
drvmsg2:	dc	'Invalid Drive, '\r
drvmsg3:	dc	'Bus Timeout, '\r
drvmsg4:	dc	'Access beyond disk size, '\r
drvmsg5:	dc	'Write protected, '\r
drvmsg6:	dc	'No media, '\r
		db	0\r
\r
    ; fat file system errors\r
\r
fr$msg0:	dc	'Unknown Error,'\r
fr$msg1:	dc	'DISK_ERR,'\r
fr$msg2:	dc	'INT_ERR,'\r
fr$msg3:	dc	'NOT_READY,'\r
fr$msg4:	dc	'NO_FILE,'\r
fr$msg5:	dc	'NO_PATH,'\r
fr$msg6:	dc	'INVALID_NAME,'\r
fr$msg7:	dc	'DENIED,'\r
fr$msg8:	dc	'EXIST,'\r
fr$msg9:	dc	'INVALID_OBJECT,'\r
fr$msg10:	dc	'WRITE_PROTECTED,'\r
fr$msg11:	dc	'INVALID_DRIVE,'\r
fr$msg12:	dc	'NOT_ENABLED,'\r
fr$msg13:	dc	'NO_FILE_SYSTEM,'\r
fr$msg14:	dc	'MKFS_ABORTED,'\r
fr$msg15:	dc	'TIMEOUT,'\r
fr$msg16:	dc	'LOCKED,'\r
fr$msg17:	dc	'NOT_ENOUGH_CORE,'\r
fr$msg18:	dc	'TOO_MANY_OPEN_FILES,'\r
fr$msg19:	dc	'FR_INVALID_PARAMETER,'\r
fr$msg20:	dc	'short read/write,'\r
		db	0\r
\r
	end\r