cbios/move.180

   1         title   'Bank & Move Module for the Modular CP/M 3 BIOS'
   2
   3 ;       CP/M-80 Version 3       -- Modular BIOS
   4 ;       Bank and Move Module for Z180-Stamp
   5 ;       Initial version 1.0
   6 ;       Compile with M80, slr180, or compatible
   7
   8         public  ?move,?xmove,?bank
   9
  10         extrn   bnk2log,bnk2phy
  11         extrn   @cbnk
  12
  13
  14         include config.inc
  15         include z180reg.inc
  16
  17
  18         cseg    ; must be in common memory
  19
  20 ?xmove:
  21     if banked
  22         ld      (src$bnk),bc    ; c -> src$bnk, b -> dst$bnk
  23     endif
  24         ret
  25
  26 ?move:
  27         ex      de,hl           ; we are passed source in DE and dest in HL
  28     if banked
  29         ld      a,(src$bnk)     ; contains 0FEh if normal block move
  30         cp      0FEh
  31         jr      nz,inter_bank_move
  32     endif
  33         ldir                    ; use Z80 block move instruction
  34         ex      de,hl           ; need next address in same regs
  35         ret
  36
  37 ; select bank in A
  38
  39 ?bank:
  40     if banked
  41         call    bnk2log
  42         out0    (bbr),a
  43     endif
  44         ret
  45
  46    if banked
  47
  48 inter_bank_move:                ; source in HL, dest in DE, count in BC
  49
  50     if 1                        ; works with new memory map
  51
  52         out0    (bcr0l),c       ; setup DMA count
  53         out0    (bcr0h),b
  54
  55         push    hl
  56         push    de
  57         ld      a,(src$bnk)
  58         call    bnk2phy
  59         out0    (sar0l),l       ; setup DMA src address
  60         out0    (sar0h),h
  61         out0    (sar0b),a
  62
  63         ex      de,hl
  64         ld      a,(dst$bnk)
  65         call    bnk2phy
  66         out0    (dar0l),l       ; setup DMA dst address
  67         out0    (dar0h),h
  68         out0    (dar0b),a
  69
  70         ld      a,M_MMOD        ; DMA burst mode
  71         out0    (dmode),a
  72         ld      a,M_DE0+M_NDWE1 ; enable DMA0
  73         out0    (dstat),a       ; move the block
  74
  75         pop     de
  76         pop     hl
  77         add     hl,bc           ; src must point past end block
  78         ex      de,hl
  79         add     hl,bc           ; and so must dst
  80         ld      bc,0
  81
  82         ld      a,0FEh
  83         ld      (src$bnk),a
  84
  85         ret                     ; return with src in DE, dst in HL, count = 0
  86
  87     else                        ; inefficient fall back
  88
  89         ld      (tmp$sp),sp
  90         ld      sp,tmp$stk
  91         ex      af,af'          ;
  92         push    af
  93 mv$blk:
  94         ld      a,(src$bnk)     ;
  95         call    ?bank
  96         ld      a,(hl)
  97         ex      af,af'          ;
  98         ld      a,(dst$bnk)
  99         call    ?bank
 100         ex      af,af'          ;
 101         ld      (de),a
 102         inc     de
 103         cpi
 104         jp      pe,mv$blk
 105         ld      a,(@cbnk)
 106         call    ?bank
 107         ld      a,0FEh
 108         ld      (src$bnk),a
 109         ex      de,hl
 110         pop     af
 111         ex      af,af'          ;
 112         ld      sp,(tmp$sp)
 113         ret
 114
 115         ds      16
 116 tmp$stk:
 117 tmp$sp:   ds    2
 118
 119     endif
 120
 121 src$bnk: db     0FEh
 122 dst$bnk: db     0FEh
 123
 124
 125    endif        ;banked
 126
 127         end