cbios/sdio.180

   1         TITLE 'sd disk handler'
   2
   3 ;    CP/M-80 Version 3     --  Modular BIOS
   4
   5
   6         dseg
   7
   8     ; Disk drive dispatching tables for linked BIOS
   9
  10         public sd0,sd1,sd2,sd3
  11
  12     ; Variables containing parameters passed by BDOS
  13
  14         extrn @adrv,@rdrv
  15         extrn @trk,@sect,@cnt
  16         extrn @dma,@dbnk
  17
  18     ; System Control Block variables
  19
  20         extrn @ermde            ; BDOS error mode
  21
  22     ; Utility routines in standard BIOS
  23
  24         extrn ?wboot            ; warm boot vector
  25         extrn ?pmsg             ; print message @<HL> up to 00, saves <BC> & <DE>
  26         extrn ?pdec             ; print binary number in <A> from 0 to 99.
  27         extrn ?pderr            ; print BIOS disk error header
  28         extrn ?conin,?cono      ; con in and out
  29         extrn ?const            ; get console status
  30
  31         extrn bnk2phy           ;
  32         extrn msg.sm            ;
  33         extrn msg.recv          ;
  34         extrn add_hla
  35
  36
  37     ; Port Address Equates
  38
  39         include config.inc
  40         include z180reg.inc
  41
  42     ; CP/M 3 Disk definition macros
  43
  44         include cpm3slr.lib
  45
  46     ; Z180 macro library instruction definitions (ignored by slr180)
  47
  48         include z180.lib
  49
  50     ; common control characters
  51
  52 cr      equ     13
  53 lf      equ     10
  54 bell    equ     7
  55
  56
  57     ; Extended Disk Parameter Headers (XPDHs)
  58
  59         dw      sd$write
  60         dw      sd$read
  61         dw      sd$login
  62         dw      sd$init0
  63         db      0,0             ; relative drive zero
  64 sd0:    dph 0,dpbsimhd512
  65
  66         dw      sd$write
  67         dw      sd$read
  68         dw      sd$login
  69         dw      sd$init1
  70         db      1,0             ; relative drive one
  71 sd1:    dph 0,dpbsimhd512
  72
  73         dw      sd$write
  74         dw      sd$read
  75         dw      sd$login
  76         dw      sd$init0
  77         db      2,0             ; relative drive zero
  78 sd2:    dph 0,dpbsimhd512
  79
  80         dw      sd$write
  81         dw      sd$read
  82         dw      sd$login
  83         dw      sd$init1
  84         db      3,0             ; relative drive one
  85 sd3:    dph 0,dpbsimhd512
  86
  87
  88         cseg                    ; DPB must be resident
  89
  90 dpbsimhd512:
  91         dpb 512,8,2048,4096,1024,6
  92
  93
  94         dseg                    ; rest is banked
  95
  96 ; Disk I/O routines for standardized BIOS interface
  97
  98 ; Initialization entry point.
  99 ; called for first time initialization.
 100
 101 sd$init0:
 102         ret
 103
 104 sd$init1:
 105 sd$init2:
 106 sd$init3:
 107         ret     ; all initialization done by drive 0
 108
 109
 110
 111
 112 ; This entry is called when a logical drive is about to
 113 ; be logged into for the purpose of density determination.
 114 ; It may adjust the parameters contained in the disk
 115 ; parameter header pointed at by <DE>
 116
 117 sd$login:
 118         xor     a
 119         ld      (residual),a
 120         ld      hl,send_msg+1
 121         ld      (hl),0          ;login function
 122         inc     hl
 123         ld      bc,(@adrv)
 124         ld      (hl),c          ;@adrv
 125         inc     hl
 126         ld      (hl),b          ;@rdrv
 127         inc     hl
 128
 129         ex      de,hl           ;xdph to hl
 130         xor     a               ;bank 0
 131         call    bnk2phy         ;phys. linear address
 132         ex      de,hl
 133         ld      (hl),e
 134         inc     hl
 135         ld      (hl),d
 136         inc     hl
 137         ld      (hl),a
 138
 139         ld      hl,send_msg
 140         ld      b,send_msg_login_len
 141         call    msg.sm
 142
 143         ld      hl,recv_msg
 144         ld      b,recv_msg_len  ; max receive message len
 145         call    msg.recv
 146
 147 ;       ld      a,(recv_msg_rc)
 148 ;       or      a
 149         ret                     ;
 150
 151
 152
 153 ; disk READ and WRITE entry points.
 154 ; these entries are called with the following arguments:
 155 ;
 156 ;     absolute drive number in @adrv (8 bits)   +0
 157 ;     relative drive number in @rdrv (8 bits)   +1
 158 ;     disk track address    in @trk (16 bits)   +2
 159 ;     disk sector address   in @sect(16 bits)   +4
 160 ;     multi sector count    in @cnt  (8 bits)   +6
 161 ;     disk transfer address in @dma (16 bits)   +7
 162 ;     disk transfer bank    in @dbnk (8 bits)   +9
 163 ;     pointer to XDPH       in <DE>
 164 ;
 165 ;     they transfer the appropriate data, perform retries
 166 ;     if necessary, then return an error code in <A>
 167
 168 sd$read:
 169         ld      de,read$msg     ; point at " Read "
 170         ld      c,1
 171         jr      rw$common
 172 sd$write:
 173         ld      de,write$msg    ; point at " Write "
 174         ld      c,2
 175 rw$common:
 176         ld      hl,residual     ; remainng sectors from last multi io?
 177         ld      a,(hl)
 178         sub     a,1
 179         jr      c,rwc_new_sectors
 180
 181         ld      (hl),a
 182         xor     a
 183         ret
 184
 185 rwc_new_sectors:
 186         ld      b,1             ; assume 1 sector to transfer
 187         ld      a,(@cnt)
 188         or      a
 189         jr      z,rwc_doit
 190
 191         ld      b,a             ; number of sectors to transfer
 192         dec     a               ; save remaining
 193         ld      (hl),a
 194         xor     a               ; reset multi sector count
 195         ld      (@cnt),a
 196
 197 ; compute pysical transfer address
 198 ;     prepare message
 199 ;     and send it to AVR.
 200
 201 rwc_doit:
 202         ld      hl,send_msg+1
 203         ld      (hl),c
 204         inc     hl
 205         ld      a,b
 206         ex      de,hl
 207         ld      (operation$name),hl ; save message for errors
 208         ld      hl,@adrv        ;address of arguments
 209         ld      bc,6
 210         ldir
 211         ld      (de),a
 212         inc     de
 213         push    de
 214         ld      e,(hl)          ;dma address
 215         inc     hl
 216         ld      d,(hl)
 217         inc     hl
 218         ld      a,(hl)          ;bank
 219         ex      de,hl
 220         call    bnk2phy         ;phys. linear address
 221         ex      de,hl
 222         pop     hl
 223         ld      (hl),e
 224         inc     hl
 225         ld      (hl),d
 226         inc     hl
 227         ld      (hl),a
 228
 229 retry:
 230
 231         ld      hl,send_msg
 232         ld      b,send_msg_rw_len
 233         call    msg.sm
 234
 235         ld      hl,recv_msg
 236         ld      b,recv_msg_len  ; max receive message len
 237         call    msg.recv
 238         ld      a,(recv_msg_rc)
 239         or      a
 240         ret     z               ; check status and return to BDOS if no error
 241
 242 ; suppress error message if BDOS is returning errors to application...
 243
 244         ld      a,(@ermde)
 245         cp      0ffh
 246         jr      z,hard$error
 247
 248         ; Had permanent error, print message like:
 249         ; BIOS Err on d: T-nn, S-mm, <operation> <type>, Retry ?
 250
 251         call    ?pderr          ; print message header
 252
 253         ld      hl,(operation$name)
 254         call    ?pmsg           ; last function (read or write)
 255
 256         ld      a,(recv_msg_rc)
 257         and     a,07fh
 258         jr      z,fatfs_err
 259
 260         ld      hl,drvmsg0      ; point at first driver error message
 261         ld      c,drvmsg_count
 262         call    pdecoded
 263
 264 fatfs_err:
 265         ld      a,(recv_msg_rc)
 266         tst     080h
 267         jr      z,prompt        ; no fatfs error
 268
 269         ld      hl,fsmsg
 270         call    ?pmsg
 271
 272         ld      hl,fr$msg0      ; point at first FatFs message
 273         ld      c,fr$msg$count
 274         ld      a,(recv_msg_rc+1)
 275         call    pdecoded
 276
 277 prompt:
 278         ld      hl,error$msg
 279         call    ?pmsg           ; print "<BEL>, Retry (Y/N) ? "
 280         call    u$conin$echo    ; get operator response
 281         cp      'Y'
 282         jr      z,retry         ; Yes, then retry 10 more times
 283
 284 hard$error:
 285                                 ; otherwise,
 286         xor     a
 287         ld      (residual),a
 288
 289         ld      a,1             ; return hard error to BDOS
 290         ret
 291
 292 cancel:                         ; here to abort job
 293         jp      ?wboot          ; leap directly to warmstart vector
 294
 295
 296
 297 ; Print message to error code in A
 298 ;
 299
 300 pdecoded:
 301         push    bc
 302         push    de
 303         push    hl              ; put pointer to first message on stack
 304         cp      c
 305         jr      c,pdc_1
 306         xor     a
 307 pdc_1:
 308         ld      bc,0
 309         ld      e,a             ; save message number
 310         xor     a
 311         inc     e
 312 pdc_nxt_str:
 313         dec     e
 314         ex      (sp),hl
 315         jr      z,pdc_found
 316         ex      (sp),hl
 317         cpir
 318         jr      z,pdc_nxt_str
 319                                 ; not found (should not happen)
 320 pdc_found:
 321         pop     hl
 322         call    ?pmsg
 323         pop     de
 324         pop     bc
 325         ret
 326
 327
 328 ; get console input, echo it, and shift to upper case
 329
 330 u$conin$echo:
 331
 332         call    ?const
 333         or      a
 334         jr      z,u$c1          ; see if any char already struck
 335         call    ?conin
 336         jr      u$conin$echo    ; yes, eat it and try again
 337 u$c1:
 338         call    ?conin
 339         push    af
 340         ld      c,a
 341         cp      ' '-1
 342         call    nc,?cono
 343         pop     af
 344         cp      'a'
 345         ret     c
 346         sub     'a'-'A'         ; make upper case
 347         ret
 348
 349
 350 residual:
 351         db      0
 352
 353 send_msg:
 354         db      2       ; disk command
 355         ds      1       ; subcommand (login/read/write)
 356         ds      1       ; @adrv
 357         ds      1       ; @rdrv
 358                         ; -read/write-          -login-
 359         ds      2       ; @trk                  xdph address
 360         ds      2       ; @sect                   (3 byte)
 361         ds      1       ; @cnt
 362         ds      3       ; transfer addr
 363 send_msg_rw_len equ     $ - send_msg
 364 send_msg_login_len equ  7
 365
 366
 367 recv_msg:
 368         ds      1       ; len
 369         ds      1       ; command
 370         ds      1       ; subcommand
 371 recv_msg_rc:
 372         ds      1       ; result code
 373         ds      4       ; room for additional parameter
 374 recv_msg_len equ $ - recv_msg
 375
 376
 377     ; error message components
 378
 379 operation$name:
 380         dw      read$msg
 381 read$msg:
 382         db      ', Read, ',0
 383 write$msg:
 384         db      ', Write, ',0
 385
 386 drvmsg0:        db      'Unknown Error, ',0
 387 drvmsg1:        db      'Invalid Parameter(s), ',0
 388 drvmsg2:        db      'Invalid Drive, ',0
 389 drvmsg3:        db      'Bus Timeout, ',0
 390 drvmsg_size     equ     $ - drvmsg0
 391 drvmsg_count    equ     3
 392
 393 fsmsg:          db      'FatFs: ',0
 394
 395 ; table of pointers to error message strings
 396
 397 fr$msg0:        db      'Unknown Error,',0
 398 fr$msg1:        db      'DISK_ERR,',0
 399 fr$msg2:        db      'INT_ERR,',0
 400 fr$msg3:        db      'NOT_READY,',0
 401 fr$msg4:        db      'NO_FILE,',0
 402 fr$msg5:        db      'NO_PATH,',0
 403 fr$msg6:        db      'INVALID_NAME,',0
 404 fr$msg7:        db      'DENIED,',0
 405 fr$msg8:        db      'EXIST,',0
 406 fr$msg9:        db      'INVALID_OBJECT,',0
 407 fr$msg10:       db      'WRITE_PROTECTED,',0
 408 fr$msg11:       db      'INVALID_DRIVE,',0
 409 fr$msg12:       db      'NOT_ENABLED,',0
 410 fr$msg13:       db      'NO_FILE_SYSTEM,',0
 411 fr$msg14:       db      'MKFS_ABORTED,',0
 412 fr$msg15:       db      'TIMEOUT,',0
 413 fr$msg16:       db      'LOCKED,',0
 414 fr$msg17:       db      'NOT_ENOUGH_CORE,',0
 415 fr$msg18:       db      'TOO_MANY_OPEN_FILES,',0
 416 fr$msg19:       db      'FR_INVALID_PARAMETER,',0
 417 fr$msg20:       db      'short read/write,',0
 418 fr$msg$size     equ     $ - fr$msg0
 419 fr$msg$count    equ     20
 420
 421 error$msg:
 422         db      ' Retry (Y/N) ? ',0
 423
 424
 425         end